From ec45499eb813e6145d5c18e9126de0a95c153c72 Mon Sep 17 00:00:00 2001
From: Ken Hornstein <kenh@pobox.com>
Date: Sat, 11 Jan 2014 01:11:45 -0500
Subject: [PATCH] Switch over to using --mime-type, since --mime seems to
 include a charset for non-text MIME types.

---
 configure.ac   | 13 +------------
 m4/mimetype.m4 | 18 ++++++++++++++++++
 2 files changed, 19 insertions(+), 12 deletions(-)
 create mode 100644 m4/mimetype.m4

diff --git a/configure.ac b/configure.ac
index c77e9e00..46bb0e8d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -304,18 +304,7 @@ AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 AC_SUBST([MAIL_SPOOL_GRP])dnl
 
-dnl ---------------------------------------------
-dnl CHECK FOR PROGRAM TO PROVIDE MIME TYPE STRING
-dnl ---------------------------------------------
-AS_IF([file --mime "${srcdir}"/configure >/dev/null 2>&1],
-      [AS_IF([file --brief --mime "${srcdir}"/configure >/dev/null 2>&1],
-             [nmh_mimetypeproc='"file --brief --mime"'],
-             [nmh_mimetypeproc='"file --mime"'])])
-AS_CASE([$nmh_mimetypeproc], [?*],
-        [AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$nmh_mimetypeproc],
-          [Program, with arguments, that provides MIME type string.])])
-AS_ECHO_N(["AS_ESCAPE([checking program to provide MIME type string ... ])"])
-AS_ECHO(["AS_ESCAPE([$nmh_mimetypeproc], [""])"])
+NMH_MIMETYPEPROC
 
 dnl ------------------
 dnl CHECK HEADER FILES
diff --git a/m4/mimetype.m4 b/m4/mimetype.m4
new file mode 100644
index 00000000..e767ff77
--- /dev/null
+++ b/m4/mimetype.m4
@@ -0,0 +1,18 @@
+dnl
+dnl Try to see if we have a program that can determine the MIME type
+dnl of a particular file
+dnl
+
+AC_DEFUN([NMH_MIMETYPEPROC],
+[AC_CACHE_CHECK([for a program to provide a MIME type string],
+		[nmh_cv_mimetype_proc],
+  [nmh_cv_mimetype_proc=
+   for mprog in 'file --brief --mime-type' 'file --mime-type'
+   do
+     AS_IF([$mprog "${srcdir}/configure" > /dev/null 2>&1],
+     	   [nmh_cv_mimetype_proc="$mprog"; break])
+   done])
+AS_IF([test X"$nmh_cv_mimetype_proc" != X],
+      [mimetype_proc="\"${nmh_cv_mimetype_proc}\""
+       AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$mimetype_proc],
+      			  [Program, with arguments, that provides MIME type string.])])])
-- 
2.56.0