diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl -------------------------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  79 dnl find an existing installation, in which case we use its location.
  80 dnl -------------------------------------------------------------------
  81 AC_PREFIX_DEFAULT([/usr/local/nmh])
  82 AC_PREFIX_PROGRAM([mhparam])
  83
  84 dnl ------------------
  85 dnl CHECK THE COMPILER
  86 dnl ------------------
  87 dnl We want these before the checks,
  88 dnl so the checks can modify their values.
  89 test -z "$CFLAGS"  &&  auto_cflags=1
  90
  91 AC_PROG_CC([cc gcc])
  92 AM_PROG_CC_C_O
  93
  94 dnl ----------------
  95 dnl CUSTOMIZE CFLAGS
  96 dnl ----------------
  97 if test -n "$auto_cflags"; then
  98   dnl The user didn't specify CFLAGS, so customize them.
  99   if test "$GCC" = yes; then
 100     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 101     dnl version 2.763, because it disables some features in the system
 102     dnl header files and warns about them with -Wall.  Try to test for
 103     dnl that generally, with gcc.
 104     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 105       [nmh_saved_cppflags="$CPPFLAGS"
 106        nmh_saved_cflags="$CFLAGS"
 107        CPPFLAGS="-D_GNU_SOURCE"
 108        CFLAGS="-ansi -Wall -Werror"
 109        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 110          [nmh_cv_has_dash_ansi=yes],
 111          [nmh_cv_has_dash_ansi=no])
 112        CPPFLAGS="$nmh_saved_cppflags"
 113        CFLAGS="$nmh_saved_cflags"])
 114     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 115       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 116   else
 117     dnl Use -v and some other options with SunStudio cc.  lex produces
 118     dnl code that causes unreachable-statement warnings.  It might be
 119     dnl better to use an autoconf test, except -v will probably succeed
 120     dnl with many other compilers but have different meaning.
 121     AS_CASE([`${CC} -V 2>&1`],
 122             [cc:\ Sun\ C*], [CFLAGS=\
 123 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 124   fi
 125
 126   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 127                  [nmh_saved_cflags="$CFLAGS"
 128                  CFLAGS="$CFLAGS -Wall -Werror"
 129                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 130                  CFLAGS="$nmh_saved_cflags"])
 131   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 132
 133   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 134                  [nmh_saved_cflags="$CFLAGS"
 135                  CFLAGS="$CFLAGS -Wextra -Werror"
 136                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 137                                 nmh_cv_has_wextra=no)
 138                  CFLAGS="$nmh_saved_cflags"])
 139   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 140 fi
 141
 142 if test "$GCC" = yes; then
 143   dnl Do this regardless of auto_cflags value.
 144   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 145   dnl gcc 4.1 and later, but only when optimization is enabled.
 146   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 147   dnl If the user configures with a CFLAGS that contains a -O flag
 148   dnl but then removes it a make time, they'll also have to remove
 149   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 150   AS_CASE([$CFLAGS],
 151           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 152 fi
 153
 154 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 155 dnl We do this here rather than in (say) h/mh.h because this macro must
 156 dnl be defined before <stdio.h> is pulled in.
 157 dnl
 158 dnl And while we're here, add the packages tree to the cpp and ld search
 159 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 160 dnl If /usr/ports is installed, we use its idea of where things are installed,
 161 dnl otherwise we assume /usr/local.
 162
 163 AS_IF([test `uname` = FreeBSD],
 164         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 165          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 166                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 167          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 168          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 169          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 170 ])
 171
 172 dnl --------------
 173 dnl CUSTOMIZE LINK
 174 dnl --------------
 175 AS_IF([test `uname` = OpenBSD],
 176       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 177       dnl so that they don't color the waterfall.
 178       [POSTLINK="2>&1 | sed -e \
 179 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 180 AC_SUBST([POSTLINK])
 181
 182 dnl -----------------
 183 dnl CUSTOMIZE LDFLAGS
 184 dnl -----------------
 185 dnl Disable clang complaint about unused -ansi when linking.
 186 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 187                [nmh_cv_has_q_unused_arguments],
 188                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 189                        grep clang >/dev/null`],
 190                       [nmh_saved_ldflags="$LDFLAGS"
 191                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 192                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 193                                          nmh_cv_has_q_unused_arguments=no)
 194                        LDFLAGS="$nmh_saved_ldflags"],
 195                        [nmh_cv_has_q_unused_arguments=no])])
 196 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 197   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 198
 199 dnl This hack turns off assertions by default, assuming
 200 dnl that configure still uses this shell variable.  Without
 201 dnl it, AC_HEADER_ASSERT enables assertions by default.
 202 test -z "$enable_assert"  &&  enable_assert=no
 203
 204 AC_HEADER_ASSERT
 205
 206 dnl ------------------
 207 dnl CHECK FOR PROGRAMS
 208 dnl ------------------
 209 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 210 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 211 AC_PROG_RANLIB          dnl Check for `ranlib'
 212 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 213 AC_PROG_SED             dnl Check for Posix-compliant sed
 214 AC_PROG_YACC            dnl Check for yacc/bison
 215 AM_PROG_LEX             dnl Check for lex/flex
 216
 217 AM_PROG_AR
 218
 219 dnl Look for `cut'
 220 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 221 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 222
 223 dnl
 224 dnl Check for MD5 program and formatting command
 225 dnl
 226 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 227 AS_CASE(["${MD5SUM}"],
 228         [md5sum], [MD5FMT="cat"],
 229         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 230         [MD5FMT="missing"])
 231 AC_SUBST([MD5FMT])
 232
 233 dnl Look for `ls'
 234 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 235 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 236
 237 dnl See how we get ls to display the owner and the group
 238 AS_IF([test "$lspath" != "no"],
 239   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 240                  [nmh_cv_ls_grpopt],
 241   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 242     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 243     dnl ls, it would seem -l gave us both the user and group.  On this type of
 244     dnl ls, -g makes _only_ the group be displayed (and not the user).
 245     nmh_cv_ls_grpopt="-l"],[
 246     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 247     nmh_cv_ls_grpopt="-lg"])])])
 248
 249 dnl Look for `sendmail'
 250 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 251 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 252
 253 dnl Cygwin FAT filesystems do not support hard links.  So default to
 254 dnl cp instead, even if running on an NTFS or other filesystem.
 255 AS_CASE(["$host_os"],
 256   [cygwin*], [LN=cp],
 257   [LN=ln])
 258 AC_SUBST([LN])
 259
 260 dnl ----------------------------------------------------------
 261 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 262 dnl ----------------------------------------------------------
 263 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 264 [for mailspool in /var/mail        dnl
 265                   /var/spool/mail  dnl
 266                   /usr/spool/mail  dnl
 267                   /dev/null;       dnl Just in case we fall through
 268 do
 269   test -d $mailspool && break
 270 done
 271 nmh_cv_mailspool=$mailspool
 272 ])
 273 mailspool=$nmh_cv_mailspool
 274 AC_SUBST([mailspool])dnl
 275
 276 dnl See whether the mail spool directory is world-writable.
 277 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 278   AC_CACHE_CHECK(whether the mail spool is world-writable,
 279                  nmh_cv_mailspool_world_writable,
 280   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 281     nmh_cv_mailspool_world_writable=no
 282   else
 283     nmh_cv_mailspool_world_writable=yes
 284   fi])
 285 fi
 286
 287 dnl Also, check for liblockfile (as found on Debian systems)
 288 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 289
 290 dnl and whether its companion program dotlockfile is setgid
 291 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 292 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 293   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 294     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 295     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 296         nmh_cv_dotlockfile_setgid=yes
 297       else
 298         nmh_cv_dotlockfile_setgid=no
 299       fi])
 300   fi
 301 fi
 302
 303 dnl Provide a way for distcheck to disable setgid_mail via
 304 dnl DISTCHECK_CONFIGURE_FLAGS.
 305 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 306   [nmh_cv_dotlockfile_setgid=yes])
 307
 308 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 309 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 310 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 311   dnl do we really need both of these?
 312   AC_DEFINE([MAILGROUP],[1],
 313     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 314   SETGID_MAIL=1
 315 fi
 316 AC_SUBST([SETGID_MAIL])dnl
 317
 318 dnl Use ls to see which group owns the mail spool directory.
 319 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 320 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 321 ])
 322 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 323 AC_SUBST([MAIL_SPOOL_GRP])dnl
 324
 325 NMH_MIMETYPEPROC
 326 NMH_MIMEENCODINGPROC
 327
 328 dnl ------------------
 329 dnl CHECK HEADER FILES
 330 dnl ------------------
 331
 332 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 333 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 334 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 335 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 336 dnl declared; if so they should have an entry added to this case statement.
 337 dnl NB that we must define this on the compiler command line, not in config.h,
 338 dnl because it must be set before any system header is included and there's no
 339 dnl portable way to make sure that files generated by lex include config.h
 340 dnl before system header files.
 341
 342 AS_CASE(["$host_os"],
 343         [linux*],
 344         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 345         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 346
 347 AC_HEADER_TIOCGWINSZ
 348 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 349
 350 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 351   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 352 [[#if HAVE_SYS_STREAM_H
 353 #  include <sys/stream.h>
 354 #endif
 355 ]])
 356
 357 dnl ---------------
 358 dnl CHECK FUNCTIONS
 359 dnl ---------------
 360 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 361
 362 dnl Check for multibyte character set support
 363 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 364             "x$ac_cv_header_wctype_h" = "xyes" -a \
 365             "x$ac_cv_func_wcwidth" = "xyes" -a \
 366             "x$ac_cv_func_mbtowc" = "xyes"],
 367       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 368                  [Define to enable support for multibyte character sets.])
 369        MULTIBYTE_ENABLED=1],
 370       [MULTIBYTE_ENABLED=0])
 371 AC_SUBST([MULTIBYTE_ENABLED])
 372
 373 dnl -------------------
 374 dnl CHECK FOR LIBRARIES
 375 dnl -------------------
 376 dnl Checks for network libraries (nsl, socket)
 377 NMH_CHECK_NETLIBS
 378
 379 dnl Check the locking functions supported and what we should use by default
 380 NMH_LOCKING
 381
 382 dnl Check for iconv
 383 NMH_CHECK_ICONV
 384
 385 dnl Check for tputs() callback argument
 386 NMH_TPUTS_PUTC_ARG
 387
 388 termcap_curses_order="termcap curses ncurses"
 389 for lib in $termcap_curses_order; do
 390   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 391 done
 392 AC_SUBST([TERMLIB])dnl
 393 AS_IF([test "x$TERMLIB" = "x"],
 394       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 395 curses or ncurses library or package that you can install?])])
 396
 397 dnl Check for readline support
 398 NMH_READLINE
 399
 400 dnl --------------
 401 dnl CHECK FOR NDBM
 402 dnl --------------
 403
 404 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 405             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 406 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 407             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 408
 409 if test "$nmh_ndbm" = "autodetect"; then
 410   if test "$nmh_ndbmheader" != "autodetect"; then
 411     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 412   else
 413
 414     dnl There are at least four implementations of ndbm, and
 415     dnl several of those can be in different places at the whim
 416     dnl of the system integrator. A good summary of this mess
 417     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 418
 419     dnl Classic ndbm with no library required (eg NetBSD): try this
 420     dnl first so we don't accidentally link in a pointless but harmless
 421     dnl library in one of the later ndbm.h+libfoo tests:
 422     NMH_CHECK_NDBM(ndbm.h,,,
 423     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 424       NMH_CHECK_NDBM(db.h,db,,
 425     dnl Berkeley DBv1 emulating ndbm:
 426         NMH_CHECK_NDBM(ndbm.h,db,,
 427           NMH_CHECK_NDBM(ndbm.h,db1,,
 428     dnl Classic ndbm:
 429             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 430     dnl glibc2.1 systems put db1 in a subdir:
 431               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 432     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 433     dnl and possibly needing gbdm_compat library:
 434                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 435                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 436                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 437     dnl 64-bit Cygwin:
 438                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 439     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 440     dnl need to be explicit:
 441                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 442   fi
 443 else
 444   dnl We don't really need to check that the user-specified values work,
 445   dnl but it is a convenience to the user to bomb out early rather than
 446   dnl after configure and half the compile process.
 447   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 448 fi
 449
 450 if test "$nmh_ndbm_found" = "no"; then
 451   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 452 else
 453   dnl Now export the lib/header to our makefile/config.h:
 454   if test x"$nmh_ndbmheader" != x; then
 455     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 456       [Define to the header containing the ndbm API prototypes.])
 457   fi
 458   if test x"$nmh_ndbm" != x; then
 459     NDBM_LIBS="-l$nmh_ndbm"
 460   else
 461     NDBM_LIBS=
 462   fi
 463   AC_SUBST([NDBM_LIBS])
 464 fi
 465
 466 dnl ------------------
 467 dnl Set RPM build root
 468 dnl ------------------
 469 dnl nmhrpm is used in the final summary, see below.  The default value is
 470 dnl reported there as ./RPM, consistent with the reporting of the default
 471 dnl source code location as ., but its absolute path is used in the Makefile.
 472 AC_ARG_WITH([rpmdir],
 473   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 474   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 475           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 476 AC_SUBST([rpmdir])
 477
 478
 479 dnl --------------------
 480 dnl CHECK FOR CYRUS-SASL
 481 dnl --------------------
 482
 483 AS_IF([test x"$sasl_support" = x"yes"],[
 484   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 485   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 486     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 487 AC_SUBST([SASLLIB])
 488
 489 dnl -----------------
 490 dnl CHECK FOR OPENSSL
 491 dnl -----------------
 492
 493 AS_IF([test x"$tls_support" = x"yes"],[
 494   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 495   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 496   dnl automatically append -lcrypto when linking with -lssl.
 497   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 498   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 499     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 500   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 501     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 502   [TLSLIB=])
 503 AC_SUBST([TLSLIB])
 504
 505 dnl ----------------
 506 dnl CHECK FLEX FIXUP
 507 dnl ----------------
 508 dnl Use LFLAGS make variable setting to work around bugs in flex
 509 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 510 dnl http://sourceforge.net/p/flex/bugs/140/
 511 AS_IF([test "$LEX" = flex],
 512       [AS_CASE([`$LEX -V`],
 513                [flex\ 2.5.35], [LFLAGS=\
 514 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 515                [flex\ 2.5.3[[67]]], [LFLAGS=\
 516 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 517        AC_SUBST([LFLAGS])])
 518
 519 dnl ------------------
 520 dnl FOR INTERNAL USE by the NMH test suite
 521 dnl ------------------
 522 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 523 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 524       AC_SUBST([nmhetcdirinst]))
 525
 526 dnl ----------------
 527 dnl CHECK STRUCTURES
 528 dnl ----------------
 529
 530 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 531 dnl (FreeBSD has a timezone() function but not a timezone global
 532 dnl variable that is visible).
 533 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 534
 535 AC_STRUCT_DIRENT_D_TYPE
 536
 537 dnl Where is <signal.h> located?  Needed as input for signames.awk
 538 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 539 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 540                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 541                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 542                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 543                  /usr/include/sys/signal.h      dnl Almost everybody else
 544                  /dev/null;                     dnl Just in case we fall through
 545 do
 546   test -f $SIGNAL_H && \
 547   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 548   break
 549 done
 550 nmh_cv_path_signal_h=$SIGNAL_H
 551 ])
 552 SIGNAL_H=$nmh_cv_path_signal_h
 553 AC_SUBST(SIGNAL_H)dnl
 554
 555 dnl
 556 dnl Sigh, this is required because under the new world order autoconf has
 557 dnl nothing to create in a few of the build directories when doing an object
 558 dnl tree build.  So make sure we created certain directories if they don't
 559 dnl exist.
 560 dnl
 561
 562 AC_CONFIG_COMMANDS([build-directories],
 563 [test -d man || AS_MKDIR_P([man])])
 564
 565 AC_CONFIG_COMMANDS_POST([
 566
 567 dnl These odd looking assignments are done to expand out unexpanded
 568 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 569 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 570 dnl again to get the final answer.
 571 dnl We only use the expanded versions to print the install paths in
 572 dnl the final summary and should use them nowhere else (see the autoconf
 573 dnl docs for the rationale for bindir etc being unexpanded).
 574 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 575 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 576 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 577 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 578 eval "nmhrpm=${nmhrpm}";
 579
 580 AC_MSG_NOTICE([
 581 nmh configuration
 582 -----------------
 583 nmh version                : AC_PACKAGE_VERSION
 584 host os                    : ${host}
 585 compiler                   : ${CC}
 586 compiler flags             : ${CFLAGS}
 587 linker flags               : ${LDFLAGS}
 588 preprocessor flags         : ${CPPFLAGS}
 589 source code location       : ${srcdir}
 590 binary install path        : ${nmhbin}
 591 libexec install path       : ${nmhlibexec}/nmh
 592 config files install path  : ${nmhsysconf}/nmh
 593 man page install path      : ${nmhman}
 594 RPM build root             : ${nmhrpm}
 595 backup prefix              : ${backup_prefix}
 596 transport system           : ${MTS}
 597 spool default locking type : ${with_locking}
 598 default smtp servers       : ${smtpservers}
 599 SASL support               : ${sasl_support}
 600 TLS support                : ${tls_support}
 601 ])])dnl
 602
 603 dnl ---------------
 604 dnl OUTPUT MAKEFILE
 605 dnl ---------------
 606 AC_CONFIG_FILES([Makefile test/common.sh])
 607 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 608 AC_OUTPUT