diplodocus.org Git - nmh/blob - m4/mimetype.m4

   1 dnl Try to see if we have a program that can determine the MIME type
   2 dnl of a particular file
   3 dnl
   4 dnl Assume that if file(1) doesn't support --mime-type, then it's
   5 dnl unusable.  The --mime option to file 4.17 on CentOS 5.9, for
   6 dnl example, prints out a long description after the mime type.  We
   7 dnl don't want that.
   8
   9 AC_DEFUN([NMH_MIMETYPEPROC],
  10 [AC_CACHE_CHECK([for a program to provide a MIME type string],
  11                 [nmh_cv_mimetype_proc],
  12   [nmh_cv_mimetype_proc=
  13    for mprog in 'file --brief --dereference --mime-type' \
  14                 'file --dereference --mime-type' \
  15                 'file --brief --mime-type' \
  16                 'file --mime-type'
  17    do
  18      AS_IF([$mprog "${srcdir}/configure" > /dev/null 2>&1],
  19            [nmh_cv_mimetype_proc="$mprog"; break])
  20    done])
  21 AS_IF([test X"$nmh_cv_mimetype_proc" != X],
  22       [mimetype_proc="\"${nmh_cv_mimetype_proc}\""
  23        AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$mimetype_proc],
  24                   [Program, with arguments, to provide MIME type.])])])
  25
  26 dnl The OpenBSD 5.4 file (4.24) reports --mime-encoding of text
  27 dnl files as "binary".  Detect that by only accepting "us-ascii".
  28 AC_DEFUN([NMH_MIMEENCODINGPROC],
  29 [AC_CACHE_CHECK([for a program to provide a MIME encoding string],
  30                 [nmh_cv_mimeencoding_proc],
  31   [nmh_cv_mimeencoding_proc=
  32    for mprog in 'file --brief --dereference --mime-encoding' \
  33                 'file --dereference --mime-encoding' \
  34                 'file --brief --mime-encoding' \
  35                 'file --mime-encoding'
  36    do
  37      AS_IF([$mprog "${srcdir}/DATE" > /dev/null 2>&1],
  38                 AS_CASE([`$mprog "${srcdir}/DATE"`],
  39                         [us-ascii],[nmh_cv_mimeencoding_proc="$mprog"; break]))
  40    done])
  41 AS_IF([test X"$nmh_cv_mimeencoding_proc" != X],
  42       [mimeencoding_proc="\"${nmh_cv_mimeencoding_proc}\""
  43        AC_DEFINE_UNQUOTED([MIMEENCODINGPROC], [$mimeencoding_proc],
  44                   [Program, with arguments, to provide MIME encoding.])])])