diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  96 if test x"$enable_debug" = x"yes"; then
  97   test -z "$LDFLAGS" && LDFLAGS=-g
  98 fi
  99
 100 AC_PROG_CC
 101 AM_PROG_CC_C_O
 102
 103 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 104 [nmh_saved_cflags="$CFLAGS"
 105  CFLAGS="$CFLAGS -Wextra -Werror"
 106  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 107  CFLAGS="$nmh_saved_cflags"])
 108
 109 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 110 dnl setup version 2.763, because it disables some features in the
 111 dnl system system header files and warns about them with -Wall.  Try
 112 dnl to test for that generally, though still with gcc.
 113 if test "$GCC" = yes; then
 114   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 115     [nmh_saved_cppflags="$CPPFLAGS"
 116      nmh_saved_cflags="$CFLAGS"
 117      CPPFLAGS="-D_GNU_SOURCE"
 118      CFLAGS="-ansi -Wall -Werror"
 119      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 120        [nmh_cv_has_dash_ansi=yes],
 121        [nmh_cv_has_dash_ansi=no])
 122      CPPFLAGS="$nmh_saved_cppflags"
 123      CFLAGS="$nmh_saved_cflags"])
 124 else
 125   nmh_cv_has_dash_ansi=no
 126 fi
 127
 128 dnl if the user hasn't specified CFLAGS, then
 129 dnl   if compiler is gcc, then
 130 dnl    use -O2 and some warning flags
 131 dnl   else use -O
 132 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 133 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 134 dnl warnings which are probably mostly spurious and which in any case we
 135 dnl don't want to deal with now.
 136 if test "$nmh_cv_has_dash_ansi" = "yes"; then
 137     nmh_gcc_warnflags="-ansi -pedantic -Wall"
 138 else
 139     nmh_gcc_warnflags="-Wall"
 140 fi
 141 if test "$nmh_cv_has_wextra" = "yes"; then
 142     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wextra"
 143 fi
 144
 145 if test -n "$auto_cflags"; then
 146   if test x"$enable_debug" = x"yes"; then
 147     if test -n "$GCC"; then
 148       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 149     else
 150       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 151     fi
 152   else
 153     if test -z "$LDFLAGS"; then
 154       case "$build_os" in
 155         darwin*)
 156           LDFLAGS=
 157           ;;
 158         *)
 159           LDFLAGS=-s
 160           ;;
 161       esac
 162     fi
 163     if test -n "$GCC"; then
 164       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 165     else
 166       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 167     fi
 168     AC_DEFINE([NDEBUG], [1],
 169               [Define to disable run-time debugging and asserts.])
 170   fi
 171 fi
 172
 173 dnl ------------------
 174 dnl CHECK FOR PROGRAMS
 175 dnl ------------------
 176 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 177 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 178 AC_PROG_RANLIB          dnl Check for `ranlib'
 179 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 180 AC_PROG_SED             dnl Check for Posix-compliant sed
 181 AM_PROG_LEX             dnl Check for lex/flex
 182
 183 AM_PROG_AR
 184
 185 dnl Look for `cut'
 186 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 187 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 188
 189 dnl
 190 dnl Check for MD5 program and formatting command
 191 dnl
 192 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 193 AS_CASE(["${MD5SUM}"],
 194         [md5sum], [MD5FMT="cat"],
 195         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 196         [MD5FMT="missing"])
 197 AC_SUBST([MD5FMT])
 198
 199 dnl ----------------------------------------------
 200 dnl check for lclint, and lint if it doesn't exist
 201 dnl ----------------------------------------------
 202 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 203 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 204   [LINT=$ac_cv_prog_linttmp1
 205   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 206   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 207   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 208     [LINT=$ac_cv_prog_linttmp2
 209     LINTFLAGS=""],
 210     [LINT="echo 'No lint program found'"
 211     LINTFLAGS=""])])
 212 AC_SUBST([LINT])dnl
 213 AC_SUBST([LINTFLAGS])dnl
 214
 215 dnl Look for `ls'
 216 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 217 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 218
 219 dnl See how we get ls to display the owner and the group
 220 AS_IF([test "$lspath" != "no"],
 221   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 222                  [nmh_cv_ls_grpopt],
 223   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 224     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 225     dnl ls, it would seem -l gave us both the user and group.  On this type of
 226     dnl ls, -g makes _only_ the group be displayed (and not the user).
 227     nmh_cv_ls_grpopt="-l"],[
 228     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 229     nmh_cv_ls_grpopt="-lg"])])])
 230
 231 dnl Look for `sendmail'
 232 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 233 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 234
 235 dnl Cygwin FAT filesystems do not support hard links.  So default to
 236 dnl cp instead, even if running on an NTFS or other filesystem.
 237 AS_CASE(["$host_os"],
 238   [cygwin*],[LN=cp],
 239   [LN=ln])
 240 AC_SUBST([LN])
 241
 242 dnl ----------------------------------------------------------
 243 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 244 dnl ----------------------------------------------------------
 245 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 246 [for mailspool in /var/mail        dnl
 247                   /var/spool/mail  dnl
 248                   /usr/spool/mail  dnl
 249                   /dev/null;       dnl Just in case we fall through
 250 do
 251   test -d $mailspool && break
 252 done
 253 nmh_cv_mailspool=$mailspool
 254 ])
 255 mailspool=$nmh_cv_mailspool
 256 AC_SUBST([mailspool])dnl
 257
 258 dnl See whether the mail spool directory is world-writable.
 259 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 260   AC_CACHE_CHECK(whether the mail spool is world-writable,
 261                  nmh_cv_mailspool_world_writable,
 262   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 263     nmh_cv_mailspool_world_writable=no
 264   else
 265     nmh_cv_mailspool_world_writable=yes
 266   fi])
 267 fi
 268
 269 dnl Also, check for liblockfile (as found on Debian systems)
 270 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 271
 272 dnl and whether its companion program dotlockfile is setgid
 273 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 274 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 275   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 276     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 277     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 278         nmh_cv_dotlockfile_setgid=yes
 279       else
 280         nmh_cv_dotlockfile_setgid=no
 281       fi])
 282   fi
 283 fi
 284
 285 dnl Provide a way for distcheck to disable setgid_mail via
 286 dnl DISTCHECK_CONFIGURE_FLAGS.
 287 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 288   [nmh_cv_dotlockfile_setgid=yes])
 289
 290 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 291 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 292 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 293   dnl do we really need both of these?
 294   AC_DEFINE(MAILGROUP,1,
 295     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 296   SETGID_MAIL=1
 297 fi
 298 AC_SUBST([SETGID_MAIL])dnl
 299
 300 dnl Use ls to see which group owns the mail spool directory.
 301 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 302 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 303 ])
 304 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 305 AC_SUBST(MAIL_SPOOL_GRP)dnl
 306
 307 dnl ------------------
 308 dnl CHECK HEADER FILES
 309 dnl ------------------
 310
 311 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 312 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 313 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 314 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 315 dnl declared; if so they should have an entry added to this case statement.
 316 dnl NB that we must define this on the compiler command line, not in config.h,
 317 dnl because it must be set before any system header is included and there's no
 318 dnl portable way to make sure that files generated by lex include config.h
 319 dnl before system header files.
 320
 321 AS_CASE(["$host_os"],
 322         [linux*],
 323         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 324           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 325                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 326
 327 AC_HEADER_TIOCGWINSZ
 328 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 329                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 330
 331 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 332   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 333 [[#if HAVE_SYS_STREAM_H
 334 #  include <sys/stream.h>
 335 #endif
 336 ]])
 337
 338 dnl ---------------
 339 dnl CHECK FUNCTIONS
 340 dnl ---------------
 341 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 342
 343 dnl Check for multibyte character set support
 344 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 345             "x$ac_cv_header_wctype_h" = "xyes" -a \
 346             "x$ac_cv_func_wcwidth" = "xyes" -a \
 347             "x$ac_cv_func_mbtowc" = "xyes"],
 348       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 349                  [Define to enable support for multibyte character sets.])
 350        MULTIBYTE_ENABLED=1],
 351       [MULTIBYTE_ENABLED=0])
 352 AC_SUBST([MULTIBYTE_ENABLED])
 353
 354 dnl -------------------
 355 dnl CHECK FOR LIBRARIES
 356 dnl -------------------
 357 dnl Check location of modf
 358 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 359
 360 dnl Checks for network libraries (nsl, socket)
 361 NMH_CHECK_NETLIBS
 362
 363 dnl Check for readline support
 364 NMH_READLINE
 365
 366 dnl Check the locking functions supported and what we should use by default
 367 NMH_LOCKING
 368
 369 dnl Check for iconv
 370 NMH_CHECK_ICONV
 371
 372 termcap_curses_order="termcap curses ncurses"
 373 for lib in $termcap_curses_order; do
 374   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 375 done
 376 AC_SUBST([TERMLIB])dnl
 377 AS_IF([test "x$TERMLIB" = "x"],
 378       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 379 or ncurses library or package that you can install?])])
 380
 381 dnl --------------
 382 dnl CHECK FOR NDBM
 383 dnl --------------
 384
 385 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 386             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 387 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 388             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 389
 390 if test "$nmh_ndbm" = "autodetect"; then
 391   if test "$nmh_ndbmheader" != "autodetect"; then
 392     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 393   else
 394
 395     dnl There are at least four implementations of ndbm, and
 396     dnl several of those can be in different places at the whim
 397     dnl of the system integrator. A good summary of this mess
 398     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 399
 400     dnl Classic ndbm with no library required (eg NetBSD): try this
 401     dnl first so we don't accidentally link in a pointless but harmless
 402     dnl library in one of the later ndbm.h+libfoo tests:
 403     NMH_CHECK_NDBM(ndbm.h,,,
 404     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 405       NMH_CHECK_NDBM(db.h,db,,
 406     dnl Berkeley DBv1 emulating ndbm:
 407         NMH_CHECK_NDBM(ndbm.h,db,,
 408           NMH_CHECK_NDBM(ndbm.h,db1,,
 409     dnl Classic ndbm:
 410             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 411     dnl glibc2.1 systems put db1 in a subdir:
 412               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 413     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 414     dnl and possibly needing gbdm_compat library:
 415                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 416                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 417                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 418                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 419
 420   fi
 421 else
 422   dnl We don't really need to check that the user-specified values work,
 423   dnl but it is a convenience to the user to bomb out early rather than
 424   dnl after configure and half the compile process.
 425   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 426 fi
 427
 428 if test "$nmh_ndbm_found" = "no"; then
 429   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 430 else
 431   dnl Now export the lib/header to our makefile/config.h:
 432   if test x"$nmh_ndbmheader" != x; then
 433     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 434       [Define to the header containing the ndbm API prototypes.])
 435   fi
 436   if test x"$nmh_ndbm" != x; then
 437     NDBM_LIBS="-l$nmh_ndbm"
 438   else
 439     NDBM_LIBS=
 440   fi
 441   AC_SUBST([NDBM_LIBS])
 442 fi
 443
 444 dnl ------------------
 445 dnl Set RPM build root
 446 dnl ------------------
 447 dnl nmhrpm is used in the final summary, see below.  The default value is
 448 dnl reported there as ./RPM, consistent with the reporting of the default
 449 dnl source code location as ., but its absolute path is used in the Makefile.
 450 AC_ARG_WITH([rpmdir],
 451   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 452   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 453           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 454 AC_SUBST([rpmdir])
 455
 456
 457 dnl --------------------
 458 dnl CHECK FOR CYRUS-SASL
 459 dnl --------------------
 460
 461 AS_IF([test x"$sasl_support" = x"yes"],[
 462   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 463   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 464     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 465 AC_SUBST([SASLLIB])
 466
 467 dnl -----------------
 468 dnl CHECK FOR OPENSSL
 469 dnl -----------------
 470
 471 AS_IF([test x"$tls_support" = x"yes"],[
 472   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 473   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 474     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 475   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 476     [AC_MSG_ERROR([OpenSSL library not found])])],
 477   [TLSLIB=])
 478 AC_SUBST([TLSLIB])
 479
 480 dnl ---------------------
 481 dnl CHECK TERMCAP LIBRARY
 482 dnl ---------------------
 483
 484 dnl Add the termcap library, so that the following configure
 485 dnl tests will find it when it tries to link test programs.
 486 nmh_save_LIBS="$LIBS"
 487 LIBS="$TERMLIB $LIBS"
 488
 489 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 490 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 491 dnl in tgetstr().
 492 dnl Under Cygwin test program crashes but exit code is still 0. So,
 493 dnl we test for a file that porgram should create
 494 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 495 [Define to 1 if tgetent() accepts NULL as a buffer.])
 496 AC_CACHE_CHECK(if tgetent accepts NULL,
 497 nmh_cv_func_tgetent_accepts_null,
 498 [AC_TRY_RUN([
 499 main()
 500 {
 501     char buf[4096];
 502     int r1 = tgetent(buf, "vt100");
 503     int r2 = tgetent((char*)0,"vt100");
 504     if (r1 >= 0 && r1 == r2) {
 505         char tbuf[1024], *u;
 506         u = tbuf;
 507         tgetstr("cl", &u);
 508         creat("conftest.tgetent", 0640);
 509     }
 510     exit((r1 != r2) || r2 == -1);
 511 }
 512 ],
 513   if test -f conftest.tgetent; then
 514     nmh_cv_func_tgetent_accepts_null=yes
 515   else
 516     nmh_cv_func_tgetent_accepts_null=no
 517   fi,
 518   nmh_cv_func_tgetent_accepts_null=no,
 519   nmh_cv_func_tgetent_accepts_null=no)])
 520 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 521   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 522 fi
 523 AC_CACHE_CHECK(if tgetent returns 0 on success,
 524 nmh_cv_func_tgetent_zero_success,
 525 [AC_TRY_RUN([
 526 main()
 527 {
 528     char buf[4096];
 529     int r1 = tgetent(buf, "!@#$%^&*");
 530     int r2 = tgetent(buf, "vt100");
 531     if (r1 < 0 && r2 == 0) {
 532         char tbuf[1024], *u;
 533         u = tbuf;
 534         tgetstr("cl", &u);
 535         creat("conftest.tgetent0", 0640);
 536     }
 537     exit(r1 == r2);
 538 }
 539 ],
 540   if test -f conftest.tgetent0; then
 541     nmh_cv_func_tgetent_zero_success=yes
 542   else
 543     nmh_cv_func_tgetent_zero_success=no
 544   fi,
 545   nmh_cv_func_tgetent_zero_success=no,
 546   nmh_cv_func_tgetent_zero_success=no)])
 547 AH_TEMPLATE([TGETENT_SUCCESS],
 548 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 549 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 550   AC_DEFINE(TGETENT_SUCCESS, 0)
 551 else
 552   AC_DEFINE(TGETENT_SUCCESS, 1)
 553 fi
 554
 555 dnl Now put the libraries back to what it was before we
 556 dnl starting checking the termcap library.
 557 LIBS="$nmh_save_LIBS"
 558
 559 dnl --------------
 560 dnl CHECK TYPEDEFS
 561 dnl --------------
 562 AC_TYPE_PID_T
 563 AC_TYPE_OFF_T
 564 AC_TYPE_UID_T
 565 AC_TYPE_MODE_T
 566 AC_TYPE_SIZE_T
 567
 568 dnl ----------------
 569 dnl CHECK STRUCTURES
 570 dnl ----------------
 571
 572 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 573 dnl (FreeBSD has a timezone() function but not a timezone global
 574 dnl variable that is visible).
 575 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 576
 577 AC_STRUCT_DIRENT_D_TYPE
 578
 579 dnl Where is <signal.h> located?  Needed as input for signames.awk
 580 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 581 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 582                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 583                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 584                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 585                  /usr/include/sys/signal.h      dnl Almost everybody else
 586                  /dev/null;                     dnl Just in case we fall through
 587 do
 588   test -f $SIGNAL_H && \
 589   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 590   break
 591 done
 592 nmh_cv_path_signal_h=$SIGNAL_H
 593 ])
 594 SIGNAL_H=$nmh_cv_path_signal_h
 595 AC_SUBST(SIGNAL_H)dnl
 596
 597 dnl
 598 dnl Sigh, this is required because under the new world order autoconf has
 599 dnl nothing to create in a few of the build directories when doing an object
 600 dnl tree build.  So make sure we created certain directories if they don't
 601 dnl exist.
 602 dnl
 603
 604 AC_CONFIG_COMMANDS([build-directories],
 605 [test -d etc || AS_MKDIR_P([etc])
 606 test -d man || AS_MKDIR_P([man])])
 607
 608 AC_CONFIG_COMMANDS_POST([
 609
 610 dnl These odd looking assignments are done to expand out unexpanded
 611 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 612 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 613 dnl again to get the final answer.
 614 dnl We only use the expanded versions to print the install paths in
 615 dnl the final summary and should use them nowhere else (see the autoconf
 616 dnl docs for the rationale for bindir etc being unexpanded).
 617 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 618 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 619 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 620 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 621 eval "nmhrpm=${nmhrpm}";
 622
 623 AC_MSG_NOTICE([
 624 nmh configuration
 625 -----------------
 626 nmh version                : AC_PACKAGE_VERSION
 627 host os                    : ${host}
 628 compiler                   : ${CC}
 629 compiler flags             : ${CFLAGS}
 630 linker flags               : ${LDFLAGS}
 631 preprocessor flags         : ${CPPFLAGS}
 632 source code location       : ${srcdir}
 633 binary install path        : ${nmhbin}
 634 library install path       : ${nmhlib}
 635 config files install path  : ${nmhsysconf}
 636 man page install path      : ${nmhman}
 637 RPM build root             : ${nmhrpm}
 638 backup prefix              : ${backup_prefix}
 639 transport system           : ${MTS}
 640 spool default locking type : ${with_locking}
 641 default smtp servers       : ${smtpservers}
 642 SASL support               : ${sasl_support}
 643 TLS support                : ${tls_support}
 644 ])])dnl
 645
 646 dnl ---------------
 647 dnl OUTPUT MAKEFILE
 648 dnl ---------------
 649 AC_CONFIG_FILES([Makefile test/common.sh])
 650 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 651 AC_OUTPUT