diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 echo "configuring for nmh dated $DATE"
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 if test x"$enable_nmh_debug" = x"yes"; then
  32   enable_debug=yes
  33 fi
  34
  35 dnl Allow users to send email from addresses other than their default?
  36 AC_ARG_ENABLE(masquerade,
  37   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  38     [enable up to 3 types of address masquerading]),
  39   [if test x"$enable_masquerade" = x"yes"; then
  40     masquerade="draft_from mmailid username_extension"
  41   else
  42     masquerade="$enable_masquerade"
  43   fi], [masquerade="draft_from mmailid username_extension"])
  44 AC_SUBST(masquerade)dnl
  45
  46 dnl Do you want to disable use of locale functions
  47 AH_TEMPLATE([LOCALE],
  48 [Undefine if you don't want locale features.  By default this is defined.])
  49 AC_ARG_ENABLE([locale],
  50 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  51 [if test x$enableval = xyes; then
  52   AC_DEFINE(LOCALE)
  53 fi],
  54 AC_DEFINE(LOCALE)
  55 )
  56
  57 dnl Do you want client-side support for using SASL for authentication?
  58 dnl Note that this code will be enabled for both POP and SMTP
  59 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  60   [Enable SASL support via the Cyrus SASL library]))
  61 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  62   AC_DEFINE([CYRUS_SASL], [1],
  63     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  64   if test x"$with_cyrus_sasl" != xyes; then
  65     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  66     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  67   fi
  68   sasl_support=yes
  69 else
  70   sasl_support=no
  71 fi
  72
  73 dnl Do you want client-side support for encryption with TLS?
  74 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  75 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
  76   AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  77   tls_support=yes
  78 else
  79   tls_support=no
  80 fi
  81
  82 dnl What should be the default editor?
  83 AC_ARG_WITH([editor],
  84   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  85
  86 if test -n "$with_editor"; then
  87   editorpath="$with_editor"
  88 fi
  89
  90 dnl Set the backup prefix
  91 AC_ARG_WITH([hash-backup],
  92   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  93 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
  94   backup_prefix="#"
  95 else
  96   backup_prefix=","
  97 fi
  98 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  99     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 100
 101 dnl What method of locking to use?
 102 AC_ARG_WITH(locking,
 103   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 104   [specify the file locking method]))
 105
 106 if test x"$with_locking" = x"dot"; then
 107   LOCKTYPE="dot"
 108   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 109 elif test x"$with_locking" = x"flock"; then
 110   LOCKTYPE="flock"
 111   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 112 elif test x"$with_locking" = x"lockf"; then
 113   LOCKTYPE="lockf"
 114   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 115 elif test x"$with_locking" = x"fcntl"; then
 116   LOCKTYPE="fcntl"
 117   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 118 else
 119   LOCKTYPE="dot"
 120   AC_DEFINE(DOT_LOCKING)dnl
 121 fi
 122
 123 dnl Should we use a locking directory?
 124 AC_ARG_ENABLE([lockdir], [
 125   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 126   AS_IF([test "x$enableval" = xyes],[
 127     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 128   AS_IF([test "x$LOCKTYPE" != xdot],[
 129     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 130   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 131                      [Directory to store dot-locking lock files])
 132 ])
 133
 134 dnl What method of posting should post use?
 135 AC_ARG_WITH([mts],
 136   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 137   [specify the default mail transport agent/service]))
 138
 139 if test x"$with_mts" = x"smtp"; then
 140   MTS="smtp"
 141 elif test x"$with_mts" = x"sendmail"; then
 142   MTS="sendmail"
 143 else
 144   MTS="smtp"
 145 fi
 146 AC_SUBST([MTS])dnl
 147
 148 dnl Both the smtp and sendmail mail transport services use the smtp code
 149 AC_DEFINE([SMTPMTS], [1],
 150   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 151
 152 dnl What should be the default pager?
 153 AC_ARG_WITH([pager],
 154   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 155
 156 if test -n "$with_pager"; then
 157   pagerpath="$with_pager"
 158 fi
 159
 160 dnl What should be the default mail server(s)?
 161 AC_ARG_WITH(smtpservers,
 162   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 163   [specify the default SMTP server(s) @<:@localhost@:>@]))
 164 if test -n "$with_smtpservers"; then
 165   smtpservers="$with_smtpservers"
 166 else
 167   smtpservers="localhost"
 168 fi
 169 AC_SUBST([smtpservers])dnl
 170
 171 dnl ----------------------------------------------------
 172 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 173 dnl ----------------------------------------------------
 174 AC_PREFIX_DEFAULT([/usr/local/nmh])
 175
 176 dnl ------------------
 177 dnl CHECK THE COMPILER
 178 dnl ------------------
 179 dnl We want these before the checks,
 180 dnl so the checks can modify their values.
 181 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 182 if test x"$enable_debug" = x"yes"; then
 183   test -z "$LDFLAGS" && LDFLAGS=-g
 184 fi
 185
 186 AC_PROG_CC
 187 AM_PROG_CC_C_O
 188
 189 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 190   [nmh_cv_has_unusedmacros],
 191   [nmh_saved_cppflags="$CPPFLAGS"
 192    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 193    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 194    CPPFLAGS="$nmh_saved_cppflags"])
 195
 196 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 197   test -z "$CPPLAGS"  &&  CPPFLAGS=-Wunused-macros \
 198                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 199   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 200 fi
 201 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 202
 203 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 204 [nmh_saved_cflags="$CFLAGS"
 205  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 206  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 207  CFLAGS="$nmh_saved_cflags"])
 208
 209 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 210 [nmh_saved_cflags="$CFLAGS"
 211  CFLAGS="$CFLAGS -Wno-pointer-sign"
 212  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 213  CFLAGS="$nmh_saved_cflags"])
 214
 215 dnl if the user hasn't specified CFLAGS, then
 216 dnl   if compiler is gcc, then
 217 dnl     use -O2 and some warning flags
 218 dnl   else use -O
 219 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 220 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 221 dnl warnings which are probably mostly spurious and which in any case we
 222 dnl don't want to deal with now.
 223 if test "$nmh_cv_has_noptrsign" = "yes"; then
 224     if test "$nmh_cv_has_wextra" = "yes"; then
 225         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 226     else
 227         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 228     fi
 229 else
 230     if test "$nmh_cv_has_wextra" = "yes"; then
 231         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 232     else
 233         nmh_gcc_warnflags="-Wall"
 234     fi
 235 fi
 236
 237 if test -n "$auto_cflags"; then
 238   if test x"$enable_debug" = x"yes"; then
 239     if test -n "$GCC"; then
 240       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 241     else
 242       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 243     fi
 244   else
 245     if test -z "$LDFLAGS"; then
 246       case "$build_os" in
 247         darwin*)
 248           LDFLAGS=
 249           ;;
 250         *)
 251           LDFLAGS=-s
 252           ;;
 253       esac
 254     fi
 255     if test -n "$GCC"; then
 256       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 257     else
 258       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 259     fi
 260   fi
 261 fi
 262
 263 AC_C_CONST              dnl Does compiler support `const'.
 264
 265 dnl ------------------
 266 dnl CHECK FOR PROGRAMS
 267 dnl ------------------
 268 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 269 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 270 AC_PROG_RANLIB          dnl Check for `ranlib'
 271 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 272 AC_PROG_SED             dnl Check for Posix-compliant sed
 273 AC_PROG_LEX             dnl Check for lex/flex
 274
 275 dnl Look for `cut'
 276 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 277 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 278
 279 dnl ----------------------------------------------
 280 dnl check for lclint, and lint if it doesn't exist
 281 dnl ----------------------------------------------
 282 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 283 if test x$ac_cv_prog_linttmp1 != xno ; then
 284   LINT=$ac_cv_prog_linttmp1
 285   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 286 else
 287   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 288   if test x$ac_cv_prog_linttmp2 != xno ; then
 289     LINT=$ac_cv_prog_linttmp2
 290     LINTFLAGS=""
 291   else
 292     LINT="echo 'No lint program found'"
 293     LINTFLAGS=""
 294   fi
 295 fi
 296 AC_SUBST([LINT])dnl
 297 AC_SUBST([LINTFLAGS])dnl
 298
 299 dnl Look for `ls'
 300 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 301 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 302
 303 dnl See how we get ls to display the owner and the group
 304 if test "$lspath" != "no"; then
 305   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 306                  [nmh_cv_ls_grpopt],
 307   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 308     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 309     dnl ls, it would seem -l gave us both the user and group.  On this type of
 310     dnl ls, -g makes _only_ the group be displayed (and not the user).
 311     nmh_cv_ls_grpopt="-l"
 312   else
 313     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 314     nmh_cv_ls_grpopt="-lg"
 315   fi])
 316 fi
 317
 318 dnl Look for `more'
 319 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 320 AC_PATH_PROG([morepath], [more], [no], [$pathtmp])
 321
 322 dnl If pager is not specified yet,
 323 dnl then use `more' as the default.
 324 if test -z "$pagerpath"; then
 325   pagerpath="$morepath"
 326 fi
 327 AC_SUBST(pagerpath)dnl
 328
 329 dnl Look for `sendmail'
 330 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 331 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 332
 333 dnl Look for `vi'
 334 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 335 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 336
 337 dnl If editor is not specified yet,
 338 dnl then use `vi' as the default.
 339 if test -z "$editorpath"; then
 340   editorpath="$vipath"
 341 fi
 342 AC_SUBST([editorpath])dnl
 343
 344 dnl ----------------------------------------------------------
 345 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 346 dnl ----------------------------------------------------------
 347 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 348 [for mailspool in /var/mail        dnl
 349                   /var/spool/mail  dnl
 350                   /usr/spool/mail  dnl
 351                   /dev/null;       dnl Just in case we fall through
 352 do
 353   test -d $mailspool && break
 354 done
 355 nmh_cv_mailspool=$mailspool
 356 ])
 357 mailspool=$nmh_cv_mailspool
 358 AC_SUBST(mailspool)dnl
 359
 360 dnl See whether the mail spool directory is world-writable.
 361 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 362   AC_CACHE_CHECK(whether the mail spool is world-writable,
 363                  nmh_cv_mailspool_world_writable,
 364   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 365     nmh_cv_mailspool_world_writable=no
 366   else
 367     nmh_cv_mailspool_world_writable=yes
 368   fi])
 369 fi
 370
 371 dnl Also, check for liblockfile (as found on Debian systems)
 372 AC_CHECK_HEADER([lockfile.h], AC_CHECK_LIB(lockfile, lockfile_create) )
 373
 374 dnl and whether its companion program dotlockfile is setgid
 375 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 376 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 377   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 378     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 379     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 380         nmh_cv_dotlockfile_setgid=yes
 381       else
 382         nmh_cv_dotlockfile_setgid=no
 383       fi])
 384   fi
 385 fi
 386
 387 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 388 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 389 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 390   dnl do we really need both of these?
 391   AC_DEFINE(MAILGROUP,1,
 392     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 393   SETGID_MAIL=1
 394 fi
 395 AC_SUBST(SETGID_MAIL)dnl
 396
 397 dnl Use ls to see which group owns the mail spool directory.
 398 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 399 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 400 ])
 401 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 402 AC_SUBST(MAIL_SPOOL_GRP)dnl
 403
 404 dnl ------------------
 405 dnl CHECK HEADER FILES
 406 dnl ------------------
 407
 408 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 409 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 410 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 411 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 412 dnl declared; if so they should have an entry added to this case statement.
 413 dnl NB that we must define this on the compiler command line, not in config.h,
 414 dnl because it must be set before any system header is included and there's no
 415 dnl portable way to make sure that files generated by lex include config.h
 416 dnl before system header files.
 417
 418 case "$host_os" in
 419   linux*)
 420     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 421     test -z "$OURDEFS"  &&  OURDEFS="-D_GNU_SOURCE"  \
 422                         ||  OURDEFS="$OURDEFS -D_GNU_SOURCE"
 423     ;;
 424 esac
 425 AC_SUBST(OURDEFS)
 426
 427 AC_HEADER_STDC
 428 AC_HEADER_TIOCGWINSZ
 429 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 430                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 431                  sys/param.h sys/time.h sys/stream.h)
 432
 433 dnl
 434 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 435 dnl really use a whole set of them, but this check should be
 436 dnl sufficient.
 437 dnl
 438 AC_CHECK_HEADER(libio.h, [
 439   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 440     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 441
 442 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 443   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 444 [[#if HAVE_SYS_STREAM_H
 445 #  include <sys/stream.h>
 446 #endif
 447 ]])
 448
 449 dnl ---------------
 450 dnl CHECK FUNCTIONS
 451 dnl ---------------
 452 AC_CHECK_FUNCS(writev lstat nl_langinfo)
 453
 454 dnl Check for multibyte character set support
 455 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 456     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 457   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 458     [Define to enable support for multibyte character sets.])
 459 fi
 460
 461 dnl -------------------
 462 dnl CHECK FOR LIBRARIES
 463 dnl -------------------
 464 dnl Check location of modf
 465 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 466
 467 dnl Checks for network libraries (nsl, socket)
 468 NMH_CHECK_NETLIBS
 469
 470 termcap_curses_order="termcap curses ncurses"
 471 for lib in $termcap_curses_order; do
 472   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 473 done
 474 AC_SUBST([TERMLIB])dnl
 475
 476 dnl ---------------
 477 dnl CHECK FOR ICONV
 478 dnl ---------------
 479
 480 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 481 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 482   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 483   if test "x$ac_found_iconv" = "xno"; then
 484     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 485     if test "x$ac_found_iconv" = "xno"; then
 486       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 487     fi
 488     if test "x$ac_found_iconv" != "xno"; then
 489       ICONVLIB="-liconv"
 490     fi
 491   else
 492     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 493     AC_CHECK_DECL(_libiconv_version,
 494       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 495       [ #include <iconv.h> ])
 496   fi
 497 fi
 498 if test "x$ac_found_iconv" = xyes; then
 499   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 500 fi
 501 AC_SUBST([ICONVLIB])
 502
 503 dnl Check if iconv uses const in prototype declaration
 504 if test "x$ac_found_iconv" = "xyes"; then
 505   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 506     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 507         #include <iconv.h>]],
 508         [[#ifdef __cplusplus
 509           "C"
 510           #endif
 511           #if defined(__STDC__) || defined(__cplusplus)
 512           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 513           #else
 514           size_t iconv();
 515           #endif]])],
 516       [ac_cv_iconv_const=],
 517       [ac_cv_iconv_const=const])])
 518   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 519     [Define as const if the declaration of iconv() needs const.])
 520 fi
 521
 522 dnl --------------
 523 dnl CHECK FOR NDBM
 524 dnl --------------
 525
 526 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 527             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 528 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 529             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 530
 531 if test "$nmh_ndbm" = "autodetect"; then
 532   if test "$nmh_ndbmheader" != "autodetect"; then
 533     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 534   else
 535
 536     dnl There are at least four implementations of ndbm, and
 537     dnl several of those can be in different places at the whim
 538     dnl of the system integrator. A good summary of this mess
 539     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 540
 541     dnl Classic ndbm with no library required (eg NetBSD): try this
 542     dnl first so we don't accidentally link in a pointless but harmless
 543     dnl library in one of the later ndbm.h+libfoo tests:
 544     NMH_CHECK_NDBM(ndbm.h,,,
 545     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 546       NMH_CHECK_NDBM(db.h,db,,
 547     dnl Berkeley DBv1 emulating ndbm:
 548         NMH_CHECK_NDBM(ndbm.h,db,,
 549           NMH_CHECK_NDBM(ndbm.h,db1,,
 550     dnl Classic ndbm:
 551             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 552     dnl glibc2.1 systems put db1 in a subdir:
 553               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 554     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 555     dnl and possibly needing gbdm_compat library:
 556                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 557                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 558                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 559                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 560
 561   fi
 562 else
 563   dnl We don't really need to check that the user-specified values work,
 564   dnl but it is a convenience to the user to bomb out early rather than
 565   dnl after configure and half the compile process.
 566   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 567 fi
 568
 569 if test "$nmh_ndbm_found" = "no"; then
 570   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 571 else
 572   dnl Now export the lib/header to our makefile/config.h:
 573   if test x"$nmh_ndbmheader" != x; then
 574     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 575       [Define to the header containing the ndbm API prototypes.])
 576   fi
 577   if test x"$nmh_ndbm" != x; then
 578     NDBM_LIBS="-l$nmh_ndbm"
 579   else
 580     NDBM_LIBS=
 581   fi
 582   AC_SUBST([NDBM_LIBS])
 583 fi
 584
 585 dnl ------------------
 586 dnl Set RPM build root
 587 dnl ------------------
 588 dnl nmhrpm is used in the final summary, see below.  The default value is
 589 dnl reported there as ./RPM, consistent with the reporting of the default
 590 dnl source code location as ., but its absolute path is used in the Makefile.
 591 AC_ARG_WITH(rpmdir,
 592   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 593   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 594           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 595 AC_SUBST([rpmdir])
 596
 597
 598 dnl --------------------
 599 dnl CHECK FOR CYRUS-SASL
 600 dnl --------------------
 601
 602 AS_IF([test x"$sasl_support" = x"yes"],[
 603   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 604   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 605     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 606 AC_SUBST([SASLLIB])
 607
 608 dnl -----------------
 609 dnl CHECK FOR OPENSSL
 610 dnl -----------------
 611
 612 AS_IF([test x"$tls_support" = x"yes"],[
 613   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 614   AC_CHECK_LIB([crypto], [BIO_write], ,
 615     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 616   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 617     [AC_MSG_ERROR([OpenSSL library not found])])])
 618
 619 dnl ---------------------
 620 dnl CHECK TERMCAP LIBRARY
 621 dnl ---------------------
 622
 623 dnl Add the termcap library, so that the following configure
 624 dnl tests will find it when it tries to link test programs.
 625 nmh_save_LIBS="$LIBS"
 626 LIBS="$TERMLIB $LIBS"
 627
 628 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 629 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 630 dnl in tgetstr().
 631 dnl Under Cygwin test program crashes but exit code is still 0. So,
 632 dnl we test for a file that porgram should create
 633 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 634 [Define to 1 if tgetent() accepts NULL as a buffer.])
 635 AC_CACHE_CHECK(if tgetent accepts NULL,
 636 nmh_cv_func_tgetent_accepts_null,
 637 [AC_TRY_RUN([
 638 main()
 639 {
 640     char buf[4096];
 641     int r1 = tgetent(buf, "vt100");
 642     int r2 = tgetent((char*)0,"vt100");
 643     if (r1 >= 0 && r1 == r2) {
 644         char tbuf[1024], *u;
 645         u = tbuf;
 646         tgetstr("cl", &u);
 647         creat("conftest.tgetent", 0640);
 648     }
 649     exit((r1 != r2) || r2 == -1);
 650 }
 651 ],
 652   if test -f conftest.tgetent; then
 653     nmh_cv_func_tgetent_accepts_null=yes
 654   else
 655     nmh_cv_func_tgetent_accepts_null=no
 656   fi,
 657   nmh_cv_func_tgetent_accepts_null=no,
 658   nmh_cv_func_tgetent_accepts_null=no)])
 659 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 660   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 661 fi
 662 AC_CACHE_CHECK(if tgetent returns 0 on success,
 663 nmh_cv_func_tgetent_zero_success,
 664 [AC_TRY_RUN([
 665 main()
 666 {
 667     char buf[4096];
 668     int r1 = tgetent(buf, "!@#$%^&*");
 669     int r2 = tgetent(buf, "vt100");
 670     if (r1 < 0 && r2 == 0) {
 671         char tbuf[1024], *u;
 672         u = tbuf;
 673         tgetstr("cl", &u);
 674         creat("conftest.tgetent0", 0640);
 675     }
 676     exit(r1 == r2);
 677 }
 678 ],
 679   if test -f conftest.tgetent0; then
 680     nmh_cv_func_tgetent_zero_success=yes
 681   else
 682     nmh_cv_func_tgetent_zero_success=no
 683   fi,
 684   nmh_cv_func_tgetent_zero_success=no,
 685   nmh_cv_func_tgetent_zero_success=no)])
 686 AH_TEMPLATE([TGETENT_SUCCESS],
 687 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 688 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 689   AC_DEFINE(TGETENT_SUCCESS, 0)
 690 else
 691   AC_DEFINE(TGETENT_SUCCESS, 1)
 692 fi
 693
 694 dnl Now put the libraries back to what it was before we
 695 dnl starting checking the termcap library.
 696 LIBS="$nmh_save_LIBS"
 697
 698 dnl --------------
 699 dnl CHECK TYPEDEFS
 700 dnl --------------
 701 AC_TYPE_PID_T
 702 AC_TYPE_OFF_T
 703 AC_TYPE_UID_T
 704 AC_TYPE_MODE_T
 705 AC_TYPE_SIZE_T
 706
 707 dnl ----------------
 708 dnl CHECK STRUCTURES
 709 dnl ----------------
 710
 711 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 712 dnl (FreeBSD has a timezone() function but not a timezone global
 713 dnl variable that is visible).
 714 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 715
 716 AC_STRUCT_DIRENT_D_TYPE
 717
 718 dnl Where is <signal.h> located?  Needed as input for signames.awk
 719 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 720 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 721                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 722                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 723                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 724                  /usr/include/sys/signal.h      dnl Almost everybody else
 725                  /dev/null;                     dnl Just in case we fall through
 726 do
 727   test -f $SIGNAL_H && \
 728   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 729   break
 730 done
 731 nmh_cv_path_signal_h=$SIGNAL_H
 732 ])
 733 SIGNAL_H=$nmh_cv_path_signal_h
 734 AC_SUBST(SIGNAL_H)dnl
 735
 736 dnl
 737 dnl Sigh, this is required because under the new world order autoconf has
 738 dnl nothing to create in a few of the build directories when doing an object
 739 dnl tree build.  So make sure we created certain directories if they don't
 740 dnl exist.
 741 dnl
 742
 743 AC_CONFIG_COMMANDS([build-directories],
 744 [test -d etc || ${MKDIR_P} etc
 745 test -d man || ${MKDIR_P} man])
 746
 747 AC_CONFIG_COMMANDS_POST([
 748
 749 dnl These odd looking assignments are done to expand out unexpanded
 750 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 751 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 752 dnl again to get the final answer.
 753 dnl We only use the expanded versions to print the install paths in
 754 dnl the final summary and should use them nowhere else (see the autoconf
 755 dnl docs for the rationale for bindir etc being unexpanded).
 756 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 757 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 758 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 759 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 760 eval "nmhrpm=${nmhrpm}";
 761
 762 echo "
 763 nmh configuration
 764 -----------------
 765 nmh version                : AC_PACKAGE_VERSION
 766 host os                    : ${host}
 767 compiler                   : ${CC}
 768 compiler flags             : ${CFLAGS}
 769 linker flags               : ${LDFLAGS}
 770 definitions                : ${OURDEFS}
 771 source code location       : ${srcdir}
 772 binary install path        : ${nmhbin}
 773 library install path       : ${nmhlib}
 774 config files install path  : ${nmhsysconf}
 775 man page install path      : ${nmhman}
 776 RPM build root             : ${nmhrpm}
 777 backup prefix              : ${backup_prefix}
 778 transport system           : ${MTS}
 779 file locking type          : ${LOCKTYPE}
 780 default smtp servers       : ${smtpservers}
 781 default editor             : ${editorpath}
 782 default pager              : ${pagerpath}
 783 email address masquerading : ${masquerade}
 784 SASL support               : ${sasl_support}
 785 TLS support                : ${tls_support}"
 786 echo ""])
 787
 788 dnl ---------------
 789 dnl OUTPUT MAKEFILE
 790 dnl ---------------
 791 AC_CONFIG_FILES([Makefile])
 792 AC_OUTPUT