diplodocus.org Git - nmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl 2.13 definitely chokes; 2.53 is the earliest version I've tested.
   8 dnl 2.50 is the major breakpoint between the old autoconf and the new,
   9 dnl so require that. If there are bug reports about 2.50-2.52 not working
  10 dnl we can always move this up a little.
  11 AC_PREREQ(2.50)
  12
  13 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  14 AC_CONFIG_SRCDIR(h/nmh.h)
  15 AC_CONFIG_HEADER(config.h)
  16
  17 AC_CANONICAL_TARGET
  18
  19 dnl ---------------------
  20 dnl define a macro or two
  21 dnl ---------------------
  22
  23 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  24 if test -n "$LIBTOOL" ; then
  25   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  26   if test x"$tmptest" != x  ; then
  27     GNU_LIBTOOL=1
  28     AC_SUBST(GNU_LIBTOOL)dnl
  29   fi
  30 fi
  31 ] )
  32
  33 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  34 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  35
  36 dnl What date of nmh are we building?
  37 DATE=`cat ${srcdir}/DATE`
  38 echo "configuring for nmh dated $DATE"
  39 AC_SUBST(DATE)dnl
  40
  41 dnl --------------------------
  42 dnl CHECK COMMAND LINE OPTIONS
  43 dnl --------------------------
  44
  45 dnl Do you want client-side support for apop?
  46 AC_ARG_ENABLE(apop,
  47 [  --enable-apop           enable client-side support for POP3 and APOP])
  48 if test x"$enable_apop" = x"yes"; then
  49   AC_DEFINE(APOP)dnl
  50   APOPLIB=md5.o
  51   enable_pop=yes
  52 fi
  53 AC_SUBST(APOPLIB)dnl
  54
  55 dnl Do you want to debug nmh?
  56 AC_ARG_ENABLE(debug,
  57 [  --enable-debug          enable nmh code debugging])
  58 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  59 if test x"$enable_nmh_debug" = x"yes"; then
  60   enable_debug=yes
  61 fi
  62
  63 dnl Allow users to send email from addresses other than their default?
  64 AC_ARG_ENABLE(masquerade,
  65   [  --enable-masquerade[='draft_from mmailid username_extension']
  66                           enable up to 3 types of address masquerading [none]],
  67   [if test x"$enable_masquerade" = x"yes"; then
  68     masquerade="draft_from mmailid username_extension"
  69   else
  70     masquerade="$enable_masquerade"
  71   fi])
  72 AC_SUBST(masquerade)dnl
  73
  74 dnl Do you want mhe support?
  75 AC_ARG_ENABLE(mhe,
  76 [  --enable-mhe            enable mhe support (DEFAULT)])
  77
  78 dnl mhe support is on by default, so define it unless --disable-mhe or the
  79 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  80 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  81   AC_DEFINE(MHE)dnl
  82 fi
  83
  84 dnl Do you want client-side support for pop?
  85 AC_ARG_ENABLE(pop,
  86 [  --enable-pop            enable client-side support for plain POP3])
  87 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  88 if test x"$enable_nmh_pop" = x"yes"; then
  89   enable_pop=yes
  90 fi
  91
  92 dnl Do you want client-side support for using SASL for authentication?
  93 dnl Note that this code will be enabled for both POP and SMTP
  94 AC_ARG_WITH(cyrus-sasl,
  95 [  --with-cyrus-sasl=<dir> Specify location of Cyrus SASL library for auth])
  96 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  97   AC_DEFINE(CYRUS_SASL)dnl
  98   sasl_support=yes
  99 else
 100   sasl_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105 [  --with-editor=EDITOR    specify the default editor])
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   [  --with-hash-backup      use # as the backup prefix (default: ,)])
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix")dnl
 120
 121 dnl Do you want support for hesiod
 122 AC_ARG_WITH(hesiod,
 123 [  --with-hesiod=PREFIX    specify location of Hesiod])
 124 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 125   AC_DEFINE(HESIOD)dnl
 126 fi
 127
 128 dnl Do you want client-side support for kpop
 129 AC_ARG_WITH(krb4,
 130 [  --with-krb4=PREFIX      specify location of Kerberos V4 for KPOP support])
 131 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 132   enable_pop=yes
 133   AC_DEFINE(KPOP)dnl
 134   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
 135 fi
 136
 137 dnl After we know if we're including apop and kpop support, do pop stuff
 138 if test x"$enable_pop" = x"yes"; then
 139   AC_DEFINE(POP)dnl
 140   POPLIB=popsbr.o
 141   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 142 else
 143   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 144 fi
 145 AC_SUBST(POPLIB)dnl
 146 AC_SUBST(POPSED)dnl
 147
 148 dnl What method of locking to use?
 149 AC_ARG_WITH(locking,
 150 [  --with-locking=LOCKTYPE specify the file locking method
 151                           (one of dot, fcntl, flock, lockf)])
 152
 153 if test x"$with_locking" = x"dot"; then
 154   LOCKTYPE="dot"
 155   AC_DEFINE(DOT_LOCKING)dnl
 156 elif test x"$with_locking" = x"flock"; then
 157   LOCKTYPE="flock"
 158   AC_DEFINE(FLOCK_LOCKING)dnl
 159 elif test x"$with_locking" = x"lockf"; then
 160   LOCKTYPE="lockf"
 161   AC_DEFINE(LOCKF_LOCKING)dnl
 162 elif test x"$with_locking" = x"fcntl"; then
 163   LOCKTYPE="fcntl"
 164   AC_DEFINE(FCNTL_LOCKING)dnl
 165 else
 166   LOCKTYPE="dot"
 167   AC_DEFINE(DOT_LOCKING)dnl
 168 fi
 169
 170 dnl What method of posting should post use?
 171 AC_ARG_WITH(mts,
 172 [  --with-mts=MTS          specify the default mail transport agent/service])
 173
 174 if test x"$with_mts" = x"smtp"; then
 175   MTS="smtp"
 176 elif test x"$with_mts" = x"sendmail"; then
 177   MTS="sendmail"
 178 else
 179   MTS="smtp"
 180 fi
 181 AC_SUBST(MTS)dnl
 182
 183 dnl Both the smtp and sendmail mail transport services use the smtp code
 184 AC_DEFINE(SMTPMTS)dnl
 185
 186 dnl What should be the default pager?
 187 AC_ARG_WITH(pager,
 188 [  --with-pager=PAGER      specify the default pager])
 189
 190 if test -n "$with_pager"; then
 191   pagerpath="$with_pager"
 192 fi
 193
 194 dnl What should be the default mail server(s)?
 195 AC_ARG_WITH(smtpservers,
 196 [  --with-smtpservers='SMTPSERVER1[ SMTPSERVER2...]'
 197                           specify the default SMTP server(s) [localhost]])
 198 if test -n "$with_smtpservers"; then
 199   smtpservers="$with_smtpservers"
 200 else
 201   smtpservers="localhost"
 202 fi
 203 AC_SUBST(smtpservers)dnl
 204
 205 dnl ----------------------------------------------------
 206 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 207 dnl ----------------------------------------------------
 208 AC_PREFIX_DEFAULT(/usr/local/nmh)
 209
 210 dnl ------------------
 211 dnl CHECK THE COMPILER
 212 dnl ------------------
 213 dnl We want these before the checks,
 214 dnl so the checks can modify their values.
 215 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 216 if test x"$enable_debug" = x"yes"; then
 217   test -z "$LDFLAGS" && LDFLAGS=-g
 218 fi
 219
 220 AC_PROG_CC
 221
 222 dnl if the user hasn't specified CFLAGS, then
 223 dnl   if compiler is gcc, then
 224 dnl     use -O2 and some warning flags
 225 dnl   else use -O
 226 if test -n "$auto_cflags"; then
 227   if test x"$enable_debug" = x"yes"; then
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 232     fi
 233   else
 234     if test -z "$LDFLAGS"; then
 235       case "$build_os" in
 236         darwin*)
 237           LDFLAGS=
 238           ;;
 239         *)
 240           LDFLAGS=-s
 241           ;;
 242       esac
 243     fi
 244     if test -n "$GCC"; then
 245       test -z "$CFLAGS" && CFLAGS="-Wall -O2" || CFLAGS="$CFLAGS -Wall -O2"
 246     else
 247       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 248     fi
 249   fi
 250 fi
 251
 252 AC_C_CONST              dnl Does compiler support `const'.
 253
 254 dnl ------------------
 255 dnl CHECK FOR PROGRAMS
 256 dnl ------------------
 257 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 258 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 259 AC_PROG_RANLIB          dnl Check for `ranlib'
 260 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 261 AC_PROG_LEX             dnl Check for lex/flex
 262
 263 dnl Look for `cut'
 264 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 265 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 266
 267 dnl ----------------------------------------------
 268 dnl check for lclint, and lint if it doesn't exist
 269 dnl ----------------------------------------------
 270 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 271 if test x$ac_cv_prog_linttmp1 != xno ; then
 272   LINT=$ac_cv_prog_linttmp1
 273   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 274 else
 275   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 276   if test x$ac_cv_prog_linttmp2 != xno ; then
 277     LINT=$ac_cv_prog_linttmp2
 278     LINTFLAGS=""
 279   else
 280     LINT="echo 'No lint program found'"
 281     LINTFLAGS=""
 282   fi
 283 fi
 284 AC_SUBST(LINT)dnl
 285 AC_SUBST(LINTFLAGS)dnl
 286
 287 dnl try to figure out which one we've got
 288 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 289 NMH_PROG_GNU_LIBTOOL
 290
 291 dnl Check for lorder and tsort commands
 292 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 293 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 294
 295 dnl If either doesn't exist, replace them with echo and cat
 296 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 297   LORDER=echo
 298   TSORT=cat
 299   AC_SUBST(LORDER)dnl
 300   AC_SUBST(TSORT)dnl
 301 dnl Mac OS X has lorder, but sh is too broken for it to work
 302 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 303 dnl   LORDER=echo
 304 dnl   TSORT=cat
 305 dnl   AC_SUBST(LORDER)dnl
 306 dnl   AC_SUBST(TSORT)dnl
 307 fi
 308
 309 dnl Check whether tsort can deal with loops
 310 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 311   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 312     nmh_cv_tsort_loop=no
 313   else
 314     nmh_cv_tsort_loop=yes
 315   fi])
 316 if test x$nmh_cv_tsort_loop = xno ; then
 317   LORDER=echo
 318   TSORT=cat
 319   AC_SUBST(LORDER)dnl
 320   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Look for `ls'
 324 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 325 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 326
 327 dnl See how we get ls to display the owner and the group
 328 if test "$lspath" != "no"; then
 329   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 330                  nmh_cv_ls_grpopt,
 331   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 332     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 333     dnl ls, it would seem -l gave us both the user and group.  On this type of
 334     dnl ls, -g makes _only_ the group be displayed (and not the user).
 335     nmh_cv_ls_grpopt="-l"
 336   else
 337     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 338     nmh_cv_ls_grpopt="-lg"
 339   fi])
 340 fi
 341
 342 dnl Look for `more'
 343 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 344 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 345
 346 dnl If pager is not specified yet,
 347 dnl then use `more' as the default.
 348 if test -z "$pagerpath"; then
 349   pagerpath="$morepath"
 350 fi
 351 AC_SUBST(pagerpath)dnl
 352
 353 dnl Look for `sendmail'
 354 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 355 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 356
 357 dnl Look for `vi'
 358 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 359 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 360
 361 dnl If editor is not specified yet,
 362 dnl then use `vi' as the default.
 363 if test -z "$editorpath"; then
 364   editorpath="$vipath"
 365 fi
 366 AC_SUBST(editorpath)dnl
 367
 368 dnl Check for broken vi
 369 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 370 [if echo 'r /nonexist-file
 371 q' | ex > /dev/null
 372 then
 373         nmh_cv_attvibug=no
 374 else
 375         nmh_cv_attvibug=yes
 376 fi])
 377
 378 if test "$nmh_cv_attvibug" = yes; then
 379   AC_DEFINE(ATTVIBUG)dnl
 380 fi
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP)dnl
 430   SETGID_MAIL=1
 431 fi
 432 AC_SUBST(SETGID_MAIL)dnl
 433
 434 dnl Use ls to see which group owns the mail spool directory.
 435 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 436 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 437 ])
 438 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 439 AC_SUBST(MAIL_SPOOL_GRP)dnl
 440
 441 dnl ------------------
 442 dnl CHECK HEADER FILES
 443 dnl ------------------
 444 AC_HEADER_DIRENT
 445 AC_HEADER_STDC
 446 AC_HEADER_TIME
 447 AC_HEADER_SYS_WAIT
 448 AC_HEADER_STAT
 449 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 450                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 451                  langinfo.h netdb.h sys/param.h sys/time.h sys/utsname.h \
 452                  iconv.h sys/stream.h arpa/inet.h arpa/ftp.h)
 453
 454
 455 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 456 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 457 #include <unistd.h>
 458 #include <termios.h>]],
 459 [[/* SunOS 4.0.3 has termios.h but not the library calls.  */
 460 tcgetattr(0, 0);]])],
 461 nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 462
 463 if test $nmh_cv_sys_posix_termios = yes; then
 464   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 465   nmh_cv_header_termios_h_tiocgwinsz,
 466   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 467 #include <termios.h>]],
 468   [[int x = TIOCGWINSZ;]])],
 469   nmh_cv_header_termios_h_tiocgwinsz=yes,nmh_cv_header_termios_h_tiocgwinsz=no)])
 470 else
 471   nmh_cv_header_termios_h_tiocgwinsz=no
 472 fi
 473
 474 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 475   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 476   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 477   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 478 #include <sys/ioctl.h>]],
 479   [[int x = TIOCGWINSZ;]])],
 480   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 481   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 482     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)dnl
 483   fi
 484 fi
 485
 486 dnl
 487 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 488 dnl really use a whole set of them, but this check should be
 489 dnl sufficient.
 490 dnl
 491 AC_CHECK_HEADER(libio.h, [
 492   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 493     AC_DEFINE(LINUX_STDIO) ]) ])
 494
 495 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM),,
 496 [[#if HAVE_SYS_STREAM_H
 497 #  include <sys/stream.h>
 498 #endif
 499 ]])
 500
 501 dnl ---------------
 502 dnl CHECK FUNCTIONS
 503 dnl ---------------
 504 AC_FUNC_VFORK
 505 AC_CHECK_LIB(mkstemp,mkstemp)
 506 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 507                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 508                sethostent getutent nl_langinfo)
 509
 510 dnl solaris screws this up
 511 AC_CHECK_FUNC(gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)],
 512   AC_CHECK_LIB(nsl, gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)] ) )
 513
 514 dnl sigsetjmp may be a macro
 515 AC_MSG_CHECKING(for sigsetjmp)
 516 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 517   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)],
 518   [AC_MSG_RESULT(no)])
 519
 520 AC_REPLACE_FUNCS(snprintf strerror strdup)
 521
 522 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 523 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 524 dnl any system header.
 525 dnl
 526 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 527 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 528 dnl need to check?
 529 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 530                 AC_EGREP_HEADER(initgroups, unistd.h,
 531                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 532
 533 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 534 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 535 dnl seems to work perfectly and IBM apparently uses it in internal code).
 536 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 537 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 538 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 539 dnl prototype.
 540 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE))
 541
 542 dnl -------------------
 543 dnl CHECK FOR LIBRARIES
 544 dnl -------------------
 545 dnl Check location of modf
 546 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 547
 548 dnl Checks for network libraries (nsl, socket)
 549 AC_CHECK_NETLIBS
 550
 551 termcap_curses_order="termcap curses ncurses"
 552 for lib in $termcap_curses_order; do
 553   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 554 done
 555 AC_SUBST(TERMLIB)dnl
 556
 557 dnl ---------------
 558 dnl CHECK FOR ICONV
 559 dnl ---------------
 560
 561 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 562 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 563   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 564   if test "x$ac_found_iconv" = "xno"; then
 565     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 566     if test "x$ac_found_iconv" = "xno"; then
 567       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 568     fi
 569     if test "x$ac_found_iconv" != "xno"; then
 570       LIBS="-liconv $LIBS"
 571     fi
 572   else
 573     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 574     AC_CHECK_DECL(_libiconv_version,
 575       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 576       [ #include <iconv.h> ])
 577   fi
 578 fi
 579 if test "x$ac_found_iconv" = xyes; then
 580   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 581 fi
 582
 583 dnl Check if iconv uses const in prototype declaration
 584 if test "x$ac_found_iconv" = "xyes"; then
 585   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 586     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 587         #include <iconv.h>]],
 588         [[#ifdef __cplusplus
 589           "C"
 590           #endif
 591           #if defined(__STDC__) || defined(__cplusplus)
 592           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 593           #else
 594           size_t iconv();
 595           #endif]])],
 596       [ac_cv_iconv_const=],
 597       [ac_cv_iconv_const=const])])
 598   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 599     [Define as const if the declaration of iconv() needs const.])
 600 fi
 601
 602 dnl ----------------
 603 dnl CHECK FOR NDBM.H
 604 dnl ----------------
 605
 606 AC_CHECK_HEADERS(db1/ndbm.h gdbm/ndbm.h db.h, break, )
 607
 608 dnl --------------
 609 dnl CHECK FOR NDBM
 610 dnl --------------
 611 dnl Checks for ndbm; we use our own autoconf macro rather than
 612 dnl using AC_CHECK_LIB because on later versions of libdb
 613 dnl the dbm_open() function is provided via a #define and
 614 dnl we don't want to hardcode searching for the internal
 615 dnl function that lies behind it.
 616 dnl This *must* come after the ndbm headers check!
 617
 618 dnl Note the special-casing of the gdbm_compat case:
 619 dnl if we find gdbm_open in -lgdbm and dbm_open in
 620 dnl -lgdbm_compat -lgdbm then we want to have both libraries
 621 dnl in LIBS in that order.
 622 NMH_CHECK_DBM(,,
 623   NMH_CHECK_DBM(ndbm,,
 624     NMH_CHECK_DBM(dbm,,
 625       NMH_CHECK_DBM(db1,,
 626         NMH_CHECK_DBM(db,,
 627           NMH_CHECK_DBM(gdbm,,
 628             AC_CHECK_LIB(gdbm,gdbm_open,
 629               NMH_CHECK_DBM(gdbm_compat,LIBS="-lgdbm_compat -lgdbm $LIBS",
 630                  AC_MSG_ERROR([cannot find a library providing dbm_open()]),-lgdbm),
 631               AC_MSG_ERROR([cannot find a library providing dbm_open()]))))))))
 632
 633 dnl ----------------
 634 dnl CHECK FOR HESIOD
 635 dnl ----------------
 636 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 637   if test x"$with_hesiod" != x"yes"; then
 638     HESIOD_INCLUDES="-I$with_hesiod/include"
 639     HESIOD_LIBS="-L$with_hesiod/lib"
 640   fi
 641   AC_CHECK_FUNC(res_send,
 642         [AC_CHECK_LIB(hesiod, hes_resolve,
 643                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 644                 [AC_MSG_ERROR(Hesiod library not found)],
 645                 $HESIOD_LIBS)],
 646         [AC_CHECK_LIB(hesiod, hes_resolve,
 647                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 648                 [AC_MSG_ERROR(Hesiod library not found)],
 649                 $HESIOD_LIBS -lresolv)])
 650
 651 fi
 652 AC_SUBST(HESIOD_INCLUDES)dnl
 653 AC_SUBST(HESIOD_LIBS)dnl
 654
 655 dnl ----------------------------------
 656 dnl CHECK FOR KRB4 (Kerberos4 support)
 657 dnl ----------------------------------
 658 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 659   if test x"$with_krb4" != x"yes"; then
 660     KRB4_INCLUDES="-I$with_krb4/include"
 661     if test -d "$with_krb4/include/kerberosIV"; then
 662       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 663     fi
 664     KRB4_LIBS="-L$with_krb4/lib"
 665   elif test -d /usr/include/kerberosIV; then
 666     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 667   fi
 668 dnl First, check if we have -lk5crypto, since that means we have a recent krb5
 669
 670   AC_CHECK_LIB(k5crypto, krb5_encrypt,
 671         [AC_CHECK_LIB(krb4, krb_rd_req,
 672                 [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lk5crypto -lcom_err"],
 673                 [AC_MSG_ERROR(Kerberos 4 compatibility libraries not found)],
 674                 $KRB4_LIBS -ldes425 -lkrb5 -lk5crypto -lcom_err)],
 675
 676         [AC_CHECK_LIB(krb4, krb_rd_req,
 677             [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 678             [AC_CHECK_LIB(krb, krb_rd_req,
 679               [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 680               [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 681               $KRB4_LIBS -ldes)],
 682             $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)],
 683         $KRB4_LIBS)
 684
 685 fi
 686 AC_SUBST(KRB4_INCLUDES)dnl
 687 AC_SUBST(KRB4_LIBS)dnl
 688
 689 dnl --------------------
 690 dnl CHECK FOR CYRUS SASL
 691 dnl --------------------
 692 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 693   if test x"$with_cyrus_sasl" != x"yes"; then
 694     SASL_INCLUDES="-I$with_cyrus_sasl/include"
 695     SASL_LIBS="-L$with_cyrus_sasl/lib"
 696
 697     dnl Do OS-specific hardcoding of SASL shared library path into executables,
 698     dnl so user isn't forced to set environment variables like Solaris'
 699     dnl LD_LIBRARY_PATH.
 700     case "$target_os" in
 701       solaris*)
 702         SASL_LIBS="$SASL_LIBS -R$with_cyrus_sasl/lib"
 703         ;;
 704     esac
 705   fi
 706   save_LDFLAGS="$LDFLAGS"
 707   LDFLAGS="$LDFLAGS $SASL_LIBS"
 708   AC_CHECK_LIB(sasl2, sasl_client_new,
 709     [SASL_LIBS="$SASL_LIBS -lsasl2"],
 710     [AC_MSG_ERROR(Cyrus SASL library not found)])
 711   LDFLAGS="$save_LDFLAGS"
 712 fi
 713 AC_SUBST(SASL_INCLUDES)dnl
 714 AC_SUBST(SASL_LIBS)dnl
 715
 716 dnl ---------------------
 717 dnl CHECK TERMCAP LIBRARY
 718 dnl ---------------------
 719
 720 dnl Add the termcap library, so that the following configure
 721 dnl tests will find it when it tries to link test programs.
 722 nmh_save_LIBS="$LIBS"
 723 LIBS="$TERMLIB $LIBS"
 724
 725 dnl Checks for external variable ospeed in the termcap library.
 726 AC_CACHE_CHECK(if an include file defines ospeed,
 727 nmh_cv_decl_ospeed_include_defines,
 728 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 729 #if HAVE_TERMIOS_H
 730 #include <termios.h>
 731 #endif
 732 #if HAVE_TERMCAP_H
 733 #include <termcap.h>
 734 #endif]], [[ospeed = 0;]])],
 735 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 736
 737 if test $nmh_cv_decl_ospeed_include_defines = no; then
 738   AC_CACHE_CHECK(if you must define ospeed,
 739   nmh_cv_decl_ospeed_must_define,
 740   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 741   [[extern short ospeed; ospeed = 0;]])],
 742   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 743 fi
 744
 745 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 746   AC_DEFINE(HAVE_OSPEED)dnl
 747 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 748   AC_DEFINE(HAVE_OSPEED)
 749   AC_DEFINE(MUST_DEFINE_OSPEED)
 750 fi
 751
 752 dnl dnl Checks if tgetent accepts NULL and will
 753 dnl dnl allocate its own termcap buffer.
 754 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 755 dnl nmh_cv_func_tgetent_accepts_null,
 756 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 757 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 758 dnl   nmh_cv_func_tgetent_accepts_null=no,
 759 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 760 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 761 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 762 dnl fi
 763
 764 dnl Now put the libraries back to what it was before we
 765 dnl starting checking the termcap library.
 766 LIBS="$nmh_save_LIBS"
 767
 768 dnl --------------
 769 dnl CHECK TYPEDEFS
 770 dnl --------------
 771 AC_TYPE_SIGNAL
 772 AC_TYPE_PID_T
 773 AC_TYPE_OFF_T
 774 AC_TYPE_UID_T
 775 AC_TYPE_MODE_T
 776 AC_TYPE_SIZE_T
 777
 778 dnl Check for sigset_t.  Currently I'm looking in
 779 dnl <sys/types.h> and <signal.h>.  Others might need
 780 dnl to be added.
 781 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 782 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 783 #include <signal.h>]], [[sigset_t tempsigset;]])],
 784 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 785 if test $nmh_cv_type_sigset_t = no; then
 786   AC_DEFINE(sigset_t, unsigned int)
 787 fi
 788
 789 dnl ----------------
 790 dnl CHECK STRUCTURES
 791 dnl ----------------
 792 AC_CHECK_MEMBERS(struct stat.st_blksize)
 793
 794 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 795 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
 796 # include <sys/time.h>
 797 # include <time.h>
 798 #else
 799 # ifdef TM_IN_SYS_TIME
 800 #  include <sys/time.h>
 801 # else
 802 #  include <time.h>
 803 # endif
 804 #endif]], [[struct tm temptm; temptm.tm_gmtoff = 0;]])],
 805 nmh_cv_struct_tm_gmtoff=yes,nmh_cv_struct_tm_gmtoff=no)])
 806 if test $nmh_cv_struct_tm_gmtoff = yes; then
 807   AC_DEFINE(HAVE_TM_GMTOFF)
 808 fi
 809
 810 AC_CACHE_CHECK(for ut_type in struct utmp, nmh_cv_struct_utmp_ut_type,
 811 [AC_TRY_COMPILE(
 812 [#include <utmp.h>],
 813 [struct utmp temputmp; temputmp.ut_type = 0;],
 814   nmh_cv_struct_utmp_ut_type=yes, nmh_cv_struct_utmp_ut_type=no)])
 815 if test $nmh_cv_struct_utmp_ut_type = yes; then
 816   AC_DEFINE(HAVE_UTMP_UT_TYPE)
 817 fi
 818
 819 dnl -------------
 820 dnl CHECK SIGNALS
 821 dnl -------------
 822 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 823 AC_MSG_CHECKING(what style of signals to use)
 824 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 825   signals_style=POSIX_SIGNALS
 826   AC_DEFINE(POSIX_SIGNALS)
 827   AC_DEFINE(RELIABLE_SIGNALS)
 828 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 829   signals_style=BSD_SIGNALS
 830   AC_DEFINE(BSD_SIGNALS)
 831   AC_DEFINE(RELIABLE_SIGNALS)
 832 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 833   signals_style=SYSV_SIGNALS
 834   AC_DEFINE(SYSV_SIGNALS)
 835 else
 836   signals_style=NO_SIGNAL_BLOCKING
 837   AC_DEFINE(NO_SIGNAL_BLOCKING)
 838 fi
 839
 840 AC_MSG_RESULT($signals_style)
 841
 842 dnl Where is <signal.h> located?  Needed as input for signames.awk
 843 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 844 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 845                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 846                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 847                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 848                  /usr/include/sys/signal.h      dnl Almost everybody else
 849                  /dev/null;                     dnl Just in case we fall through
 850 do
 851   test -f $SIGNAL_H && \
 852   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 853   break
 854 done
 855 nmh_cv_path_signal_h=$SIGNAL_H
 856 ])
 857 SIGNAL_H=$nmh_cv_path_signal_h
 858 AC_SUBST(SIGNAL_H)dnl
 859
 860 dnl ----------------
 861 dnl OS SPECIFIC DEFINES
 862 dnl ----------------
 863 case "$target_os" in
 864
 865   solaris2*)
 866     AC_DEFINE(SYS5)
 867     AC_DEFINE(SVR4)
 868     ;;
 869   irix*)
 870     AC_DEFINE(SYS5)
 871     AC_DEFINE(SVR4)
 872     ;;
 873   osf*)
 874     AC_DEFINE(SYS5)
 875     AC_DEFINE(SVR4)
 876     ;;
 877   aix*)
 878     AC_DEFINE(SYS5)
 879     AC_DEFINE(SVR4)
 880     ;;
 881   sunos4*)
 882     AC_DEFINE(BSD42)
 883     ;;
 884   freebsd*)
 885     AC_DEFINE(BSD42)
 886     AC_DEFINE(BSD44)
 887     ;;
 888   netbsd*)
 889     AC_DEFINE(BSD42)
 890     AC_DEFINE(BSD44)
 891     ;;
 892   openbsd*)
 893     AC_DEFINE(BSD42)
 894     AC_DEFINE(BSD44)
 895     ;;
 896   bsd/os*)
 897     AC_DEFINE(BSD42)
 898     AC_DEFINE(BSD44)
 899     ;;
 900   sco5*)
 901     AC_DEFINE(SYS5)
 902     AC_DEFINE(SCO_5_STDIO)
 903     ;;
 904 esac
 905
 906
 907 dnl ----------------
 908 dnl OUTPUT MAKEFILES
 909 dnl ----------------
 910 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 911                 mts/Makefile mts/smtp/Makefile \
 912                 etc/Makefile docs/Makefile man/Makefile)
 913 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 914 AC_OUTPUT
 915
 916 dnl Umm, what's the point of these assignments??  -- <dan-nmh@dilvish.speed.net>
 917 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 918 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 919 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 920 eval "nmhman=${mandir}"
 921
 922 pop_kinds=no
 923 if test x"$enable_pop" = x"yes"; then
 924   pop_kinds="yes ("
 925
 926   if test x"$enable_apop" = x"yes"; then
 927     pop_kinds="${pop_kinds}APOP "
 928   fi
 929
 930   if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 931     pop_kinds="${pop_kinds}KPOP "
 932   fi
 933
 934   pop_kinds="${pop_kinds}POP3)"
 935 fi
 936
 937 echo "
 938 nmh configuration
 939 -----------------
 940 nmh version                : AC_PACKAGE_VERSION
 941 target os                  : ${target}
 942 compiler                   : ${CC}
 943 compiler flags             : ${CFLAGS}
 944 linker flags               : ${LDFLAGS}
 945 source code location       : ${srcdir}
 946 binary install path        : ${nmhbin2}
 947 libary install path        : ${nmhlib2}
 948 config files install path  : ${nmhsysconf2}
 949 man page install path      : ${nmhman}
 950 backup prefix              : ${backup_prefix}
 951 transport system           : ${MTS}
 952 file locking type          : ${LOCKTYPE}
 953 default smtp servers       : ${smtpservers}
 954 default editor             : ${editorpath}
 955 default pager              : ${pagerpath}
 956 email address masquerading : ${masquerade}
 957 pop is enabled             : ${pop_kinds}
 958 SASL support               : ${sasl_support}"
 959 echo ""