diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AC_ARG_WITH(locking,
  75   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  76   [specify the file locking method]))
  77
  78 if test x"$with_locking" = x"dot"; then
  79   LOCKTYPE="dot"
  80   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  81 elif test x"$with_locking" = x"flock"; then
  82   LOCKTYPE="flock"
  83   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  84 elif test x"$with_locking" = x"lockf"; then
  85   LOCKTYPE="lockf"
  86   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  87 elif test x"$with_locking" = x"fcntl"; then
  88   LOCKTYPE="fcntl"
  89   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  90 else
  91   LOCKTYPE="dot"
  92   AC_DEFINE(DOT_LOCKING)dnl
  93 fi
  94
  95 dnl Should we use a locking directory?
  96 AC_ARG_ENABLE([lockdir],
  97   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
  98   AS_IF([test "x$enableval" = xyes],[
  99     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 100   AS_IF([test "x$LOCKTYPE" != xdot],[
 101     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 102   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 103                      [Directory to store dot-locking lock files])
 104 ])
 105
 106 dnl What method of posting should post use?
 107 AC_ARG_WITH([mts],
 108   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 109   [specify the default mail transport agent/service]))
 110
 111 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 112       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 113       [MTS="smtp"])
 114 AC_SUBST([MTS])dnl
 115
 116 dnl What should be the default pager?
 117 AC_ARG_WITH([pager],
 118   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 119
 120 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 121
 122 dnl If a pager is not explicitly specified, then look for one.
 123 dnl Fall back to `cat', to avoid catastrophic failure of
 124 dnl `mhshow', et al., if pagerpath is set to `no'.
 125 if test -z "$pagerpath"; then
 126   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 127   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 128 fi
 129 AC_SUBST(pagerpath)dnl
 130
 131 dnl What should be the default mail server(s)?
 132 AC_ARG_WITH(smtpservers,
 133   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 134   [specify the default SMTP server(s) @<:@localhost@:>@]))
 135 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 136       [smtpservers="localhost"])
 137 AC_SUBST([smtpservers])dnl
 138
 139 dnl ----------------------------------------------------
 140 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 141 dnl ----------------------------------------------------
 142 AC_PREFIX_DEFAULT([/usr/local/nmh])
 143
 144 dnl ------------------
 145 dnl CHECK THE COMPILER
 146 dnl ------------------
 147 dnl We want these before the checks,
 148 dnl so the checks can modify their values.
 149 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 150 if test x"$enable_debug" = x"yes"; then
 151   test -z "$LDFLAGS" && LDFLAGS=-g
 152 fi
 153
 154 AC_PROG_CC
 155 AM_PROG_CC_C_O
 156
 157 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 158   [nmh_cv_has_unusedmacros],
 159   [nmh_saved_cppflags="$CPPFLAGS"
 160    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 161    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 162    CPPFLAGS="$nmh_saved_cppflags"])
 163
 164 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 165   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 166                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 167   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 168 fi
 169 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 170
 171 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 172   [nmh_cv_has_nosigncompare],
 173   [nmh_saved_cppflags="$CPPFLAGS"
 174    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 175    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 176                   nmh_cv_has_nosigncompare=no)
 177    CPPFLAGS="$nmh_saved_cppflags"])
 178
 179 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 180   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 181 fi
 182 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 183
 184 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 185 [nmh_saved_cflags="$CFLAGS"
 186  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 187  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 188  CFLAGS="$nmh_saved_cflags"])
 189
 190 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 191 [nmh_saved_cflags="$CFLAGS"
 192  CFLAGS="$CFLAGS -Wno-pointer-sign"
 193  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 194  CFLAGS="$nmh_saved_cflags"])
 195
 196 dnl if the user hasn't specified CFLAGS, then
 197 dnl   if compiler is gcc, then
 198 dnl    use -O2 and some warning flags
 199 dnl   else use -O
 200 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 201 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 202 dnl warnings which are probably mostly spurious and which in any case we
 203 dnl don't want to deal with now.
 204 if test "$nmh_cv_has_noptrsign" = "yes"; then
 205     if test "$nmh_cv_has_wextra" = "yes"; then
 206         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 207     else
 208         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 209     fi
 210 else
 211     if test "$nmh_cv_has_wextra" = "yes"; then
 212         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 213     else
 214         nmh_gcc_warnflags="-Wall"
 215     fi
 216 fi
 217
 218 if test -n "$auto_cflags"; then
 219   if test x"$enable_debug" = x"yes"; then
 220     if test -n "$GCC"; then
 221       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 222     else
 223       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 224     fi
 225   else
 226     if test -z "$LDFLAGS"; then
 227       case "$build_os" in
 228         darwin*)
 229           LDFLAGS=
 230           ;;
 231         *)
 232           LDFLAGS=-s
 233           ;;
 234       esac
 235     fi
 236     if test -n "$GCC"; then
 237       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 238     else
 239       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 240     fi
 241   fi
 242 fi
 243
 244 AC_C_CONST              dnl Does compiler support `const'.
 245
 246 dnl ------------------
 247 dnl CHECK FOR PROGRAMS
 248 dnl ------------------
 249 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 250 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 251 AC_PROG_RANLIB          dnl Check for `ranlib'
 252 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 253 AC_PROG_SED             dnl Check for Posix-compliant sed
 254 AC_PROG_LEX             dnl Check for lex/flex
 255
 256 dnl Look for `cut'
 257 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 258 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 259
 260 dnl
 261 dnl Check for MD5 program and formatting command
 262 dnl
 263 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 264 AS_CASE(["${MD5SUM}"],
 265         [md5sum], [MD5FMT="cat"],
 266         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 267         [MD5FMT="missing"])
 268 AC_SUBST([MD5FMT])
 269
 270 dnl ----------------------------------------------
 271 dnl check for lclint, and lint if it doesn't exist
 272 dnl ----------------------------------------------
 273 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 274 if test x$ac_cv_prog_linttmp1 != xno ; then
 275   LINT=$ac_cv_prog_linttmp1
 276   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 277 else
 278   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 279   if test x$ac_cv_prog_linttmp2 != xno ; then
 280     LINT=$ac_cv_prog_linttmp2
 281     LINTFLAGS=""
 282   else
 283     LINT="echo 'No lint program found'"
 284     LINTFLAGS=""
 285   fi
 286 fi
 287 AC_SUBST([LINT])dnl
 288 AC_SUBST([LINTFLAGS])dnl
 289
 290 dnl Look for `ls'
 291 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 292 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 293
 294 dnl See how we get ls to display the owner and the group
 295 if test "$lspath" != "no"; then
 296   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 297                  [nmh_cv_ls_grpopt],
 298   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 299     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 300     dnl ls, it would seem -l gave us both the user and group.  On this type of
 301     dnl ls, -g makes _only_ the group be displayed (and not the user).
 302     nmh_cv_ls_grpopt="-l"
 303   else
 304     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 305     nmh_cv_ls_grpopt="-lg"
 306   fi])
 307 fi
 308
 309 dnl Look for `sendmail'
 310 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 311 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 312
 313 dnl Look for `vi'
 314 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 315 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 316
 317 dnl If editor is not specified yet,
 318 dnl then use `vi' as the default.
 319 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 320 AC_SUBST([editorpath])dnl
 321
 322 dnl ----------------------------------------------------------
 323 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 324 dnl ----------------------------------------------------------
 325 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 326 [for mailspool in /var/mail        dnl
 327                   /var/spool/mail  dnl
 328                   /usr/spool/mail  dnl
 329                   /dev/null;       dnl Just in case we fall through
 330 do
 331   test -d $mailspool && break
 332 done
 333 nmh_cv_mailspool=$mailspool
 334 ])
 335 mailspool=$nmh_cv_mailspool
 336 AC_SUBST([mailspool])dnl
 337
 338 dnl See whether the mail spool directory is world-writable.
 339 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 340   AC_CACHE_CHECK(whether the mail spool is world-writable,
 341                  nmh_cv_mailspool_world_writable,
 342   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 343     nmh_cv_mailspool_world_writable=no
 344   else
 345     nmh_cv_mailspool_world_writable=yes
 346   fi])
 347 fi
 348
 349 dnl Also, check for liblockfile (as found on Debian systems)
 350 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 351
 352 dnl and whether its companion program dotlockfile is setgid
 353 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 354 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 355   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 356     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 357     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 358         nmh_cv_dotlockfile_setgid=yes
 359       else
 360         nmh_cv_dotlockfile_setgid=no
 361       fi])
 362   fi
 363 fi
 364
 365 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 366 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 367 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 368   dnl do we really need both of these?
 369   AC_DEFINE(MAILGROUP,1,
 370     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 371   SETGID_MAIL=1
 372 fi
 373 AC_SUBST(SETGID_MAIL)dnl
 374
 375 dnl Use ls to see which group owns the mail spool directory.
 376 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 377 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 378 ])
 379 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 380 AC_SUBST(MAIL_SPOOL_GRP)dnl
 381
 382 dnl ------------------
 383 dnl CHECK HEADER FILES
 384 dnl ------------------
 385
 386 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 387 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 388 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 389 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 390 dnl declared; if so they should have an entry added to this case statement.
 391 dnl NB that we must define this on the compiler command line, not in config.h,
 392 dnl because it must be set before any system header is included and there's no
 393 dnl portable way to make sure that files generated by lex include config.h
 394 dnl before system header files.
 395
 396 AS_CASE(["$host_os"],
 397         [linux*],
 398         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 399           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 400                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 401
 402 AC_HEADER_STDC
 403 AC_HEADER_TIOCGWINSZ
 404 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 405                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 406                   sys/param.h sys/time.h sys/stream.h])
 407
 408 dnl
 409 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 410 dnl really use a whole set of them, but this check should be
 411 dnl sufficient.
 412 dnl
 413 AC_CHECK_HEADER(libio.h, [
 414   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 415     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 416
 417 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 418   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 419 [[#if HAVE_SYS_STREAM_H
 420 #  include <sys/stream.h>
 421 #endif
 422 ]])
 423
 424 dnl ---------------
 425 dnl CHECK FUNCTIONS
 426 dnl ---------------
 427 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 428
 429 dnl Check for multibyte character set support
 430 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 431     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 432   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 433     [Define to enable support for multibyte character sets.])
 434 fi
 435
 436 dnl -------------------
 437 dnl CHECK FOR LIBRARIES
 438 dnl -------------------
 439 dnl Check location of modf
 440 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 441
 442 dnl Checks for network libraries (nsl, socket)
 443 NMH_CHECK_NETLIBS
 444
 445 NMH_READLINE
 446
 447 termcap_curses_order="termcap curses ncurses"
 448 for lib in $termcap_curses_order; do
 449   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 450 done
 451 AC_SUBST([TERMLIB])dnl
 452 AS_IF([test "x$TERMLIB" = "x"],
 453       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 454 or ncurses library or package that you can install?])])
 455
 456
 457 dnl ---------------
 458 dnl CHECK FOR ICONV
 459 dnl ---------------
 460
 461 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 462 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 463   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 464   if test "x$ac_found_iconv" = "xno"; then
 465     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 466     if test "x$ac_found_iconv" = "xno"; then
 467       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 468     fi
 469     if test "x$ac_found_iconv" != "xno"; then
 470       ICONVLIB="-liconv"
 471     fi
 472   else
 473     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 474     AC_CHECK_DECL(_libiconv_version,
 475       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 476       [ #include <iconv.h> ])
 477   fi
 478 fi
 479 if test "x$ac_found_iconv" = xyes; then
 480   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 481 fi
 482 AC_SUBST([ICONVLIB])
 483
 484 dnl Check if iconv uses const in prototype declaration
 485 if test "x$ac_found_iconv" = "xyes"; then
 486   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 487     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 488         #include <iconv.h>]],
 489         [[#ifdef __cplusplus
 490           "C"
 491           #endif
 492           #if defined(__STDC__) || defined(__cplusplus)
 493           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 494           #else
 495           size_t iconv();
 496           #endif]])],
 497       [ac_cv_iconv_const=],
 498       [ac_cv_iconv_const=const])])
 499   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 500     [Define as const if the declaration of iconv() needs const.])
 501 fi
 502
 503 dnl --------------
 504 dnl CHECK FOR NDBM
 505 dnl --------------
 506
 507 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 508             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 509 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 510             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 511
 512 if test "$nmh_ndbm" = "autodetect"; then
 513   if test "$nmh_ndbmheader" != "autodetect"; then
 514     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 515   else
 516
 517     dnl There are at least four implementations of ndbm, and
 518     dnl several of those can be in different places at the whim
 519     dnl of the system integrator. A good summary of this mess
 520     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 521
 522     dnl Classic ndbm with no library required (eg NetBSD): try this
 523     dnl first so we don't accidentally link in a pointless but harmless
 524     dnl library in one of the later ndbm.h+libfoo tests:
 525     NMH_CHECK_NDBM(ndbm.h,,,
 526     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 527       NMH_CHECK_NDBM(db.h,db,,
 528     dnl Berkeley DBv1 emulating ndbm:
 529         NMH_CHECK_NDBM(ndbm.h,db,,
 530           NMH_CHECK_NDBM(ndbm.h,db1,,
 531     dnl Classic ndbm:
 532             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 533     dnl glibc2.1 systems put db1 in a subdir:
 534               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 535     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 536     dnl and possibly needing gbdm_compat library:
 537                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 538                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 539                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 540                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 541
 542   fi
 543 else
 544   dnl We don't really need to check that the user-specified values work,
 545   dnl but it is a convenience to the user to bomb out early rather than
 546   dnl after configure and half the compile process.
 547   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 548 fi
 549
 550 if test "$nmh_ndbm_found" = "no"; then
 551   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 552 else
 553   dnl Now export the lib/header to our makefile/config.h:
 554   if test x"$nmh_ndbmheader" != x; then
 555     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 556       [Define to the header containing the ndbm API prototypes.])
 557   fi
 558   if test x"$nmh_ndbm" != x; then
 559     NDBM_LIBS="-l$nmh_ndbm"
 560   else
 561     NDBM_LIBS=
 562   fi
 563   AC_SUBST([NDBM_LIBS])
 564 fi
 565
 566 dnl ------------------
 567 dnl Set RPM build root
 568 dnl ------------------
 569 dnl nmhrpm is used in the final summary, see below.  The default value is
 570 dnl reported there as ./RPM, consistent with the reporting of the default
 571 dnl source code location as ., but its absolute path is used in the Makefile.
 572 AC_ARG_WITH(rpmdir,
 573   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 574   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 575           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 576 AC_SUBST([rpmdir])
 577
 578
 579 dnl --------------------
 580 dnl CHECK FOR CYRUS-SASL
 581 dnl --------------------
 582
 583 AS_IF([test x"$sasl_support" = x"yes"],[
 584   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 585   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 586     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 587 AC_SUBST([SASLLIB])
 588
 589 dnl -----------------
 590 dnl CHECK FOR OPENSSL
 591 dnl -----------------
 592
 593 AS_IF([test x"$tls_support" = x"yes"],[
 594   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 595   AC_CHECK_LIB([crypto], [BIO_write], ,
 596     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 597   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 598     [AC_MSG_ERROR([OpenSSL library not found])])])
 599
 600 dnl ---------------------
 601 dnl CHECK TERMCAP LIBRARY
 602 dnl ---------------------
 603
 604 dnl Add the termcap library, so that the following configure
 605 dnl tests will find it when it tries to link test programs.
 606 nmh_save_LIBS="$LIBS"
 607 LIBS="$TERMLIB $LIBS"
 608
 609 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 610 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 611 dnl in tgetstr().
 612 dnl Under Cygwin test program crashes but exit code is still 0. So,
 613 dnl we test for a file that porgram should create
 614 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 615 [Define to 1 if tgetent() accepts NULL as a buffer.])
 616 AC_CACHE_CHECK(if tgetent accepts NULL,
 617 nmh_cv_func_tgetent_accepts_null,
 618 [AC_TRY_RUN([
 619 main()
 620 {
 621     char buf[4096];
 622     int r1 = tgetent(buf, "vt100");
 623     int r2 = tgetent((char*)0,"vt100");
 624     if (r1 >= 0 && r1 == r2) {
 625         char tbuf[1024], *u;
 626         u = tbuf;
 627         tgetstr("cl", &u);
 628         creat("conftest.tgetent", 0640);
 629     }
 630     exit((r1 != r2) || r2 == -1);
 631 }
 632 ],
 633   if test -f conftest.tgetent; then
 634     nmh_cv_func_tgetent_accepts_null=yes
 635   else
 636     nmh_cv_func_tgetent_accepts_null=no
 637   fi,
 638   nmh_cv_func_tgetent_accepts_null=no,
 639   nmh_cv_func_tgetent_accepts_null=no)])
 640 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 641   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 642 fi
 643 AC_CACHE_CHECK(if tgetent returns 0 on success,
 644 nmh_cv_func_tgetent_zero_success,
 645 [AC_TRY_RUN([
 646 main()
 647 {
 648     char buf[4096];
 649     int r1 = tgetent(buf, "!@#$%^&*");
 650     int r2 = tgetent(buf, "vt100");
 651     if (r1 < 0 && r2 == 0) {
 652         char tbuf[1024], *u;
 653         u = tbuf;
 654         tgetstr("cl", &u);
 655         creat("conftest.tgetent0", 0640);
 656     }
 657     exit(r1 == r2);
 658 }
 659 ],
 660   if test -f conftest.tgetent0; then
 661     nmh_cv_func_tgetent_zero_success=yes
 662   else
 663     nmh_cv_func_tgetent_zero_success=no
 664   fi,
 665   nmh_cv_func_tgetent_zero_success=no,
 666   nmh_cv_func_tgetent_zero_success=no)])
 667 AH_TEMPLATE([TGETENT_SUCCESS],
 668 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 669 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 670   AC_DEFINE(TGETENT_SUCCESS, 0)
 671 else
 672   AC_DEFINE(TGETENT_SUCCESS, 1)
 673 fi
 674
 675 dnl Now put the libraries back to what it was before we
 676 dnl starting checking the termcap library.
 677 LIBS="$nmh_save_LIBS"
 678
 679 dnl --------------
 680 dnl CHECK TYPEDEFS
 681 dnl --------------
 682 AC_TYPE_PID_T
 683 AC_TYPE_OFF_T
 684 AC_TYPE_UID_T
 685 AC_TYPE_MODE_T
 686 AC_TYPE_SIZE_T
 687
 688 dnl ----------------
 689 dnl CHECK STRUCTURES
 690 dnl ----------------
 691
 692 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 693 dnl (FreeBSD has a timezone() function but not a timezone global
 694 dnl variable that is visible).
 695 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 696
 697 AC_STRUCT_DIRENT_D_TYPE
 698
 699 dnl Where is <signal.h> located?  Needed as input for signames.awk
 700 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 701 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 702                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 703                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 704                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 705                  /usr/include/sys/signal.h      dnl Almost everybody else
 706                  /dev/null;                     dnl Just in case we fall through
 707 do
 708   test -f $SIGNAL_H && \
 709   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 710   break
 711 done
 712 nmh_cv_path_signal_h=$SIGNAL_H
 713 ])
 714 SIGNAL_H=$nmh_cv_path_signal_h
 715 AC_SUBST(SIGNAL_H)dnl
 716
 717 dnl
 718 dnl Sigh, this is required because under the new world order autoconf has
 719 dnl nothing to create in a few of the build directories when doing an object
 720 dnl tree build.  So make sure we created certain directories if they don't
 721 dnl exist.
 722 dnl
 723
 724 AC_CONFIG_COMMANDS([build-directories],
 725 [test -d etc || ${MKDIR_P} etc
 726 test -d man || ${MKDIR_P} man])
 727
 728 AC_CONFIG_COMMANDS_POST([
 729
 730 dnl These odd looking assignments are done to expand out unexpanded
 731 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 732 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 733 dnl again to get the final answer.
 734 dnl We only use the expanded versions to print the install paths in
 735 dnl the final summary and should use them nowhere else (see the autoconf
 736 dnl docs for the rationale for bindir etc being unexpanded).
 737 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 738 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 739 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 740 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 741 eval "nmhrpm=${nmhrpm}";
 742
 743 AC_MSG_NOTICE([
 744 nmh configuration
 745 -----------------
 746 nmh version                : AC_PACKAGE_VERSION
 747 host os                    : ${host}
 748 compiler                   : ${CC}
 749 compiler flags             : ${CFLAGS}
 750 linker flags               : ${LDFLAGS}
 751 preprocessor flags         : ${CPPFLAGS}
 752 source code location       : ${srcdir}
 753 binary install path        : ${nmhbin}
 754 library install path       : ${nmhlib}
 755 config files install path  : ${nmhsysconf}
 756 man page install path      : ${nmhman}
 757 RPM build root             : ${nmhrpm}
 758 backup prefix              : ${backup_prefix}
 759 transport system           : ${MTS}
 760 file locking type          : ${LOCKTYPE}
 761 default smtp servers       : ${smtpservers}
 762 default editor             : ${editorpath}
 763 default pager              : ${pagerpath}
 764 SASL support               : ${sasl_support}
 765 TLS support                : ${tls_support}
 766 ])])dnl
 767
 768 dnl ---------------
 769 dnl OUTPUT MAKEFILE
 770 dnl ---------------
 771 AC_CONFIG_FILES([Makefile test/common.sh])
 772 AC_OUTPUT