diplodocus.org Git - nmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want client-side support for pop?
  60 AC_ARG_ENABLE(pop,
  61   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  62 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  63 if test x"$enable_nmh_pop" = x"yes"; then
  64   enable_pop=yes
  65 fi
  66
  67 dnl Do you want to disable use of locale functions
  68 AH_TEMPLATE([LOCALE],
  69 [Undefine if you don't want locale features.  By default this is defined.])
  70 AC_ARG_ENABLE([locale],
  71 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  72 [if test x$enableval = xyes; then
  73   AC_DEFINE(LOCALE)
  74 fi],
  75 AC_DEFINE(LOCALE)
  76 )
  77
  78 dnl Do you want client-side support for using SASL for authentication?
  79 dnl Note that this code will be enabled for both POP and SMTP
  80 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  81   [Enable SASL support via the Cyrus SASL library]))
  82 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  83   AC_DEFINE(CYRUS_SASL, 1,
  84     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  85   if test x"$with_cyrus_sasl" != xyes; then
  86     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  87     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  88   fi
  89   sasl_support=yes
  90 else
  91   sasl_support=no
  92 fi
  93
  94 dnl Do you want client-side support for encryption with TLS?
  95 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
  96 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
  97   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
  98   tls_support=yes
  99 else
 100   tls_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 120     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 121
 122 dnl After we know if we're including apop and kpop support, do pop stuff
 123 if test x"$enable_pop" = x"yes"; then
 124   AC_DEFINE(POP, 1,
 125     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 126   POPLIB=popsbr.o
 127   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 128 else
 129   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 130 fi
 131 AC_SUBST(POPLIB)dnl
 132 AC_SUBST(POPSED)dnl
 133
 134 dnl What method of locking to use?
 135 AC_ARG_WITH(locking,
 136   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 137   [specify the file locking method]))
 138
 139 if test x"$with_locking" = x"dot"; then
 140   LOCKTYPE="dot"
 141   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 142 elif test x"$with_locking" = x"flock"; then
 143   LOCKTYPE="flock"
 144   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 145 elif test x"$with_locking" = x"lockf"; then
 146   LOCKTYPE="lockf"
 147   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 148 elif test x"$with_locking" = x"fcntl"; then
 149   LOCKTYPE="fcntl"
 150   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 151 else
 152   LOCKTYPE="dot"
 153   AC_DEFINE(DOT_LOCKING)dnl
 154 fi
 155
 156 dnl Should we use a locking directory?
 157 AC_ARG_ENABLE([lockdir], [
 158   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 159   AS_IF([test "x$enableval" = xyes],[
 160     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 161   AS_IF([test "x$LOCKTYPE" != xdot],[
 162     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 163   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 164                      [Directory to store dot-locking lock files])
 165 ])
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_STDC
 465 AC_HEADER_TIME
 466 AC_HEADER_TIOCGWINSZ
 467 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 468                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 469                  sys/param.h sys/time.h sys/stream.h)
 470
 471 dnl
 472 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 473 dnl really use a whole set of them, but this check should be
 474 dnl sufficient.
 475 dnl
 476 AC_CHECK_HEADER(libio.h, [
 477   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 478     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 479
 480 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 481   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 482 [[#if HAVE_SYS_STREAM_H
 483 #  include <sys/stream.h>
 484 #endif
 485 ]])
 486
 487 dnl ---------------
 488 dnl CHECK FUNCTIONS
 489 dnl ---------------
 490 AC_CHECK_FUNCS(writev lstat tzset getutent nl_langinfo sigaction sigprocmask \
 491                sigblock sigsetmask sighold sigrelse)
 492
 493 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 494 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 495 dnl any system header.
 496 dnl
 497 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 498 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 499 dnl need to check?
 500 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 501 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 502                 AC_EGREP_HEADER(initgroups, unistd.h,
 503                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 504
 505 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 506 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 507 dnl seems to work perfectly and IBM apparently uses it in internal code).
 508 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 509 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 510 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 511 dnl prototype.
 512 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 513   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 514
 515 dnl Check for multibyte character set support
 516 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 517     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 518   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 519     [Define to enable support for multibyte character sets.])
 520 fi
 521
 522 dnl -------------------
 523 dnl CHECK FOR LIBRARIES
 524 dnl -------------------
 525 dnl Check location of modf
 526 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 527
 528 dnl Checks for network libraries (nsl, socket)
 529 AC_CHECK_NETLIBS
 530
 531 termcap_curses_order="termcap curses ncurses"
 532 for lib in $termcap_curses_order; do
 533   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 534 done
 535 AC_SUBST(TERMLIB)dnl
 536
 537 dnl ---------------
 538 dnl CHECK FOR ICONV
 539 dnl ---------------
 540
 541 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 542 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 543   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 544   if test "x$ac_found_iconv" = "xno"; then
 545     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 546     if test "x$ac_found_iconv" = "xno"; then
 547       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 548     fi
 549     if test "x$ac_found_iconv" != "xno"; then
 550       LIBS="-liconv $LIBS"
 551     fi
 552   else
 553     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 554     AC_CHECK_DECL(_libiconv_version,
 555       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 556       [ #include <iconv.h> ])
 557   fi
 558 fi
 559 if test "x$ac_found_iconv" = xyes; then
 560   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 561 fi
 562
 563 dnl Check if iconv uses const in prototype declaration
 564 if test "x$ac_found_iconv" = "xyes"; then
 565   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 566     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 567         #include <iconv.h>]],
 568         [[#ifdef __cplusplus
 569           "C"
 570           #endif
 571           #if defined(__STDC__) || defined(__cplusplus)
 572           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 573           #else
 574           size_t iconv();
 575           #endif]])],
 576       [ac_cv_iconv_const=],
 577       [ac_cv_iconv_const=const])])
 578   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 579     [Define as const if the declaration of iconv() needs const.])
 580 fi
 581
 582 dnl --------------
 583 dnl CHECK FOR NDBM
 584 dnl --------------
 585
 586 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 587             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 588 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 589             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 590
 591 if test "$nmh_ndbm" = "autodetect"; then
 592   if test "$nmh_ndbmheader" != "autodetect"; then
 593     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 594   else
 595
 596     dnl There are at least four implementations of ndbm, and
 597     dnl several of those can be in different places at the whim
 598     dnl of the system integrator. A good summary of this mess
 599     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 600
 601     dnl Classic ndbm with no library required (eg NetBSD): try this
 602     dnl first so we don't accidentally link in a pointless but harmless
 603     dnl library in one of the later ndbm.h+libfoo tests:
 604     NMH_CHECK_NDBM(ndbm.h,,,
 605     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 606       NMH_CHECK_NDBM(db.h,db,,
 607     dnl Berkeley DBv1 emulating ndbm:
 608         NMH_CHECK_NDBM(ndbm.h,db,,
 609           NMH_CHECK_NDBM(ndbm.h,db1,,
 610     dnl Classic ndbm:
 611             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 612     dnl glibc2.1 systems put db1 in a subdir:
 613               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 614     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 615     dnl and possibly needing gbdm_compat library:
 616                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 617                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 618                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 619                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 620
 621   fi
 622 else
 623   dnl We don't really need to check that the user-specified values work,
 624   dnl but it is a convenience to the user to bomb out early rather than
 625   dnl after configure and half the compile process.
 626   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 627 fi
 628
 629 if test "$nmh_ndbm_found" = "no"; then
 630   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 631 else
 632   dnl Now export the lib/header to our makefile/config.h:
 633   if test x"$nmh_ndbmheader" != x; then
 634     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 635       [Define to the header containing the ndbm API prototypes.])
 636   fi
 637   if test x"$nmh_ndbm" != x; then
 638     NDBM_LIBS="-l$nmh_ndbm"
 639   else
 640     NDBM_LIBS=
 641   fi
 642   AC_SUBST(NDBM_LIBS)
 643 fi
 644
 645 dnl ------------------
 646 dnl Set RPM build root
 647 dnl ------------------
 648 dnl nmhrpm is used in the final summary, see below.  The default value is
 649 dnl reported there as ./RPM, consistent with the reporting of the default
 650 dnl source code location as ., but its absolute path is used in the Makefile.
 651 AC_ARG_WITH(rpmdir,
 652   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 653   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 654           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 655 AC_SUBST(rpmdir)
 656
 657
 658 dnl --------------------
 659 dnl CHECK FOR CYRUS-SASL
 660 dnl --------------------
 661
 662 AS_IF([test x"$sasl_support" = x"yes"],[
 663   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 664   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 665     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 666
 667 dnl -----------------
 668 dnl CHECK FOR OPENSSL
 669 dnl -----------------
 670
 671 AS_IF([test x"$tls_support" = x"yes"],[
 672   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 673   AC_CHECK_LIB([crypto], [BIO_write], ,
 674     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 675   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 676     [AC_MSG_ERROR([OpenSSL library not found])])])
 677
 678 dnl ---------------------
 679 dnl CHECK TERMCAP LIBRARY
 680 dnl ---------------------
 681
 682 dnl Add the termcap library, so that the following configure
 683 dnl tests will find it when it tries to link test programs.
 684 nmh_save_LIBS="$LIBS"
 685 LIBS="$TERMLIB $LIBS"
 686
 687 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 688 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 689 dnl in tgetstr().
 690 dnl Under Cygwin test program crashes but exit code is still 0. So,
 691 dnl we test for a file that porgram should create
 692 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 693 [Define to 1 if tgetent() accepts NULL as a buffer.])
 694 AC_CACHE_CHECK(if tgetent accepts NULL,
 695 nmh_cv_func_tgetent_accepts_null,
 696 [AC_TRY_RUN([
 697 main()
 698 {
 699     char buf[4096];
 700     int r1 = tgetent(buf, "vt100");
 701     int r2 = tgetent((char*)0,"vt100");
 702     if (r1 >= 0 && r1 == r2) {
 703         char tbuf[1024], *u;
 704         u = tbuf;
 705         tgetstr("cl", &u);
 706         creat("conftest.tgetent", 0640);
 707     }
 708     exit((r1 != r2) || r2 == -1);
 709 }
 710 ],
 711   if test -f conftest.tgetent; then
 712     nmh_cv_func_tgetent_accepts_null=yes
 713   else
 714     nmh_cv_func_tgetent_accepts_null=no
 715   fi,
 716   nmh_cv_func_tgetent_accepts_null=no,
 717   nmh_cv_func_tgetent_accepts_null=no)])
 718 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 719   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 720 fi
 721 AC_CACHE_CHECK(if tgetent returns 0 on success,
 722 nmh_cv_func_tgetent_zero_success,
 723 [AC_TRY_RUN([
 724 main()
 725 {
 726     char buf[4096];
 727     int r1 = tgetent(buf, "!@#$%^&*");
 728     int r2 = tgetent(buf, "vt100");
 729     if (r1 < 0 && r2 == 0) {
 730         char tbuf[1024], *u;
 731         u = tbuf;
 732         tgetstr("cl", &u);
 733         creat("conftest.tgetent0", 0640);
 734     }
 735     exit(r1 == r2);
 736 }
 737 ],
 738   if test -f conftest.tgetent0; then
 739     nmh_cv_func_tgetent_zero_success=yes
 740   else
 741     nmh_cv_func_tgetent_zero_success=no
 742   fi,
 743   nmh_cv_func_tgetent_zero_success=no,
 744   nmh_cv_func_tgetent_zero_success=no)])
 745 AH_TEMPLATE([TGETENT_SUCCESS],
 746 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 747 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 748   AC_DEFINE(TGETENT_SUCCESS, 0)
 749 else
 750   AC_DEFINE(TGETENT_SUCCESS, 1)
 751 fi
 752
 753 dnl Now put the libraries back to what it was before we
 754 dnl starting checking the termcap library.
 755 LIBS="$nmh_save_LIBS"
 756
 757 dnl --------------
 758 dnl CHECK TYPEDEFS
 759 dnl --------------
 760 AC_TYPE_SIGNAL
 761 AC_TYPE_PID_T
 762 AC_TYPE_OFF_T
 763 AC_TYPE_UID_T
 764 AC_TYPE_MODE_T
 765 AC_TYPE_SIZE_T
 766
 767 dnl Check for sigset_t.  Currently I'm looking in
 768 dnl <sys/types.h> and <signal.h>.  Others might need
 769 dnl to be added.
 770 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 771 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 772 #include <signal.h>]], [[sigset_t tempsigset;]])],
 773 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 774 if test $nmh_cv_type_sigset_t = no; then
 775   AC_DEFINE(sigset_t, unsigned int,
 776     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 777 fi
 778
 779 dnl ----------------
 780 dnl CHECK STRUCTURES
 781 dnl ----------------
 782
 783 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 784   [#ifdef TIME_WITH_SYS_TIME
 785 # include <sys/time.h>
 786 # include <time.h>
 787 #else
 788 # ifdef TM_IN_SYS_TIME
 789 #  include <sys/time.h>
 790 # else
 791 #  include <time.h>
 792 # endif
 793 #endif])
 794
 795 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 796
 797 AC_STRUCT_DIRENT_D_TYPE
 798
 799 dnl -------------
 800 dnl CHECK SIGNALS
 801 dnl -------------
 802 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 803 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 804 AC_MSG_CHECKING(what style of signals to use)
 805 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 806   signals_style=POSIX_SIGNALS
 807   AC_DEFINE(POSIX_SIGNALS, 1,
 808     [Define to 1 if you use POSIX style signal handling.])
 809   AC_DEFINE(RELIABLE_SIGNALS)
 810 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 811   signals_style=BSD_SIGNALS
 812   AC_DEFINE(BSD_SIGNALS,1,
 813     [Define to 1 if you use BSD style signal handling (and can block signals).])
 814   AC_DEFINE(RELIABLE_SIGNALS)
 815 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 816   signals_style=SYSV_SIGNALS
 817   AC_DEFINE(SYSV_SIGNALS,1,
 818     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 819 else
 820   signals_style=NO_SIGNAL_BLOCKING
 821   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 822     [Define to 1 if you have no signal blocking at all (bummer).])
 823 fi
 824
 825 AC_MSG_RESULT($signals_style)
 826
 827 dnl Where is <signal.h> located?  Needed as input for signames.awk
 828 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 829 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 830                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 831                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 832                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 833                  /usr/include/sys/signal.h      dnl Almost everybody else
 834                  /dev/null;                     dnl Just in case we fall through
 835 do
 836   test -f $SIGNAL_H && \
 837   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 838   break
 839 done
 840 nmh_cv_path_signal_h=$SIGNAL_H
 841 ])
 842 SIGNAL_H=$nmh_cv_path_signal_h
 843 AC_SUBST(SIGNAL_H)dnl
 844
 845 dnl ----------------
 846 dnl OS SPECIFIC DEFINES
 847 dnl ----------------
 848 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 849 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 850 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 851 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 852 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 853
 854 case "$target_os" in
 855
 856   solaris2*)
 857     AC_DEFINE(SYS5)
 858     AC_DEFINE(SVR4)
 859     ;;
 860   irix*)
 861     AC_DEFINE(SYS5)
 862     AC_DEFINE(SVR4)
 863     ;;
 864   osf*)
 865     AC_DEFINE(SYS5)
 866     AC_DEFINE(SVR4)
 867     ;;
 868   aix*)
 869     AC_DEFINE(SYS5)
 870     AC_DEFINE(SVR4)
 871     ;;
 872   sunos4*)
 873     AC_DEFINE(BSD42)
 874     ;;
 875   freebsd*)
 876     AC_DEFINE(BSD42)
 877     AC_DEFINE(BSD44)
 878     ;;
 879   netbsd*)
 880     AC_DEFINE(BSD42)
 881     AC_DEFINE(BSD44)
 882     ;;
 883   openbsd*)
 884     AC_DEFINE(BSD42)
 885     AC_DEFINE(BSD44)
 886     ;;
 887   bsd/os*)
 888     AC_DEFINE(BSD42)
 889     AC_DEFINE(BSD44)
 890     ;;
 891   sco5*)
 892     AC_DEFINE(SYS5)
 893     AC_DEFINE(SCO_5_STDIO)
 894     ;;
 895 esac
 896
 897
 898 dnl ----------------
 899 dnl OUTPUT MAKEFILES
 900 dnl ----------------
 901 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 902                 mts/Makefile mts/smtp/Makefile \
 903                 etc/Makefile docs/Makefile man/Makefile)
 904 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 905 AC_OUTPUT
 906
 907 dnl These odd looking assignments are done to expand out unexpanded
 908 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 909 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 910 dnl again to get the final answer.
 911 dnl We only use the expanded versions to print the install paths in
 912 dnl the final summary and should use them nowhere else (see the autoconf
 913 dnl docs for the rationale for bindir etc being unexpanded).
 914 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 915 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 916 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 917 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 918 eval "nmhrpm=${nmhrpm}";
 919
 920 pop_kinds=no
 921 if test x"$enable_pop" = x"yes"; then
 922   pop_kinds="yes ("
 923
 924   if test x"$enable_apop" = x"yes"; then
 925     pop_kinds="${pop_kinds}APOP "
 926   fi
 927
 928   pop_kinds="${pop_kinds}POP3)"
 929 fi
 930
 931 echo "
 932 nmh configuration
 933 -----------------
 934 nmh version                : AC_PACKAGE_VERSION
 935 target os                  : ${target}
 936 compiler                   : ${CC}
 937 compiler flags             : ${CFLAGS}
 938 linker flags               : ${LDFLAGS}
 939 definitions                : ${OURDEFS}
 940 source code location       : ${srcdir}
 941 binary install path        : ${nmhbin}
 942 library install path       : ${nmhlib}
 943 config files install path  : ${nmhsysconf}
 944 man page install path      : ${nmhman}
 945 RPM build root             : ${nmhrpm}
 946 backup prefix              : ${backup_prefix}
 947 transport system           : ${MTS}
 948 file locking type          : ${LOCKTYPE}
 949 default smtp servers       : ${smtpservers}
 950 default editor             : ${editorpath}
 951 default pager              : ${pagerpath}
 952 email address masquerading : ${masquerade}
 953 pop is enabled             : ${pop_kinds}
 954 SASL support               : ${sasl_support}
 955 TLS support                : ${tls_support}"
 956 echo ""