diplodocus.org Git - nmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl 2.13 definitely chokes; 2.53 is the earliest version I've tested.
   8 dnl 2.50 is the major breakpoint between the old autoconf and the new,
   9 dnl so require that. If there are bug reports about 2.50-2.52 not working
  10 dnl we can always move this up a little.
  11 AC_PREREQ(2.50)
  12
  13 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  14 AC_CONFIG_SRCDIR(h/nmh.h)
  15 AC_CONFIG_HEADER(config.h)
  16
  17 AC_CANONICAL_TARGET
  18
  19 dnl ---------------------
  20 dnl define a macro or two
  21 dnl ---------------------
  22
  23 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  24 if test -n "$LIBTOOL" ; then
  25   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  26   if test x"$tmptest" != x  ; then
  27     GNU_LIBTOOL=1
  28     AC_SUBST(GNU_LIBTOOL)dnl
  29   fi
  30 fi
  31 ] )
  32
  33 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  34 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  35
  36 dnl What date of nmh are we building?
  37 DATE=`cat ${srcdir}/DATE`
  38 echo "configuring for nmh dated $DATE"
  39 AC_SUBST(DATE)dnl
  40
  41 dnl --------------------------
  42 dnl CHECK COMMAND LINE OPTIONS
  43 dnl --------------------------
  44
  45 dnl Do you want client-side support for apop?
  46 AC_ARG_ENABLE(apop,
  47 [  --enable-apop           enable client-side support for POP3 and APOP])
  48 if test x"$enable_apop" = x"yes"; then
  49   AC_DEFINE(APOP)dnl
  50   APOPLIB=md5.o
  51   enable_pop=yes
  52 fi
  53 AC_SUBST(APOPLIB)dnl
  54
  55 dnl Do you want to debug nmh?
  56 AC_ARG_ENABLE(debug,
  57 [  --enable-debug          enable nmh code debugging])
  58 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  59 if test x"$enable_nmh_debug" = x"yes"; then
  60   enable_debug=yes
  61 fi
  62
  63 dnl Allow users to send email from addresses other than their default?
  64 AC_ARG_ENABLE(masquerade,
  65   [  --enable-masquerade[='draft_from mmailid username_extension']
  66                           enable up to 3 types of address masquerading [none]],
  67   [if test x"$enable_masquerade" = x"yes"; then
  68     masquerade="draft_from mmailid username_extension"
  69   else
  70     masquerade="$enable_masquerade"
  71   fi])
  72 AC_SUBST(masquerade)dnl
  73
  74 dnl Do you want mhe support?
  75 AC_ARG_ENABLE(mhe,
  76 [  --enable-mhe            enable mhe support (DEFAULT)])
  77
  78 dnl mhe support is on by default, so define it unless --disable-mhe or the
  79 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  80 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  81   AC_DEFINE(MHE)dnl
  82 fi
  83
  84 dnl Do you want client-side support for pop?
  85 AC_ARG_ENABLE(pop,
  86 [  --enable-pop            enable client-side support for plain POP3])
  87 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  88 if test x"$enable_nmh_pop" = x"yes"; then
  89   enable_pop=yes
  90 fi
  91
  92 dnl Do you want client-side support for using SASL for authentication?
  93 dnl Note that this code will be enabled for both POP and SMTP
  94 AC_ARG_WITH(cyrus-sasl,
  95 [  --with-cyrus-sasl=<dir> Specify location of Cyrus SASL library for auth])
  96 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  97   AC_DEFINE(CYRUS_SASL)dnl
  98   sasl_support=yes
  99 else
 100   sasl_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105 [  --with-editor=EDITOR    specify the default editor])
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   [  --with-hash-backup      use # as the backup prefix (default: ,)])
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix")dnl
 120
 121 dnl Do you want support for hesiod
 122 AC_ARG_WITH(hesiod,
 123 [  --with-hesiod=PREFIX    specify location of Hesiod])
 124 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 125   AC_DEFINE(HESIOD)dnl
 126 fi
 127
 128 dnl Do you want client-side support for kpop
 129 AC_ARG_WITH(krb4,
 130 [  --with-krb4=PREFIX      specify location of Kerberos V4 for KPOP support])
 131 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 132   enable_pop=yes
 133   AC_DEFINE(KPOP)dnl
 134   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
 135 fi
 136
 137 dnl After we know if we're including apop and kpop support, do pop stuff
 138 if test x"$enable_pop" = x"yes"; then
 139   AC_DEFINE(POP)dnl
 140   POPLIB=popsbr.o
 141   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 142 else
 143   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 144 fi
 145 AC_SUBST(POPLIB)dnl
 146 AC_SUBST(POPSED)dnl
 147
 148 dnl What method of locking to use?
 149 AC_ARG_WITH(locking,
 150 [  --with-locking=LOCKTYPE specify the file locking method
 151                           (one of dot, fcntl, flock, lockf)])
 152
 153 if test x"$with_locking" = x"dot"; then
 154   LOCKTYPE="dot"
 155   AC_DEFINE(DOT_LOCKING)dnl
 156 elif test x"$with_locking" = x"flock"; then
 157   LOCKTYPE="flock"
 158   AC_DEFINE(FLOCK_LOCKING)dnl
 159 elif test x"$with_locking" = x"lockf"; then
 160   LOCKTYPE="lockf"
 161   AC_DEFINE(LOCKF_LOCKING)dnl
 162 elif test x"$with_locking" = x"fcntl"; then
 163   LOCKTYPE="fcntl"
 164   AC_DEFINE(FCNTL_LOCKING)dnl
 165 else
 166   LOCKTYPE="dot"
 167   AC_DEFINE(DOT_LOCKING)dnl
 168 fi
 169
 170 dnl What method of posting should post use?
 171 AC_ARG_WITH(mts,
 172 [  --with-mts=MTS          specify the default mail transport agent/service])
 173
 174 if test x"$with_mts" = x"smtp"; then
 175   MTS="smtp"
 176 elif test x"$with_mts" = x"sendmail"; then
 177   MTS="sendmail"
 178 else
 179   MTS="smtp"
 180 fi
 181 AC_SUBST(MTS)dnl
 182
 183 dnl Both the smtp and sendmail mail transport services use the smtp code
 184 AC_DEFINE(SMTPMTS)dnl
 185
 186 dnl What should be the default pager?
 187 AC_ARG_WITH(pager,
 188 [  --with-pager=PAGER      specify the default pager])
 189
 190 if test -n "$with_pager"; then
 191   pagerpath="$with_pager"
 192 fi
 193
 194 dnl What should be the default mail server(s)?
 195 AC_ARG_WITH(smtpservers,
 196 [  --with-smtpservers='SMTPSERVER1[ SMTPSERVER2...]'
 197                           specify the default SMTP server(s) [localhost]])
 198 if test -n "$with_smtpservers"; then
 199   smtpservers="$with_smtpservers"
 200 else
 201   smtpservers="localhost"
 202 fi
 203 AC_SUBST(smtpservers)dnl
 204
 205 dnl ----------------------------------------------------
 206 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 207 dnl ----------------------------------------------------
 208 AC_PREFIX_DEFAULT(/usr/local/nmh)
 209
 210 dnl ------------------
 211 dnl CHECK THE COMPILER
 212 dnl ------------------
 213 dnl We want these before the checks,
 214 dnl so the checks can modify their values.
 215 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 216 if test x"$enable_debug" = x"yes"; then
 217   test -z "$LDFLAGS" && LDFLAGS=-g
 218 fi
 219
 220 AC_PROG_CC
 221
 222 dnl if the user hasn't specified CFLAGS, then
 223 dnl   if compiler is gcc, then
 224 dnl     use -O2 and some warning flags
 225 dnl   else use -O
 226 if test -n "$auto_cflags"; then
 227   if test x"$enable_debug" = x"yes"; then
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 232     fi
 233   else
 234     if test -z "$LDFLAGS"; then
 235       case "$build_os" in
 236         darwin*)
 237           LDFLAGS=
 238           ;;
 239         *)
 240           LDFLAGS=-s
 241           ;;
 242       esac
 243     fi
 244     if test -n "$GCC"; then
 245       test -z "$CFLAGS" && CFLAGS="-Wall -O2" || CFLAGS="$CFLAGS -Wall -O2"
 246     else
 247       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 248     fi
 249   fi
 250 fi
 251
 252 AC_C_CONST              dnl Does compiler support `const'.
 253
 254 dnl ------------------
 255 dnl CHECK FOR PROGRAMS
 256 dnl ------------------
 257 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 258 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 259 AC_PROG_RANLIB          dnl Check for `ranlib'
 260 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 261 AC_PROG_LEX             dnl Check for lex/flex
 262
 263 dnl Look for `cut'
 264 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 265 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 266
 267 dnl ----------------------------------------------
 268 dnl check for lclint, and lint if it doesn't exist
 269 dnl ----------------------------------------------
 270 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 271 if test x$ac_cv_prog_linttmp1 != xno ; then
 272   LINT=$ac_cv_prog_linttmp1
 273   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 274 else
 275   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 276   if test x$ac_cv_prog_linttmp2 != xno ; then
 277     LINT=$ac_cv_prog_linttmp2
 278     LINTFLAGS=""
 279   else
 280     LINT="echo 'No lint program found'"
 281     LINTFLAGS=""
 282   fi
 283 fi
 284 AC_SUBST(LINT)dnl
 285 AC_SUBST(LINTFLAGS)dnl
 286
 287 dnl try to figure out which one we've got
 288 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 289 NMH_PROG_GNU_LIBTOOL
 290
 291 dnl Check for lorder and tsort commands
 292 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 293 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 294
 295 dnl If either doesn't exist, replace them with echo and cat
 296 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 297   LORDER=echo
 298   TSORT=cat
 299   AC_SUBST(LORDER)dnl
 300   AC_SUBST(TSORT)dnl
 301 dnl Mac OS X has lorder, but sh is too broken for it to work
 302 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 303 dnl   LORDER=echo
 304 dnl   TSORT=cat
 305 dnl   AC_SUBST(LORDER)dnl
 306 dnl   AC_SUBST(TSORT)dnl
 307 fi
 308
 309 dnl Check whether tsort can deal with loops
 310 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 311   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 312     nmh_cv_tsort_loop=no
 313   else
 314     nmh_cv_tsort_loop=yes
 315   fi])
 316 if test x$nmh_cv_tsort_loop = xno ; then
 317   LORDER=echo
 318   TSORT=cat
 319   AC_SUBST(LORDER)dnl
 320   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Look for `ls'
 324 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 325 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 326
 327 dnl See how we get ls to display the owner and the group
 328 if test "$lspath" != "no"; then
 329   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 330                  nmh_cv_ls_grpopt,
 331   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 332     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 333     dnl ls, it would seem -l gave us both the user and group.  On this type of
 334     dnl ls, -g makes _only_ the group be displayed (and not the user).
 335     nmh_cv_ls_grpopt="-l"
 336   else
 337     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 338     nmh_cv_ls_grpopt="-lg"
 339   fi])
 340 fi
 341
 342 dnl Look for `more'
 343 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 344 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 345
 346 dnl If pager is not specified yet,
 347 dnl then use `more' as the default.
 348 if test -z "$pagerpath"; then
 349   pagerpath="$morepath"
 350 fi
 351 AC_SUBST(pagerpath)dnl
 352
 353 dnl Look for `sendmail'
 354 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 355 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 356
 357 dnl Look for `vi'
 358 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 359 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 360
 361 dnl If editor is not specified yet,
 362 dnl then use `vi' as the default.
 363 if test -z "$editorpath"; then
 364   editorpath="$vipath"
 365 fi
 366 AC_SUBST(editorpath)dnl
 367
 368 dnl Check for broken vi
 369 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 370 [if echo 'r /nonexist-file
 371 q' | ex > /dev/null
 372 then
 373         nmh_cv_attvibug=no
 374 else
 375         nmh_cv_attvibug=yes
 376 fi])
 377
 378 if test "$nmh_cv_attvibug" = yes; then
 379   AC_DEFINE(ATTVIBUG)dnl
 380 fi
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP)dnl
 430   SETGID_MAIL=1
 431 fi
 432 AC_SUBST(SETGID_MAIL)dnl
 433
 434 dnl Use ls to see which group owns the mail spool directory.
 435 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 436 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 437 ])
 438 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 439 AC_SUBST(MAIL_SPOOL_GRP)dnl
 440
 441 dnl ------------------
 442 dnl CHECK HEADER FILES
 443 dnl ------------------
 444 AC_HEADER_DIRENT
 445 AC_HEADER_STDC
 446 AC_HEADER_TIME
 447 AC_HEADER_SYS_WAIT
 448 AC_HEADER_STAT
 449 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 450                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 451                  langinfo.h netdb.h sys/param.h sys/time.h sys/utsname.h \
 452                  iconv.h sys/stream.h arpa/inet.h arpa/ftp.h)
 453
 454
 455 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 456 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 457 #include <unistd.h>
 458 #include <termios.h>]],
 459 [[/* SunOS 4.0.3 has termios.h but not the library calls.  */
 460 tcgetattr(0, 0);]])],
 461 nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 462
 463 if test $nmh_cv_sys_posix_termios = yes; then
 464   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 465   nmh_cv_header_termios_h_tiocgwinsz,
 466   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 467 #include <termios.h>]],
 468   [[int x = TIOCGWINSZ;]])],
 469   nmh_cv_header_termios_h_tiocgwinsz=yes,nmh_cv_header_termios_h_tiocgwinsz=no)])
 470 else
 471   nmh_cv_header_termios_h_tiocgwinsz=no
 472 fi
 473
 474 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 475   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 476   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 477   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 478 #include <sys/ioctl.h>]],
 479   [[int x = TIOCGWINSZ;]])],
 480   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 481   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 482     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)dnl
 483   fi
 484 fi
 485
 486 dnl
 487 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 488 dnl really use a whole set of them, but this check should be
 489 dnl sufficient.
 490 dnl
 491 AC_CHECK_HEADER(libio.h, [
 492   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 493     AC_DEFINE(LINUX_STDIO) ]) ])
 494
 495 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM),,
 496 [[#if HAVE_SYS_STREAM_H
 497 #  include <sys/stream.h>
 498 #endif
 499 ]])
 500
 501 dnl ---------------
 502 dnl CHECK FUNCTIONS
 503 dnl ---------------
 504 AC_FUNC_VFORK
 505 AC_CHECK_LIB(mkstemp,mkstemp)
 506 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 507                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 508                sethostent getutent nl_langinfo)
 509
 510 dnl solaris screws this up
 511 AC_CHECK_FUNC(gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)],
 512   AC_CHECK_LIB(nsl, gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)] ) )
 513
 514 dnl sigsetjmp may be a macro
 515 AC_MSG_CHECKING(for sigsetjmp)
 516 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 517   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)],
 518   [AC_MSG_RESULT(no)])
 519
 520 AC_REPLACE_FUNCS(snprintf strdup)
 521
 522 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 523 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 524 dnl any system header.
 525 dnl
 526 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 527 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 528 dnl need to check?
 529 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 530                 AC_EGREP_HEADER(initgroups, unistd.h,
 531                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 532
 533 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 534 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 535 dnl seems to work perfectly and IBM apparently uses it in internal code).
 536 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 537 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 538 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 539 dnl prototype.
 540 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE))
 541
 542 dnl -------------------
 543 dnl CHECK FOR LIBRARIES
 544 dnl -------------------
 545 dnl Check location of modf
 546 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 547
 548 dnl Checks for network libraries (nsl, socket)
 549 AC_CHECK_NETLIBS
 550
 551 termcap_curses_order="termcap curses ncurses"
 552 for lib in $termcap_curses_order; do
 553   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 554 done
 555 AC_SUBST(TERMLIB)dnl
 556
 557 dnl ---------------
 558 dnl CHECK FOR ICONV
 559 dnl ---------------
 560
 561 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 562 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 563   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 564   if test "x$ac_found_iconv" = "xno"; then
 565     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 566     if test "x$ac_found_iconv" = "xno"; then
 567       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 568     fi
 569     if test "x$ac_found_iconv" != "xno"; then
 570       LIBS="-liconv $LIBS"
 571     fi
 572   else
 573     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 574     AC_CHECK_DECL(_libiconv_version,
 575       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 576       [ #include <iconv.h> ])
 577   fi
 578 fi
 579 if test "x$ac_found_iconv" = xyes; then
 580   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 581 fi
 582
 583 dnl Check if iconv uses const in prototype declaration
 584 if test "x$ac_found_iconv" = "xyes"; then
 585   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 586     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 587         #include <iconv.h>]],
 588         [[#ifdef __cplusplus
 589           "C"
 590           #endif
 591           #if defined(__STDC__) || defined(__cplusplus)
 592           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 593           #else
 594           size_t iconv();
 595           #endif]])],
 596       [ac_cv_iconv_const=],
 597       [ac_cv_iconv_const=const])])
 598   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 599     [Define as const if the declaration of iconv() needs const.])
 600 fi
 601
 602 dnl --------------
 603 dnl CHECK FOR NDBM
 604 dnl --------------
 605
 606 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 607             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 608 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 609             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 610
 611 if test "$nmh_ndbm" = "autodetect"; then
 612   if test "$nmh_ndbmheader" != "autodetect"; then
 613     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 614   else
 615
 616     dnl There are at least four implementations of ndbm, and
 617     dnl several of those can be in different places at the whim
 618     dnl of the system integrator. A good summary of this mess
 619     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 620
 621     dnl Classic ndbm with no library required (eg NetBSD): try this
 622     dnl first so we don't accidentally link in a pointless but harmless
 623     dnl library in one of the later ndbm.h+libfoo tests:
 624     NMH_CHECK_NDBM(ndbm.h,,,
 625     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 626       NMH_CHECK_NDBM(db.h,db,,
 627     dnl Berkeley DBv1 emulating ndbm:
 628         NMH_CHECK_NDBM(ndbm.h,db,,
 629           NMH_CHECK_NDBM(ndbm.h,db1,,
 630     dnl Classic ndbm:
 631             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 632     dnl glibc2.1 systems put db1 in a subdir:
 633               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 634     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 635     dnl and possibly needing gbdm_compat library:
 636                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 637                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 638                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 639                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 640
 641   fi
 642 else
 643   dnl We don't really need to check that the user-specified values work,
 644   dnl but it is a convenience to the user to bomb out early rather than
 645   dnl after configure and half the compile process.
 646   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 647 fi
 648
 649 if test "$nmh_ndbm_found" = "no"; then
 650   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 651 else
 652   dnl Now export the lib/header to our makefile/config.h:
 653   if test x"$nmh_ndbmheader" != x; then
 654     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>)
 655   fi
 656   if test x"$nmh_ndbm" != x; then
 657     NDBM_LIBS="-l$nmh_ndbm"
 658   else
 659     NDBM_LIBS=
 660   fi
 661   AC_SUBST(NDBM_LIBS)
 662 fi
 663
 664
 665 dnl ----------------
 666 dnl CHECK FOR HESIOD
 667 dnl ----------------
 668 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 669   if test x"$with_hesiod" != x"yes"; then
 670     HESIOD_INCLUDES="-I$with_hesiod/include"
 671     HESIOD_LIBS="-L$with_hesiod/lib"
 672   fi
 673   AC_CHECK_FUNC(res_send,
 674         [AC_CHECK_LIB(hesiod, hes_resolve,
 675                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 676                 [AC_MSG_ERROR(Hesiod library not found)],
 677                 $HESIOD_LIBS)],
 678         [AC_CHECK_LIB(hesiod, hes_resolve,
 679                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 680                 [AC_MSG_ERROR(Hesiod library not found)],
 681                 $HESIOD_LIBS -lresolv)])
 682
 683 fi
 684 AC_SUBST(HESIOD_INCLUDES)dnl
 685 AC_SUBST(HESIOD_LIBS)dnl
 686
 687 dnl ----------------------------------
 688 dnl CHECK FOR KRB4 (Kerberos4 support)
 689 dnl ----------------------------------
 690 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 691   if test x"$with_krb4" != x"yes"; then
 692     KRB4_INCLUDES="-I$with_krb4/include"
 693     if test -d "$with_krb4/include/kerberosIV"; then
 694       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 695     fi
 696     KRB4_LIBS="-L$with_krb4/lib"
 697   elif test -d /usr/include/kerberosIV; then
 698     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 699   fi
 700 dnl First, check if we have -lk5crypto, since that means we have a recent krb5
 701
 702   AC_CHECK_LIB(k5crypto, krb5_encrypt,
 703         [AC_CHECK_LIB(krb4, krb_rd_req,
 704                 [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lk5crypto -lcom_err"],
 705                 [AC_MSG_ERROR(Kerberos 4 compatibility libraries not found)],
 706                 $KRB4_LIBS -ldes425 -lkrb5 -lk5crypto -lcom_err)],
 707
 708         [AC_CHECK_LIB(krb4, krb_rd_req,
 709             [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 710             [AC_CHECK_LIB(krb, krb_rd_req,
 711               [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 712               [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 713               $KRB4_LIBS -ldes)],
 714             $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)],
 715         $KRB4_LIBS)
 716
 717 fi
 718 AC_SUBST(KRB4_INCLUDES)dnl
 719 AC_SUBST(KRB4_LIBS)dnl
 720
 721 dnl --------------------
 722 dnl CHECK FOR CYRUS SASL
 723 dnl --------------------
 724 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 725   if test x"$with_cyrus_sasl" != x"yes"; then
 726     SASL_INCLUDES="-I$with_cyrus_sasl/include"
 727     SASL_LIBS="-L$with_cyrus_sasl/lib"
 728
 729     dnl Do OS-specific hardcoding of SASL shared library path into executables,
 730     dnl so user isn't forced to set environment variables like Solaris'
 731     dnl LD_LIBRARY_PATH.
 732     case "$target_os" in
 733       solaris*)
 734         SASL_LIBS="$SASL_LIBS -R$with_cyrus_sasl/lib"
 735         ;;
 736     esac
 737   fi
 738   save_LDFLAGS="$LDFLAGS"
 739   LDFLAGS="$LDFLAGS $SASL_LIBS"
 740   AC_CHECK_LIB(sasl2, sasl_client_new,
 741     [SASL_LIBS="$SASL_LIBS -lsasl2"],
 742     [AC_MSG_ERROR(Cyrus SASL library not found)])
 743   LDFLAGS="$save_LDFLAGS"
 744 fi
 745 AC_SUBST(SASL_INCLUDES)dnl
 746 AC_SUBST(SASL_LIBS)dnl
 747
 748 dnl ---------------------
 749 dnl CHECK TERMCAP LIBRARY
 750 dnl ---------------------
 751
 752 dnl Add the termcap library, so that the following configure
 753 dnl tests will find it when it tries to link test programs.
 754 nmh_save_LIBS="$LIBS"
 755 LIBS="$TERMLIB $LIBS"
 756
 757 dnl Checks for external variable ospeed in the termcap library.
 758 AC_CACHE_CHECK(if an include file defines ospeed,
 759 nmh_cv_decl_ospeed_include_defines,
 760 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 761 #if HAVE_TERMIOS_H
 762 #include <termios.h>
 763 #endif
 764 #if HAVE_TERMCAP_H
 765 #include <termcap.h>
 766 #endif]], [[ospeed = 0;]])],
 767 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 768
 769 if test $nmh_cv_decl_ospeed_include_defines = no; then
 770   AC_CACHE_CHECK(if you must define ospeed,
 771   nmh_cv_decl_ospeed_must_define,
 772   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 773   [[extern short ospeed; ospeed = 0;]])],
 774   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 775 fi
 776
 777 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 778   AC_DEFINE(HAVE_OSPEED)dnl
 779 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 780   AC_DEFINE(HAVE_OSPEED)
 781   AC_DEFINE(MUST_DEFINE_OSPEED)
 782 fi
 783
 784 dnl dnl Checks if tgetent accepts NULL and will
 785 dnl dnl allocate its own termcap buffer.
 786 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 787 dnl nmh_cv_func_tgetent_accepts_null,
 788 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 789 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 790 dnl   nmh_cv_func_tgetent_accepts_null=no,
 791 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 792 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 793 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 794 dnl fi
 795
 796 dnl Now put the libraries back to what it was before we
 797 dnl starting checking the termcap library.
 798 LIBS="$nmh_save_LIBS"
 799
 800 dnl --------------
 801 dnl CHECK TYPEDEFS
 802 dnl --------------
 803 AC_TYPE_SIGNAL
 804 AC_TYPE_PID_T
 805 AC_TYPE_OFF_T
 806 AC_TYPE_UID_T
 807 AC_TYPE_MODE_T
 808 AC_TYPE_SIZE_T
 809
 810 dnl Check for sigset_t.  Currently I'm looking in
 811 dnl <sys/types.h> and <signal.h>.  Others might need
 812 dnl to be added.
 813 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 814 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 815 #include <signal.h>]], [[sigset_t tempsigset;]])],
 816 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 817 if test $nmh_cv_type_sigset_t = no; then
 818   AC_DEFINE(sigset_t, unsigned int)
 819 fi
 820
 821 dnl ----------------
 822 dnl CHECK STRUCTURES
 823 dnl ----------------
 824 AC_CHECK_MEMBERS(struct stat.st_blksize)
 825
 826 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 827 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
 828 # include <sys/time.h>
 829 # include <time.h>
 830 #else
 831 # ifdef TM_IN_SYS_TIME
 832 #  include <sys/time.h>
 833 # else
 834 #  include <time.h>
 835 # endif
 836 #endif]], [[struct tm temptm; temptm.tm_gmtoff = 0;]])],
 837 nmh_cv_struct_tm_gmtoff=yes,nmh_cv_struct_tm_gmtoff=no)])
 838 if test $nmh_cv_struct_tm_gmtoff = yes; then
 839   AC_DEFINE(HAVE_TM_GMTOFF)
 840 fi
 841
 842 AC_CACHE_CHECK(for ut_type in struct utmp, nmh_cv_struct_utmp_ut_type,
 843 [AC_TRY_COMPILE(
 844 [#include <utmp.h>],
 845 [struct utmp temputmp; temputmp.ut_type = 0;],
 846   nmh_cv_struct_utmp_ut_type=yes, nmh_cv_struct_utmp_ut_type=no)])
 847 if test $nmh_cv_struct_utmp_ut_type = yes; then
 848   AC_DEFINE(HAVE_UTMP_UT_TYPE)
 849 fi
 850
 851 dnl -------------
 852 dnl CHECK SIGNALS
 853 dnl -------------
 854 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 855 AC_MSG_CHECKING(what style of signals to use)
 856 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 857   signals_style=POSIX_SIGNALS
 858   AC_DEFINE(POSIX_SIGNALS)
 859   AC_DEFINE(RELIABLE_SIGNALS)
 860 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 861   signals_style=BSD_SIGNALS
 862   AC_DEFINE(BSD_SIGNALS)
 863   AC_DEFINE(RELIABLE_SIGNALS)
 864 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 865   signals_style=SYSV_SIGNALS
 866   AC_DEFINE(SYSV_SIGNALS)
 867 else
 868   signals_style=NO_SIGNAL_BLOCKING
 869   AC_DEFINE(NO_SIGNAL_BLOCKING)
 870 fi
 871
 872 AC_MSG_RESULT($signals_style)
 873
 874 dnl Where is <signal.h> located?  Needed as input for signames.awk
 875 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 876 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 877                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 878                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 879                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 880                  /usr/include/sys/signal.h      dnl Almost everybody else
 881                  /dev/null;                     dnl Just in case we fall through
 882 do
 883   test -f $SIGNAL_H && \
 884   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 885   break
 886 done
 887 nmh_cv_path_signal_h=$SIGNAL_H
 888 ])
 889 SIGNAL_H=$nmh_cv_path_signal_h
 890 AC_SUBST(SIGNAL_H)dnl
 891
 892 dnl ----------------
 893 dnl OS SPECIFIC DEFINES
 894 dnl ----------------
 895 case "$target_os" in
 896
 897   solaris2*)
 898     AC_DEFINE(SYS5)
 899     AC_DEFINE(SVR4)
 900     ;;
 901   irix*)
 902     AC_DEFINE(SYS5)
 903     AC_DEFINE(SVR4)
 904     ;;
 905   osf*)
 906     AC_DEFINE(SYS5)
 907     AC_DEFINE(SVR4)
 908     ;;
 909   aix*)
 910     AC_DEFINE(SYS5)
 911     AC_DEFINE(SVR4)
 912     ;;
 913   sunos4*)
 914     AC_DEFINE(BSD42)
 915     ;;
 916   freebsd*)
 917     AC_DEFINE(BSD42)
 918     AC_DEFINE(BSD44)
 919     ;;
 920   netbsd*)
 921     AC_DEFINE(BSD42)
 922     AC_DEFINE(BSD44)
 923     ;;
 924   openbsd*)
 925     AC_DEFINE(BSD42)
 926     AC_DEFINE(BSD44)
 927     ;;
 928   bsd/os*)
 929     AC_DEFINE(BSD42)
 930     AC_DEFINE(BSD44)
 931     ;;
 932   sco5*)
 933     AC_DEFINE(SYS5)
 934     AC_DEFINE(SCO_5_STDIO)
 935     ;;
 936 esac
 937
 938
 939 dnl ----------------
 940 dnl OUTPUT MAKEFILES
 941 dnl ----------------
 942 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 943                 mts/Makefile mts/smtp/Makefile \
 944                 etc/Makefile docs/Makefile man/Makefile)
 945 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 946 AC_OUTPUT
 947
 948 dnl Umm, what's the point of these assignments??  -- <dan-nmh@dilvish.speed.net>
 949 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 950 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 951 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 952 eval "nmhman=${mandir}"
 953
 954 pop_kinds=no
 955 if test x"$enable_pop" = x"yes"; then
 956   pop_kinds="yes ("
 957
 958   if test x"$enable_apop" = x"yes"; then
 959     pop_kinds="${pop_kinds}APOP "
 960   fi
 961
 962   if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 963     pop_kinds="${pop_kinds}KPOP "
 964   fi
 965
 966   pop_kinds="${pop_kinds}POP3)"
 967 fi
 968
 969 echo "
 970 nmh configuration
 971 -----------------
 972 nmh version                : AC_PACKAGE_VERSION
 973 target os                  : ${target}
 974 compiler                   : ${CC}
 975 compiler flags             : ${CFLAGS}
 976 linker flags               : ${LDFLAGS}
 977 source code location       : ${srcdir}
 978 binary install path        : ${nmhbin2}
 979 libary install path        : ${nmhlib2}
 980 config files install path  : ${nmhsysconf2}
 981 man page install path      : ${nmhman}
 982 backup prefix              : ${backup_prefix}
 983 transport system           : ${MTS}
 984 file locking type          : ${LOCKTYPE}
 985 default smtp servers       : ${smtpservers}
 986 default editor             : ${editorpath}
 987 default pager              : ${pagerpath}
 988 email address masquerading : ${masquerade}
 989 pop is enabled             : ${pop_kinds}
 990 SASL support               : ${sasl_support}"
 991 echo ""