diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  96 if test x"$enable_debug" = x"yes"; then
  97   test -z "$LDFLAGS" && LDFLAGS=-g
  98 fi
  99
 100 dnl Use SunStudio cc, with -v, on Solaris if user didn't set CC.
 101 if test -z "$CC"  -a  -d /opt/solarisstudio12.3/bin; then
 102   CC=/opt/solarisstudio12.3/bin/cc; export CC
 103   ${CC} -V
 104   CFLAGS="${CFLAGS:+$CFLAGS }-v"
 105 fi
 106
 107 AC_PROG_CC
 108 AM_PROG_CC_C_O
 109
 110 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 111 [nmh_saved_cflags="$CFLAGS"
 112  CFLAGS="$CFLAGS -Wextra -Werror"
 113  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 114  CFLAGS="$nmh_saved_cflags"])
 115
 116 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 117 dnl version 2.763, because it disables some features in the system
 118 dnl header files and warns about them with -Wall.  Try to test for
 119 dnl that generally, though still with gcc.
 120 if test "$GCC" = yes; then
 121   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 122     [nmh_saved_cppflags="$CPPFLAGS"
 123      nmh_saved_cflags="$CFLAGS"
 124      CPPFLAGS="-D_GNU_SOURCE"
 125      CFLAGS="-ansi -Wall -Werror"
 126      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 127        [nmh_cv_has_dash_ansi=yes],
 128        [nmh_cv_has_dash_ansi=no])
 129      CPPFLAGS="$nmh_saved_cppflags"
 130      CFLAGS="$nmh_saved_cflags"])
 131
 132   dnl Disable clang complaint about unused -ansi when linking.
 133   AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 134                  [nmh_cv_has_q_unused_arguments],
 135     [nmh_saved_ldflags="$LDFLAGS"
 136      LDFLAGS="$LDFLAGS -Qunused-arguments"
 137      AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 138                  nmh_cv_has_q_unused_arguments=no)
 139      LDFLAGS="$nmh_saved_ldflags"])
 140
 141   if test "$nmh_cv_has_q_unused_arguments" = "yes"; then
 142     test -z "$LDFLAGS" && LDFLAGS=-Qunused-arguments \
 143                        || LDFLAGS="$LDFLAGS -Qunused-arguments"
 144   fi
 145 else
 146   nmh_cv_has_dash_ansi=no
 147 fi
 148
 149 dnl if the user hasn't specified CFLAGS, then
 150 dnl   if compiler is gcc, then
 151 dnl    use -O2 and some warning flags
 152 dnl   else use -O
 153 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 154 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 155 dnl warnings which are probably mostly spurious and which in any case we
 156 dnl don't want to deal with now.
 157 if test "$nmh_cv_has_dash_ansi" = "yes"; then
 158     nmh_gcc_warnflags="-ansi -pedantic -Wall"
 159 else
 160     nmh_gcc_warnflags="-Wall"
 161 fi
 162 if test "$nmh_cv_has_wextra" = "yes"; then
 163     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wextra"
 164 fi
 165
 166 if test -n "$auto_cflags"; then
 167   if test x"$enable_debug" = x"yes"; then
 168     if test -n "$GCC"; then
 169       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 170     else
 171       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 172     fi
 173   else
 174     if test -z "$LDFLAGS"; then
 175       case "$build_os" in
 176         darwin*)
 177           LDFLAGS=
 178           ;;
 179         *)
 180           LDFLAGS=-s
 181           ;;
 182       esac
 183     fi
 184     if test -n "$GCC"; then
 185       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 186     else
 187       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 188     fi
 189     AC_DEFINE([NDEBUG], [1],
 190               [Define to disable run-time debugging and asserts.])
 191   fi
 192 fi
 193
 194 dnl ------------------
 195 dnl CHECK FOR PROGRAMS
 196 dnl ------------------
 197 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 198 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 199 AC_PROG_RANLIB          dnl Check for `ranlib'
 200 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 201 AC_PROG_SED             dnl Check for Posix-compliant sed
 202 AM_PROG_LEX             dnl Check for lex/flex
 203
 204 AM_PROG_AR
 205
 206 dnl Look for `cut'
 207 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 208 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 209
 210 dnl
 211 dnl Check for MD5 program and formatting command
 212 dnl
 213 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 214 AS_CASE(["${MD5SUM}"],
 215         [md5sum], [MD5FMT="cat"],
 216         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 217         [MD5FMT="missing"])
 218 AC_SUBST([MD5FMT])
 219
 220 dnl ----------------------------------------------
 221 dnl check for lclint, and lint if it doesn't exist
 222 dnl ----------------------------------------------
 223 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 224 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 225   [LINT=$ac_cv_prog_linttmp1
 226   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 227   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 228   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 229     [LINT=$ac_cv_prog_linttmp2
 230     LINTFLAGS=""],
 231     [LINT="echo 'No lint program found'"
 232     LINTFLAGS=""])])
 233 AC_SUBST([LINT])dnl
 234 AC_SUBST([LINTFLAGS])dnl
 235
 236 dnl Look for `ls'
 237 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 238 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 239
 240 dnl See how we get ls to display the owner and the group
 241 AS_IF([test "$lspath" != "no"],
 242   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 243                  [nmh_cv_ls_grpopt],
 244   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 245     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 246     dnl ls, it would seem -l gave us both the user and group.  On this type of
 247     dnl ls, -g makes _only_ the group be displayed (and not the user).
 248     nmh_cv_ls_grpopt="-l"],[
 249     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 250     nmh_cv_ls_grpopt="-lg"])])])
 251
 252 dnl Look for `sendmail'
 253 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 254 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 255
 256 dnl Cygwin FAT filesystems do not support hard links.  So default to
 257 dnl cp instead, even if running on an NTFS or other filesystem.
 258 AS_CASE(["$host_os"],
 259   [cygwin*], [LN=cp],
 260   [LN=ln])
 261 AC_SUBST([LN])
 262
 263 dnl ----------------------------------------------------------
 264 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 265 dnl ----------------------------------------------------------
 266 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 267 [for mailspool in /var/mail        dnl
 268                   /var/spool/mail  dnl
 269                   /usr/spool/mail  dnl
 270                   /dev/null;       dnl Just in case we fall through
 271 do
 272   test -d $mailspool && break
 273 done
 274 nmh_cv_mailspool=$mailspool
 275 ])
 276 mailspool=$nmh_cv_mailspool
 277 AC_SUBST([mailspool])dnl
 278
 279 dnl See whether the mail spool directory is world-writable.
 280 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 281   AC_CACHE_CHECK(whether the mail spool is world-writable,
 282                  nmh_cv_mailspool_world_writable,
 283   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 284     nmh_cv_mailspool_world_writable=no
 285   else
 286     nmh_cv_mailspool_world_writable=yes
 287   fi])
 288 fi
 289
 290 dnl Also, check for liblockfile (as found on Debian systems)
 291 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 292
 293 dnl and whether its companion program dotlockfile is setgid
 294 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 295 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 296   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 297     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 298     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 299         nmh_cv_dotlockfile_setgid=yes
 300       else
 301         nmh_cv_dotlockfile_setgid=no
 302       fi])
 303   fi
 304 fi
 305
 306 dnl Provide a way for distcheck to disable setgid_mail via
 307 dnl DISTCHECK_CONFIGURE_FLAGS.
 308 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 309   [nmh_cv_dotlockfile_setgid=yes])
 310
 311 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 312 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 313 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 314   dnl do we really need both of these?
 315   AC_DEFINE(MAILGROUP,1,
 316     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 317   SETGID_MAIL=1
 318 fi
 319 AC_SUBST([SETGID_MAIL])dnl
 320
 321 dnl Use ls to see which group owns the mail spool directory.
 322 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 323 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 324 ])
 325 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 326 AC_SUBST(MAIL_SPOOL_GRP)dnl
 327
 328 dnl ------------------
 329 dnl CHECK HEADER FILES
 330 dnl ------------------
 331
 332 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 333 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 334 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 335 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 336 dnl declared; if so they should have an entry added to this case statement.
 337 dnl NB that we must define this on the compiler command line, not in config.h,
 338 dnl because it must be set before any system header is included and there's no
 339 dnl portable way to make sure that files generated by lex include config.h
 340 dnl before system header files.
 341
 342 AS_CASE(["$host_os"],
 343         [linux*],
 344         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 345           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 346                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 347
 348 AC_HEADER_TIOCGWINSZ
 349 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 350                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 351
 352 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 353   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 354 [[#if HAVE_SYS_STREAM_H
 355 #  include <sys/stream.h>
 356 #endif
 357 ]])
 358
 359 dnl ---------------
 360 dnl CHECK FUNCTIONS
 361 dnl ---------------
 362 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 363
 364 dnl Check for multibyte character set support
 365 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 366             "x$ac_cv_header_wctype_h" = "xyes" -a \
 367             "x$ac_cv_func_wcwidth" = "xyes" -a \
 368             "x$ac_cv_func_mbtowc" = "xyes"],
 369       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 370                  [Define to enable support for multibyte character sets.])
 371        MULTIBYTE_ENABLED=1],
 372       [MULTIBYTE_ENABLED=0])
 373 AC_SUBST([MULTIBYTE_ENABLED])
 374
 375 dnl -------------------
 376 dnl CHECK FOR LIBRARIES
 377 dnl -------------------
 378 dnl Check location of modf
 379 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 380
 381 dnl Checks for network libraries (nsl, socket)
 382 NMH_CHECK_NETLIBS
 383
 384 dnl Check for readline support
 385 NMH_READLINE
 386
 387 dnl Check the locking functions supported and what we should use by default
 388 NMH_LOCKING
 389
 390 dnl Check for iconv
 391 NMH_CHECK_ICONV
 392
 393 termcap_curses_order="termcap curses ncurses"
 394 for lib in $termcap_curses_order; do
 395   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 396 done
 397 AC_SUBST([TERMLIB])dnl
 398 AS_IF([test "x$TERMLIB" = "x"],
 399       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 400 or ncurses library or package that you can install?])])
 401
 402 dnl --------------
 403 dnl CHECK FOR NDBM
 404 dnl --------------
 405
 406 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 407             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 408 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 409             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 410
 411 if test "$nmh_ndbm" = "autodetect"; then
 412   if test "$nmh_ndbmheader" != "autodetect"; then
 413     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 414   else
 415
 416     dnl There are at least four implementations of ndbm, and
 417     dnl several of those can be in different places at the whim
 418     dnl of the system integrator. A good summary of this mess
 419     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 420
 421     dnl Classic ndbm with no library required (eg NetBSD): try this
 422     dnl first so we don't accidentally link in a pointless but harmless
 423     dnl library in one of the later ndbm.h+libfoo tests:
 424     NMH_CHECK_NDBM(ndbm.h,,,
 425     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 426       NMH_CHECK_NDBM(db.h,db,,
 427     dnl Berkeley DBv1 emulating ndbm:
 428         NMH_CHECK_NDBM(ndbm.h,db,,
 429           NMH_CHECK_NDBM(ndbm.h,db1,,
 430     dnl Classic ndbm:
 431             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 432     dnl glibc2.1 systems put db1 in a subdir:
 433               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 434     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 435     dnl and possibly needing gbdm_compat library:
 436                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 437                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 438                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 439                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 440
 441   fi
 442 else
 443   dnl We don't really need to check that the user-specified values work,
 444   dnl but it is a convenience to the user to bomb out early rather than
 445   dnl after configure and half the compile process.
 446   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 447 fi
 448
 449 if test "$nmh_ndbm_found" = "no"; then
 450   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 451 else
 452   dnl Now export the lib/header to our makefile/config.h:
 453   if test x"$nmh_ndbmheader" != x; then
 454     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 455       [Define to the header containing the ndbm API prototypes.])
 456   fi
 457   if test x"$nmh_ndbm" != x; then
 458     NDBM_LIBS="-l$nmh_ndbm"
 459   else
 460     NDBM_LIBS=
 461   fi
 462   AC_SUBST([NDBM_LIBS])
 463 fi
 464
 465 dnl ------------------
 466 dnl Set RPM build root
 467 dnl ------------------
 468 dnl nmhrpm is used in the final summary, see below.  The default value is
 469 dnl reported there as ./RPM, consistent with the reporting of the default
 470 dnl source code location as ., but its absolute path is used in the Makefile.
 471 AC_ARG_WITH([rpmdir],
 472   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 473   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 474           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 475 AC_SUBST([rpmdir])
 476
 477
 478 dnl --------------------
 479 dnl CHECK FOR CYRUS-SASL
 480 dnl --------------------
 481
 482 AS_IF([test x"$sasl_support" = x"yes"],[
 483   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 484   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 485     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 486 AC_SUBST([SASLLIB])
 487
 488 dnl -----------------
 489 dnl CHECK FOR OPENSSL
 490 dnl -----------------
 491
 492 AS_IF([test x"$tls_support" = x"yes"],[
 493   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 494   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 495     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 496   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 497     [AC_MSG_ERROR([OpenSSL library not found])])],
 498   [TLSLIB=])
 499 AC_SUBST([TLSLIB])
 500
 501 dnl ---------------------
 502 dnl CHECK TERMCAP LIBRARY
 503 dnl ---------------------
 504
 505 dnl Add the termcap library, so that the following configure
 506 dnl tests will find it when it tries to link test programs.
 507 nmh_save_LIBS="$LIBS"
 508 LIBS="$TERMLIB $LIBS"
 509
 510 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 511 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 512 dnl in tgetstr().
 513 dnl Under Cygwin test program crashes but exit code is still 0. So,
 514 dnl we test for a file that porgram should create
 515 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 516 [Define to 1 if tgetent() accepts NULL as a buffer.])
 517 AC_CACHE_CHECK(if tgetent accepts NULL,
 518 nmh_cv_func_tgetent_accepts_null,
 519 [AC_TRY_RUN([
 520 main()
 521 {
 522     char buf[4096];
 523     int r1 = tgetent(buf, "vt100");
 524     int r2 = tgetent((char*)0,"vt100");
 525     if (r1 >= 0 && r1 == r2) {
 526         char tbuf[1024], *u;
 527         u = tbuf;
 528         tgetstr("cl", &u);
 529         creat("conftest.tgetent", 0640);
 530     }
 531     exit((r1 != r2) || r2 == -1);
 532 }
 533 ],
 534   if test -f conftest.tgetent; then
 535     nmh_cv_func_tgetent_accepts_null=yes
 536   else
 537     nmh_cv_func_tgetent_accepts_null=no
 538   fi,
 539   nmh_cv_func_tgetent_accepts_null=no,
 540   nmh_cv_func_tgetent_accepts_null=no)])
 541 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 542   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 543 fi
 544 AC_CACHE_CHECK(if tgetent returns 0 on success,
 545 nmh_cv_func_tgetent_zero_success,
 546 [AC_TRY_RUN([
 547 main()
 548 {
 549     char buf[4096];
 550     int r1 = tgetent(buf, "!@#$%^&*");
 551     int r2 = tgetent(buf, "vt100");
 552     if (r1 < 0 && r2 == 0) {
 553         char tbuf[1024], *u;
 554         u = tbuf;
 555         tgetstr("cl", &u);
 556         creat("conftest.tgetent0", 0640);
 557     }
 558     exit(r1 == r2);
 559 }
 560 ],
 561   if test -f conftest.tgetent0; then
 562     nmh_cv_func_tgetent_zero_success=yes
 563   else
 564     nmh_cv_func_tgetent_zero_success=no
 565   fi,
 566   nmh_cv_func_tgetent_zero_success=no,
 567   nmh_cv_func_tgetent_zero_success=no)])
 568 AH_TEMPLATE([TGETENT_SUCCESS],
 569 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 570 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 571   AC_DEFINE(TGETENT_SUCCESS, 0)
 572 else
 573   AC_DEFINE(TGETENT_SUCCESS, 1)
 574 fi
 575
 576 dnl Now put the libraries back to what it was before we
 577 dnl starting checking the termcap library.
 578 LIBS="$nmh_save_LIBS"
 579
 580 dnl ----------------
 581 dnl CHECK FLEX FIXUP
 582 dnl ----------------
 583 dnl Use LFLAGS make variable setting to work around bugs in flex
 584 dnl 2.5.35-37 that cause signed/unsigned mismatch,
 585 dnl http://sourceforge.net/p/flex/bugs/140/
 586 AS_IF([test "$LEX" = flex],
 587       [AS_CASE([`$LEX -V`],
 588                [flex\ 2.5.35], [[LFLAGS=\
 589 '; printf "%s\n" '\''1,$$s/(size_t) \(num_to_read\)/\1/'\'' w q | ed -s $@']],
 590                [flex\ 2.5.3@<:@67@:>@], [[LFLAGS=\
 591 '; printf "%s\n" '\''1,$$s/\(   \)int i;/\1yy_size_t i;/'\'' w q | ed -s $@']])
 592        AC_SUBST([LFLAGS])])
 593
 594 dnl --------------
 595 dnl CHECK TYPEDEFS
 596 dnl --------------
 597 AC_TYPE_PID_T
 598 AC_TYPE_OFF_T
 599 AC_TYPE_UID_T
 600 AC_TYPE_MODE_T
 601 AC_TYPE_SIZE_T
 602
 603 dnl ----------------
 604 dnl CHECK STRUCTURES
 605 dnl ----------------
 606
 607 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 608 dnl (FreeBSD has a timezone() function but not a timezone global
 609 dnl variable that is visible).
 610 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 611
 612 AC_STRUCT_DIRENT_D_TYPE
 613
 614 dnl Where is <signal.h> located?  Needed as input for signames.awk
 615 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 616 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 617                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 618                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 619                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 620                  /usr/include/sys/signal.h      dnl Almost everybody else
 621                  /dev/null;                     dnl Just in case we fall through
 622 do
 623   test -f $SIGNAL_H && \
 624   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 625   break
 626 done
 627 nmh_cv_path_signal_h=$SIGNAL_H
 628 ])
 629 SIGNAL_H=$nmh_cv_path_signal_h
 630 AC_SUBST(SIGNAL_H)dnl
 631
 632 dnl
 633 dnl Sigh, this is required because under the new world order autoconf has
 634 dnl nothing to create in a few of the build directories when doing an object
 635 dnl tree build.  So make sure we created certain directories if they don't
 636 dnl exist.
 637 dnl
 638
 639 AC_CONFIG_COMMANDS([build-directories],
 640 [test -d etc || AS_MKDIR_P([etc])
 641 test -d man || AS_MKDIR_P([man])])
 642
 643 AC_CONFIG_COMMANDS_POST([
 644
 645 dnl These odd looking assignments are done to expand out unexpanded
 646 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 647 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 648 dnl again to get the final answer.
 649 dnl We only use the expanded versions to print the install paths in
 650 dnl the final summary and should use them nowhere else (see the autoconf
 651 dnl docs for the rationale for bindir etc being unexpanded).
 652 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 653 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 654 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 655 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 656 eval "nmhrpm=${nmhrpm}";
 657
 658 AC_MSG_NOTICE([
 659 nmh configuration
 660 -----------------
 661 nmh version                : AC_PACKAGE_VERSION
 662 host os                    : ${host}
 663 compiler                   : ${CC}
 664 compiler flags             : ${CFLAGS}
 665 linker flags               : ${LDFLAGS}
 666 preprocessor flags         : ${CPPFLAGS}
 667 source code location       : ${srcdir}
 668 binary install path        : ${nmhbin}
 669 library install path       : ${nmhlib}
 670 config files install path  : ${nmhsysconf}
 671 man page install path      : ${nmhman}
 672 RPM build root             : ${nmhrpm}
 673 backup prefix              : ${backup_prefix}
 674 transport system           : ${MTS}
 675 spool default locking type : ${with_locking}
 676 default smtp servers       : ${smtpservers}
 677 SASL support               : ${sasl_support}
 678 TLS support                : ${tls_support}
 679 ])])dnl
 680
 681 dnl ---------------
 682 dnl OUTPUT MAKEFILE
 683 dnl ---------------
 684 AC_CONFIG_FILES([Makefile test/common.sh])
 685 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 686 AC_OUTPUT