diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  44 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  45   [Enable OAuth2 support in SMTP auth]))
  46
  47 dnl Do you want client-side support for encryption with TLS?
  48 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  49 AS_IF([test x"$with_tls" != x"no"],[
  50       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  51       tls_support=yes],[tls_support=no])
  52
  53 dnl Set the backup prefix
  54 AC_ARG_WITH([hash-backup],
  55   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  56 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  57       [backup_prefix="#"], [backup_prefix=","])
  58 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  59     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  60
  61 dnl What method of posting should post use?
  62 AC_ARG_WITH([mts],
  63   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  64   [specify the default mail transport agent/service]))
  65
  66 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  67       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  68       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  69       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  70       [MTS="smtp"])
  71 AC_SUBST([MTS])dnl
  72
  73 dnl What should be the default mail server(s)?
  74 AC_ARG_WITH([smtpservers],
  75   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  76   [specify the default SMTP server(s) @<:@localhost@:>@])])
  77 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  78       [smtpservers="localhost"])
  79 AC_SUBST([smtpservers])dnl
  80
  81 dnl -------------------------------------------------------------------
  82 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  83 dnl find an existing installation, in which case we use its location.
  84 dnl -------------------------------------------------------------------
  85 AC_PREFIX_DEFAULT([/usr/local/nmh])
  86 AC_PREFIX_PROGRAM([mhparam])
  87
  88 dnl ------------------
  89 dnl CHECK THE COMPILER
  90 dnl ------------------
  91
  92 AC_PROG_CC([cc gcc])
  93 AM_PROG_CC_C_O
  94
  95 dnl ----------------
  96 dnl CUSTOMIZE CFLAGS
  97 dnl ----------------
  98 dnl The user didn't specify CFLAGS, so customize them.
  99 if test "$GCC" != yes; then
 100   dnl Use -v and some other options with SunStudio cc.  lex produces
 101   dnl code that causes unreachable-statement warnings.  It might be
 102   dnl better to use an autoconf test, except -v will probably succeed
 103   dnl with many other compilers but have different meaning.
 104   AS_CASE([`${CC} -V 2>&1`],
 105           [cc:\ Sun\ C*], [CFLAGS=\
 106 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 107 fi
 108
 109 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 110                [nmh_saved_cflags="$CFLAGS"
 111                CFLAGS="$CFLAGS -Wall -Werror"
 112                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 113                CFLAGS="$nmh_saved_cflags"])
 114 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 115
 116 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 117                [nmh_saved_cflags="$CFLAGS"
 118                CFLAGS="$CFLAGS -Wextra -Werror"
 119                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 120                               nmh_cv_has_wextra=no)
 121                CFLAGS="$nmh_saved_cflags"])
 122 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 123
 124 if test "$GCC" = yes; then
 125   dnl Do this regardless of auto_cflags value.
 126   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 127   dnl gcc 4.1 and later, but only when optimization is enabled.
 128   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 129   dnl If the user configures with a CFLAGS that contains a -O flag
 130   dnl but then removes it a make time, they'll also have to remove
 131   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 132   AS_CASE([$CFLAGS],
 133           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 134 fi
 135
 136 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 137 dnl We do this here rather than in (say) h/mh.h because this macro must
 138 dnl be defined before <stdio.h> is pulled in.
 139 dnl
 140 dnl And while we're here, add the packages tree to the cpp and ld search
 141 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 142 dnl If /usr/ports is installed, we use its idea of where things are installed,
 143 dnl otherwise we assume /usr/local.
 144
 145 AS_IF([test `uname` = FreeBSD],
 146         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 147          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 148                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 149          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 150          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 151          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 152 ])
 153
 154 dnl --------------
 155 dnl CUSTOMIZE LINK
 156 dnl --------------
 157 AS_IF([test `uname` = OpenBSD],
 158       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 159       dnl so that they don't color the waterfall.
 160       [POSTLINK="2>&1 | sed -e \
 161 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 162 AC_SUBST([POSTLINK])
 163
 164 dnl -----------------
 165 dnl CUSTOMIZE LDFLAGS
 166 dnl -----------------
 167 dnl Disable clang complaint about unused -ansi when linking.
 168 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 169                [nmh_cv_has_q_unused_arguments],
 170                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 171                        grep clang >/dev/null`],
 172                       [nmh_saved_ldflags="$LDFLAGS"
 173                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 174                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 175                                          nmh_cv_has_q_unused_arguments=no)
 176                        LDFLAGS="$nmh_saved_ldflags"],
 177                        [nmh_cv_has_q_unused_arguments=no])])
 178 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 179   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 180
 181 dnl This hack turns off assertions by default, assuming
 182 dnl that configure still uses this shell variable.  Without
 183 dnl it, AC_HEADER_ASSERT enables assertions by default.
 184 test -z "$enable_assert"  &&  enable_assert=no
 185
 186 AC_HEADER_ASSERT
 187
 188 dnl ------------------
 189 dnl CHECK FOR PROGRAMS
 190 dnl ------------------
 191 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 192 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 193 AC_PROG_RANLIB          dnl Check for `ranlib'
 194 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 195 AC_PROG_SED             dnl Check for Posix-compliant sed
 196 AC_PROG_YACC            dnl Check for yacc/bison
 197 AM_PROG_LEX             dnl Check for lex/flex
 198
 199 AM_PROG_AR
 200
 201 dnl Look for `cut'
 202 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 203 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 204
 205 dnl
 206 dnl Check for MD5 program and formatting command
 207 dnl
 208 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 209 AS_CASE(["${MD5SUM}"],
 210         [md5sum], [MD5FMT="cat"],
 211         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 212         [MD5FMT="missing"])
 213 AC_SUBST([MD5FMT])
 214
 215 dnl Look for `ls'
 216 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 217 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 218
 219 dnl See how we get ls to display the owner and the group
 220 AS_IF([test "$lspath" != "no"],
 221   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 222                  [nmh_cv_ls_grpopt],
 223   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 224     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 225     dnl ls, it would seem -l gave us both the user and group.  On this type of
 226     dnl ls, -g makes _only_ the group be displayed (and not the user).
 227     nmh_cv_ls_grpopt="-l"],[
 228     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 229     nmh_cv_ls_grpopt="-lg"])])])
 230
 231 dnl Look for `sendmail'
 232 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 233 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 234
 235 dnl Cygwin FAT filesystems do not support hard links.  So default to
 236 dnl cp instead, even if running on an NTFS or other filesystem.
 237 AS_CASE(["$host_os"],
 238   [cygwin*], [LN=cp],
 239   [LN=ln])
 240 AC_SUBST([LN])
 241
 242 dnl ----------------------------------------------------------
 243 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 244 dnl ----------------------------------------------------------
 245 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 246 [for mailspool in /var/mail        dnl
 247                   /var/spool/mail  dnl
 248                   /usr/spool/mail  dnl
 249                   /dev/null;       dnl Just in case we fall through
 250 do
 251   test -d $mailspool && break
 252 done
 253 nmh_cv_mailspool=$mailspool
 254 ])
 255 mailspool=$nmh_cv_mailspool
 256 AC_SUBST([mailspool])dnl
 257
 258 dnl See whether the mail spool directory is world-writable.
 259 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 260   AC_CACHE_CHECK(whether the mail spool is world-writable,
 261                  nmh_cv_mailspool_world_writable,
 262   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 263     nmh_cv_mailspool_world_writable=no
 264   else
 265     nmh_cv_mailspool_world_writable=yes
 266   fi])
 267 fi
 268
 269 dnl Also, check for liblockfile (as found on Debian systems)
 270 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 271
 272 dnl and whether its companion program dotlockfile is setgid
 273 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 274 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 275   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 276     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 277     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 278         nmh_cv_dotlockfile_setgid=yes
 279       else
 280         nmh_cv_dotlockfile_setgid=no
 281       fi])
 282   fi
 283 fi
 284
 285 dnl Provide a way for distcheck to disable setgid_mail via
 286 dnl DISTCHECK_CONFIGURE_FLAGS.
 287 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 288   [nmh_cv_dotlockfile_setgid=yes])
 289
 290 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 291 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 292 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 293   dnl do we really need both of these?
 294   AC_DEFINE([MAILGROUP],[1],
 295     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 296   SETGID_MAIL=1
 297 fi
 298 AC_SUBST([SETGID_MAIL])dnl
 299
 300 dnl Use ls to see which group owns the mail spool directory.
 301 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 302 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 303 ])
 304 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 305 AC_SUBST([MAIL_SPOOL_GRP])dnl
 306
 307 NMH_MIMETYPEPROC
 308 NMH_MIMEENCODINGPROC
 309
 310 dnl ------------------
 311 dnl CHECK HEADER FILES
 312 dnl ------------------
 313
 314 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 315 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 316 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 317 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 318 dnl declared; if so they should have an entry added to this case statement.
 319 dnl NB that we must define this on the compiler command line, not in config.h,
 320 dnl because it must be set before any system header is included and there's no
 321 dnl portable way to make sure that files generated by lex include config.h
 322 dnl before system header files.
 323
 324 AS_CASE(["$host_os"],
 325         [linux*],
 326         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 327         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 328
 329 AC_HEADER_TIOCGWINSZ
 330 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 331
 332 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 333   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 334 [[#if HAVE_SYS_STREAM_H
 335 #  include <sys/stream.h>
 336 #endif
 337 ]])
 338
 339 dnl ---------------
 340 dnl CHECK FUNCTIONS
 341 dnl ---------------
 342 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 343
 344 dnl Check for multibyte character set support
 345 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 346             "x$ac_cv_header_wctype_h" = "xyes" -a \
 347             "x$ac_cv_func_wcwidth" = "xyes" -a \
 348             "x$ac_cv_func_mbtowc" = "xyes"],
 349       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 350                  [Define to enable support for multibyte character sets.])
 351        MULTIBYTE_ENABLED=1],
 352       [MULTIBYTE_ENABLED=0])
 353 AC_SUBST([MULTIBYTE_ENABLED])
 354
 355 dnl -------------------
 356 dnl CHECK FOR LIBRARIES
 357 dnl -------------------
 358 dnl Checks for network libraries (nsl, socket)
 359 NMH_CHECK_NETLIBS
 360
 361 dnl Check the locking functions supported and what we should use by default
 362 NMH_LOCKING
 363
 364 dnl Check for iconv
 365 NMH_CHECK_ICONV
 366
 367 dnl Check for tputs() callback argument
 368 NMH_TPUTS_PUTC_ARG
 369
 370 termcap_curses_order="termcap curses ncurses"
 371 for lib in $termcap_curses_order; do
 372   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 373 done
 374 AC_SUBST([TERMLIB])dnl
 375 AS_IF([test "x$TERMLIB" = "x"],
 376       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 377 curses or ncurses library or package that you can install?])])
 378
 379 dnl Check for readline support
 380 NMH_READLINE
 381
 382 dnl --------------
 383 dnl CHECK FOR NDBM
 384 dnl --------------
 385
 386 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 387             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 388 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 389             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 390
 391 if test "$nmh_ndbm" = "autodetect"; then
 392   if test "$nmh_ndbmheader" != "autodetect"; then
 393     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 394   else
 395
 396     dnl There are at least four implementations of ndbm, and
 397     dnl several of those can be in different places at the whim
 398     dnl of the system integrator. A good summary of this mess
 399     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 400
 401     dnl Classic ndbm with no library required (eg NetBSD): try this
 402     dnl first so we don't accidentally link in a pointless but harmless
 403     dnl library in one of the later ndbm.h+libfoo tests:
 404     NMH_CHECK_NDBM(ndbm.h,,,
 405     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 406       NMH_CHECK_NDBM(db.h,db,,
 407     dnl Berkeley DBv1 emulating ndbm:
 408         NMH_CHECK_NDBM(ndbm.h,db,,
 409           NMH_CHECK_NDBM(ndbm.h,db1,,
 410     dnl Classic ndbm:
 411             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 412     dnl glibc2.1 systems put db1 in a subdir:
 413               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 414     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 415     dnl and possibly needing gbdm_compat library:
 416                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 417                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 418                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 419     dnl 64-bit Cygwin:
 420                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 421     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 422     dnl need to be explicit:
 423                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 424   fi
 425 else
 426   dnl We don't really need to check that the user-specified values work,
 427   dnl but it is a convenience to the user to bomb out early rather than
 428   dnl after configure and half the compile process.
 429   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 430 fi
 431
 432 if test "$nmh_ndbm_found" = "no"; then
 433   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 434 else
 435   dnl Now export the lib/header to our makefile/config.h:
 436   if test x"$nmh_ndbmheader" != x; then
 437     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 438       [Define to the header containing the ndbm API prototypes.])
 439   fi
 440   if test x"$nmh_ndbm" != x; then
 441     NDBM_LIBS="-l$nmh_ndbm"
 442   else
 443     NDBM_LIBS=
 444   fi
 445   AC_SUBST([NDBM_LIBS])
 446 fi
 447
 448 dnl ------------------
 449 dnl Set RPM build root
 450 dnl ------------------
 451 dnl nmhrpm is used in the final summary, see below.  The default value is
 452 dnl reported there as ./RPM, consistent with the reporting of the default
 453 dnl source code location as ., but its absolute path is used in the Makefile.
 454 AC_ARG_WITH([rpmdir],
 455   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 456   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 457           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 458 AC_SUBST([rpmdir])
 459
 460
 461 dnl --------------------
 462 dnl CHECK FOR CYRUS-SASL
 463 dnl --------------------
 464
 465 AS_IF([test x"$sasl_support" = x"yes"],[
 466   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 467   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 468     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 469 AC_SUBST([SASLLIB])
 470
 471 dnl -----------------
 472 dnl CHECK FOR OPENSSL
 473 dnl -----------------
 474
 475 AS_IF([test x"$tls_support" = x"yes"],[
 476   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 477   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 478   dnl automatically append -lcrypto when linking with -lssl.
 479   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 480   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 481     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 482   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 483     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 484   [TLSLIB=])
 485 AC_SUBST([TLSLIB])
 486
 487 dnl -----------------
 488 dnl CHECK FOR CURL
 489 dnl -----------------
 490 dnl Look for curl if oauth not disabled (--without-oauth).
 491 AC_PATH_PROG([curl_config], [curl-config])
 492 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 493     save_CFLAGS="$CFLAGS"
 494     CFLAGS="$CFLAGS `$curl_config --cflags`"
 495     AC_CHECK_HEADER([curl/curl.h], [
 496         HAVE_CURL_H=1
 497         AC_CHECK_LIB([curl], [curl_easy_init], [
 498             CURLLIB="`$curl_config --libs`"
 499             AC_SUBST([CURLLIB])
 500             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 501             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 502                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 503                    CURL_USER_AGENT=libcurl/UNKNOWN])
 504                    echo "HEYEPG ($CURL_USER_AGENT)"
 505             AC_SUBST([CURL_USER_AGENT])
 506           ])
 507       ], [
 508         CFLAGS="$save_CFLAGS"
 509       ])
 510   ])
 511
 512 dnl -----------------
 513 dnl Enable OAuth?
 514 dnl -----------------
 515 dnl By default (with_oauth=''), enable OAuth if curl is found.
 516 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 517 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 518 oauth_support=no
 519 OAUTH_SUPPORT=0
 520 AC_SUBST([OAUTH_SUPPORT])
 521 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 522       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 523       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 524       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 525       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 526       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 527        OAUTH_SUPPORT=1
 528        oauth_support=yes])
 529
 530 dnl ----------------
 531 dnl CHECK FLEX FIXUP
 532 dnl ----------------
 533 dnl Use LFLAGS make variable setting to work around bugs in flex
 534 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 535 dnl http://sourceforge.net/p/flex/bugs/140/
 536 AS_IF([test "$LEX" = flex],
 537       [AS_CASE([`$LEX -V`],
 538                [flex\ 2.5.35], [LFLAGS=\
 539 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 540                [flex\ 2.5.3[[67]]], [LFLAGS=\
 541 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 542        AC_SUBST([LFLAGS])])
 543
 544 dnl ------------------
 545 dnl FOR INTERNAL USE by the NMH test suite
 546 dnl ------------------
 547 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 548 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 549       AC_SUBST([nmhetcdirinst]))
 550
 551 dnl ----------------
 552 dnl CHECK STRUCTURES
 553 dnl ----------------
 554
 555 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 556 dnl (FreeBSD has a timezone() function but not a timezone global
 557 dnl variable that is visible).
 558 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 559
 560 AC_STRUCT_DIRENT_D_TYPE
 561
 562 dnl
 563 dnl Sigh, this is required because under the new world order autoconf has
 564 dnl nothing to create in a few of the build directories when doing an object
 565 dnl tree build.  So make sure we created certain directories if they don't
 566 dnl exist.
 567 dnl
 568
 569 AC_CONFIG_COMMANDS([build-directories],
 570 [test -d man || AS_MKDIR_P([man])])
 571
 572 AC_CONFIG_COMMANDS_POST([
 573
 574 dnl These odd looking assignments are done to expand out unexpanded
 575 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 576 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 577 dnl again to get the final answer.
 578 dnl We only use the expanded versions to print the install paths in
 579 dnl the final summary and should use them nowhere else (see the autoconf
 580 dnl docs for the rationale for bindir etc being unexpanded).
 581 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 582 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 583 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 584 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 585 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 586 eval "nmhrpm=${nmhrpm}";
 587
 588 AC_MSG_NOTICE([
 589 nmh configuration
 590 -----------------
 591 nmh version                : AC_PACKAGE_VERSION
 592 host os                    : ${host}
 593 compiler                   : ${CC}
 594 compiler flags             : ${CFLAGS}
 595 linker flags               : ${LDFLAGS}
 596 preprocessor flags         : ${CPPFLAGS}
 597 source code location       : ${srcdir}
 598 binary install path        : ${nmhbin}
 599 libexec install path       : ${nmhlibexec}/nmh
 600 config files install path  : ${nmhsysconf}/nmh
 601 man page install path      : ${nmhman}
 602 docs install path          : ${nmhdoc}
 603 RPM build root             : ${nmhrpm}
 604 backup prefix              : ${backup_prefix}
 605 transport system           : ${MTS}
 606 spool default locking type : ${with_locking}
 607 default smtp servers       : ${smtpservers}
 608 SASL support               : ${sasl_support}
 609 TLS support                : ${tls_support}
 610 OAuth support              : ${oauth_support}
 611 ])])dnl
 612
 613 dnl ---------------
 614 dnl OUTPUT MAKEFILE
 615 dnl ---------------
 616 AC_CONFIG_FILES([Makefile test/common.sh])
 617 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 618 AC_OUTPUT