diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122
 123     dnl For Ubuntu gcc 4.8.1, with -O2.  It would be better to fix all these,
 124     dnl but until then, suppress the warning.
 125     AC_CACHE_CHECK([whether compiler needs -Wno-unused-result],
 126                    [nmh_cv_needs_wnur],
 127                    [nmh_saved_cflags="$CFLAGS"
 128                     CFLAGS="$CFLAGS -Werror -O2"
 129                     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
 130                                         [extern const char *path;
 131                                          chdir (path);
 132                                          return 0;])],
 133                                        [nmh_cv_needs_wnur=no],
 134                                        [nmh_cv_needs_wnur=yes])
 135                     CFLAGS="$nmh_saved_cflags"])
 136     AS_IF([test "$nmh_cv_needs_wnur" = yes],
 137           [CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"])
 138   else
 139     dnl Use -v and some other options with SunStudio cc.  lex produces
 140     dnl code that causes unreachable-statement warnings.  It might be
 141     dnl better to use an autoconf test, except -v will probably succeed
 142     dnl with many other compilers but have different meaning.
 143     AS_CASE([`${CC} -V 2>&1`],
 144             [cc:\ Sun\ C*], [CFLAGS=\
 145 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 146   fi
 147
 148   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 149                  [nmh_saved_cflags="$CFLAGS"
 150                  CFLAGS="$CFLAGS -Wall -Werror"
 151                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 152                  CFLAGS="$nmh_saved_cflags"])
 153   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 154
 155   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 156                  [nmh_saved_cflags="$CFLAGS"
 157                  CFLAGS="$CFLAGS -Wextra -Werror"
 158                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 159                                 nmh_cv_has_wextra=no)
 160                  CFLAGS="$nmh_saved_cflags"])
 161   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 162 fi
 163
 164 dnl --------------
 165 dnl CUSTOMIZE LINK
 166 dnl --------------
 167 AS_IF([test `uname` = OpenBSD],
 168       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 169       dnl so that they don't color the waterfall.
 170       [POSTLINK="2>&1 | sed -e \
 171 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 172 AC_SUBST([POSTLINK])
 173
 174 dnl -----------------
 175 dnl CUSTOMIZE LDFLAGS
 176 dnl -----------------
 177 dnl Disable clang complaint about unused -ansi when linking.
 178 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 179                [nmh_cv_has_q_unused_arguments],
 180                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 181                        grep clang >/dev/null`],
 182                       [nmh_saved_ldflags="$LDFLAGS"
 183                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 184                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 185                                          nmh_cv_has_q_unused_arguments=no)
 186                        LDFLAGS="$nmh_saved_ldflags"],
 187                        [nmh_cv_has_q_unused_arguments=no])])
 188 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 189   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 190
 191 dnl This hack turns off assertions by default, assuming
 192 dnl that configure still uses this shell variable.  Without
 193 dnl it, AC_HEADER_ASSERT enables assertions by default.
 194 test -z "$enable_assert"  &&  enable_assert=no
 195
 196 AC_HEADER_ASSERT
 197
 198 dnl ------------------
 199 dnl CHECK FOR PROGRAMS
 200 dnl ------------------
 201 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 202 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 203 AC_PROG_RANLIB          dnl Check for `ranlib'
 204 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 205 AC_PROG_SED             dnl Check for Posix-compliant sed
 206 AM_PROG_LEX             dnl Check for lex/flex
 207
 208 AM_PROG_AR
 209
 210 dnl Look for `cut'
 211 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 212 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 213
 214 dnl
 215 dnl Check for MD5 program and formatting command
 216 dnl
 217 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 218 AS_CASE(["${MD5SUM}"],
 219         [md5sum], [MD5FMT="cat"],
 220         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 221         [MD5FMT="missing"])
 222 AC_SUBST([MD5FMT])
 223
 224 dnl Look for `ls'
 225 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 226 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 227
 228 dnl See how we get ls to display the owner and the group
 229 AS_IF([test "$lspath" != "no"],
 230   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 231                  [nmh_cv_ls_grpopt],
 232   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 233     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 234     dnl ls, it would seem -l gave us both the user and group.  On this type of
 235     dnl ls, -g makes _only_ the group be displayed (and not the user).
 236     nmh_cv_ls_grpopt="-l"],[
 237     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 238     nmh_cv_ls_grpopt="-lg"])])])
 239
 240 dnl Look for `sendmail'
 241 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 242 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 243
 244 dnl Cygwin FAT filesystems do not support hard links.  So default to
 245 dnl cp instead, even if running on an NTFS or other filesystem.
 246 AS_CASE(["$host_os"],
 247   [cygwin*], [LN=cp],
 248   [LN=ln])
 249 AC_SUBST([LN])
 250
 251 dnl ----------------------------------------------------------
 252 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 253 dnl ----------------------------------------------------------
 254 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 255 [for mailspool in /var/mail        dnl
 256                   /var/spool/mail  dnl
 257                   /usr/spool/mail  dnl
 258                   /dev/null;       dnl Just in case we fall through
 259 do
 260   test -d $mailspool && break
 261 done
 262 nmh_cv_mailspool=$mailspool
 263 ])
 264 mailspool=$nmh_cv_mailspool
 265 AC_SUBST([mailspool])dnl
 266
 267 dnl See whether the mail spool directory is world-writable.
 268 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 269   AC_CACHE_CHECK(whether the mail spool is world-writable,
 270                  nmh_cv_mailspool_world_writable,
 271   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 272     nmh_cv_mailspool_world_writable=no
 273   else
 274     nmh_cv_mailspool_world_writable=yes
 275   fi])
 276 fi
 277
 278 dnl Also, check for liblockfile (as found on Debian systems)
 279 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 280
 281 dnl and whether its companion program dotlockfile is setgid
 282 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 283 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 284   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 285     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 286     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 287         nmh_cv_dotlockfile_setgid=yes
 288       else
 289         nmh_cv_dotlockfile_setgid=no
 290       fi])
 291   fi
 292 fi
 293
 294 dnl Provide a way for distcheck to disable setgid_mail via
 295 dnl DISTCHECK_CONFIGURE_FLAGS.
 296 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 297   [nmh_cv_dotlockfile_setgid=yes])
 298
 299 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 300 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 301 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 302   dnl do we really need both of these?
 303   AC_DEFINE([MAILGROUP],[1],
 304     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 305   SETGID_MAIL=1
 306 fi
 307 AC_SUBST([SETGID_MAIL])dnl
 308
 309 dnl Use ls to see which group owns the mail spool directory.
 310 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 311 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 312 ])
 313 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 314 AC_SUBST([MAIL_SPOOL_GRP])dnl
 315
 316 NMH_MIMETYPEPROC
 317 NMH_MIMEENCODINGPROC
 318
 319 dnl ------------------
 320 dnl CHECK HEADER FILES
 321 dnl ------------------
 322
 323 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 324 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 325 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 326 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 327 dnl declared; if so they should have an entry added to this case statement.
 328 dnl NB that we must define this on the compiler command line, not in config.h,
 329 dnl because it must be set before any system header is included and there's no
 330 dnl portable way to make sure that files generated by lex include config.h
 331 dnl before system header files.
 332
 333 AS_CASE(["$host_os"],
 334         [linux*],
 335         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 336           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 337                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 338
 339 AC_HEADER_TIOCGWINSZ
 340 AC_CHECK_HEADERS([fcntl.h langinfo.h wchar.h wctype.h sys/param.h \
 341                   sys/time.h sys/stream.h])
 342
 343 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 344   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 345 [[#if HAVE_SYS_STREAM_H
 346 #  include <sys/stream.h>
 347 #endif
 348 ]])
 349
 350 dnl ---------------
 351 dnl CHECK FUNCTIONS
 352 dnl ---------------
 353 AC_CHECK_FUNCS([wcwidth mbtowc nl_langinfo getutxent arc4random])
 354
 355 dnl Check for multibyte character set support
 356 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 357             "x$ac_cv_header_wctype_h" = "xyes" -a \
 358             "x$ac_cv_func_wcwidth" = "xyes" -a \
 359             "x$ac_cv_func_mbtowc" = "xyes"],
 360       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 361                  [Define to enable support for multibyte character sets.])
 362        MULTIBYTE_ENABLED=1],
 363       [MULTIBYTE_ENABLED=0])
 364 AC_SUBST([MULTIBYTE_ENABLED])
 365
 366 dnl -------------------
 367 dnl CHECK FOR LIBRARIES
 368 dnl -------------------
 369 dnl Checks for network libraries (nsl, socket)
 370 NMH_CHECK_NETLIBS
 371
 372 dnl Check the locking functions supported and what we should use by default
 373 NMH_LOCKING
 374
 375 dnl Check for iconv
 376 NMH_CHECK_ICONV
 377
 378 dnl Check for tputs() callback argument
 379 NMH_TPUTS_PUTC_ARG
 380
 381 termcap_curses_order="termcap curses ncurses"
 382 for lib in $termcap_curses_order; do
 383   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 384 done
 385 AC_SUBST([TERMLIB])dnl
 386 AS_IF([test "x$TERMLIB" = "x"],
 387       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 388 curses or ncurses library or package that you can install?])])
 389
 390 dnl Check for readline support
 391 NMH_READLINE
 392
 393 dnl --------------
 394 dnl CHECK FOR NDBM
 395 dnl --------------
 396
 397 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 398             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 399 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 400             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 401
 402 if test "$nmh_ndbm" = "autodetect"; then
 403   if test "$nmh_ndbmheader" != "autodetect"; then
 404     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 405   else
 406
 407     dnl There are at least four implementations of ndbm, and
 408     dnl several of those can be in different places at the whim
 409     dnl of the system integrator. A good summary of this mess
 410     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 411
 412     dnl Classic ndbm with no library required (eg NetBSD): try this
 413     dnl first so we don't accidentally link in a pointless but harmless
 414     dnl library in one of the later ndbm.h+libfoo tests:
 415     NMH_CHECK_NDBM(ndbm.h,,,
 416     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 417       NMH_CHECK_NDBM(db.h,db,,
 418     dnl Berkeley DBv1 emulating ndbm:
 419         NMH_CHECK_NDBM(ndbm.h,db,,
 420           NMH_CHECK_NDBM(ndbm.h,db1,,
 421     dnl Classic ndbm:
 422             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 423     dnl glibc2.1 systems put db1 in a subdir:
 424               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 425     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 426     dnl and possibly needing gbdm_compat library:
 427                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 428                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 429                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 430                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 431
 432   fi
 433 else
 434   dnl We don't really need to check that the user-specified values work,
 435   dnl but it is a convenience to the user to bomb out early rather than
 436   dnl after configure and half the compile process.
 437   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 438 fi
 439
 440 if test "$nmh_ndbm_found" = "no"; then
 441   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 442 else
 443   dnl Now export the lib/header to our makefile/config.h:
 444   if test x"$nmh_ndbmheader" != x; then
 445     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 446       [Define to the header containing the ndbm API prototypes.])
 447   fi
 448   if test x"$nmh_ndbm" != x; then
 449     NDBM_LIBS="-l$nmh_ndbm"
 450   else
 451     NDBM_LIBS=
 452   fi
 453   AC_SUBST([NDBM_LIBS])
 454 fi
 455
 456 dnl ------------------
 457 dnl Set RPM build root
 458 dnl ------------------
 459 dnl nmhrpm is used in the final summary, see below.  The default value is
 460 dnl reported there as ./RPM, consistent with the reporting of the default
 461 dnl source code location as ., but its absolute path is used in the Makefile.
 462 AC_ARG_WITH([rpmdir],
 463   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 464   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 465           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 466 AC_SUBST([rpmdir])
 467
 468
 469 dnl --------------------
 470 dnl CHECK FOR CYRUS-SASL
 471 dnl --------------------
 472
 473 AS_IF([test x"$sasl_support" = x"yes"],[
 474   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 475   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 476     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 477 AC_SUBST([SASLLIB])
 478
 479 dnl -----------------
 480 dnl CHECK FOR OPENSSL
 481 dnl -----------------
 482
 483 AS_IF([test x"$tls_support" = x"yes"],[
 484   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 485   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 486   dnl automatically append -lcrypto when linking with -lssl.
 487   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 488   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 489     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 490   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 491     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 492   [TLSLIB=])
 493 AC_SUBST([TLSLIB])
 494
 495 dnl ----------------
 496 dnl CHECK FLEX FIXUP
 497 dnl ----------------
 498 dnl Use LFLAGS make variable setting to work around bugs in flex
 499 dnl 2.5.36 that cause signed/unsigned mismatch,
 500 dnl http://sourceforge.net/p/flex/bugs/140/
 501 AS_IF([test "$LEX" = flex],
 502       [AS_CASE([`$LEX -V`],
 503                [flex\ 2.5.35], [LFLAGS=\
 504 '; sed -e "s/   int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@; true'],
 505                [flex\ 2.5.36], [LFLAGS=\
 506 '; sed -s "s/\( \)int i;/\1yy_size_t i;/" $@ >$.tmp && mv -f $@.tmp $@; true'])
 507        AC_SUBST([LFLAGS])])
 508
 509 dnl ----------------
 510 dnl CHECK STRUCTURES
 511 dnl ----------------
 512
 513 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 514 dnl (FreeBSD has a timezone() function but not a timezone global
 515 dnl variable that is visible).
 516 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 517
 518 AC_STRUCT_DIRENT_D_TYPE
 519
 520 dnl Where is <signal.h> located?  Needed as input for signames.awk
 521 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 522 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 523                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 524                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 525                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 526                  /usr/include/sys/signal.h      dnl Almost everybody else
 527                  /dev/null;                     dnl Just in case we fall through
 528 do
 529   test -f $SIGNAL_H && \
 530   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 531   break
 532 done
 533 nmh_cv_path_signal_h=$SIGNAL_H
 534 ])
 535 SIGNAL_H=$nmh_cv_path_signal_h
 536 AC_SUBST(SIGNAL_H)dnl
 537
 538 dnl
 539 dnl Sigh, this is required because under the new world order autoconf has
 540 dnl nothing to create in a few of the build directories when doing an object
 541 dnl tree build.  So make sure we created certain directories if they don't
 542 dnl exist.
 543 dnl
 544
 545 AC_CONFIG_COMMANDS([build-directories],
 546 [test -d man || AS_MKDIR_P([man])])
 547
 548 AC_CONFIG_COMMANDS_POST([
 549
 550 dnl These odd looking assignments are done to expand out unexpanded
 551 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 552 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 553 dnl again to get the final answer.
 554 dnl We only use the expanded versions to print the install paths in
 555 dnl the final summary and should use them nowhere else (see the autoconf
 556 dnl docs for the rationale for bindir etc being unexpanded).
 557 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 558 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 559 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 560 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 561 eval "nmhrpm=${nmhrpm}";
 562
 563 AC_MSG_NOTICE([
 564 nmh configuration
 565 -----------------
 566 nmh version                : AC_PACKAGE_VERSION
 567 host os                    : ${host}
 568 compiler                   : ${CC}
 569 compiler flags             : ${CFLAGS}
 570 linker flags               : ${LDFLAGS}
 571 preprocessor flags         : ${CPPFLAGS}
 572 source code location       : ${srcdir}
 573 binary install path        : ${nmhbin}
 574 library install path       : ${nmhlib}
 575 config files install path  : ${nmhsysconf}
 576 man page install path      : ${nmhman}
 577 RPM build root             : ${nmhrpm}
 578 backup prefix              : ${backup_prefix}
 579 transport system           : ${MTS}
 580 spool default locking type : ${with_locking}
 581 default smtp servers       : ${smtpservers}
 582 SASL support               : ${sasl_support}
 583 TLS support                : ${tls_support}
 584 ])])dnl
 585
 586 dnl ---------------
 587 dnl OUTPUT MAKEFILE
 588 dnl ---------------
 589 AC_CONFIG_FILES([Makefile test/common.sh])
 590 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 591 AC_OUTPUT