diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl ----------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  79 dnl ----------------------------------------------------
  80 AC_PREFIX_DEFAULT([/usr/local/nmh])
  81
  82 dnl ------------------
  83 dnl CHECK THE COMPILER
  84 dnl ------------------
  85 dnl We want these before the checks,
  86 dnl so the checks can modify their values.
  87 test -z "$CFLAGS"  &&  auto_cflags=1
  88
  89 AC_PROG_CC([cc gcc])
  90 AM_PROG_CC_C_O
  91
  92 dnl ----------------
  93 dnl CUSTOMIZE CFLAGS
  94 dnl ----------------
  95 if test -n "$auto_cflags"; then
  96   dnl The user didn't specify CFLAGS, so customize them.
  97   if test "$GCC" = yes; then
  98     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
  99     dnl version 2.763, because it disables some features in the system
 100     dnl header files and warns about them with -Wall.  Try to test for
 101     dnl that generally, with gcc.
 102     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 103       [nmh_saved_cppflags="$CPPFLAGS"
 104        nmh_saved_cflags="$CFLAGS"
 105        CPPFLAGS="-D_GNU_SOURCE"
 106        CFLAGS="-ansi -Wall -Werror"
 107        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 108          [nmh_cv_has_dash_ansi=yes],
 109          [nmh_cv_has_dash_ansi=no])
 110        CPPFLAGS="$nmh_saved_cppflags"
 111        CFLAGS="$nmh_saved_cflags"])
 112     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 113       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 114
 115     dnl For Ubuntu gcc 4.8.1, with -O2.  It would be better to fix all these,
 116     dnl but until then, suppress the warning.
 117     AC_CACHE_CHECK([whether compiler needs -Wno-unused-result],
 118                    [nmh_cv_needs_wnur],
 119                    [nmh_saved_cflags="$CFLAGS"
 120                     CFLAGS="$CFLAGS -Werror -O2"
 121                     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
 122                                         [extern const char *path;
 123                                          chdir (path);
 124                                          return 0;])],
 125                                        [nmh_cv_needs_wnur=no],
 126                                        [nmh_cv_needs_wnur=yes])
 127                     CFLAGS="$nmh_saved_cflags"])
 128     AS_IF([test "$nmh_cv_needs_wnur" = yes],
 129           [CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"])
 130   else
 131     dnl Use -v and some other options with SunStudio cc.  lex produces
 132     dnl code that causes unreachable-statement warnings.  It might be
 133     dnl better to use an autoconf test, except -v will probably succeed
 134     dnl with many other compilers but have different meaning.
 135     AS_CASE([`${CC} -V 2>&1`],
 136             [cc:\ Sun\ C*], [CFLAGS=\
 137 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 138   fi
 139
 140   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 141                  [nmh_saved_cflags="$CFLAGS"
 142                  CFLAGS="$CFLAGS -Wall -Werror"
 143                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 146
 147   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 148                  [nmh_saved_cflags="$CFLAGS"
 149                  CFLAGS="$CFLAGS -Wextra -Werror"
 150                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 151                                 nmh_cv_has_wextra=no)
 152                  CFLAGS="$nmh_saved_cflags"])
 153   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 154 fi
 155
 156 dnl --------------
 157 dnl CUSTOMIZE LINK
 158 dnl --------------
 159 AS_IF([test `uname` = OpenBSD],
 160       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 161       dnl so that they don't color the waterfall.
 162       [POSTLINK="2>&1 | sed -e \
 163 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 164 AC_SUBST([POSTLINK])
 165
 166 dnl -----------------
 167 dnl CUSTOMIZE LDFLAGS
 168 dnl -----------------
 169 dnl Disable clang complaint about unused -ansi when linking.
 170 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 171                [nmh_cv_has_q_unused_arguments],
 172                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 173                        grep clang >/dev/null`],
 174                       [nmh_saved_ldflags="$LDFLAGS"
 175                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 176                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 177                                          nmh_cv_has_q_unused_arguments=no)
 178                        LDFLAGS="$nmh_saved_ldflags"],
 179                        [nmh_cv_has_q_unused_arguments=no])])
 180 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 181   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 182
 183 dnl This hack turns off assertions by default, assuming
 184 dnl that configure still uses this shell variable.  Without
 185 dnl it, AC_HEADER_ASSERT enables assertions by default.
 186 test -z "$enable_assert"  &&  enable_assert=no
 187
 188 AC_HEADER_ASSERT
 189
 190 dnl ------------------
 191 dnl CHECK FOR PROGRAMS
 192 dnl ------------------
 193 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 194 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 195 AC_PROG_RANLIB          dnl Check for `ranlib'
 196 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 197 AC_PROG_SED             dnl Check for Posix-compliant sed
 198 AM_PROG_LEX             dnl Check for lex/flex
 199
 200 AM_PROG_AR
 201
 202 dnl Look for `cut'
 203 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 204 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 205
 206 dnl
 207 dnl Check for MD5 program and formatting command
 208 dnl
 209 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 210 AS_CASE(["${MD5SUM}"],
 211         [md5sum], [MD5FMT="cat"],
 212         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 213         [MD5FMT="missing"])
 214 AC_SUBST([MD5FMT])
 215
 216 dnl Look for `ls'
 217 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 218 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 219
 220 dnl See how we get ls to display the owner and the group
 221 AS_IF([test "$lspath" != "no"],
 222   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 223                  [nmh_cv_ls_grpopt],
 224   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 225     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 226     dnl ls, it would seem -l gave us both the user and group.  On this type of
 227     dnl ls, -g makes _only_ the group be displayed (and not the user).
 228     nmh_cv_ls_grpopt="-l"],[
 229     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 230     nmh_cv_ls_grpopt="-lg"])])])
 231
 232 dnl Look for `sendmail'
 233 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 234 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 235
 236 dnl Cygwin FAT filesystems do not support hard links.  So default to
 237 dnl cp instead, even if running on an NTFS or other filesystem.
 238 AS_CASE(["$host_os"],
 239   [cygwin*], [LN=cp],
 240   [LN=ln])
 241 AC_SUBST([LN])
 242
 243 dnl ----------------------------------------------------------
 244 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 245 dnl ----------------------------------------------------------
 246 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 247 [for mailspool in /var/mail        dnl
 248                   /var/spool/mail  dnl
 249                   /usr/spool/mail  dnl
 250                   /dev/null;       dnl Just in case we fall through
 251 do
 252   test -d $mailspool && break
 253 done
 254 nmh_cv_mailspool=$mailspool
 255 ])
 256 mailspool=$nmh_cv_mailspool
 257 AC_SUBST([mailspool])dnl
 258
 259 dnl See whether the mail spool directory is world-writable.
 260 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 261   AC_CACHE_CHECK(whether the mail spool is world-writable,
 262                  nmh_cv_mailspool_world_writable,
 263   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 264     nmh_cv_mailspool_world_writable=no
 265   else
 266     nmh_cv_mailspool_world_writable=yes
 267   fi])
 268 fi
 269
 270 dnl Also, check for liblockfile (as found on Debian systems)
 271 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 272
 273 dnl and whether its companion program dotlockfile is setgid
 274 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 275 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 276   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 277     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 278     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 279         nmh_cv_dotlockfile_setgid=yes
 280       else
 281         nmh_cv_dotlockfile_setgid=no
 282       fi])
 283   fi
 284 fi
 285
 286 dnl Provide a way for distcheck to disable setgid_mail via
 287 dnl DISTCHECK_CONFIGURE_FLAGS.
 288 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 289   [nmh_cv_dotlockfile_setgid=yes])
 290
 291 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 292 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 293 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 294   dnl do we really need both of these?
 295   AC_DEFINE([MAILGROUP],[1],
 296     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 297   SETGID_MAIL=1
 298 fi
 299 AC_SUBST([SETGID_MAIL])dnl
 300
 301 dnl Use ls to see which group owns the mail spool directory.
 302 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 303 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 304 ])
 305 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 306 AC_SUBST([MAIL_SPOOL_GRP])dnl
 307
 308 NMH_MIMETYPEPROC
 309 NMH_MIMEENCODINGPROC
 310
 311 dnl ------------------
 312 dnl CHECK HEADER FILES
 313 dnl ------------------
 314
 315 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 316 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 317 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 318 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 319 dnl declared; if so they should have an entry added to this case statement.
 320 dnl NB that we must define this on the compiler command line, not in config.h,
 321 dnl because it must be set before any system header is included and there's no
 322 dnl portable way to make sure that files generated by lex include config.h
 323 dnl before system header files.
 324
 325 AS_CASE(["$host_os"],
 326         [linux*],
 327         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 328           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 329                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 330
 331 AC_HEADER_TIOCGWINSZ
 332 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 333
 334 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 335   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 336 [[#if HAVE_SYS_STREAM_H
 337 #  include <sys/stream.h>
 338 #endif
 339 ]])
 340
 341 dnl ---------------
 342 dnl CHECK FUNCTIONS
 343 dnl ---------------
 344 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 345
 346 dnl Check for multibyte character set support
 347 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 348             "x$ac_cv_header_wctype_h" = "xyes" -a \
 349             "x$ac_cv_func_wcwidth" = "xyes" -a \
 350             "x$ac_cv_func_mbtowc" = "xyes"],
 351       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 352                  [Define to enable support for multibyte character sets.])
 353        MULTIBYTE_ENABLED=1],
 354       [MULTIBYTE_ENABLED=0])
 355 AC_SUBST([MULTIBYTE_ENABLED])
 356
 357 dnl -------------------
 358 dnl CHECK FOR LIBRARIES
 359 dnl -------------------
 360 dnl Checks for network libraries (nsl, socket)
 361 NMH_CHECK_NETLIBS
 362
 363 dnl Check the locking functions supported and what we should use by default
 364 NMH_LOCKING
 365
 366 dnl Check for iconv
 367 NMH_CHECK_ICONV
 368
 369 dnl Check for tputs() callback argument
 370 NMH_TPUTS_PUTC_ARG
 371
 372 termcap_curses_order="termcap curses ncurses"
 373 for lib in $termcap_curses_order; do
 374   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 375 done
 376 AC_SUBST([TERMLIB])dnl
 377 AS_IF([test "x$TERMLIB" = "x"],
 378       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 379 curses or ncurses library or package that you can install?])])
 380
 381 dnl Check for readline support
 382 NMH_READLINE
 383
 384 dnl --------------
 385 dnl CHECK FOR NDBM
 386 dnl --------------
 387
 388 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 389             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 390 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 391             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 392
 393 if test "$nmh_ndbm" = "autodetect"; then
 394   if test "$nmh_ndbmheader" != "autodetect"; then
 395     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 396   else
 397
 398     dnl There are at least four implementations of ndbm, and
 399     dnl several of those can be in different places at the whim
 400     dnl of the system integrator. A good summary of this mess
 401     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 402
 403     dnl Classic ndbm with no library required (eg NetBSD): try this
 404     dnl first so we don't accidentally link in a pointless but harmless
 405     dnl library in one of the later ndbm.h+libfoo tests:
 406     NMH_CHECK_NDBM(ndbm.h,,,
 407     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 408       NMH_CHECK_NDBM(db.h,db,,
 409     dnl Berkeley DBv1 emulating ndbm:
 410         NMH_CHECK_NDBM(ndbm.h,db,,
 411           NMH_CHECK_NDBM(ndbm.h,db1,,
 412     dnl Classic ndbm:
 413             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 414     dnl glibc2.1 systems put db1 in a subdir:
 415               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 416     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 417     dnl and possibly needing gbdm_compat library:
 418                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 419                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 420                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 421     dnl 64-bit Cygwin:
 422                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 423     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 424     dnl need to be explicit:
 425                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 426   fi
 427 else
 428   dnl We don't really need to check that the user-specified values work,
 429   dnl but it is a convenience to the user to bomb out early rather than
 430   dnl after configure and half the compile process.
 431   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 432 fi
 433
 434 if test "$nmh_ndbm_found" = "no"; then
 435   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 436 else
 437   dnl Now export the lib/header to our makefile/config.h:
 438   if test x"$nmh_ndbmheader" != x; then
 439     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 440       [Define to the header containing the ndbm API prototypes.])
 441   fi
 442   if test x"$nmh_ndbm" != x; then
 443     NDBM_LIBS="-l$nmh_ndbm"
 444   else
 445     NDBM_LIBS=
 446   fi
 447   AC_SUBST([NDBM_LIBS])
 448 fi
 449
 450 dnl ------------------
 451 dnl Set RPM build root
 452 dnl ------------------
 453 dnl nmhrpm is used in the final summary, see below.  The default value is
 454 dnl reported there as ./RPM, consistent with the reporting of the default
 455 dnl source code location as ., but its absolute path is used in the Makefile.
 456 AC_ARG_WITH([rpmdir],
 457   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 458   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 459           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 460 AC_SUBST([rpmdir])
 461
 462
 463 dnl --------------------
 464 dnl CHECK FOR CYRUS-SASL
 465 dnl --------------------
 466
 467 AS_IF([test x"$sasl_support" = x"yes"],[
 468   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 469   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 470     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 471 AC_SUBST([SASLLIB])
 472
 473 dnl -----------------
 474 dnl CHECK FOR OPENSSL
 475 dnl -----------------
 476
 477 AS_IF([test x"$tls_support" = x"yes"],[
 478   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 479   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 480   dnl automatically append -lcrypto when linking with -lssl.
 481   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 482   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 483     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 484   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 485     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 486   [TLSLIB=])
 487 AC_SUBST([TLSLIB])
 488
 489 dnl ----------------
 490 dnl CHECK FLEX FIXUP
 491 dnl ----------------
 492 dnl Use LFLAGS make variable setting to work around bugs in flex
 493 dnl 2.5.36 that cause signed/unsigned mismatch,
 494 dnl http://sourceforge.net/p/flex/bugs/140/
 495 AS_IF([test "$LEX" = flex],
 496       [AS_CASE([`$LEX -V`],
 497                [flex\ 2.5.35], [LFLAGS=\
 498 '; sed -e "s/   int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@; true'],
 499                [flex\ 2.5.36], [LFLAGS=\
 500 '; sed -s "s/\( \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@; true'])
 501        AC_SUBST([LFLAGS])])
 502
 503 dnl ----------------
 504 dnl CHECK STRUCTURES
 505 dnl ----------------
 506
 507 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 508 dnl (FreeBSD has a timezone() function but not a timezone global
 509 dnl variable that is visible).
 510 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 511
 512 AC_STRUCT_DIRENT_D_TYPE
 513
 514 dnl Where is <signal.h> located?  Needed as input for signames.awk
 515 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 516 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 517                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 518                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 519                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 520                  /usr/include/sys/signal.h      dnl Almost everybody else
 521                  /dev/null;                     dnl Just in case we fall through
 522 do
 523   test -f $SIGNAL_H && \
 524   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 525   break
 526 done
 527 nmh_cv_path_signal_h=$SIGNAL_H
 528 ])
 529 SIGNAL_H=$nmh_cv_path_signal_h
 530 AC_SUBST(SIGNAL_H)dnl
 531
 532 dnl
 533 dnl Sigh, this is required because under the new world order autoconf has
 534 dnl nothing to create in a few of the build directories when doing an object
 535 dnl tree build.  So make sure we created certain directories if they don't
 536 dnl exist.
 537 dnl
 538
 539 AC_CONFIG_COMMANDS([build-directories],
 540 [test -d man || AS_MKDIR_P([man])])
 541
 542 AC_CONFIG_COMMANDS_POST([
 543
 544 dnl These odd looking assignments are done to expand out unexpanded
 545 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 546 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 547 dnl again to get the final answer.
 548 dnl We only use the expanded versions to print the install paths in
 549 dnl the final summary and should use them nowhere else (see the autoconf
 550 dnl docs for the rationale for bindir etc being unexpanded).
 551 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 552 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 553 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 554 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 555 eval "nmhrpm=${nmhrpm}";
 556
 557 AC_MSG_NOTICE([
 558 nmh configuration
 559 -----------------
 560 nmh version                : AC_PACKAGE_VERSION
 561 host os                    : ${host}
 562 compiler                   : ${CC}
 563 compiler flags             : ${CFLAGS}
 564 linker flags               : ${LDFLAGS}
 565 preprocessor flags         : ${CPPFLAGS}
 566 source code location       : ${srcdir}
 567 binary install path        : ${nmhbin}
 568 library install path       : ${nmhlib}
 569 config files install path  : ${nmhsysconf}
 570 man page install path      : ${nmhman}
 571 RPM build root             : ${nmhrpm}
 572 backup prefix              : ${backup_prefix}
 573 transport system           : ${MTS}
 574 spool default locking type : ${with_locking}
 575 default smtp servers       : ${smtpservers}
 576 SASL support               : ${sasl_support}
 577 TLS support                : ${tls_support}
 578 ])])dnl
 579
 580 dnl ---------------
 581 dnl OUTPUT MAKEFILE
 582 dnl ---------------
 583 AC_CONFIG_FILES([Makefile test/common.sh])
 584 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 585 AC_OUTPUT