diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl ----------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  79 dnl ----------------------------------------------------
  80 AC_PREFIX_DEFAULT([/usr/local/nmh])
  81
  82 dnl ------------------
  83 dnl CHECK THE COMPILER
  84 dnl ------------------
  85 dnl We want these before the checks,
  86 dnl so the checks can modify their values.
  87 test -z "$CFLAGS"  &&  auto_cflags=1
  88
  89 AC_PROG_CC([cc gcc])
  90 AM_PROG_CC_C_O
  91
  92 dnl ----------------
  93 dnl CUSTOMIZE CFLAGS
  94 dnl ----------------
  95 if test -n "$auto_cflags"; then
  96   dnl The user didn't specify CFLAGS, so customize them.
  97   if test "$GCC" = yes; then
  98     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
  99     dnl version 2.763, because it disables some features in the system
 100     dnl header files and warns about them with -Wall.  Try to test for
 101     dnl that generally, with gcc.
 102     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 103       [nmh_saved_cppflags="$CPPFLAGS"
 104        nmh_saved_cflags="$CFLAGS"
 105        CPPFLAGS="-D_GNU_SOURCE"
 106        CFLAGS="-ansi -Wall -Werror"
 107        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 108          [nmh_cv_has_dash_ansi=yes],
 109          [nmh_cv_has_dash_ansi=no])
 110        CPPFLAGS="$nmh_saved_cppflags"
 111        CFLAGS="$nmh_saved_cflags"])
 112     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 113       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 114
 115     dnl For Ubuntu gcc 4.8.1, with -O2.  It would be better to fix all these,
 116     dnl but until then, suppress the warning.
 117     AC_CACHE_CHECK([whether compiler needs -Wno-unused-result],
 118                    [nmh_cv_needs_wnur],
 119                    [nmh_saved_cflags="$CFLAGS"
 120                     CFLAGS="$CFLAGS -Werror -O2"
 121                     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
 122                                         [extern const char *path;
 123                                          chdir (path);
 124                                          return 0;])],
 125                                        [nmh_cv_needs_wnur=no],
 126                                        [nmh_cv_needs_wnur=yes])
 127                     CFLAGS="$nmh_saved_cflags"])
 128     AS_IF([test "$nmh_cv_needs_wnur" = yes],
 129           [CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"])
 130   else
 131     dnl Use -v and some other options with SunStudio cc.  lex produces
 132     dnl code that causes unreachable-statement warnings.  It might be
 133     dnl better to use an autoconf test, except -v will probably succeed
 134     dnl with many other compilers but have different meaning.
 135     AS_CASE([`${CC} -V 2>&1`],
 136             [cc:\ Sun\ C*], [CFLAGS=\
 137 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 138   fi
 139
 140   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 141                  [nmh_saved_cflags="$CFLAGS"
 142                  CFLAGS="$CFLAGS -Wall -Werror"
 143                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 146
 147   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 148                  [nmh_saved_cflags="$CFLAGS"
 149                  CFLAGS="$CFLAGS -Wextra -Werror"
 150                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 151                                 nmh_cv_has_wextra=no)
 152                  CFLAGS="$nmh_saved_cflags"])
 153   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 154 fi
 155
 156 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 157 dnl We do this here rather than in (say) h/mh.h because this macro must
 158 dnl be defined before <stdio.h> is pulled in.
 159 AS_IF([test `uname` = FreeBSD],
 160         [CPPFLAGS="$CPPFLAGS -D_WITH_GETLINE"])
 161
 162 dnl --------------
 163 dnl CUSTOMIZE LINK
 164 dnl --------------
 165 AS_IF([test `uname` = OpenBSD],
 166       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 167       dnl so that they don't color the waterfall.
 168       [POSTLINK="2>&1 | sed -e \
 169 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 170 AC_SUBST([POSTLINK])
 171
 172 dnl -----------------
 173 dnl CUSTOMIZE LDFLAGS
 174 dnl -----------------
 175 dnl Disable clang complaint about unused -ansi when linking.
 176 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 177                [nmh_cv_has_q_unused_arguments],
 178                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 179                        grep clang >/dev/null`],
 180                       [nmh_saved_ldflags="$LDFLAGS"
 181                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 182                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 183                                          nmh_cv_has_q_unused_arguments=no)
 184                        LDFLAGS="$nmh_saved_ldflags"],
 185                        [nmh_cv_has_q_unused_arguments=no])])
 186 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 187   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 188
 189 dnl This hack turns off assertions by default, assuming
 190 dnl that configure still uses this shell variable.  Without
 191 dnl it, AC_HEADER_ASSERT enables assertions by default.
 192 test -z "$enable_assert"  &&  enable_assert=no
 193
 194 AC_HEADER_ASSERT
 195
 196 dnl ------------------
 197 dnl CHECK FOR PROGRAMS
 198 dnl ------------------
 199 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 200 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 201 AC_PROG_RANLIB          dnl Check for `ranlib'
 202 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 203 AC_PROG_SED             dnl Check for Posix-compliant sed
 204 AM_PROG_LEX             dnl Check for lex/flex
 205
 206 AM_PROG_AR
 207
 208 dnl Look for `cut'
 209 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 210 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 211
 212 dnl
 213 dnl Check for MD5 program and formatting command
 214 dnl
 215 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 216 AS_CASE(["${MD5SUM}"],
 217         [md5sum], [MD5FMT="cat"],
 218         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 219         [MD5FMT="missing"])
 220 AC_SUBST([MD5FMT])
 221
 222 dnl Look for `ls'
 223 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 224 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 225
 226 dnl See how we get ls to display the owner and the group
 227 AS_IF([test "$lspath" != "no"],
 228   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 229                  [nmh_cv_ls_grpopt],
 230   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 231     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 232     dnl ls, it would seem -l gave us both the user and group.  On this type of
 233     dnl ls, -g makes _only_ the group be displayed (and not the user).
 234     nmh_cv_ls_grpopt="-l"],[
 235     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 236     nmh_cv_ls_grpopt="-lg"])])])
 237
 238 dnl Look for `sendmail'
 239 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 240 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 241
 242 dnl Cygwin FAT filesystems do not support hard links.  So default to
 243 dnl cp instead, even if running on an NTFS or other filesystem.
 244 AS_CASE(["$host_os"],
 245   [cygwin*], [LN=cp],
 246   [LN=ln])
 247 AC_SUBST([LN])
 248
 249 dnl ----------------------------------------------------------
 250 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 251 dnl ----------------------------------------------------------
 252 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 253 [for mailspool in /var/mail        dnl
 254                   /var/spool/mail  dnl
 255                   /usr/spool/mail  dnl
 256                   /dev/null;       dnl Just in case we fall through
 257 do
 258   test -d $mailspool && break
 259 done
 260 nmh_cv_mailspool=$mailspool
 261 ])
 262 mailspool=$nmh_cv_mailspool
 263 AC_SUBST([mailspool])dnl
 264
 265 dnl See whether the mail spool directory is world-writable.
 266 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 267   AC_CACHE_CHECK(whether the mail spool is world-writable,
 268                  nmh_cv_mailspool_world_writable,
 269   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 270     nmh_cv_mailspool_world_writable=no
 271   else
 272     nmh_cv_mailspool_world_writable=yes
 273   fi])
 274 fi
 275
 276 dnl Also, check for liblockfile (as found on Debian systems)
 277 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 278
 279 dnl and whether its companion program dotlockfile is setgid
 280 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 281 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 282   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 283     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 284     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 285         nmh_cv_dotlockfile_setgid=yes
 286       else
 287         nmh_cv_dotlockfile_setgid=no
 288       fi])
 289   fi
 290 fi
 291
 292 dnl Provide a way for distcheck to disable setgid_mail via
 293 dnl DISTCHECK_CONFIGURE_FLAGS.
 294 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 295   [nmh_cv_dotlockfile_setgid=yes])
 296
 297 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 298 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 299 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 300   dnl do we really need both of these?
 301   AC_DEFINE([MAILGROUP],[1],
 302     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 303   SETGID_MAIL=1
 304 fi
 305 AC_SUBST([SETGID_MAIL])dnl
 306
 307 dnl Use ls to see which group owns the mail spool directory.
 308 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 309 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 310 ])
 311 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 312 AC_SUBST([MAIL_SPOOL_GRP])dnl
 313
 314 NMH_MIMETYPEPROC
 315 NMH_MIMEENCODINGPROC
 316
 317 dnl ------------------
 318 dnl CHECK HEADER FILES
 319 dnl ------------------
 320
 321 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 322 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 323 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 324 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 325 dnl declared; if so they should have an entry added to this case statement.
 326 dnl NB that we must define this on the compiler command line, not in config.h,
 327 dnl because it must be set before any system header is included and there's no
 328 dnl portable way to make sure that files generated by lex include config.h
 329 dnl before system header files.
 330
 331 AS_CASE(["$host_os"],
 332         [linux*],
 333         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 334           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 335                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 336
 337 AC_HEADER_TIOCGWINSZ
 338 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 339
 340 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 341   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 342 [[#if HAVE_SYS_STREAM_H
 343 #  include <sys/stream.h>
 344 #endif
 345 ]])
 346
 347 dnl ---------------
 348 dnl CHECK FUNCTIONS
 349 dnl ---------------
 350 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 351
 352 dnl Check for multibyte character set support
 353 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 354             "x$ac_cv_header_wctype_h" = "xyes" -a \
 355             "x$ac_cv_func_wcwidth" = "xyes" -a \
 356             "x$ac_cv_func_mbtowc" = "xyes"],
 357       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 358                  [Define to enable support for multibyte character sets.])
 359        MULTIBYTE_ENABLED=1],
 360       [MULTIBYTE_ENABLED=0])
 361 AC_SUBST([MULTIBYTE_ENABLED])
 362
 363 dnl -------------------
 364 dnl CHECK FOR LIBRARIES
 365 dnl -------------------
 366 dnl Checks for network libraries (nsl, socket)
 367 NMH_CHECK_NETLIBS
 368
 369 dnl Check the locking functions supported and what we should use by default
 370 NMH_LOCKING
 371
 372 dnl Check for iconv
 373 NMH_CHECK_ICONV
 374
 375 dnl Check for tputs() callback argument
 376 NMH_TPUTS_PUTC_ARG
 377
 378 termcap_curses_order="termcap curses ncurses"
 379 for lib in $termcap_curses_order; do
 380   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 381 done
 382 AC_SUBST([TERMLIB])dnl
 383 AS_IF([test "x$TERMLIB" = "x"],
 384       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 385 curses or ncurses library or package that you can install?])])
 386
 387 dnl Check for readline support
 388 NMH_READLINE
 389
 390 dnl --------------
 391 dnl CHECK FOR NDBM
 392 dnl --------------
 393
 394 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 395             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 396 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 397             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 398
 399 if test "$nmh_ndbm" = "autodetect"; then
 400   if test "$nmh_ndbmheader" != "autodetect"; then
 401     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 402   else
 403
 404     dnl There are at least four implementations of ndbm, and
 405     dnl several of those can be in different places at the whim
 406     dnl of the system integrator. A good summary of this mess
 407     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 408
 409     dnl Classic ndbm with no library required (eg NetBSD): try this
 410     dnl first so we don't accidentally link in a pointless but harmless
 411     dnl library in one of the later ndbm.h+libfoo tests:
 412     NMH_CHECK_NDBM(ndbm.h,,,
 413     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 414       NMH_CHECK_NDBM(db.h,db,,
 415     dnl Berkeley DBv1 emulating ndbm:
 416         NMH_CHECK_NDBM(ndbm.h,db,,
 417           NMH_CHECK_NDBM(ndbm.h,db1,,
 418     dnl Classic ndbm:
 419             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 420     dnl glibc2.1 systems put db1 in a subdir:
 421               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 422     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 423     dnl and possibly needing gbdm_compat library:
 424                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 425                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 426                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 427     dnl 64-bit Cygwin:
 428                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 429     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 430     dnl need to be explicit:
 431                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 432   fi
 433 else
 434   dnl We don't really need to check that the user-specified values work,
 435   dnl but it is a convenience to the user to bomb out early rather than
 436   dnl after configure and half the compile process.
 437   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 438 fi
 439
 440 if test "$nmh_ndbm_found" = "no"; then
 441   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 442 else
 443   dnl Now export the lib/header to our makefile/config.h:
 444   if test x"$nmh_ndbmheader" != x; then
 445     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 446       [Define to the header containing the ndbm API prototypes.])
 447   fi
 448   if test x"$nmh_ndbm" != x; then
 449     NDBM_LIBS="-l$nmh_ndbm"
 450   else
 451     NDBM_LIBS=
 452   fi
 453   AC_SUBST([NDBM_LIBS])
 454 fi
 455
 456 dnl ------------------
 457 dnl Set RPM build root
 458 dnl ------------------
 459 dnl nmhrpm is used in the final summary, see below.  The default value is
 460 dnl reported there as ./RPM, consistent with the reporting of the default
 461 dnl source code location as ., but its absolute path is used in the Makefile.
 462 AC_ARG_WITH([rpmdir],
 463   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 464   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 465           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 466 AC_SUBST([rpmdir])
 467
 468
 469 dnl --------------------
 470 dnl CHECK FOR CYRUS-SASL
 471 dnl --------------------
 472
 473 AS_IF([test x"$sasl_support" = x"yes"],[
 474   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 475   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 476     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 477 AC_SUBST([SASLLIB])
 478
 479 dnl -----------------
 480 dnl CHECK FOR OPENSSL
 481 dnl -----------------
 482
 483 AS_IF([test x"$tls_support" = x"yes"],[
 484   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 485   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 486   dnl automatically append -lcrypto when linking with -lssl.
 487   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 488   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 489     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 490   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 491     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 492   [TLSLIB=])
 493 AC_SUBST([TLSLIB])
 494
 495 dnl ----------------
 496 dnl CHECK FLEX FIXUP
 497 dnl ----------------
 498 dnl Use LFLAGS make variable setting to work around bugs in flex
 499 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 500 dnl http://sourceforge.net/p/flex/bugs/140/
 501 AS_IF([test "$LEX" = flex],
 502       [AS_CASE([`$LEX -V`],
 503                [flex\ 2.5.35], [LFLAGS=\
 504 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 505                [flex\ 2.5.3[[67]]], [LFLAGS=\
 506 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 507        AC_SUBST([LFLAGS])])
 508
 509 dnl ----------------
 510 dnl CHECK STRUCTURES
 511 dnl ----------------
 512
 513 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 514 dnl (FreeBSD has a timezone() function but not a timezone global
 515 dnl variable that is visible).
 516 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 517
 518 AC_STRUCT_DIRENT_D_TYPE
 519
 520 dnl Where is <signal.h> located?  Needed as input for signames.awk
 521 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 522 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 523                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 524                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 525                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 526                  /usr/include/sys/signal.h      dnl Almost everybody else
 527                  /dev/null;                     dnl Just in case we fall through
 528 do
 529   test -f $SIGNAL_H && \
 530   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 531   break
 532 done
 533 nmh_cv_path_signal_h=$SIGNAL_H
 534 ])
 535 SIGNAL_H=$nmh_cv_path_signal_h
 536 AC_SUBST(SIGNAL_H)dnl
 537
 538 dnl
 539 dnl Sigh, this is required because under the new world order autoconf has
 540 dnl nothing to create in a few of the build directories when doing an object
 541 dnl tree build.  So make sure we created certain directories if they don't
 542 dnl exist.
 543 dnl
 544
 545 AC_CONFIG_COMMANDS([build-directories],
 546 [test -d man || AS_MKDIR_P([man])])
 547
 548 AC_CONFIG_COMMANDS_POST([
 549
 550 dnl These odd looking assignments are done to expand out unexpanded
 551 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 552 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 553 dnl again to get the final answer.
 554 dnl We only use the expanded versions to print the install paths in
 555 dnl the final summary and should use them nowhere else (see the autoconf
 556 dnl docs for the rationale for bindir etc being unexpanded).
 557 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 558 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 559 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 560 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 561 eval "nmhrpm=${nmhrpm}";
 562
 563 AC_MSG_NOTICE([
 564 nmh configuration
 565 -----------------
 566 nmh version                : AC_PACKAGE_VERSION
 567 host os                    : ${host}
 568 compiler                   : ${CC}
 569 compiler flags             : ${CFLAGS}
 570 linker flags               : ${LDFLAGS}
 571 preprocessor flags         : ${CPPFLAGS}
 572 source code location       : ${srcdir}
 573 binary install path        : ${nmhbin}
 574 library install path       : ${nmhlib}
 575 config files install path  : ${nmhsysconf}
 576 man page install path      : ${nmhman}
 577 RPM build root             : ${nmhrpm}
 578 backup prefix              : ${backup_prefix}
 579 transport system           : ${MTS}
 580 spool default locking type : ${with_locking}
 581 default smtp servers       : ${smtpservers}
 582 SASL support               : ${sasl_support}
 583 TLS support                : ${tls_support}
 584 ])])dnl
 585
 586 dnl ---------------
 587 dnl OUTPUT MAKEFILE
 588 dnl ---------------
 589 AC_CONFIG_FILES([Makefile test/common.sh])
 590 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 591 AC_OUTPUT