diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  44 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  45   [Enable OAuth2 support in SMTP auth]))
  46 AS_IF([test x"$with_oauth" != x -a x"$with_oauth" != x"no"],[
  47       AC_DEFINE([OAUTH_SUPPORT], [1],
  48                 [Support OAuth2 in SMTP auth.])dnl
  49       OAUTH_SUPPORT=1; oauth_support=yes], [OAUTH_SUPPORT=0; oauth_support=no])
  50 AC_SUBST(OAUTH_SUPPORT)
  51
  52 dnl Do you want client-side support for encryption with TLS?
  53 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  54 AS_IF([test x"$with_tls" != x"no"],[
  55       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  56       tls_support=yes],[tls_support=no])
  57
  58 dnl Set the backup prefix
  59 AC_ARG_WITH([hash-backup],
  60   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  61 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  62       [backup_prefix="#"], [backup_prefix=","])
  63 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  64     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  65
  66 dnl What method of posting should post use?
  67 AC_ARG_WITH([mts],
  68   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  69   [specify the default mail transport agent/service]))
  70
  71 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  72       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  74       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  75       [MTS="smtp"])
  76 AC_SUBST([MTS])dnl
  77
  78 dnl What should be the default mail server(s)?
  79 AC_ARG_WITH([smtpservers],
  80   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  81   [specify the default SMTP server(s) @<:@localhost@:>@])])
  82 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  83       [smtpservers="localhost"])
  84 AC_SUBST([smtpservers])dnl
  85
  86 dnl -------------------------------------------------------------------
  87 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  88 dnl find an existing installation, in which case we use its location.
  89 dnl -------------------------------------------------------------------
  90 AC_PREFIX_DEFAULT([/usr/local/nmh])
  91 AC_PREFIX_PROGRAM([mhparam])
  92
  93 dnl ------------------
  94 dnl CHECK THE COMPILER
  95 dnl ------------------
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 dnl The user didn't specify CFLAGS, so customize them.
 104 if test "$GCC" != yes; then
 105   dnl Use -v and some other options with SunStudio cc.  lex produces
 106   dnl code that causes unreachable-statement warnings.  It might be
 107   dnl better to use an autoconf test, except -v will probably succeed
 108   dnl with many other compilers but have different meaning.
 109   AS_CASE([`${CC} -V 2>&1`],
 110           [cc:\ Sun\ C*], [CFLAGS=\
 111 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 112 fi
 113
 114 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 115                [nmh_saved_cflags="$CFLAGS"
 116                CFLAGS="$CFLAGS -Wall -Werror"
 117                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 118                CFLAGS="$nmh_saved_cflags"])
 119 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 120
 121 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 122                [nmh_saved_cflags="$CFLAGS"
 123                CFLAGS="$CFLAGS -Wextra -Werror"
 124                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 125                               nmh_cv_has_wextra=no)
 126                CFLAGS="$nmh_saved_cflags"])
 127 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 128
 129 if test "$GCC" = yes; then
 130   dnl Do this regardless of auto_cflags value.
 131   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 132   dnl gcc 4.1 and later, but only when optimization is enabled.
 133   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 134   dnl If the user configures with a CFLAGS that contains a -O flag
 135   dnl but then removes it a make time, they'll also have to remove
 136   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 137   AS_CASE([$CFLAGS],
 138           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 139 fi
 140
 141 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 142 dnl We do this here rather than in (say) h/mh.h because this macro must
 143 dnl be defined before <stdio.h> is pulled in.
 144 dnl
 145 dnl And while we're here, add the packages tree to the cpp and ld search
 146 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 147 dnl If /usr/ports is installed, we use its idea of where things are installed,
 148 dnl otherwise we assume /usr/local.
 149
 150 AS_IF([test `uname` = FreeBSD],
 151         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 152          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 153                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 154          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 155          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 156          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 157 ])
 158
 159 dnl --------------
 160 dnl CUSTOMIZE LINK
 161 dnl --------------
 162 AS_IF([test `uname` = OpenBSD],
 163       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 164       dnl so that they don't color the waterfall.
 165       [POSTLINK="2>&1 | sed -e \
 166 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 167 AC_SUBST([POSTLINK])
 168
 169 dnl -----------------
 170 dnl CUSTOMIZE LDFLAGS
 171 dnl -----------------
 172 dnl Disable clang complaint about unused -ansi when linking.
 173 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 174                [nmh_cv_has_q_unused_arguments],
 175                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 176                        grep clang >/dev/null`],
 177                       [nmh_saved_ldflags="$LDFLAGS"
 178                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 179                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 180                                          nmh_cv_has_q_unused_arguments=no)
 181                        LDFLAGS="$nmh_saved_ldflags"],
 182                        [nmh_cv_has_q_unused_arguments=no])])
 183 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 184   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 185
 186 dnl This hack turns off assertions by default, assuming
 187 dnl that configure still uses this shell variable.  Without
 188 dnl it, AC_HEADER_ASSERT enables assertions by default.
 189 test -z "$enable_assert"  &&  enable_assert=no
 190
 191 AC_HEADER_ASSERT
 192
 193 dnl ------------------
 194 dnl CHECK FOR PROGRAMS
 195 dnl ------------------
 196 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 197 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 198 AC_PROG_RANLIB          dnl Check for `ranlib'
 199 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 200 AC_PROG_SED             dnl Check for Posix-compliant sed
 201 AC_PROG_YACC            dnl Check for yacc/bison
 202 AM_PROG_LEX             dnl Check for lex/flex
 203
 204 AM_PROG_AR
 205
 206 dnl Look for `cut'
 207 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 208 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 209
 210 dnl
 211 dnl Check for MD5 program and formatting command
 212 dnl
 213 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 214 AS_CASE(["${MD5SUM}"],
 215         [md5sum], [MD5FMT="cat"],
 216         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 217         [MD5FMT="missing"])
 218 AC_SUBST([MD5FMT])
 219
 220 dnl Look for `ls'
 221 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 222 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 223
 224 dnl See how we get ls to display the owner and the group
 225 AS_IF([test "$lspath" != "no"],
 226   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 227                  [nmh_cv_ls_grpopt],
 228   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 229     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 230     dnl ls, it would seem -l gave us both the user and group.  On this type of
 231     dnl ls, -g makes _only_ the group be displayed (and not the user).
 232     nmh_cv_ls_grpopt="-l"],[
 233     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 234     nmh_cv_ls_grpopt="-lg"])])])
 235
 236 dnl Look for `sendmail'
 237 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 238 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 239
 240 dnl Cygwin FAT filesystems do not support hard links.  So default to
 241 dnl cp instead, even if running on an NTFS or other filesystem.
 242 AS_CASE(["$host_os"],
 243   [cygwin*], [LN=cp],
 244   [LN=ln])
 245 AC_SUBST([LN])
 246
 247 dnl ----------------------------------------------------------
 248 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 249 dnl ----------------------------------------------------------
 250 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 251 [for mailspool in /var/mail        dnl
 252                   /var/spool/mail  dnl
 253                   /usr/spool/mail  dnl
 254                   /dev/null;       dnl Just in case we fall through
 255 do
 256   test -d $mailspool && break
 257 done
 258 nmh_cv_mailspool=$mailspool
 259 ])
 260 mailspool=$nmh_cv_mailspool
 261 AC_SUBST([mailspool])dnl
 262
 263 dnl See whether the mail spool directory is world-writable.
 264 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 265   AC_CACHE_CHECK(whether the mail spool is world-writable,
 266                  nmh_cv_mailspool_world_writable,
 267   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 268     nmh_cv_mailspool_world_writable=no
 269   else
 270     nmh_cv_mailspool_world_writable=yes
 271   fi])
 272 fi
 273
 274 dnl Also, check for liblockfile (as found on Debian systems)
 275 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 276
 277 dnl and whether its companion program dotlockfile is setgid
 278 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 279 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 280   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 281     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 282     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 283         nmh_cv_dotlockfile_setgid=yes
 284       else
 285         nmh_cv_dotlockfile_setgid=no
 286       fi])
 287   fi
 288 fi
 289
 290 dnl Provide a way for distcheck to disable setgid_mail via
 291 dnl DISTCHECK_CONFIGURE_FLAGS.
 292 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 293   [nmh_cv_dotlockfile_setgid=yes])
 294
 295 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 296 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 297 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 298   dnl do we really need both of these?
 299   AC_DEFINE([MAILGROUP],[1],
 300     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 301   SETGID_MAIL=1
 302 fi
 303 AC_SUBST([SETGID_MAIL])dnl
 304
 305 dnl Use ls to see which group owns the mail spool directory.
 306 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 307 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 308 ])
 309 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 310 AC_SUBST([MAIL_SPOOL_GRP])dnl
 311
 312 NMH_MIMETYPEPROC
 313 NMH_MIMEENCODINGPROC
 314
 315 dnl ------------------
 316 dnl CHECK HEADER FILES
 317 dnl ------------------
 318
 319 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 320 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 321 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 322 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 323 dnl declared; if so they should have an entry added to this case statement.
 324 dnl NB that we must define this on the compiler command line, not in config.h,
 325 dnl because it must be set before any system header is included and there's no
 326 dnl portable way to make sure that files generated by lex include config.h
 327 dnl before system header files.
 328
 329 AS_CASE(["$host_os"],
 330         [linux*],
 331         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 332         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 333
 334 AC_HEADER_TIOCGWINSZ
 335 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 336
 337 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 338   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 339 [[#if HAVE_SYS_STREAM_H
 340 #  include <sys/stream.h>
 341 #endif
 342 ]])
 343
 344 dnl ---------------
 345 dnl CHECK FUNCTIONS
 346 dnl ---------------
 347 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 348
 349 dnl Check for multibyte character set support
 350 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 351             "x$ac_cv_header_wctype_h" = "xyes" -a \
 352             "x$ac_cv_func_wcwidth" = "xyes" -a \
 353             "x$ac_cv_func_mbtowc" = "xyes"],
 354       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 355                  [Define to enable support for multibyte character sets.])
 356        MULTIBYTE_ENABLED=1],
 357       [MULTIBYTE_ENABLED=0])
 358 AC_SUBST([MULTIBYTE_ENABLED])
 359
 360 dnl -------------------
 361 dnl CHECK FOR LIBRARIES
 362 dnl -------------------
 363 dnl Checks for network libraries (nsl, socket)
 364 NMH_CHECK_NETLIBS
 365
 366 dnl Check the locking functions supported and what we should use by default
 367 NMH_LOCKING
 368
 369 dnl Check for iconv
 370 NMH_CHECK_ICONV
 371
 372 dnl Check for tputs() callback argument
 373 NMH_TPUTS_PUTC_ARG
 374
 375 termcap_curses_order="termcap curses ncurses"
 376 for lib in $termcap_curses_order; do
 377   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 378 done
 379 AC_SUBST([TERMLIB])dnl
 380 AS_IF([test "x$TERMLIB" = "x"],
 381       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 382 curses or ncurses library or package that you can install?])])
 383
 384 dnl Check for readline support
 385 NMH_READLINE
 386
 387 dnl --------------
 388 dnl CHECK FOR NDBM
 389 dnl --------------
 390
 391 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 392             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 393 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 394             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 395
 396 if test "$nmh_ndbm" = "autodetect"; then
 397   if test "$nmh_ndbmheader" != "autodetect"; then
 398     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 399   else
 400
 401     dnl There are at least four implementations of ndbm, and
 402     dnl several of those can be in different places at the whim
 403     dnl of the system integrator. A good summary of this mess
 404     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 405
 406     dnl Classic ndbm with no library required (eg NetBSD): try this
 407     dnl first so we don't accidentally link in a pointless but harmless
 408     dnl library in one of the later ndbm.h+libfoo tests:
 409     NMH_CHECK_NDBM(ndbm.h,,,
 410     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 411       NMH_CHECK_NDBM(db.h,db,,
 412     dnl Berkeley DBv1 emulating ndbm:
 413         NMH_CHECK_NDBM(ndbm.h,db,,
 414           NMH_CHECK_NDBM(ndbm.h,db1,,
 415     dnl Classic ndbm:
 416             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 417     dnl glibc2.1 systems put db1 in a subdir:
 418               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 419     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 420     dnl and possibly needing gbdm_compat library:
 421                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 422                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 423                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 424     dnl 64-bit Cygwin:
 425                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 426     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 427     dnl need to be explicit:
 428                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 429   fi
 430 else
 431   dnl We don't really need to check that the user-specified values work,
 432   dnl but it is a convenience to the user to bomb out early rather than
 433   dnl after configure and half the compile process.
 434   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 435 fi
 436
 437 if test "$nmh_ndbm_found" = "no"; then
 438   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 439 else
 440   dnl Now export the lib/header to our makefile/config.h:
 441   if test x"$nmh_ndbmheader" != x; then
 442     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 443       [Define to the header containing the ndbm API prototypes.])
 444   fi
 445   if test x"$nmh_ndbm" != x; then
 446     NDBM_LIBS="-l$nmh_ndbm"
 447   else
 448     NDBM_LIBS=
 449   fi
 450   AC_SUBST([NDBM_LIBS])
 451 fi
 452
 453 dnl ------------------
 454 dnl Set RPM build root
 455 dnl ------------------
 456 dnl nmhrpm is used in the final summary, see below.  The default value is
 457 dnl reported there as ./RPM, consistent with the reporting of the default
 458 dnl source code location as ., but its absolute path is used in the Makefile.
 459 AC_ARG_WITH([rpmdir],
 460   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 461   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 462           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 463 AC_SUBST([rpmdir])
 464
 465
 466 dnl --------------------
 467 dnl CHECK FOR CYRUS-SASL
 468 dnl --------------------
 469
 470 AS_IF([test x"$sasl_support" = x"yes"],[
 471   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 472   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 473     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 474 AC_SUBST([SASLLIB])
 475
 476 dnl -----------------
 477 dnl CHECK FOR OPENSSL
 478 dnl -----------------
 479
 480 AS_IF([test x"$tls_support" = x"yes"],[
 481   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 482   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 483   dnl automatically append -lcrypto when linking with -lssl.
 484   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 485   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 486     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 487   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 488     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 489   [TLSLIB=])
 490 AC_SUBST([TLSLIB])
 491
 492 dnl -----------------
 493 dnl CHECK FOR CURL
 494 dnl -----------------
 495 AS_IF([test x"$OAUTH_SUPPORT" = x"1"],[
 496   AC_PATH_PROG([curl_config], [curl-config])
 497   AC_CHECK_HEADER([curl/curl.h], [], [AC_MSG_ERROR([curl/curl.h not found])])
 498   AC_CHECK_LIB([curl], [curl_easy_init], [CURLLIB="`$curl_config --libs`"],
 499     [AC_MSG_ERROR([curl library not found])],[$CURLLIB])
 500   CURL_USER_AGENT=`$curl_config --version | sed 's| |/|'`
 501   ],
 502   [CURLLIB=
 503    CURL_USER_AGENT=
 504 ])
 505 AC_SUBST([CURLLIB])
 506 AC_SUBST([CURL_USER_AGENT])
 507
 508 dnl ----------------
 509 dnl CHECK FLEX FIXUP
 510 dnl ----------------
 511 dnl Use LFLAGS make variable setting to work around bugs in flex
 512 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 513 dnl http://sourceforge.net/p/flex/bugs/140/
 514 AS_IF([test "$LEX" = flex],
 515       [AS_CASE([`$LEX -V`],
 516                [flex\ 2.5.35], [LFLAGS=\
 517 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 518                [flex\ 2.5.3[[67]]], [LFLAGS=\
 519 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 520        AC_SUBST([LFLAGS])])
 521
 522 dnl ------------------
 523 dnl FOR INTERNAL USE by the NMH test suite
 524 dnl ------------------
 525 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 526 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 527       AC_SUBST([nmhetcdirinst]))
 528
 529 dnl ----------------
 530 dnl CHECK STRUCTURES
 531 dnl ----------------
 532
 533 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 534 dnl (FreeBSD has a timezone() function but not a timezone global
 535 dnl variable that is visible).
 536 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 537
 538 AC_STRUCT_DIRENT_D_TYPE
 539
 540 dnl Where is <signal.h> located?  Needed as input for signames.awk
 541 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 542 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 543                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 544                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 545                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 546                  /usr/include/sys/signal.h      dnl Almost everybody else
 547                  /dev/null;                     dnl Just in case we fall through
 548 do
 549   test -f $SIGNAL_H && \
 550   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 551   break
 552 done
 553 nmh_cv_path_signal_h=$SIGNAL_H
 554 ])
 555 SIGNAL_H=$nmh_cv_path_signal_h
 556 AC_SUBST(SIGNAL_H)dnl
 557
 558 dnl
 559 dnl Sigh, this is required because under the new world order autoconf has
 560 dnl nothing to create in a few of the build directories when doing an object
 561 dnl tree build.  So make sure we created certain directories if they don't
 562 dnl exist.
 563 dnl
 564
 565 AC_CONFIG_COMMANDS([build-directories],
 566 [test -d man || AS_MKDIR_P([man])])
 567
 568 AC_CONFIG_COMMANDS_POST([
 569
 570 dnl These odd looking assignments are done to expand out unexpanded
 571 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 572 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 573 dnl again to get the final answer.
 574 dnl We only use the expanded versions to print the install paths in
 575 dnl the final summary and should use them nowhere else (see the autoconf
 576 dnl docs for the rationale for bindir etc being unexpanded).
 577 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 578 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 579 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 580 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 581 eval "nmhrpm=${nmhrpm}";
 582
 583 AC_MSG_NOTICE([
 584 nmh configuration
 585 -----------------
 586 nmh version                : AC_PACKAGE_VERSION
 587 host os                    : ${host}
 588 compiler                   : ${CC}
 589 compiler flags             : ${CFLAGS}
 590 linker flags               : ${LDFLAGS}
 591 preprocessor flags         : ${CPPFLAGS}
 592 source code location       : ${srcdir}
 593 binary install path        : ${nmhbin}
 594 libexec install path       : ${nmhlibexec}/nmh
 595 config files install path  : ${nmhsysconf}/nmh
 596 man page install path      : ${nmhman}
 597 RPM build root             : ${nmhrpm}
 598 backup prefix              : ${backup_prefix}
 599 transport system           : ${MTS}
 600 spool default locking type : ${with_locking}
 601 default smtp servers       : ${smtpservers}
 602 SASL support               : ${sasl_support}
 603 TLS support                : ${tls_support}
 604 OAuth support              : ${oauth_support}
 605 ])])dnl
 606
 607 dnl ---------------
 608 dnl OUTPUT MAKEFILE
 609 dnl ---------------
 610 AC_CONFIG_FILES([Makefile test/common.sh])
 611 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 612 AC_OUTPUT