diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want to debug nmh?
  27 AC_ARG_ENABLE([debug],
  28   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  29
  30 dnl Do you want client-side support for using SASL for authentication?
  31 dnl Note that this code will be enabled for both POP and SMTP
  32 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  33   [Enable SASL support via the Cyrus SASL library]))
  34 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  35       AC_DEFINE([CYRUS_SASL], [1],
  36                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  37       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  38             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  39             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  40       sasl_support=yes], [sasl_support=no])
  41
  42 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  43 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  44   [Enable OAuth2 support in SMTP auth]))
  45
  46 dnl Do you want client-side support for encryption with TLS?
  47 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  48 AS_IF([test x"$with_tls" != x"no"],[
  49       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  50       tls_support=yes],[tls_support=no])
  51
  52 dnl Set the backup prefix
  53 AC_ARG_WITH([hash-backup],
  54   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  55 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  56       [backup_prefix="#"], [backup_prefix=","])
  57 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  58     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  59
  60 dnl What method of posting should post use?
  61 AC_ARG_WITH([mts],
  62   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  63   [specify the default mail transport agent/service]))
  64
  65 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  66       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  67       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  68       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  69       [MTS="smtp"])
  70 AC_SUBST([MTS])dnl
  71
  72 dnl What should be the default mail server(s)?
  73 AC_ARG_WITH([smtpservers],
  74   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  75   [specify the default SMTP server(s) @<:@localhost@:>@])])
  76 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  77       [smtpservers="localhost"])
  78 AC_SUBST([smtpservers])dnl
  79
  80 dnl -------------------------------------------------------------------
  81 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  82 dnl find an existing installation, in which case we use its location.
  83 dnl -------------------------------------------------------------------
  84 AC_PREFIX_DEFAULT([/usr/local/nmh])
  85 AC_PREFIX_PROGRAM([mhparam])
  86
  87 dnl ------------------
  88 dnl CHECK THE COMPILER
  89 dnl ------------------
  90
  91 AC_PROG_CC([cc gcc])
  92 AM_PROG_CC_C_O
  93
  94 dnl ------------------
  95 dnl CHECK HEADER FILES
  96 dnl ------------------
  97
  98 AC_HEADER_TIOCGWINSZ
  99 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
 100                   sys/param.h sys/time.h sys/stream.h])
 101
 102 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 103   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 104 [[#if HAVE_SYS_STREAM_H
 105 #  include <sys/stream.h>
 106 #endif
 107 ]])
 108
 109 dnl ---------------
 110 dnl CHECK FUNCTIONS
 111 dnl ---------------
 112 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 113
 114 dnl Use custom getline for platforms that don't have it.
 115 AC_CONFIG_LIBOBJ_DIR([sbr])
 116 AC_REPLACE_FUNCS([getline])
 117
 118 dnl -----------------------
 119 dnl CHECK MULTIBYTE SUPPORT
 120 dnl -----------------------
 121 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 122             "x$ac_cv_header_wctype_h" = "xyes" -a \
 123             "x$ac_cv_func_wcwidth" = "xyes" -a \
 124             "x$ac_cv_func_mbtowc" = "xyes"],
 125       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 126                  [Define to enable support for multibyte character sets.])
 127        MULTIBYTE_ENABLED=1],
 128       [MULTIBYTE_ENABLED=0])
 129 AC_SUBST([MULTIBYTE_ENABLED])
 130
 131 dnl ----------------
 132 dnl CUSTOMIZE CFLAGS
 133 dnl ----------------
 134 dnl The user didn't specify CFLAGS, so customize them.
 135
 136 if test "$GCC" != yes; then
 137   dnl Use -v and some other options with SunStudio cc.  lex produces
 138   dnl code that causes unreachable-statement warnings.  It might be
 139   dnl better to use an autoconf test, except -v will probably succeed
 140   dnl with many other compilers but have different meaning.
 141   AS_CASE([`${CC} -V 2>&1`],
 142           [cc:*\ Sun\ C*], [CFLAGS=\
 143 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 144 fi
 145
 146 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 147                [nmh_saved_cflags="$CFLAGS"
 148                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 149                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 150                CFLAGS="$nmh_saved_cflags"])
 151 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 152
 153 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 154                [nmh_saved_cflags="$CFLAGS"
 155                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 156                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 157                               nmh_cv_has_wextra=no)
 158                CFLAGS="$nmh_saved_cflags"])
 159 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 160
 161 AC_SUBST([AM_CFLAGS])
 162
 163 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 164 dnl MULTIBYTE_ENABLED having already been set.
 165 NMH_ADDL_CPPFLAGS
 166
 167 if test "$GCC" = yes; then
 168   dnl Do this regardless of auto_cflags value.
 169   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 170   dnl gcc 4.1 and later, but only when optimization is enabled.
 171   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 172   dnl If the user configures with a CFLAGS that contains a -O flag
 173   dnl but then removes it a make time, they'll also have to remove
 174   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 175   AS_CASE([$CFLAGS],
 176           [-O*|*' -O'*],[AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 177 fi
 178
 179 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 180 dnl We do this here rather than in (say) h/mh.h because this macro must
 181 dnl be defined before <stdio.h> is pulled in.
 182 dnl
 183 dnl And while we're here, add the packages tree to the cpp and ld search
 184 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 185 dnl If /usr/ports is installed, we use its idea of where things are installed,
 186 dnl otherwise we assume /usr/local.
 187
 188 AS_IF([test `uname` = FreeBSD],
 189         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 190          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 191                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 192          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 193          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 194          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 195 ])
 196
 197 dnl --------------
 198 dnl CUSTOMIZE LINK
 199 dnl --------------
 200 AS_IF([test `uname` = OpenBSD],
 201       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 202       dnl so that they don't color the waterfall.
 203       [POSTLINK="2>&1 | sed -e \
 204 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 205 AC_SUBST([POSTLINK])
 206
 207 dnl -----------------
 208 dnl CUSTOMIZE LDFLAGS
 209 dnl -----------------
 210 dnl Disable clang complaint about unused -ansi when linking.
 211 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 212                [nmh_cv_has_q_unused_arguments],
 213                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 214                        grep clang >/dev/null`],
 215                       [nmh_saved_ldflags="$LDFLAGS"
 216                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 217                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 218                                          nmh_cv_has_q_unused_arguments=no)
 219                        LDFLAGS="$nmh_saved_ldflags"],
 220                        [nmh_cv_has_q_unused_arguments=no])])
 221 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 222   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 223
 224 dnl This hack turns off assertions by default, assuming
 225 dnl that configure still uses this shell variable.  Without
 226 dnl it, AC_HEADER_ASSERT enables assertions by default.
 227 test -z "$enable_assert"  &&  enable_assert=no
 228
 229 AC_HEADER_ASSERT
 230
 231 dnl ------------------
 232 dnl CHECK FOR PROGRAMS
 233 dnl ------------------
 234 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 235 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 236 AC_PROG_RANLIB          dnl Check for `ranlib'
 237 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 238 AC_PROG_SED             dnl Check for Posix-compliant sed
 239 AC_PROG_YACC            dnl Check for yacc/bison
 240 AM_PROG_LEX             dnl Check for lex/flex
 241
 242 AM_PROG_AR
 243
 244 dnl Look for `cut'
 245 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 246 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 247
 248 dnl
 249 dnl Check for MD5 program and formatting command
 250 dnl
 251 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 252 AS_CASE(["${MD5SUM}"],
 253         [md5sum], [MD5FMT="cat"],
 254         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 255         [MD5FMT="missing"])
 256 AC_SUBST([MD5FMT])
 257
 258 dnl Look for `ls'
 259 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 260 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 261
 262 dnl See how we get ls to display the owner and the group
 263 AS_IF([test "$lspath" != "no"],
 264   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 265                  [nmh_cv_ls_grpopt],
 266   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 267     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 268     dnl ls, it would seem -l gave us both the user and group.  On this type of
 269     dnl ls, -g makes _only_ the group be displayed (and not the user).
 270     nmh_cv_ls_grpopt="-l"],[
 271     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 272     nmh_cv_ls_grpopt="-lg"])])])
 273
 274 dnl Look for `sendmail'
 275 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 276 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 277
 278 dnl Cygwin FAT filesystems do not support hard links.  So default to
 279 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 280 dnl therefore, this cannot be made into a dynamic test, in order to
 281 dnl support the least common Cygwin denominator.
 282 AS_CASE(["$host_os"],
 283   [cygwin*], [LN=cp],
 284   [LN=ln])
 285 AC_SUBST([LN])
 286
 287 dnl ----------------------------------------------------------
 288 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 289 dnl ----------------------------------------------------------
 290 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 291 [for mailspool in /var/mail        dnl
 292                   /var/spool/mail  dnl
 293                   /usr/spool/mail  dnl
 294                   /dev/null;       dnl Just in case we fall through
 295 do
 296   test -d $mailspool && break
 297 done
 298 nmh_cv_mailspool=$mailspool
 299 ])
 300 mailspool=$nmh_cv_mailspool
 301 AC_SUBST([mailspool])dnl
 302
 303 dnl See whether the mail spool directory is world-writable.
 304 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 305   AC_CACHE_CHECK(whether the mail spool is world-writable,
 306                  nmh_cv_mailspool_world_writable,
 307   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 308     nmh_cv_mailspool_world_writable=no
 309   else
 310     nmh_cv_mailspool_world_writable=yes
 311   fi])
 312 fi
 313
 314 dnl Also, check for liblockfile (as found on Debian systems)
 315 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 316
 317 dnl and whether its companion program dotlockfile is setgid
 318 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 319 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 320   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 321     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 322     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 323         nmh_cv_dotlockfile_setgid=yes
 324       else
 325         nmh_cv_dotlockfile_setgid=no
 326       fi])
 327   fi
 328 fi
 329
 330 dnl Provide a way for distcheck to disable setgid_mail via
 331 dnl DISTCHECK_CONFIGURE_FLAGS.
 332 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 333   [nmh_cv_dotlockfile_setgid=yes])
 334
 335 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 336 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 337 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 338   dnl do we really need both of these?
 339   AC_DEFINE([MAILGROUP],[1],
 340     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 341   SETGID_MAIL=1
 342 fi
 343 AC_SUBST([SETGID_MAIL])dnl
 344
 345 dnl Use ls to see which group owns the mail spool directory.
 346 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 347 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 348 ])
 349 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 350 AC_SUBST([MAIL_SPOOL_GRP])dnl
 351
 352 NMH_MIMETYPEPROC
 353 NMH_MIMEENCODINGPROC
 354
 355 dnl -------------------
 356 dnl CHECK FOR LIBRARIES
 357 dnl -------------------
 358 dnl Checks for network libraries (nsl, socket)
 359 NMH_CHECK_NETLIBS
 360
 361 dnl Check the locking functions supported and what we should use by default
 362 NMH_LOCKING
 363
 364 dnl Check for iconv
 365 NMH_CHECK_ICONV
 366
 367 dnl Check for tputs() callback argument
 368 NMH_TPUTS_PUTC_ARG
 369
 370 termcap_curses_order="termcap curses ncurses"
 371 for lib in $termcap_curses_order; do
 372   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 373 done
 374 AC_SUBST([TERMLIB])dnl
 375 AS_IF([test "x$TERMLIB" = "x"],
 376       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 377 curses or ncurses library or package that you can install?])])
 378
 379 dnl Check for readline support
 380 NMH_READLINE
 381
 382 dnl --------------
 383 dnl CHECK FOR NDBM
 384 dnl --------------
 385
 386 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 387             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 388 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 389             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 390
 391 if test "$nmh_ndbm" = "autodetect"; then
 392   if test "$nmh_ndbmheader" != "autodetect"; then
 393     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 394   else
 395
 396     dnl There are at least four implementations of ndbm, and
 397     dnl several of those can be in different places at the whim
 398     dnl of the system integrator. A good summary of this mess
 399     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 400
 401     dnl Classic ndbm with no library required (eg NetBSD): try this
 402     dnl first so we don't accidentally link in a pointless but harmless
 403     dnl library in one of the later ndbm.h+libfoo tests:
 404     NMH_CHECK_NDBM(ndbm.h,,,
 405     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 406       NMH_CHECK_NDBM(db.h,db,,
 407     dnl Berkeley DBv1 emulating ndbm:
 408         NMH_CHECK_NDBM(ndbm.h,db,,
 409           NMH_CHECK_NDBM(ndbm.h,db1,,
 410     dnl Classic ndbm:
 411             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 412     dnl glibc2.1 systems put db1 in a subdir:
 413               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 414     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 415     dnl and possibly needing gbdm_compat library:
 416                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 417                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 418                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 419     dnl 64-bit Cygwin:
 420                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 421     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 422     dnl need to be explicit:
 423                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 424   fi
 425 else
 426   dnl We don't really need to check that the user-specified values work,
 427   dnl but it is a convenience to the user to bomb out early rather than
 428   dnl after configure and half the compile process.
 429   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 430 fi
 431
 432 if test "$nmh_ndbm_found" = "no"; then
 433   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 434 else
 435   dnl Now export the lib/header to our makefile/config.h:
 436   if test x"$nmh_ndbmheader" != x; then
 437     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 438       [Define to the header containing the ndbm API prototypes.])
 439   fi
 440   if test x"$nmh_ndbm" != x; then
 441     NDBM_LIBS="-l$nmh_ndbm"
 442   else
 443     NDBM_LIBS=
 444   fi
 445   AC_SUBST([NDBM_LIBS])
 446 fi
 447
 448 dnl ------------------
 449 dnl Set RPM build root
 450 dnl ------------------
 451 dnl nmhrpm is used in the final summary, see below.  The default value is
 452 dnl reported there as ./RPM, consistent with the reporting of the default
 453 dnl source code location as ., but its absolute path is used in the Makefile.
 454 AC_ARG_WITH([rpmdir],
 455   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 456   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 457           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 458 AC_SUBST([rpmdir])
 459
 460
 461 dnl --------------------
 462 dnl CHECK FOR CYRUS-SASL
 463 dnl --------------------
 464
 465 AS_IF([test x"$sasl_support" = x"yes"],[
 466   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 467   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 468     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 469 AC_SUBST([SASLLIB])
 470
 471 dnl -----------------
 472 dnl CHECK FOR OPENSSL
 473 dnl -----------------
 474
 475 AS_IF([test x"$tls_support" = x"yes"],[
 476   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 477   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 478   dnl automatically append -lcrypto when linking with -lssl.
 479   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 480   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 481     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 482   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"],
 483     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 484   [TLSLIB=])
 485 AC_SUBST([TLSLIB])
 486
 487 dnl -----------------
 488 dnl CHECK FOR CURL
 489 dnl -----------------
 490 dnl Look for curl if oauth not disabled (--without-oauth).
 491 AC_PATH_PROG([curl_config], [curl-config])
 492 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 493     save_CFLAGS="$CFLAGS"
 494     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 495     AC_CHECK_HEADER([curl/curl.h], [
 496         HAVE_CURL_H=1
 497         AC_CHECK_LIB([curl], [curl_easy_init], [
 498             CURLLIB="`$curl_config --libs`"
 499             AC_SUBST([CURLLIB])
 500             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 501             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 502                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 503                    CURL_USER_AGENT=libcurl/UNKNOWN])
 504             AC_SUBST([CURL_USER_AGENT])
 505           ])
 506       ])
 507     CFLAGS="$save_CFLAGS"
 508   ])
 509
 510 dnl -----------------
 511 dnl Enable OAuth?
 512 dnl -----------------
 513 dnl By default (with_oauth=''), enable OAuth if curl is found.
 514 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 515 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 516 oauth_support=no
 517 OAUTH_SUPPORT=0
 518 AC_SUBST([OAUTH_SUPPORT])
 519 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 520       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 521       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 522       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 523       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 524       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 525        OAUTH_SUPPORT=1
 526        oauth_support=yes])
 527
 528 dnl ----------------
 529 dnl CHECK FLEX FIXUP
 530 dnl ----------------
 531 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 532 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 533 dnl http://sourceforge.net/p/flex/bugs/140/
 534 AS_IF([test "$LEX" = flex],
 535       [AS_CASE([`$LEX -V`],
 536                [flex\ 2.5.35], [AM_LFLAGS=\
 537 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 538                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 539 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 540        AC_SUBST([AM_LFLAGS])])
 541
 542 dnl ------------------
 543 dnl FOR INTERNAL USE by the NMH test suite
 544 dnl ------------------
 545 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 546 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 547       AC_SUBST([nmhetcdirinst]))
 548
 549 dnl ----------------
 550 dnl CHECK STRUCTURES
 551 dnl ----------------
 552
 553 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 554 dnl (FreeBSD has a timezone() function but not a timezone global
 555 dnl variable that is visible).
 556 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 557
 558 AC_STRUCT_DIRENT_D_TYPE
 559
 560 dnl
 561 dnl Sigh, this is required because under the new world order autoconf has
 562 dnl nothing to create in a few of the build directories when doing an object
 563 dnl tree build.  So make sure we created certain directories if they don't
 564 dnl exist.
 565 dnl
 566
 567 AC_CONFIG_COMMANDS([build-directories],
 568 [test -d man || AS_MKDIR_P([man])])
 569
 570 AC_CONFIG_COMMANDS_POST([
 571
 572 dnl These odd looking assignments are done to expand out unexpanded
 573 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 574 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 575 dnl again to get the final answer.
 576 dnl We only use the expanded versions to print the install paths in
 577 dnl the final summary and should use them nowhere else (see the autoconf
 578 dnl docs for the rationale for bindir etc being unexpanded).
 579 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 580 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 581 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 582 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 583 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 584 eval "nmhrpm=${nmhrpm}";
 585
 586 AC_MSG_NOTICE([
 587 nmh configuration
 588 -----------------
 589 nmh version                : AC_PACKAGE_VERSION
 590 host os                    : ${host}
 591 compiler                   : ${CC}
 592 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 593 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 594 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 595 source code location       : ${srcdir}
 596 binary install path        : ${nmhbin}
 597 libexec install path       : ${nmhlibexec}/nmh
 598 config files install path  : ${nmhsysconf}/nmh
 599 man page install path      : ${nmhman}
 600 docs install path          : ${nmhdoc}
 601 RPM build root             : ${nmhrpm}
 602 backup prefix              : ${backup_prefix}
 603 transport system           : ${MTS}
 604 spool default locking type : ${with_locking}
 605 default smtp servers       : ${smtpservers}
 606 SASL support               : ${sasl_support}
 607 TLS support                : ${tls_support}
 608 OAuth support              : ${oauth_support}
 609 ])])dnl
 610
 611 dnl ---------------
 612 dnl OUTPUT MAKEFILE
 613 dnl ---------------
 614 AC_CONFIG_FILES([Makefile test/common.sh])
 615 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 616 AC_OUTPUT