diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  96 if test x"$enable_debug" = x"yes"; then
  97   test -z "$LDFLAGS" && LDFLAGS=-g
  98 fi
  99
 100 AC_PROG_CC
 101 AM_PROG_CC_C_O
 102
 103 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 104 [nmh_saved_cflags="$CFLAGS"
 105  CFLAGS="$CFLAGS -Wextra -Werror"
 106  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 107  CFLAGS="$nmh_saved_cflags"])
 108
 109 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 110 dnl setup version 2.763, because it disables some features in the
 111 dnl system system header files and warns about them with -Wall.  Try
 112 dnl to test for that generally, though still with gcc.
 113 if test "$GCC" = yes; then
 114     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 115       [nmh_saved_cppflags="$CPPFLAGS"
 116        nmh_saved_cflags="$CFLAGS"
 117        CPPFLAGS="-D_GNU_SOURCE"
 118        CFLAGS="-ansi -Wall -Werror"
 119        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 120          [nmh_cv_has_dash_ansi=yes],
 121          [nmh_cv_has_dash_ansi=no])
 122        CPPFLAGS="$nmh_saved_cppflags"
 123        CFLAGS="$nmh_saved_cflags"])
 124   else
 125     nmh_cv_has_dash_ansi=no
 126   fi
 127
 128 dnl if the user hasn't specified CFLAGS, then
 129 dnl   if compiler is gcc, then
 130 dnl    use -O2 and some warning flags
 131 dnl   else use -O
 132 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 133 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 134 dnl warnings which are probably mostly spurious and which in any case we
 135 dnl don't want to deal with now.
 136 if test "$nmh_cv_has_dash_ansi" = "yes"; then
 137     nmh_gcc_warnflags="-ansi -pedantic -Wall"
 138 else
 139     nmh_gcc_warnflags="-Wall"
 140 fi
 141 if test "$nmh_cv_has_wextra" = "yes"; then
 142     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wextra"
 143 fi
 144
 145 if test -n "$auto_cflags"; then
 146   if test x"$enable_debug" = x"yes"; then
 147     if test -n "$GCC"; then
 148       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 149     else
 150       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 151     fi
 152   else
 153     if test -z "$LDFLAGS"; then
 154       case "$build_os" in
 155         darwin*)
 156           LDFLAGS=
 157           ;;
 158         *)
 159 #         LDFLAGS=-s
 160           LDFLAGS=
 161           ;;
 162       esac
 163     fi
 164     if test -n "$GCC"; then
 165 #      test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 166       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 167     else
 168       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 169     fi
 170     AC_DEFINE([NDEBUG], [1],
 171               [Define to disable run-time debugging and asserts.])
 172   fi
 173 fi
 174
 175 dnl ------------------
 176 dnl CHECK FOR PROGRAMS
 177 dnl ------------------
 178 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 179 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 180 AC_PROG_RANLIB          dnl Check for `ranlib'
 181 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 182 AC_PROG_SED             dnl Check for Posix-compliant sed
 183 AM_PROG_LEX             dnl Check for lex/flex
 184
 185 AM_PROG_AR
 186
 187 dnl Look for `cut'
 188 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 189 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 190
 191 dnl
 192 dnl Check for MD5 program and formatting command
 193 dnl
 194 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 195 AS_CASE(["${MD5SUM}"],
 196         [md5sum], [MD5FMT="cat"],
 197         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 198         [MD5FMT="missing"])
 199 AC_SUBST([MD5FMT])
 200
 201 dnl ----------------------------------------------
 202 dnl check for lclint, and lint if it doesn't exist
 203 dnl ----------------------------------------------
 204 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 205 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 206   [LINT=$ac_cv_prog_linttmp1
 207   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 208   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 209   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 210     [LINT=$ac_cv_prog_linttmp2
 211     LINTFLAGS=""],
 212     [LINT="echo 'No lint program found'"
 213     LINTFLAGS=""])])
 214 AC_SUBST([LINT])dnl
 215 AC_SUBST([LINTFLAGS])dnl
 216
 217 dnl Look for `ls'
 218 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 219 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 220
 221 dnl See how we get ls to display the owner and the group
 222 AS_IF([test "$lspath" != "no"],
 223   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 224                  [nmh_cv_ls_grpopt],
 225   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 226     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 227     dnl ls, it would seem -l gave us both the user and group.  On this type of
 228     dnl ls, -g makes _only_ the group be displayed (and not the user).
 229     nmh_cv_ls_grpopt="-l"],[
 230     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 231     nmh_cv_ls_grpopt="-lg"])])])
 232
 233 dnl Look for `sendmail'
 234 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 235 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 236
 237 dnl Cygwin FAT filesystems do not support hard links.  So default to
 238 dnl cp instead, even if running on an NTFS or other filesystem.
 239 AS_CASE(["$host_os"],
 240   [cygwin*], [LN=cp],
 241   [LN=ln])
 242 AC_SUBST([LN])
 243
 244 dnl ----------------------------------------------------------
 245 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 246 dnl ----------------------------------------------------------
 247 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 248 [for mailspool in /var/mail        dnl
 249                   /var/spool/mail  dnl
 250                   /usr/spool/mail  dnl
 251                   /dev/null;       dnl Just in case we fall through
 252 do
 253   test -d $mailspool && break
 254 done
 255 nmh_cv_mailspool=$mailspool
 256 ])
 257 mailspool=$nmh_cv_mailspool
 258 AC_SUBST([mailspool])dnl
 259
 260 dnl See whether the mail spool directory is world-writable.
 261 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 262   AC_CACHE_CHECK(whether the mail spool is world-writable,
 263                  nmh_cv_mailspool_world_writable,
 264   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 265     nmh_cv_mailspool_world_writable=no
 266   else
 267     nmh_cv_mailspool_world_writable=yes
 268   fi])
 269 fi
 270
 271 dnl Also, check for liblockfile (as found on Debian systems)
 272 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 273
 274 dnl and whether its companion program dotlockfile is setgid
 275 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 276 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 277   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 278     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 279     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 280         nmh_cv_dotlockfile_setgid=yes
 281       else
 282         nmh_cv_dotlockfile_setgid=no
 283       fi])
 284   fi
 285 fi
 286
 287 dnl Provide a way for distcheck to disable setgid_mail via
 288 dnl DISTCHECK_CONFIGURE_FLAGS.
 289 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 290   [nmh_cv_dotlockfile_setgid=yes])
 291
 292 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 293 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 294 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 295   dnl do we really need both of these?
 296   AC_DEFINE(MAILGROUP,1,
 297     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 298   SETGID_MAIL=1
 299 fi
 300 AC_SUBST([SETGID_MAIL])dnl
 301
 302 dnl Use ls to see which group owns the mail spool directory.
 303 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 304 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 305 ])
 306 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 307 AC_SUBST(MAIL_SPOOL_GRP)dnl
 308
 309 dnl ------------------
 310 dnl CHECK HEADER FILES
 311 dnl ------------------
 312
 313 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 314 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 315 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 316 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 317 dnl declared; if so they should have an entry added to this case statement.
 318 dnl NB that we must define this on the compiler command line, not in config.h,
 319 dnl because it must be set before any system header is included and there's no
 320 dnl portable way to make sure that files generated by lex include config.h
 321 dnl before system header files.
 322
 323 AS_CASE(["$host_os"],
 324         [linux*],
 325         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 326           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 327                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 328
 329 AC_HEADER_TIOCGWINSZ
 330 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 331                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 332
 333 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 334   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 335 [[#if HAVE_SYS_STREAM_H
 336 #  include <sys/stream.h>
 337 #endif
 338 ]])
 339
 340 dnl ---------------
 341 dnl CHECK FUNCTIONS
 342 dnl ---------------
 343 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 344
 345 dnl Check for multibyte character set support
 346 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 347             "x$ac_cv_header_wctype_h" = "xyes" -a \
 348             "x$ac_cv_func_wcwidth" = "xyes" -a \
 349             "x$ac_cv_func_mbtowc" = "xyes"],
 350       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 351                  [Define to enable support for multibyte character sets.])
 352        MULTIBYTE_ENABLED=1],
 353       [MULTIBYTE_ENABLED=0])
 354 AC_SUBST([MULTIBYTE_ENABLED])
 355
 356 dnl -------------------
 357 dnl CHECK FOR LIBRARIES
 358 dnl -------------------
 359 dnl Check location of modf
 360 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 361
 362 dnl Checks for network libraries (nsl, socket)
 363 NMH_CHECK_NETLIBS
 364
 365 dnl Check for readline support
 366 NMH_READLINE
 367
 368 dnl Check the locking functions supported and what we should use by default
 369 NMH_LOCKING
 370
 371 dnl Check for iconv
 372 NMH_CHECK_ICONV
 373
 374 termcap_curses_order="termcap curses ncurses"
 375 for lib in $termcap_curses_order; do
 376   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 377 done
 378 AC_SUBST([TERMLIB])dnl
 379 AS_IF([test "x$TERMLIB" = "x"],
 380       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 381 or ncurses library or package that you can install?])])
 382
 383 dnl --------------
 384 dnl CHECK FOR NDBM
 385 dnl --------------
 386
 387 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 388             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 389 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 390             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 391
 392 if test "$nmh_ndbm" = "autodetect"; then
 393   if test "$nmh_ndbmheader" != "autodetect"; then
 394     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 395   else
 396
 397     dnl There are at least four implementations of ndbm, and
 398     dnl several of those can be in different places at the whim
 399     dnl of the system integrator. A good summary of this mess
 400     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 401
 402     dnl Classic ndbm with no library required (eg NetBSD): try this
 403     dnl first so we don't accidentally link in a pointless but harmless
 404     dnl library in one of the later ndbm.h+libfoo tests:
 405     NMH_CHECK_NDBM(ndbm.h,,,
 406     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 407       NMH_CHECK_NDBM(db.h,db,,
 408     dnl Berkeley DBv1 emulating ndbm:
 409         NMH_CHECK_NDBM(ndbm.h,db,,
 410           NMH_CHECK_NDBM(ndbm.h,db1,,
 411     dnl Classic ndbm:
 412             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 413     dnl glibc2.1 systems put db1 in a subdir:
 414               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 415     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 416     dnl and possibly needing gbdm_compat library:
 417                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 418                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 419                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 420                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 421
 422   fi
 423 else
 424   dnl We don't really need to check that the user-specified values work,
 425   dnl but it is a convenience to the user to bomb out early rather than
 426   dnl after configure and half the compile process.
 427   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 428 fi
 429
 430 if test "$nmh_ndbm_found" = "no"; then
 431   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 432 else
 433   dnl Now export the lib/header to our makefile/config.h:
 434   if test x"$nmh_ndbmheader" != x; then
 435     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 436       [Define to the header containing the ndbm API prototypes.])
 437   fi
 438   if test x"$nmh_ndbm" != x; then
 439     NDBM_LIBS="-l$nmh_ndbm"
 440   else
 441     NDBM_LIBS=
 442   fi
 443   AC_SUBST([NDBM_LIBS])
 444 fi
 445
 446 dnl ------------------
 447 dnl Set RPM build root
 448 dnl ------------------
 449 dnl nmhrpm is used in the final summary, see below.  The default value is
 450 dnl reported there as ./RPM, consistent with the reporting of the default
 451 dnl source code location as ., but its absolute path is used in the Makefile.
 452 AC_ARG_WITH([rpmdir],
 453   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 454   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 455           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 456 AC_SUBST([rpmdir])
 457
 458
 459 dnl --------------------
 460 dnl CHECK FOR CYRUS-SASL
 461 dnl --------------------
 462
 463 AS_IF([test x"$sasl_support" = x"yes"],[
 464   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 465   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 466     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 467 AC_SUBST([SASLLIB])
 468
 469 dnl -----------------
 470 dnl CHECK FOR OPENSSL
 471 dnl -----------------
 472
 473 AS_IF([test x"$tls_support" = x"yes"],[
 474   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 475   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 476     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 477   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 478     [AC_MSG_ERROR([OpenSSL library not found])])],
 479   [TLSLIB=])
 480 AC_SUBST([TLSLIB])
 481
 482 dnl ---------------------
 483 dnl CHECK TERMCAP LIBRARY
 484 dnl ---------------------
 485
 486 dnl Add the termcap library, so that the following configure
 487 dnl tests will find it when it tries to link test programs.
 488 nmh_save_LIBS="$LIBS"
 489 LIBS="$TERMLIB $LIBS"
 490
 491 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 492 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 493 dnl in tgetstr().
 494 dnl Under Cygwin test program crashes but exit code is still 0. So,
 495 dnl we test for a file that porgram should create
 496 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 497 [Define to 1 if tgetent() accepts NULL as a buffer.])
 498 AC_CACHE_CHECK(if tgetent accepts NULL,
 499 nmh_cv_func_tgetent_accepts_null,
 500 [AC_TRY_RUN([
 501 main()
 502 {
 503     char buf[4096];
 504     int r1 = tgetent(buf, "vt100");
 505     int r2 = tgetent((char*)0,"vt100");
 506     if (r1 >= 0 && r1 == r2) {
 507         char tbuf[1024], *u;
 508         u = tbuf;
 509         tgetstr("cl", &u);
 510         creat("conftest.tgetent", 0640);
 511     }
 512     exit((r1 != r2) || r2 == -1);
 513 }
 514 ],
 515   if test -f conftest.tgetent; then
 516     nmh_cv_func_tgetent_accepts_null=yes
 517   else
 518     nmh_cv_func_tgetent_accepts_null=no
 519   fi,
 520   nmh_cv_func_tgetent_accepts_null=no,
 521   nmh_cv_func_tgetent_accepts_null=no)])
 522 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 523   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 524 fi
 525 AC_CACHE_CHECK(if tgetent returns 0 on success,
 526 nmh_cv_func_tgetent_zero_success,
 527 [AC_TRY_RUN([
 528 main()
 529 {
 530     char buf[4096];
 531     int r1 = tgetent(buf, "!@#$%^&*");
 532     int r2 = tgetent(buf, "vt100");
 533     if (r1 < 0 && r2 == 0) {
 534         char tbuf[1024], *u;
 535         u = tbuf;
 536         tgetstr("cl", &u);
 537         creat("conftest.tgetent0", 0640);
 538     }
 539     exit(r1 == r2);
 540 }
 541 ],
 542   if test -f conftest.tgetent0; then
 543     nmh_cv_func_tgetent_zero_success=yes
 544   else
 545     nmh_cv_func_tgetent_zero_success=no
 546   fi,
 547   nmh_cv_func_tgetent_zero_success=no,
 548   nmh_cv_func_tgetent_zero_success=no)])
 549 AH_TEMPLATE([TGETENT_SUCCESS],
 550 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 551 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 552   AC_DEFINE(TGETENT_SUCCESS, 0)
 553 else
 554   AC_DEFINE(TGETENT_SUCCESS, 1)
 555 fi
 556
 557 dnl Now put the libraries back to what it was before we
 558 dnl starting checking the termcap library.
 559 LIBS="$nmh_save_LIBS"
 560
 561 dnl ----------------
 562 dnl CHECK FLEX FIXUP
 563 dnl ----------------
 564 dnl Use LFLAGS make variable setting to work around bugs in flex
 565 dnl 2.5.35-37 that cause signed/unsigned mismatch,
 566 dnl http://sourceforge.net/p/flex/bugs/140/
 567 AS_IF([test "$LEX" = flex],
 568       [AS_CASE([`$LEX -V`],
 569                [flex\ 2.5.35], [[LFLAGS=\
 570 '; printf "%s\n" '\''1,$$s/(size_t) \(num_to_read\)/\1/'\'' w q | ed -s $@']],
 571                [flex\ 2.5.3@<:@67@:>@], [[LFLAGS=\
 572 '; printf "%s\n" '\''1,$$s/\(   \)int i;/\1yy_size_t i;/'\'' w q | ed -s $@']])
 573        AC_SUBST([LFLAGS])])
 574
 575 dnl --------------
 576 dnl CHECK TYPEDEFS
 577 dnl --------------
 578 AC_TYPE_PID_T
 579 AC_TYPE_OFF_T
 580 AC_TYPE_UID_T
 581 AC_TYPE_MODE_T
 582 AC_TYPE_SIZE_T
 583
 584 dnl ----------------
 585 dnl CHECK STRUCTURES
 586 dnl ----------------
 587
 588 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 589 dnl (FreeBSD has a timezone() function but not a timezone global
 590 dnl variable that is visible).
 591 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 592
 593 AC_STRUCT_DIRENT_D_TYPE
 594
 595 dnl Where is <signal.h> located?  Needed as input for signames.awk
 596 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 597 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 598                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 599                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 600                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 601                  /usr/include/sys/signal.h      dnl Almost everybody else
 602                  /dev/null;                     dnl Just in case we fall through
 603 do
 604   test -f $SIGNAL_H && \
 605   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 606   break
 607 done
 608 nmh_cv_path_signal_h=$SIGNAL_H
 609 ])
 610 SIGNAL_H=$nmh_cv_path_signal_h
 611 AC_SUBST(SIGNAL_H)dnl
 612
 613 dnl
 614 dnl Sigh, this is required because under the new world order autoconf has
 615 dnl nothing to create in a few of the build directories when doing an object
 616 dnl tree build.  So make sure we created certain directories if they don't
 617 dnl exist.
 618 dnl
 619
 620 AC_CONFIG_COMMANDS([build-directories],
 621 [test -d etc || AS_MKDIR_P([etc])
 622 test -d man || AS_MKDIR_P([man])])
 623
 624 AC_CONFIG_COMMANDS_POST([
 625
 626 dnl These odd looking assignments are done to expand out unexpanded
 627 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 628 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 629 dnl again to get the final answer.
 630 dnl We only use the expanded versions to print the install paths in
 631 dnl the final summary and should use them nowhere else (see the autoconf
 632 dnl docs for the rationale for bindir etc being unexpanded).
 633 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 634 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 635 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 636 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 637 eval "nmhrpm=${nmhrpm}";
 638
 639 AC_MSG_NOTICE([
 640 nmh configuration
 641 -----------------
 642 nmh version                : AC_PACKAGE_VERSION
 643 host os                    : ${host}
 644 compiler                   : ${CC}
 645 compiler flags             : ${CFLAGS}
 646 linker flags               : ${LDFLAGS}
 647 preprocessor flags         : ${CPPFLAGS}
 648 source code location       : ${srcdir}
 649 binary install path        : ${nmhbin}
 650 library install path       : ${nmhlib}
 651 config files install path  : ${nmhsysconf}
 652 man page install path      : ${nmhman}
 653 RPM build root             : ${nmhrpm}
 654 backup prefix              : ${backup_prefix}
 655 transport system           : ${MTS}
 656 spool default locking type : ${with_locking}
 657 default smtp servers       : ${smtpservers}
 658 SASL support               : ${sasl_support}
 659 TLS support                : ${tls_support}
 660 ])])dnl
 661
 662 dnl ---------------
 663 dnl OUTPUT MAKEFILE
 664 dnl ---------------
 665 AC_CONFIG_FILES([Makefile test/common.sh])
 666 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 667 AC_OUTPUT