diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want client-side support for using SASL for authentication?
  27 dnl Note that this code will be enabled for both POP and SMTP
  28 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  29   [Enable SASL support via the Cyrus SASL library]))
  30 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != xyes -a \
  31             x"$with_cyrus_sasl" != xno],[
  32   AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  33   AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  34
  35 dnl Do you want client-side support for encryption with TLS?
  36 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  37
  38 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  39 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  40   [Enable OAuth2 support in SMTP auth]))
  41
  42 dnl Set the backup prefix
  43 AC_ARG_WITH([hash-backup],
  44   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  45 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  46       [backup_prefix="#"], [backup_prefix=","])
  47 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  48     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  49
  50 dnl What method of posting should post use?
  51 AC_ARG_WITH([mts],
  52   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  53   [specify the default mail transport agent/service]))
  54
  55 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  56       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  57       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  58       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  59       [MTS="smtp"])
  60 AC_SUBST([MTS])dnl
  61
  62 dnl What should be the default mail server?
  63 AC_ARG_WITH([smtpserver],
  64   [AS_HELP_STRING([--with-smtpserver='SMTPSERVER'],
  65   [specify the default SMTP server @<:@localhost@:>@])])
  66 AS_IF([test -n "$with_smtpserver"], [smtpserver="$with_smtpserver"],
  67       [smtpserver="localhost"])
  68 AC_SUBST([smtpserver])dnl
  69
  70 dnl -------------------------------------------------------------------
  71 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  72 dnl find an existing installation, in which case we use its location.
  73 dnl -------------------------------------------------------------------
  74 AC_PREFIX_DEFAULT([/usr/local/nmh])
  75 AC_PREFIX_PROGRAM([mhparam])
  76
  77 dnl ------------------
  78 dnl CHECK THE COMPILER
  79 dnl ------------------
  80
  81 AC_PROG_CC([cc gcc])
  82 AM_PROG_CC_C_O
  83
  84 dnl ------------------
  85 dnl CHECK HEADER FILES
  86 dnl ------------------
  87
  88 AC_HEADER_TIOCGWINSZ
  89 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
  90                   sys/param.h sys/time.h sys/stream.h])
  91
  92 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
  93   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
  94 [[#if HAVE_SYS_STREAM_H
  95 #  include <sys/stream.h>
  96 #endif
  97 ]])
  98
  99 dnl ---------------
 100 dnl CHECK FUNCTIONS
 101 dnl ---------------
 102 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 103
 104 dnl Use custom getline for platforms that don't have it.
 105 AC_CONFIG_LIBOBJ_DIR([sbr])
 106 AC_REPLACE_FUNCS([getline])
 107
 108 dnl -----------------------
 109 dnl CHECK MULTIBYTE SUPPORT
 110 dnl -----------------------
 111 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 112             "x$ac_cv_header_wctype_h" = "xyes" -a \
 113             "x$ac_cv_func_wcwidth" = "xyes" -a \
 114             "x$ac_cv_func_mbtowc" = "xyes"],
 115       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 116                  [Define to enable support for multibyte character sets.])
 117        MULTIBYTE_ENABLED=1],
 118       [MULTIBYTE_ENABLED=0])
 119 AC_SUBST([MULTIBYTE_ENABLED])
 120
 121 dnl ----------------
 122 dnl CUSTOMIZE CFLAGS
 123 dnl ----------------
 124 dnl The user didn't specify CFLAGS, so customize them.
 125
 126 if test "$GCC" != yes; then
 127   dnl Use -v and some other options with SunStudio cc.  lex produces
 128   dnl code that causes unreachable-statement warnings.  It might be
 129   dnl better to use an autoconf test, except -v will probably succeed
 130   dnl with many other compilers but have different meaning.
 131   AS_CASE([`${CC} -V 2>&1`],
 132           [cc:*\ Sun\ C*], [CFLAGS=\
 133 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 134 fi
 135
 136 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 137                [nmh_saved_cflags="$CFLAGS"
 138                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 139                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 140                CFLAGS="$nmh_saved_cflags"])
 141 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 142
 143 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 144                [nmh_saved_cflags="$CFLAGS"
 145                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 146                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 147                               nmh_cv_has_wextra=no)
 148                CFLAGS="$nmh_saved_cflags"])
 149 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 150
 151 AC_SUBST([AM_CFLAGS])
 152
 153 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 154 dnl MULTIBYTE_ENABLED having already been set.
 155 NMH_ADDL_CPPFLAGS
 156
 157 if test "$GCC" = yes; then
 158   dnl Do this regardless of auto_cflags value.
 159   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 160   dnl gcc 4.1 and later, but only when optimization is enabled.
 161   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 162   dnl If the user configures with a CFLAGS that contains a -O flag
 163   dnl but then removes it a make time, they'll also have to remove
 164   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 165   dnl Use "\ " instead of ' ' or " " for compatiblity with posh.
 166   AS_CASE([$CFLAGS],
 167           [-O|*\ -O|-O[[!0]]*|*\ -O[[!0]]*],
 168           [AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 169 fi
 170
 171 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 172 dnl We do this here rather than in (say) h/mh.h because this macro must
 173 dnl be defined before <stdio.h> is pulled in.
 174 dnl
 175 dnl And while we're here, add the packages tree to the cpp and ld search
 176 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 177 dnl If /usr/ports is installed, we use its idea of where things are installed,
 178 dnl otherwise we assume /usr/local.
 179
 180 AS_IF([test `uname` = FreeBSD],
 181         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 182          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 183                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 184          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 185          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 186          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 187 ])
 188
 189 dnl --------------
 190 dnl CUSTOMIZE LINK
 191 dnl --------------
 192 AS_IF([test `uname` = OpenBSD],
 193       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 194       dnl so that they don't color the waterfall.
 195       [POSTLINK="2>&1 | sed -e \
 196 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 197 AC_SUBST([POSTLINK])
 198
 199 dnl -----------------
 200 dnl CUSTOMIZE LDFLAGS
 201 dnl -----------------
 202 dnl Disable clang complaint about unused -ansi when linking.
 203 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 204                [nmh_cv_has_q_unused_arguments],
 205                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 206                        grep clang >/dev/null`],
 207                       [nmh_saved_ldflags="$LDFLAGS"
 208                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 209                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 210                                          nmh_cv_has_q_unused_arguments=no)
 211                        LDFLAGS="$nmh_saved_ldflags"],
 212                        [nmh_cv_has_q_unused_arguments=no])])
 213 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 214   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 215 AC_SUBST([AM_LDFLAGS])
 216
 217 AC_HEADER_ASSERT
 218
 219 dnl ------------------
 220 dnl CHECK FOR PROGRAMS
 221 dnl ------------------
 222 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 223 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 224 AC_PROG_RANLIB          dnl Check for `ranlib'
 225 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 226 AC_PROG_SED             dnl Check for Posix-compliant sed
 227 AC_PROG_YACC            dnl Check for yacc/bison
 228 AM_PROG_LEX             dnl Check for lex/flex
 229
 230 AM_PROG_AR
 231
 232 dnl Look for `cut'
 233 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 234 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 235
 236 dnl
 237 dnl Check for MD5 program and formatting command
 238 dnl
 239 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 240 AS_CASE(["${MD5SUM}"],
 241         [md5sum], [MD5FMT="cat"],
 242         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 243         [MD5FMT="missing"])
 244 AC_SUBST([MD5FMT])
 245
 246 dnl Look for `ls'
 247 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 248 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 249
 250 dnl See how we get ls to display the owner and the group
 251 AS_IF([test "$lspath" != "no"],
 252   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 253                  [nmh_cv_ls_grpopt],
 254   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 255     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 256     dnl ls, it would seem -l gave us both the user and group.  On this type of
 257     dnl ls, -g makes _only_ the group be displayed (and not the user).
 258     nmh_cv_ls_grpopt="-l"],[
 259     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 260     nmh_cv_ls_grpopt="-lg"])])])
 261
 262 dnl Look for `sendmail'
 263 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 264 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 265
 266 dnl Cygwin FAT filesystems do not support hard links.  So default to
 267 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 268 dnl therefore, this cannot be made into a dynamic test, in order to
 269 dnl support the least common Cygwin denominator.
 270 AS_CASE(["$host_os"],
 271   [cygwin*], [LN=cp],
 272   [LN=ln])
 273 AC_SUBST([LN])
 274
 275 dnl ----------------------------------------------------------
 276 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 277 dnl ----------------------------------------------------------
 278 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 279 [for mailspool in /var/mail        dnl
 280                   /var/spool/mail  dnl
 281                   /usr/spool/mail  dnl
 282                   /dev/null;       dnl Just in case we fall through
 283 do
 284   test -d $mailspool && break
 285 done
 286 nmh_cv_mailspool=$mailspool
 287 ])
 288 mailspool=$nmh_cv_mailspool
 289 AC_SUBST([mailspool])dnl
 290
 291 dnl See whether the mail spool directory is world-writable.
 292 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 293   AC_CACHE_CHECK(whether the mail spool is world-writable,
 294                  nmh_cv_mailspool_world_writable,
 295   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 296     nmh_cv_mailspool_world_writable=no
 297   else
 298     nmh_cv_mailspool_world_writable=yes
 299   fi])
 300 fi
 301
 302 dnl Also, check for liblockfile (as found on Debian systems)
 303 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 304
 305 dnl and whether its companion program dotlockfile is setgid
 306 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 307 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 308   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 309     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 310     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 311         nmh_cv_dotlockfile_setgid=yes
 312       else
 313         nmh_cv_dotlockfile_setgid=no
 314       fi])
 315   fi
 316 fi
 317
 318 dnl Provide a way for distcheck to disable setgid_mail via
 319 dnl DISTCHECK_CONFIGURE_FLAGS.
 320 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 321   [nmh_cv_dotlockfile_setgid=yes])
 322
 323 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 324 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 325 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 326   dnl do we really need both of these?
 327   AC_DEFINE([MAILGROUP],[1],
 328     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 329   SETGID_MAIL=1
 330 fi
 331 AC_SUBST([SETGID_MAIL])dnl
 332
 333 dnl Use ls to see which group owns the mail spool directory.
 334 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 335 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 336 ])
 337 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 338 AC_SUBST([MAIL_SPOOL_GRP])dnl
 339
 340 NMH_MIMETYPEPROC
 341 NMH_MIMEENCODINGPROC
 342
 343 dnl -------------------
 344 dnl CHECK FOR LIBRARIES
 345 dnl -------------------
 346 dnl Checks for network libraries (nsl, socket)
 347 NMH_CHECK_NETLIBS
 348
 349 dnl Check the locking functions supported and what we should use by default
 350 NMH_LOCKING
 351
 352 dnl Check for iconv
 353 NMH_CHECK_ICONV
 354
 355 dnl Check for tputs() callback argument
 356 NMH_TPUTS_PUTC_ARG
 357
 358 termcap_curses_order="termcap curses ncurses"
 359 for lib in $termcap_curses_order; do
 360   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 361 done
 362 AC_SUBST([TERMLIB])dnl
 363 AS_IF([test "x$TERMLIB" = "x"],
 364       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 365 curses or ncurses library or package that you can install?])])
 366
 367 dnl Check for readline support
 368 NMH_READLINE
 369
 370 dnl --------------
 371 dnl CHECK FOR NDBM
 372 dnl --------------
 373
 374 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 375             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 376 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 377             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 378
 379 if test "$nmh_ndbm" = "autodetect"; then
 380   if test "$nmh_ndbmheader" != "autodetect"; then
 381     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 382   else
 383
 384     dnl There are at least four implementations of ndbm, and
 385     dnl several of those can be in different places at the whim
 386     dnl of the system integrator. A good summary of this mess
 387     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 388
 389     dnl Classic ndbm with no library required (eg NetBSD): try this
 390     dnl first so we don't accidentally link in a pointless but harmless
 391     dnl library in one of the later ndbm.h+libfoo tests:
 392     NMH_CHECK_NDBM(ndbm.h,,,
 393     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 394       NMH_CHECK_NDBM(db.h,db,,
 395     dnl Berkeley DBv1 emulating ndbm:
 396         NMH_CHECK_NDBM(ndbm.h,db,,
 397           NMH_CHECK_NDBM(ndbm.h,db1,,
 398     dnl Classic ndbm:
 399             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 400     dnl glibc2.1 systems put db1 in a subdir:
 401               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 402     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 403     dnl and possibly needing gbdm_compat library:
 404                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 405                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 406                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 407     dnl 64-bit Cygwin:
 408                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 409     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 410     dnl need to be explicit:
 411                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 412   fi
 413 else
 414   dnl We don't really need to check that the user-specified values work,
 415   dnl but it is a convenience to the user to bomb out early rather than
 416   dnl after configure and half the compile process.
 417   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 418 fi
 419
 420 if test "$nmh_ndbm_found" = "no"; then
 421   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 422 else
 423   dnl Now export the lib/header to our makefile/config.h:
 424   if test x"$nmh_ndbmheader" != x; then
 425     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 426       [Define to the header containing the ndbm API prototypes.])
 427   fi
 428   if test x"$nmh_ndbm" != x; then
 429     NDBM_LIBS="-l$nmh_ndbm"
 430   else
 431     NDBM_LIBS=
 432   fi
 433   AC_SUBST([NDBM_LIBS])
 434 fi
 435
 436 dnl ------------------
 437 dnl Set RPM build root
 438 dnl ------------------
 439 dnl nmhrpm is used in the final summary, see below.  The default value is
 440 dnl reported there as ./RPM, consistent with the reporting of the default
 441 dnl source code location as ., but its absolute path is used in the Makefile.
 442 AC_ARG_WITH([rpmdir],
 443   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 444   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 445           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 446 AC_SUBST([rpmdir])
 447
 448
 449 dnl --------------------
 450 dnl CHECK FOR CYRUS-SASL
 451 dnl --------------------
 452
 453 AS_IF([test x"$with_cyrus_sasl" != x"no"],[
 454   AC_CHECK_HEADER([sasl/sasl.h], HAVE_SASL_H=1)
 455   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"])])
 456 AC_SUBST([SASLLIB])
 457
 458 dnl -----------------
 459 dnl Enable SASL?
 460 dnl -----------------
 461 dnl By default (with_cyrus_sasl=''), enable SASL if header and lib are found.
 462 dnl If SASL requested (--with-cyrus-sasl with_cyrus_sasl=yes), error if header or lib not found.
 463 dnl If SASL disabled (--without-cyrus-sasl with_cyrus_sasl=no), don't enable it.
 464 sasl_support=no
 465 CYRUS_SASL=0
 466 AC_SUBST([CYRUS_SASL])
 467 AS_IF([test "x$with_cyrus_sasl" = xyes && test "x$HAVE_SASL_H" = x],
 468       [AC_MSG_ERROR([SASL requested but sasl.h not found])],
 469       [test "x$with_cyrus_sasl" = xyes && test "x$SASLLIB" = x],
 470       [AC_MSG_ERROR([SASL requested but Cyrus SASL library not found])],
 471       [test "x$with_cyrus_sasl" != xno && test "x$HAVE_SASL_H" = x1 &&
 472        test "x$SASLLIB" != x],
 473       [AC_DEFINE([CYRUS_SASL], [1],
 474         [Define to use the Cyrus SASL library for authentication of POP and SMTP.])
 475        CYRUS_SASL=1
 476        sasl_support=yes])
 477
 478 dnl -----------------
 479 dnl CHECK FOR OPENSSL
 480 dnl -----------------
 481
 482 AS_IF([test x"$with_tls" != x"no"],[
 483   dnl OpenBSD 5 needs the other-libraries (fifth argument) to the
 484   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 485   dnl automatically append -lcrypto when linking with -lssl.
 486   AC_CHECK_HEADER([openssl/ssl.h], HAVE_SSL_H=1)
 487   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"])
 488   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"], [TLSLIB=],
 489                [$TLSLIB])])
 490 AC_SUBST([TLSLIB])
 491
 492 dnl -----------------
 493 dnl Enable TLS?
 494 dnl -----------------
 495 dnl By default (with_tls=''), enable TLS if header and libs were found.
 496 dnl If TLS requested (--with-tls with_tls=yes), error if header/lib not found.
 497 dnl If TLS disabled (--without-tls with_tls=no), don't enable it.
 498 tls_support=no
 499 TLS_SUPPORT=0
 500 AC_SUBST([TLS_SUPPORT])
 501 AS_IF([test "x$with_tls" = xyes && test "x$HAVE_SSL_H" = x],
 502       [AC_MSG_ERROR([TLS requested but openssl/ssl.h not found])],
 503       [test "x$with_tls" = xyes && test "x$TLSLIB" = x],
 504       [AC_MSG_ERROR([TLS requested but crypto or ssl library not found])],
 505       [test "x$with_tls" != xno && test "x$HAVE_SSL_H" = x1 && test "x$TLSLIB" != x],
 506       [AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])
 507        TLS_SUPPORT=1
 508        tls_support=yes
 509        save_LIBS="$LIBS"
 510        LIBS="$LIBS $TLSLIB"
 511        AC_CHECK_FUNCS([X509_VERIFY_PARAM_set1_host])
 512        LIBS="$save_LIBS"])
 513
 514 dnl -----------------
 515 dnl CHECK FOR CURL
 516 dnl -----------------
 517 dnl Look for curl if oauth not disabled (--without-oauth).
 518 AC_PATH_PROG([curl_config], [curl-config])
 519 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 520     save_CFLAGS="$CFLAGS"
 521     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 522     AC_CHECK_HEADER([curl/curl.h], [
 523         HAVE_CURL_H=1
 524         AC_CHECK_LIB([curl], [curl_easy_init], [
 525             CURLLIB="`$curl_config --libs`"
 526             AC_SUBST([CURLLIB])
 527             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 528             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 529                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 530                    CURL_USER_AGENT=libcurl/UNKNOWN])
 531             AC_SUBST([CURL_USER_AGENT])
 532           ])
 533       ])
 534     CFLAGS="$save_CFLAGS"
 535   ])
 536
 537 dnl -----------------
 538 dnl Enable OAuth?
 539 dnl -----------------
 540 dnl By default (with_oauth=''), enable OAuth if curl is found.
 541 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 542 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 543 oauth_support=no
 544 OAUTH_SUPPORT=0
 545 AC_SUBST([OAUTH_SUPPORT])
 546 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 547       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 548       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 549       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 550       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 551       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 552        OAUTH_SUPPORT=1
 553        oauth_support=yes])
 554
 555 dnl ----------------
 556 dnl CHECK FLEX FIXUP
 557 dnl ----------------
 558 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 559 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 560 dnl http://sourceforge.net/p/flex/bugs/140/
 561 dnl 2.6.1 bug: https://github.com/westes/flex/issues/97
 562 AS_IF([test "$LEX" = flex],
 563       [AS_CASE([`$LEX -V`],
 564                [flex\ 2.5.35], [AM_LFLAGS=\
 565 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 566                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 567 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 568                [flex\ 2.6.0], [AM_LFLAGS=\
 569 '; sed "s/, num_to_read/, (size_t) num_to_read/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 570                [flex\ 2.6.1], [AM_LFLAGS=\
 571 '; sed '\''/\<int num_to_read\>/s/int/size_t/; \
 572                 s/\<yy_size_t i\>/int i/; \
 573                 s/int n; \\/yy_size_t n; \\/'\'' $@ >$@.tmp && mv -f $@.tmp $@;'])
 574        AC_SUBST([AM_LFLAGS])])
 575
 576 dnl ------------------
 577 dnl FOR INTERNAL USE by the NMH test suite
 578 dnl ------------------
 579 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 580 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 581       AC_SUBST([nmhetcdirinst]))
 582
 583 dnl ----------------
 584 dnl CHECK STRUCTURES
 585 dnl ----------------
 586
 587 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 588 dnl (FreeBSD has a timezone() function but not a timezone global
 589 dnl variable that is visible).
 590 dnl On Linux, $AM_CPPFLAGS contains -D_GNU_SOURCE, which makes
 591 dnl tm_gmtoff visible.
 592 nmh_saved_CPPFLAGS="$CPPFLAGS"
 593 CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 594 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[[#include <time.h>]])
 595 CPPFLAGS="$nmh_saved_CPPFLAGS"
 596
 597 AC_STRUCT_DIRENT_D_TYPE
 598
 599 dnl
 600 dnl Sigh, this is required because under the new world order autoconf has
 601 dnl nothing to create in a few of the build directories when doing an object
 602 dnl tree build.  So make sure we created certain directories if they don't
 603 dnl exist.
 604 dnl
 605
 606 AC_CONFIG_COMMANDS([build-directories],
 607 [test -d man || AS_MKDIR_P([man])])
 608
 609 AC_CONFIG_COMMANDS_POST([
 610
 611 dnl These odd looking assignments are done to expand out unexpanded
 612 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 613 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 614 dnl again to get the final answer.
 615 dnl We only use the expanded versions to print the install paths in
 616 dnl the final summary and should use them nowhere else (see the autoconf
 617 dnl docs for the rationale for bindir etc being unexpanded).
 618 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 619 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 620 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 621 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 622 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 623 eval "nmhrpm=${nmhrpm}";
 624
 625 AC_MSG_NOTICE([
 626 nmh configuration
 627 -----------------
 628 nmh version                : AC_PACKAGE_VERSION
 629 host os                    : ${host}
 630 compiler                   : ${CC}
 631 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 632 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 633 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 634 source code location       : ${srcdir}
 635 binary install path        : ${nmhbin}
 636 libexec install path       : ${nmhlibexec}/nmh
 637 config files install path  : ${nmhsysconf}/nmh
 638 man page install path      : ${nmhman}
 639 docs install path          : ${nmhdoc}
 640 RPM build root             : ${nmhrpm}
 641 backup prefix              : ${backup_prefix}
 642 transport system           : ${MTS}
 643 spool default locking type : ${with_locking}
 644 default smtp server        : ${smtpserver}
 645 SASL support               : ${sasl_support}
 646 TLS support                : ${tls_support}
 647 OAuth support              : ${oauth_support}
 648 ])])dnl
 649
 650 dnl ---------------
 651 dnl OUTPUT MAKEFILE
 652 dnl ---------------
 653 AC_CONFIG_FILES([Makefile test/common.sh])
 654 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 655 AC_OUTPUT