diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*|openbsd*|darwin*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
 119       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
 120       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
 121       [MTS="smtp"])
 122 AC_SUBST([MTS])dnl
 123
 124 dnl What should be the default pager?
 125 AC_ARG_WITH([pager],
 126   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 127
 128 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 129
 130 dnl If a pager is not explicitly specified, then look for one.
 131 dnl Fall back to `cat', to avoid catastrophic failure of
 132 dnl `mhshow', et al., if pagerpath is set to `no'.
 133 if test -z "$pagerpath"; then
 134   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 135   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 136 fi
 137 AC_SUBST(pagerpath)dnl
 138
 139 dnl What should be the default mail server(s)?
 140 AC_ARG_WITH(smtpservers,
 141   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 142   [specify the default SMTP server(s) @<:@localhost@:>@]))
 143 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 144       [smtpservers="localhost"])
 145 AC_SUBST([smtpservers])dnl
 146
 147 dnl ----------------------------------------------------
 148 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 149 dnl ----------------------------------------------------
 150 AC_PREFIX_DEFAULT([/usr/local/nmh])
 151
 152 dnl ------------------
 153 dnl CHECK THE COMPILER
 154 dnl ------------------
 155 dnl We want these before the checks,
 156 dnl so the checks can modify their values.
 157 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 158 if test x"$enable_debug" = x"yes"; then
 159   test -z "$LDFLAGS" && LDFLAGS=-g
 160 fi
 161
 162 AC_PROG_CC
 163 AM_PROG_CC_C_O
 164
 165 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 166   [nmh_cv_has_unusedmacros],
 167   [nmh_saved_cppflags="$CPPFLAGS"
 168    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 169    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 170    CPPFLAGS="$nmh_saved_cppflags"])
 171
 172 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 173   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 174                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 175   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 176 fi
 177 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 178
 179 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 180   [nmh_cv_has_nosigncompare],
 181   [nmh_saved_cppflags="$CPPFLAGS"
 182    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 183    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 184                   nmh_cv_has_nosigncompare=no)
 185    CPPFLAGS="$nmh_saved_cppflags"])
 186
 187 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 188   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 189 fi
 190 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 191
 192 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 193 [nmh_saved_cflags="$CFLAGS"
 194  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 195  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 196  CFLAGS="$nmh_saved_cflags"])
 197
 198 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 199 [nmh_saved_cflags="$CFLAGS"
 200  CFLAGS="$CFLAGS -Wno-pointer-sign"
 201  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 202  CFLAGS="$nmh_saved_cflags"])
 203
 204 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 205 dnl setup version 2.763, because it disables some features in the
 206 dnl system system header files and warns about them with -Wall.  Try
 207 dnl to test for that generally, though still with gcc.
 208 if test "$GCC" = yes; then
 209   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 210     [nmh_saved_cppflags="$CPPFLAGS"
 211      nmh_saved_cflags="$CFLAGS"
 212      CPPFLAGS="-D_GNU_SOURCE"
 213      CFLAGS="-ansi -Wall -Werror"
 214      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 215        [nmh_cv_has_dash_ansi=yes],
 216        [nmh_cv_has_dash_ansi=no])
 217      CPPFLAGS="$nmh_saved_cppflags"
 218      CFLAGS="$nmh_saved_cflags"])
 219 else
 220   nmh_cv_has_dash_ansi=no
 221 fi
 222
 223 dnl if the user hasn't specified CFLAGS, then
 224 dnl   if compiler is gcc, then
 225 dnl    use -O2 and some warning flags
 226 dnl   else use -O
 227 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 228 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 229 dnl warnings which are probably mostly spurious and which in any case we
 230 dnl don't want to deal with now.
 231 if test "$nmh_cv_has_noptrsign" = "yes"; then
 232     if test "$nmh_cv_has_dash_ansi" = "yes"; then
 233         nmh_gcc_common_flags="-ansi -pedantic -Wall"
 234     else
 235         nmh_gcc_common_flags="-Wall"
 236     fi
 237     if test "$nmh_cv_has_wextra" = "yes"; then
 238         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 239 "-Wno-pointer-sign"
 240     else
 241         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 242     fi
 243 else
 244     if test "$nmh_cv_has_wextra" = "yes"; then
 245         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 246     else
 247         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 248     fi
 249 fi
 250
 251 if test -n "$auto_cflags"; then
 252   if test x"$enable_debug" = x"yes"; then
 253     if test -n "$GCC"; then
 254       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 255     else
 256       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 257     fi
 258   else
 259     if test -z "$LDFLAGS"; then
 260       case "$build_os" in
 261         darwin*)
 262           LDFLAGS=
 263           ;;
 264         *)
 265           LDFLAGS=-s
 266           ;;
 267       esac
 268     fi
 269     if test -n "$GCC"; then
 270       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 271     else
 272       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 273     fi
 274   fi
 275 fi
 276
 277 AC_C_CONST              dnl Does compiler support `const'.
 278
 279 dnl ------------------
 280 dnl CHECK FOR PROGRAMS
 281 dnl ------------------
 282 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 283 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 284 AC_PROG_RANLIB          dnl Check for `ranlib'
 285 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 286 AC_PROG_SED             dnl Check for Posix-compliant sed
 287 AC_PROG_LEX             dnl Check for lex/flex
 288
 289 dnl Look for `cut'
 290 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 291 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 292
 293 dnl
 294 dnl Check for MD5 program and formatting command
 295 dnl
 296 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 297 AS_CASE(["${MD5SUM}"],
 298         [md5sum], [MD5FMT="cat"],
 299         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 300         [MD5FMT="missing"])
 301 AC_SUBST([MD5FMT])
 302
 303 dnl ----------------------------------------------
 304 dnl check for lclint, and lint if it doesn't exist
 305 dnl ----------------------------------------------
 306 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 307 if test x$ac_cv_prog_linttmp1 != xno ; then
 308   LINT=$ac_cv_prog_linttmp1
 309   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 310 else
 311   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 312   if test x$ac_cv_prog_linttmp2 != xno ; then
 313     LINT=$ac_cv_prog_linttmp2
 314     LINTFLAGS=""
 315   else
 316     LINT="echo 'No lint program found'"
 317     LINTFLAGS=""
 318   fi
 319 fi
 320 AC_SUBST([LINT])dnl
 321 AC_SUBST([LINTFLAGS])dnl
 322
 323 dnl Look for `ls'
 324 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 325 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 326
 327 dnl See how we get ls to display the owner and the group
 328 if test "$lspath" != "no"; then
 329   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 330                  [nmh_cv_ls_grpopt],
 331   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 332     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 333     dnl ls, it would seem -l gave us both the user and group.  On this type of
 334     dnl ls, -g makes _only_ the group be displayed (and not the user).
 335     nmh_cv_ls_grpopt="-l"
 336   else
 337     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 338     nmh_cv_ls_grpopt="-lg"
 339   fi])
 340 fi
 341
 342 dnl Look for `sendmail'
 343 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 344 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 345
 346 dnl Look for `vi'
 347 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 348 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 349
 350 dnl If editor is not specified yet,
 351 dnl then use `vi' as the default.
 352 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 353 AC_SUBST([editorpath])dnl
 354
 355 dnl Cygwin FAT filesystems do not support hard links.  So default to
 356 dnl cp instead, even if running on an NTFS or other filesystem.
 357 AS_CASE(["$host_os"],
 358   [cygwin*],[LN=cp],
 359   [LN=ln])
 360 AC_SUBST([LN])
 361
 362 dnl ----------------------------------------------------------
 363 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 364 dnl ----------------------------------------------------------
 365 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 366 [for mailspool in /var/mail        dnl
 367                   /var/spool/mail  dnl
 368                   /usr/spool/mail  dnl
 369                   /dev/null;       dnl Just in case we fall through
 370 do
 371   test -d $mailspool && break
 372 done
 373 nmh_cv_mailspool=$mailspool
 374 ])
 375 mailspool=$nmh_cv_mailspool
 376 AC_SUBST([mailspool])dnl
 377
 378 dnl See whether the mail spool directory is world-writable.
 379 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 380   AC_CACHE_CHECK(whether the mail spool is world-writable,
 381                  nmh_cv_mailspool_world_writable,
 382   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 383     nmh_cv_mailspool_world_writable=no
 384   else
 385     nmh_cv_mailspool_world_writable=yes
 386   fi])
 387 fi
 388
 389 dnl Also, check for liblockfile (as found on Debian systems)
 390 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 391
 392 dnl and whether its companion program dotlockfile is setgid
 393 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 394 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 395   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 396     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 397     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 398         nmh_cv_dotlockfile_setgid=yes
 399       else
 400         nmh_cv_dotlockfile_setgid=no
 401       fi])
 402   fi
 403 fi
 404
 405 dnl Provide a way for distcheck to disable setgid_mail via
 406 dnl DISTCHECK_CONFIGURE_FLAGS.
 407 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 408   nmh_cv_dotlockfile_setgid=yes
 409 fi
 410
 411 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 412 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 413 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 414   dnl do we really need both of these?
 415   AC_DEFINE(MAILGROUP,1,
 416     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 417   SETGID_MAIL=1
 418 fi
 419 AC_SUBST(SETGID_MAIL)dnl
 420
 421 dnl Use ls to see which group owns the mail spool directory.
 422 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 423 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 424 ])
 425 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 426 AC_SUBST(MAIL_SPOOL_GRP)dnl
 427
 428 dnl ------------------
 429 dnl CHECK HEADER FILES
 430 dnl ------------------
 431
 432 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 433 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 434 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 435 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 436 dnl declared; if so they should have an entry added to this case statement.
 437 dnl NB that we must define this on the compiler command line, not in config.h,
 438 dnl because it must be set before any system header is included and there's no
 439 dnl portable way to make sure that files generated by lex include config.h
 440 dnl before system header files.
 441
 442 AS_CASE(["$host_os"],
 443         [linux*],
 444         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 445           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 446                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 447
 448 AC_HEADER_STDC
 449 AC_HEADER_TIOCGWINSZ
 450 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 451                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 452                   sys/param.h sys/time.h sys/stream.h])
 453
 454 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 455   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 456 [[#if HAVE_SYS_STREAM_H
 457 #  include <sys/stream.h>
 458 #endif
 459 ]])
 460
 461 dnl ---------------
 462 dnl CHECK FUNCTIONS
 463 dnl ---------------
 464 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 465
 466 dnl Check for multibyte character set support
 467 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 468             "x$ac_cv_header_wctype_h" = "xyes" -a \
 469             "x$ac_cv_func_wcwidth" = "xyes" -a \
 470             "x$ac_cv_func_mbtowc" = "xyes"],
 471       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 472                  [Define to enable support for multibyte character sets.])
 473        MULTIBYTE_ENABLED=1],
 474       [MULTIBYTE_ENABLED=0])
 475 AC_SUBST([MULTIBYTE_ENABLED])
 476
 477 dnl -------------------
 478 dnl CHECK FOR LIBRARIES
 479 dnl -------------------
 480 dnl Check location of modf
 481 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 482
 483 dnl Checks for network libraries (nsl, socket)
 484 NMH_CHECK_NETLIBS
 485
 486 NMH_READLINE
 487
 488 termcap_curses_order="termcap curses ncurses"
 489 for lib in $termcap_curses_order; do
 490   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 491 done
 492 AC_SUBST([TERMLIB])dnl
 493 AS_IF([test "x$TERMLIB" = "x"],
 494       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 495 or ncurses library or package that you can install?])])
 496
 497
 498 dnl ---------------
 499 dnl CHECK FOR ICONV
 500 dnl ---------------
 501
 502 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 503 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 504   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 505   if test "x$ac_found_iconv" = "xno"; then
 506     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 507     if test "x$ac_found_iconv" = "xno"; then
 508       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 509     fi
 510     if test "x$ac_found_iconv" != "xno"; then
 511       ICONVLIB="-liconv"
 512     fi
 513   else
 514     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 515     AC_CHECK_DECL(_libiconv_version,
 516       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 517       [ #include <iconv.h> ])
 518   fi
 519 fi
 520 if test "x$ac_found_iconv" = xyes; then
 521   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 522 fi
 523 AC_SUBST([ICONVLIB])
 524
 525 dnl Check if iconv uses const in prototype declaration
 526 if test "x$ac_found_iconv" = "xyes"; then
 527   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 528     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 529         #include <iconv.h>]],
 530         [[#ifdef __cplusplus
 531           "C"
 532           #endif
 533           #if defined(__STDC__) || defined(__cplusplus)
 534           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 535           #else
 536           size_t iconv();
 537           #endif]])],
 538       [ac_cv_iconv_const=],
 539       [ac_cv_iconv_const=const])])
 540   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 541     [Define as const if the declaration of iconv() needs const.])
 542 fi
 543
 544 dnl --------------
 545 dnl CHECK FOR NDBM
 546 dnl --------------
 547
 548 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 549             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 550 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 551             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 552
 553 if test "$nmh_ndbm" = "autodetect"; then
 554   if test "$nmh_ndbmheader" != "autodetect"; then
 555     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 556   else
 557
 558     dnl There are at least four implementations of ndbm, and
 559     dnl several of those can be in different places at the whim
 560     dnl of the system integrator. A good summary of this mess
 561     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 562
 563     dnl Classic ndbm with no library required (eg NetBSD): try this
 564     dnl first so we don't accidentally link in a pointless but harmless
 565     dnl library in one of the later ndbm.h+libfoo tests:
 566     NMH_CHECK_NDBM(ndbm.h,,,
 567     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 568       NMH_CHECK_NDBM(db.h,db,,
 569     dnl Berkeley DBv1 emulating ndbm:
 570         NMH_CHECK_NDBM(ndbm.h,db,,
 571           NMH_CHECK_NDBM(ndbm.h,db1,,
 572     dnl Classic ndbm:
 573             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 574     dnl glibc2.1 systems put db1 in a subdir:
 575               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 576     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 577     dnl and possibly needing gbdm_compat library:
 578                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 579                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 580                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 581                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 582
 583   fi
 584 else
 585   dnl We don't really need to check that the user-specified values work,
 586   dnl but it is a convenience to the user to bomb out early rather than
 587   dnl after configure and half the compile process.
 588   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 589 fi
 590
 591 if test "$nmh_ndbm_found" = "no"; then
 592   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 593 else
 594   dnl Now export the lib/header to our makefile/config.h:
 595   if test x"$nmh_ndbmheader" != x; then
 596     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 597       [Define to the header containing the ndbm API prototypes.])
 598   fi
 599   if test x"$nmh_ndbm" != x; then
 600     NDBM_LIBS="-l$nmh_ndbm"
 601   else
 602     NDBM_LIBS=
 603   fi
 604   AC_SUBST([NDBM_LIBS])
 605 fi
 606
 607 dnl ------------------
 608 dnl Set RPM build root
 609 dnl ------------------
 610 dnl nmhrpm is used in the final summary, see below.  The default value is
 611 dnl reported there as ./RPM, consistent with the reporting of the default
 612 dnl source code location as ., but its absolute path is used in the Makefile.
 613 AC_ARG_WITH(rpmdir,
 614   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 615   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 616           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 617 AC_SUBST([rpmdir])
 618
 619
 620 dnl --------------------
 621 dnl CHECK FOR CYRUS-SASL
 622 dnl --------------------
 623
 624 AS_IF([test x"$sasl_support" = x"yes"],[
 625   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 626   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 627     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 628 AC_SUBST([SASLLIB])
 629
 630 dnl -----------------
 631 dnl CHECK FOR OPENSSL
 632 dnl -----------------
 633
 634 AS_IF([test x"$tls_support" = x"yes"],[
 635   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 636   AC_CHECK_LIB([crypto], [BIO_write], ,
 637     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 638   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 639     [AC_MSG_ERROR([OpenSSL library not found])])])
 640
 641 dnl ---------------------
 642 dnl CHECK TERMCAP LIBRARY
 643 dnl ---------------------
 644
 645 dnl Add the termcap library, so that the following configure
 646 dnl tests will find it when it tries to link test programs.
 647 nmh_save_LIBS="$LIBS"
 648 LIBS="$TERMLIB $LIBS"
 649
 650 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 651 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 652 dnl in tgetstr().
 653 dnl Under Cygwin test program crashes but exit code is still 0. So,
 654 dnl we test for a file that porgram should create
 655 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 656 [Define to 1 if tgetent() accepts NULL as a buffer.])
 657 AC_CACHE_CHECK(if tgetent accepts NULL,
 658 nmh_cv_func_tgetent_accepts_null,
 659 [AC_TRY_RUN([
 660 main()
 661 {
 662     char buf[4096];
 663     int r1 = tgetent(buf, "vt100");
 664     int r2 = tgetent((char*)0,"vt100");
 665     if (r1 >= 0 && r1 == r2) {
 666         char tbuf[1024], *u;
 667         u = tbuf;
 668         tgetstr("cl", &u);
 669         creat("conftest.tgetent", 0640);
 670     }
 671     exit((r1 != r2) || r2 == -1);
 672 }
 673 ],
 674   if test -f conftest.tgetent; then
 675     nmh_cv_func_tgetent_accepts_null=yes
 676   else
 677     nmh_cv_func_tgetent_accepts_null=no
 678   fi,
 679   nmh_cv_func_tgetent_accepts_null=no,
 680   nmh_cv_func_tgetent_accepts_null=no)])
 681 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 682   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 683 fi
 684 AC_CACHE_CHECK(if tgetent returns 0 on success,
 685 nmh_cv_func_tgetent_zero_success,
 686 [AC_TRY_RUN([
 687 main()
 688 {
 689     char buf[4096];
 690     int r1 = tgetent(buf, "!@#$%^&*");
 691     int r2 = tgetent(buf, "vt100");
 692     if (r1 < 0 && r2 == 0) {
 693         char tbuf[1024], *u;
 694         u = tbuf;
 695         tgetstr("cl", &u);
 696         creat("conftest.tgetent0", 0640);
 697     }
 698     exit(r1 == r2);
 699 }
 700 ],
 701   if test -f conftest.tgetent0; then
 702     nmh_cv_func_tgetent_zero_success=yes
 703   else
 704     nmh_cv_func_tgetent_zero_success=no
 705   fi,
 706   nmh_cv_func_tgetent_zero_success=no,
 707   nmh_cv_func_tgetent_zero_success=no)])
 708 AH_TEMPLATE([TGETENT_SUCCESS],
 709 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 710 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 711   AC_DEFINE(TGETENT_SUCCESS, 0)
 712 else
 713   AC_DEFINE(TGETENT_SUCCESS, 1)
 714 fi
 715
 716 dnl Now put the libraries back to what it was before we
 717 dnl starting checking the termcap library.
 718 LIBS="$nmh_save_LIBS"
 719
 720 dnl --------------
 721 dnl CHECK TYPEDEFS
 722 dnl --------------
 723 AC_TYPE_PID_T
 724 AC_TYPE_OFF_T
 725 AC_TYPE_UID_T
 726 AC_TYPE_MODE_T
 727 AC_TYPE_SIZE_T
 728
 729 dnl ----------------
 730 dnl CHECK STRUCTURES
 731 dnl ----------------
 732
 733 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 734 dnl (FreeBSD has a timezone() function but not a timezone global
 735 dnl variable that is visible).
 736 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 737
 738 AC_STRUCT_DIRENT_D_TYPE
 739
 740 dnl Where is <signal.h> located?  Needed as input for signames.awk
 741 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 742 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 743                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 744                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 745                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 746                  /usr/include/sys/signal.h      dnl Almost everybody else
 747                  /dev/null;                     dnl Just in case we fall through
 748 do
 749   test -f $SIGNAL_H && \
 750   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 751   break
 752 done
 753 nmh_cv_path_signal_h=$SIGNAL_H
 754 ])
 755 SIGNAL_H=$nmh_cv_path_signal_h
 756 AC_SUBST(SIGNAL_H)dnl
 757
 758 dnl
 759 dnl Sigh, this is required because under the new world order autoconf has
 760 dnl nothing to create in a few of the build directories when doing an object
 761 dnl tree build.  So make sure we created certain directories if they don't
 762 dnl exist.
 763 dnl
 764
 765 AC_CONFIG_COMMANDS([build-directories],
 766 [test -d etc || ${MKDIR_P} etc
 767 test -d man || ${MKDIR_P} man])
 768
 769 AC_CONFIG_COMMANDS_POST([
 770
 771 dnl These odd looking assignments are done to expand out unexpanded
 772 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 773 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 774 dnl again to get the final answer.
 775 dnl We only use the expanded versions to print the install paths in
 776 dnl the final summary and should use them nowhere else (see the autoconf
 777 dnl docs for the rationale for bindir etc being unexpanded).
 778 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 779 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 780 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 781 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 782 eval "nmhrpm=${nmhrpm}";
 783
 784 AC_MSG_NOTICE([
 785 nmh configuration
 786 -----------------
 787 nmh version                : AC_PACKAGE_VERSION
 788 host os                    : ${host}
 789 compiler                   : ${CC}
 790 compiler flags             : ${CFLAGS}
 791 linker flags               : ${LDFLAGS}
 792 preprocessor flags         : ${CPPFLAGS}
 793 source code location       : ${srcdir}
 794 binary install path        : ${nmhbin}
 795 library install path       : ${nmhlib}
 796 config files install path  : ${nmhsysconf}
 797 man page install path      : ${nmhman}
 798 RPM build root             : ${nmhrpm}
 799 backup prefix              : ${backup_prefix}
 800 transport system           : ${MTS}
 801 file locking type          : ${LOCKTYPE}
 802 default smtp servers       : ${smtpservers}
 803 default editor             : ${editorpath}
 804 default pager              : ${pagerpath}
 805 SASL support               : ${sasl_support}
 806 TLS support                : ${tls_support}
 807 ])])dnl
 808
 809 dnl ---------------
 810 dnl OUTPUT MAKEFILE
 811 dnl ---------------
 812 AC_CONFIG_FILES([Makefile test/common.sh])
 813 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 814 AC_OUTPUT