diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl -------------------------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  79 dnl find an existing installation, in which case we use its location.
  80 dnl -------------------------------------------------------------------
  81 AC_PREFIX_DEFAULT([/usr/local/nmh])
  82 AC_PREFIX_PROGRAM([mhparam])
  83
  84 dnl ------------------
  85 dnl CHECK THE COMPILER
  86 dnl ------------------
  87 dnl We want these before the checks,
  88 dnl so the checks can modify their values.
  89 test -z "$CFLAGS"  &&  auto_cflags=1
  90
  91 AC_PROG_CC([cc gcc])
  92 AM_PROG_CC_C_O
  93
  94 dnl ----------------
  95 dnl CUSTOMIZE CFLAGS
  96 dnl ----------------
  97 if test -n "$auto_cflags"; then
  98   dnl The user didn't specify CFLAGS, so customize them.
  99   if test "$GCC" = yes; then
 100     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 101     dnl version 2.763, because it disables some features in the system
 102     dnl header files and warns about them with -Wall.  Try to test for
 103     dnl that generally, with gcc.
 104     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 105       [nmh_saved_cppflags="$CPPFLAGS"
 106        nmh_saved_cflags="$CFLAGS"
 107        CPPFLAGS="-D_GNU_SOURCE"
 108        CFLAGS="-ansi -Wall -Werror"
 109        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 110          [nmh_cv_has_dash_ansi=yes],
 111          [nmh_cv_has_dash_ansi=no])
 112        CPPFLAGS="$nmh_saved_cppflags"
 113        CFLAGS="$nmh_saved_cflags"])
 114     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 115       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 116   else
 117     dnl Use -v and some other options with SunStudio cc.  lex produces
 118     dnl code that causes unreachable-statement warnings.  It might be
 119     dnl better to use an autoconf test, except -v will probably succeed
 120     dnl with many other compilers but have different meaning.
 121     AS_CASE([`${CC} -V 2>&1`],
 122             [cc:\ Sun\ C*], [CFLAGS=\
 123 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 124   fi
 125
 126   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 127                  [nmh_saved_cflags="$CFLAGS"
 128                  CFLAGS="$CFLAGS -Wall -Werror"
 129                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 130                  CFLAGS="$nmh_saved_cflags"])
 131   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 132
 133   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 134                  [nmh_saved_cflags="$CFLAGS"
 135                  CFLAGS="$CFLAGS -Wextra -Werror"
 136                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 137                                 nmh_cv_has_wextra=no)
 138                  CFLAGS="$nmh_saved_cflags"])
 139   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 140 fi
 141
 142 if test "$GCC" = yes; then
 143   dnl Do this regardless of auto_cflags value.
 144   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 145   dnl gcc 4.1 and later, but only when optimization is enabled.
 146   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 147   dnl If the user configures with a CFLAGS that contains a -O flag
 148   dnl but then removes it a make time, they'll also have to remove
 149   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 150   AS_CASE([$CFLAGS],
 151           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 152 fi
 153
 154 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 155 dnl We do this here rather than in (say) h/mh.h because this macro must
 156 dnl be defined before <stdio.h> is pulled in.
 157 dnl
 158 dnl And while we're here, add the packages tree to the cpp and ld search
 159 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 160 dnl If /usr/ports is installed, we use its idea of where things are installed,
 161 dnl otherwise we assume /usr/local.
 162
 163 AS_IF([test `uname` = FreeBSD],
 164         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 165          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 166                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 167          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 168          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 169          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 170 ])
 171
 172 dnl --------------
 173 dnl CUSTOMIZE LINK
 174 dnl --------------
 175 AS_IF([test `uname` = OpenBSD],
 176       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 177       dnl so that they don't color the waterfall.
 178       [POSTLINK="2>&1 | sed -e \
 179 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 180 AC_SUBST([POSTLINK])
 181
 182 dnl -----------------
 183 dnl CUSTOMIZE LDFLAGS
 184 dnl -----------------
 185 dnl Disable clang complaint about unused -ansi when linking.
 186 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 187                [nmh_cv_has_q_unused_arguments],
 188                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 189                        grep clang >/dev/null`],
 190                       [nmh_saved_ldflags="$LDFLAGS"
 191                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 192                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 193                                          nmh_cv_has_q_unused_arguments=no)
 194                        LDFLAGS="$nmh_saved_ldflags"],
 195                        [nmh_cv_has_q_unused_arguments=no])])
 196 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 197   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 198
 199 dnl This hack turns off assertions by default, assuming
 200 dnl that configure still uses this shell variable.  Without
 201 dnl it, AC_HEADER_ASSERT enables assertions by default.
 202 test -z "$enable_assert"  &&  enable_assert=no
 203
 204 AC_HEADER_ASSERT
 205
 206 dnl ------------------
 207 dnl CHECK FOR PROGRAMS
 208 dnl ------------------
 209 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 210 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 211 AC_PROG_RANLIB          dnl Check for `ranlib'
 212 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 213 AC_PROG_SED             dnl Check for Posix-compliant sed
 214 AM_PROG_LEX             dnl Check for lex/flex
 215
 216 AM_PROG_AR
 217
 218 dnl Look for `cut'
 219 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 220 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 221
 222 dnl
 223 dnl Check for MD5 program and formatting command
 224 dnl
 225 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 226 AS_CASE(["${MD5SUM}"],
 227         [md5sum], [MD5FMT="cat"],
 228         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 229         [MD5FMT="missing"])
 230 AC_SUBST([MD5FMT])
 231
 232 dnl Look for `ls'
 233 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 234 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 235
 236 dnl See how we get ls to display the owner and the group
 237 AS_IF([test "$lspath" != "no"],
 238   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 239                  [nmh_cv_ls_grpopt],
 240   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 241     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 242     dnl ls, it would seem -l gave us both the user and group.  On this type of
 243     dnl ls, -g makes _only_ the group be displayed (and not the user).
 244     nmh_cv_ls_grpopt="-l"],[
 245     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 246     nmh_cv_ls_grpopt="-lg"])])])
 247
 248 dnl Look for `sendmail'
 249 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 250 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 251
 252 dnl Cygwin FAT filesystems do not support hard links.  So default to
 253 dnl cp instead, even if running on an NTFS or other filesystem.
 254 AS_CASE(["$host_os"],
 255   [cygwin*], [LN=cp],
 256   [LN=ln])
 257 AC_SUBST([LN])
 258
 259 dnl ----------------------------------------------------------
 260 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 261 dnl ----------------------------------------------------------
 262 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 263 [for mailspool in /var/mail        dnl
 264                   /var/spool/mail  dnl
 265                   /usr/spool/mail  dnl
 266                   /dev/null;       dnl Just in case we fall through
 267 do
 268   test -d $mailspool && break
 269 done
 270 nmh_cv_mailspool=$mailspool
 271 ])
 272 mailspool=$nmh_cv_mailspool
 273 AC_SUBST([mailspool])dnl
 274
 275 dnl See whether the mail spool directory is world-writable.
 276 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 277   AC_CACHE_CHECK(whether the mail spool is world-writable,
 278                  nmh_cv_mailspool_world_writable,
 279   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 280     nmh_cv_mailspool_world_writable=no
 281   else
 282     nmh_cv_mailspool_world_writable=yes
 283   fi])
 284 fi
 285
 286 dnl Also, check for liblockfile (as found on Debian systems)
 287 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 288
 289 dnl and whether its companion program dotlockfile is setgid
 290 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 291 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 292   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 293     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 294     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 295         nmh_cv_dotlockfile_setgid=yes
 296       else
 297         nmh_cv_dotlockfile_setgid=no
 298       fi])
 299   fi
 300 fi
 301
 302 dnl Provide a way for distcheck to disable setgid_mail via
 303 dnl DISTCHECK_CONFIGURE_FLAGS.
 304 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 305   [nmh_cv_dotlockfile_setgid=yes])
 306
 307 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 308 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 309 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 310   dnl do we really need both of these?
 311   AC_DEFINE([MAILGROUP],[1],
 312     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 313   SETGID_MAIL=1
 314 fi
 315 AC_SUBST([SETGID_MAIL])dnl
 316
 317 dnl Use ls to see which group owns the mail spool directory.
 318 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 319 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 320 ])
 321 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 322 AC_SUBST([MAIL_SPOOL_GRP])dnl
 323
 324 NMH_MIMETYPEPROC
 325 NMH_MIMEENCODINGPROC
 326
 327 dnl ------------------
 328 dnl CHECK HEADER FILES
 329 dnl ------------------
 330
 331 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 332 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 333 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 334 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 335 dnl declared; if so they should have an entry added to this case statement.
 336 dnl NB that we must define this on the compiler command line, not in config.h,
 337 dnl because it must be set before any system header is included and there's no
 338 dnl portable way to make sure that files generated by lex include config.h
 339 dnl before system header files.
 340
 341 AS_CASE(["$host_os"],
 342         [linux*],
 343         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 344         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 345
 346 AC_HEADER_TIOCGWINSZ
 347 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 348
 349 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 350   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 351 [[#if HAVE_SYS_STREAM_H
 352 #  include <sys/stream.h>
 353 #endif
 354 ]])
 355
 356 dnl ---------------
 357 dnl CHECK FUNCTIONS
 358 dnl ---------------
 359 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 360
 361 dnl Check for multibyte character set support
 362 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 363             "x$ac_cv_header_wctype_h" = "xyes" -a \
 364             "x$ac_cv_func_wcwidth" = "xyes" -a \
 365             "x$ac_cv_func_mbtowc" = "xyes"],
 366       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 367                  [Define to enable support for multibyte character sets.])
 368        MULTIBYTE_ENABLED=1],
 369       [MULTIBYTE_ENABLED=0])
 370 AC_SUBST([MULTIBYTE_ENABLED])
 371
 372 dnl -------------------
 373 dnl CHECK FOR LIBRARIES
 374 dnl -------------------
 375 dnl Checks for network libraries (nsl, socket)
 376 NMH_CHECK_NETLIBS
 377
 378 dnl Check the locking functions supported and what we should use by default
 379 NMH_LOCKING
 380
 381 dnl Check for iconv
 382 NMH_CHECK_ICONV
 383
 384 dnl Check for tputs() callback argument
 385 NMH_TPUTS_PUTC_ARG
 386
 387 termcap_curses_order="termcap curses ncurses"
 388 for lib in $termcap_curses_order; do
 389   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 390 done
 391 AC_SUBST([TERMLIB])dnl
 392 AS_IF([test "x$TERMLIB" = "x"],
 393       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 394 curses or ncurses library or package that you can install?])])
 395
 396 dnl Check for readline support
 397 NMH_READLINE
 398
 399 dnl --------------
 400 dnl CHECK FOR NDBM
 401 dnl --------------
 402
 403 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 404             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 405 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 406             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 407
 408 if test "$nmh_ndbm" = "autodetect"; then
 409   if test "$nmh_ndbmheader" != "autodetect"; then
 410     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 411   else
 412
 413     dnl There are at least four implementations of ndbm, and
 414     dnl several of those can be in different places at the whim
 415     dnl of the system integrator. A good summary of this mess
 416     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 417
 418     dnl Classic ndbm with no library required (eg NetBSD): try this
 419     dnl first so we don't accidentally link in a pointless but harmless
 420     dnl library in one of the later ndbm.h+libfoo tests:
 421     NMH_CHECK_NDBM(ndbm.h,,,
 422     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 423       NMH_CHECK_NDBM(db.h,db,,
 424     dnl Berkeley DBv1 emulating ndbm:
 425         NMH_CHECK_NDBM(ndbm.h,db,,
 426           NMH_CHECK_NDBM(ndbm.h,db1,,
 427     dnl Classic ndbm:
 428             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 429     dnl glibc2.1 systems put db1 in a subdir:
 430               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 431     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 432     dnl and possibly needing gbdm_compat library:
 433                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 434                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 435                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 436     dnl 64-bit Cygwin:
 437                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 438     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 439     dnl need to be explicit:
 440                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 441   fi
 442 else
 443   dnl We don't really need to check that the user-specified values work,
 444   dnl but it is a convenience to the user to bomb out early rather than
 445   dnl after configure and half the compile process.
 446   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 447 fi
 448
 449 if test "$nmh_ndbm_found" = "no"; then
 450   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 451 else
 452   dnl Now export the lib/header to our makefile/config.h:
 453   if test x"$nmh_ndbmheader" != x; then
 454     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 455       [Define to the header containing the ndbm API prototypes.])
 456   fi
 457   if test x"$nmh_ndbm" != x; then
 458     NDBM_LIBS="-l$nmh_ndbm"
 459   else
 460     NDBM_LIBS=
 461   fi
 462   AC_SUBST([NDBM_LIBS])
 463 fi
 464
 465 dnl ------------------
 466 dnl Set RPM build root
 467 dnl ------------------
 468 dnl nmhrpm is used in the final summary, see below.  The default value is
 469 dnl reported there as ./RPM, consistent with the reporting of the default
 470 dnl source code location as ., but its absolute path is used in the Makefile.
 471 AC_ARG_WITH([rpmdir],
 472   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 473   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 474           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 475 AC_SUBST([rpmdir])
 476
 477
 478 dnl --------------------
 479 dnl CHECK FOR CYRUS-SASL
 480 dnl --------------------
 481
 482 AS_IF([test x"$sasl_support" = x"yes"],[
 483   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 484   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 485     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 486 AC_SUBST([SASLLIB])
 487
 488 dnl -----------------
 489 dnl CHECK FOR OPENSSL
 490 dnl -----------------
 491
 492 AS_IF([test x"$tls_support" = x"yes"],[
 493   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 494   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 495   dnl automatically append -lcrypto when linking with -lssl.
 496   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 497   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 498     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 499   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 500     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 501   [TLSLIB=])
 502 AC_SUBST([TLSLIB])
 503
 504 dnl ----------------
 505 dnl CHECK FLEX FIXUP
 506 dnl ----------------
 507 dnl Use LFLAGS make variable setting to work around bugs in flex
 508 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 509 dnl http://sourceforge.net/p/flex/bugs/140/
 510 AS_IF([test "$LEX" = flex],
 511       [AS_CASE([`$LEX -V`],
 512                [flex\ 2.5.35], [LFLAGS=\
 513 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 514                [flex\ 2.5.3[[67]]], [LFLAGS=\
 515 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 516        AC_SUBST([LFLAGS])])
 517
 518 dnl ------------------
 519 dnl FOR INTERNAL USE by the NMH test suite
 520 dnl ------------------
 521 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 522 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 523       AC_SUBST([nmhetcdirinst]))
 524
 525 dnl ----------------
 526 dnl CHECK STRUCTURES
 527 dnl ----------------
 528
 529 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 530 dnl (FreeBSD has a timezone() function but not a timezone global
 531 dnl variable that is visible).
 532 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 533
 534 AC_STRUCT_DIRENT_D_TYPE
 535
 536 dnl Where is <signal.h> located?  Needed as input for signames.awk
 537 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 538 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 539                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 540                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 541                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 542                  /usr/include/sys/signal.h      dnl Almost everybody else
 543                  /dev/null;                     dnl Just in case we fall through
 544 do
 545   test -f $SIGNAL_H && \
 546   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 547   break
 548 done
 549 nmh_cv_path_signal_h=$SIGNAL_H
 550 ])
 551 SIGNAL_H=$nmh_cv_path_signal_h
 552 AC_SUBST(SIGNAL_H)dnl
 553
 554 dnl
 555 dnl Sigh, this is required because under the new world order autoconf has
 556 dnl nothing to create in a few of the build directories when doing an object
 557 dnl tree build.  So make sure we created certain directories if they don't
 558 dnl exist.
 559 dnl
 560
 561 AC_CONFIG_COMMANDS([build-directories],
 562 [test -d man || AS_MKDIR_P([man])])
 563
 564 AC_CONFIG_COMMANDS_POST([
 565
 566 dnl These odd looking assignments are done to expand out unexpanded
 567 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 568 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 569 dnl again to get the final answer.
 570 dnl We only use the expanded versions to print the install paths in
 571 dnl the final summary and should use them nowhere else (see the autoconf
 572 dnl docs for the rationale for bindir etc being unexpanded).
 573 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 574 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 575 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 576 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 577 eval "nmhrpm=${nmhrpm}";
 578
 579 AC_MSG_NOTICE([
 580 nmh configuration
 581 -----------------
 582 nmh version                : AC_PACKAGE_VERSION
 583 host os                    : ${host}
 584 compiler                   : ${CC}
 585 compiler flags             : ${CFLAGS}
 586 linker flags               : ${LDFLAGS}
 587 preprocessor flags         : ${CPPFLAGS}
 588 source code location       : ${srcdir}
 589 binary install path        : ${nmhbin}
 590 libexec install path       : ${nmhlibexec}/nmh
 591 config files install path  : ${nmhsysconf}/nmh
 592 man page install path      : ${nmhman}
 593 RPM build root             : ${nmhrpm}
 594 backup prefix              : ${backup_prefix}
 595 transport system           : ${MTS}
 596 spool default locking type : ${with_locking}
 597 default smtp servers       : ${smtpservers}
 598 SASL support               : ${sasl_support}
 599 TLS support                : ${tls_support}
 600 ])])dnl
 601
 602 dnl ---------------
 603 dnl OUTPUT MAKEFILE
 604 dnl ---------------
 605 AC_CONFIG_FILES([Makefile test/common.sh])
 606 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 607 AC_OUTPUT