diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122   else
 123     dnl Use -v and some other options with SunStudio cc.  lex produces
 124     dnl code that causes unreachable-statement warnings.  It might be
 125     dnl better to use an autoconf test, except -v will probably succeed
 126     dnl with many other compilers but have different meaning.
 127     AS_CASE([`${CC} -V 2>&1`],
 128             [cc:\ Sun\ C*], [CFLAGS=\
 129 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 130   fi
 131
 132   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 133                  [nmh_saved_cflags="$CFLAGS"
 134                  CFLAGS="$CFLAGS -Wall -Werror"
 135                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 138
 139   AC_CACHE_CHECK([whether compiler supports -Wno-unused-result],
 140                  [nmh_cv_has_wnur],
 141                  [nmh_saved_cflags="$CFLAGS"
 142                  CFLAGS="$CFLAGS -Wno-unused-result -Werror"
 143                  AC_TRY_COMPILE([],[],nmh_cv_has_wnur=yes,nmh_cv_has_wnur=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wnur" = "yes"  && \
 146     CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"
 147
 148   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 149                  [nmh_saved_cflags="$CFLAGS"
 150                  CFLAGS="$CFLAGS -Wextra -Werror"
 151                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 152                                 nmh_cv_has_wextra=no)
 153                  CFLAGS="$nmh_saved_cflags"])
 154   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 155 fi
 156
 157 dnl --------------
 158 dnl CUSTOMIZE LINK
 159 dnl --------------
 160 if test `uname` = OpenBSD; then
 161   dnl Filter out "often/almost always misused" warnings from OpenBSD linker.
 162   [POSTLINK="2>&1 | egrep -v ': [w]arning: s[a-z]+\(\) is \
 163 (almost always|often) misused, please use'; true"]
 164 fi
 165 AC_SUBST([POSTLINK])
 166
 167 dnl -----------------
 168 dnl CUSTOMIZE LDFLAGS
 169 dnl -----------------
 170 if test "$GCC" = yes; then
 171   dnl Disable clang complaint about unused -ansi when linking.
 172   AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 173                  [nmh_cv_has_q_unused_arguments],
 174                  [nmh_saved_ldflags="$LDFLAGS"
 175                   LDFLAGS="$LDFLAGS -Qunused-arguments"
 176                   AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 177                                     nmh_cv_has_q_unused_arguments=no)
 178                   LDFLAGS="$nmh_saved_ldflags"])
 179   test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 180     LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 181 fi
 182
 183 dnl This really shouldn't be necessary.  And we really shouldn't add -s.
 184 if test x"$enable_debug" = x"yes"; then
 185   test -z "$LDFLAGS" && LDFLAGS=-g
 186 else
 187   if test -z "$LDFLAGS"; then
 188     case "$build_os" in
 189       darwin*) LDFLAGS= ;;
 190             *) LDFLAGS=-s ;;
 191     esac
 192   fi
 193 fi
 194
 195 dnl This hack turns off assertions by default, assuming
 196 dnl that configure still uses this shell variable.  Without
 197 dnl it, AC_HEADER_ASSERT enables assertions by default.
 198 test -z "$enable_assert"  &&  enable_assert=no
 199
 200 AC_HEADER_ASSERT
 201
 202 dnl ------------------
 203 dnl CHECK FOR PROGRAMS
 204 dnl ------------------
 205 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 206 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 207 AC_PROG_RANLIB          dnl Check for `ranlib'
 208 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 209 AC_PROG_SED             dnl Check for Posix-compliant sed
 210 AM_PROG_LEX             dnl Check for lex/flex
 211
 212 AM_PROG_AR
 213
 214 dnl Look for `cut'
 215 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 216 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 217
 218 dnl
 219 dnl Check for MD5 program and formatting command
 220 dnl
 221 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 222 AS_CASE(["${MD5SUM}"],
 223         [md5sum], [MD5FMT="cat"],
 224         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 225         [MD5FMT="missing"])
 226 AC_SUBST([MD5FMT])
 227
 228 dnl Look for `ls'
 229 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 230 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 231
 232 dnl See how we get ls to display the owner and the group
 233 AS_IF([test "$lspath" != "no"],
 234   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 235                  [nmh_cv_ls_grpopt],
 236   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 237     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 238     dnl ls, it would seem -l gave us both the user and group.  On this type of
 239     dnl ls, -g makes _only_ the group be displayed (and not the user).
 240     nmh_cv_ls_grpopt="-l"],[
 241     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 242     nmh_cv_ls_grpopt="-lg"])])])
 243
 244 dnl Look for `sendmail'
 245 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 246 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 247
 248 dnl Cygwin FAT filesystems do not support hard links.  So default to
 249 dnl cp instead, even if running on an NTFS or other filesystem.
 250 AS_CASE(["$host_os"],
 251   [cygwin*], [LN=cp],
 252   [LN=ln])
 253 AC_SUBST([LN])
 254
 255 dnl ----------------------------------------------------------
 256 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 257 dnl ----------------------------------------------------------
 258 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 259 [for mailspool in /var/mail        dnl
 260                   /var/spool/mail  dnl
 261                   /usr/spool/mail  dnl
 262                   /dev/null;       dnl Just in case we fall through
 263 do
 264   test -d $mailspool && break
 265 done
 266 nmh_cv_mailspool=$mailspool
 267 ])
 268 mailspool=$nmh_cv_mailspool
 269 AC_SUBST([mailspool])dnl
 270
 271 dnl See whether the mail spool directory is world-writable.
 272 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 273   AC_CACHE_CHECK(whether the mail spool is world-writable,
 274                  nmh_cv_mailspool_world_writable,
 275   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 276     nmh_cv_mailspool_world_writable=no
 277   else
 278     nmh_cv_mailspool_world_writable=yes
 279   fi])
 280 fi
 281
 282 dnl Also, check for liblockfile (as found on Debian systems)
 283 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 284
 285 dnl and whether its companion program dotlockfile is setgid
 286 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 287 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 288   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 289     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 290     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 291         nmh_cv_dotlockfile_setgid=yes
 292       else
 293         nmh_cv_dotlockfile_setgid=no
 294       fi])
 295   fi
 296 fi
 297
 298 dnl Provide a way for distcheck to disable setgid_mail via
 299 dnl DISTCHECK_CONFIGURE_FLAGS.
 300 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 301   [nmh_cv_dotlockfile_setgid=yes])
 302
 303 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 304 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 305 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 306   dnl do we really need both of these?
 307   AC_DEFINE([MAILGROUP],[1],
 308     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 309   SETGID_MAIL=1
 310 fi
 311 AC_SUBST([SETGID_MAIL])dnl
 312
 313 dnl Use ls to see which group owns the mail spool directory.
 314 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 315 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 316 ])
 317 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 318 AC_SUBST([MAIL_SPOOL_GRP])dnl
 319
 320 dnl ---------------------------------------------
 321 dnl CHECK FOR PROGRAM TO PROVIDE MIME TYPE STRING
 322 dnl ---------------------------------------------
 323 AS_IF([file --mime "${srcdir}"/configure >/dev/null 2>&1],
 324       [AS_IF([file --brief --mime "${srcdir}"/configure >/dev/null 2>&1],
 325              [nmh_mimetypeproc='"file --brief --mime"'],
 326              [nmh_mimetypeproc='"file --mime"'])])
 327 AS_CASE([$nmh_mimetypeproc], [?*],
 328         [AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$nmh_mimetypeproc],
 329           [Program, with arguments, that provides MIME type string.])])
 330 AS_ECHO_N(["AS_ESCAPE([checking program to provide MIME type string ... ])"])
 331 AS_ECHO(["AS_ESCAPE([$nmh_mimetypeproc], [""])"])
 332
 333 dnl ------------------
 334 dnl CHECK HEADER FILES
 335 dnl ------------------
 336
 337 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 338 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 339 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 340 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 341 dnl declared; if so they should have an entry added to this case statement.
 342 dnl NB that we must define this on the compiler command line, not in config.h,
 343 dnl because it must be set before any system header is included and there's no
 344 dnl portable way to make sure that files generated by lex include config.h
 345 dnl before system header files.
 346
 347 AS_CASE(["$host_os"],
 348         [linux*],
 349         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 350           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 351                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 352
 353 AC_HEADER_TIOCGWINSZ
 354 AC_CHECK_HEADERS([fcntl.h langinfo.h wchar.h wctype.h sys/param.h \
 355                   sys/time.h sys/stream.h])
 356
 357 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 358   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 359 [[#if HAVE_SYS_STREAM_H
 360 #  include <sys/stream.h>
 361 #endif
 362 ]])
 363
 364 dnl ---------------
 365 dnl CHECK FUNCTIONS
 366 dnl ---------------
 367 AC_CHECK_FUNCS([wcwidth mbtowc nl_langinfo getutxent arc4random])
 368
 369 dnl Check for multibyte character set support
 370 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 371             "x$ac_cv_header_wctype_h" = "xyes" -a \
 372             "x$ac_cv_func_wcwidth" = "xyes" -a \
 373             "x$ac_cv_func_mbtowc" = "xyes"],
 374       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 375                  [Define to enable support for multibyte character sets.])
 376        MULTIBYTE_ENABLED=1],
 377       [MULTIBYTE_ENABLED=0])
 378 AC_SUBST([MULTIBYTE_ENABLED])
 379
 380 dnl -------------------
 381 dnl CHECK FOR LIBRARIES
 382 dnl -------------------
 383 dnl Checks for network libraries (nsl, socket)
 384 NMH_CHECK_NETLIBS
 385
 386 dnl Check for readline support
 387 NMH_READLINE
 388
 389 dnl Check the locking functions supported and what we should use by default
 390 NMH_LOCKING
 391
 392 dnl Check for iconv
 393 NMH_CHECK_ICONV
 394
 395 dnl Check for tputs() callback argument
 396 NMH_TPUTS_PUTC_ARG
 397
 398 termcap_curses_order="termcap curses ncurses"
 399 for lib in $termcap_curses_order; do
 400   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 401 done
 402 AC_SUBST([TERMLIB])dnl
 403 AS_IF([test "x$TERMLIB" = "x"],
 404       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a curses
 405 or ncurses library or package that you can install?])])
 406
 407 dnl --------------
 408 dnl CHECK FOR NDBM
 409 dnl --------------
 410
 411 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 412             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 413 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 414             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 415
 416 if test "$nmh_ndbm" = "autodetect"; then
 417   if test "$nmh_ndbmheader" != "autodetect"; then
 418     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 419   else
 420
 421     dnl There are at least four implementations of ndbm, and
 422     dnl several of those can be in different places at the whim
 423     dnl of the system integrator. A good summary of this mess
 424     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 425
 426     dnl Classic ndbm with no library required (eg NetBSD): try this
 427     dnl first so we don't accidentally link in a pointless but harmless
 428     dnl library in one of the later ndbm.h+libfoo tests:
 429     NMH_CHECK_NDBM(ndbm.h,,,
 430     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 431       NMH_CHECK_NDBM(db.h,db,,
 432     dnl Berkeley DBv1 emulating ndbm:
 433         NMH_CHECK_NDBM(ndbm.h,db,,
 434           NMH_CHECK_NDBM(ndbm.h,db1,,
 435     dnl Classic ndbm:
 436             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 437     dnl glibc2.1 systems put db1 in a subdir:
 438               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 439     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 440     dnl and possibly needing gbdm_compat library:
 441                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 442                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 443                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 444                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 445
 446   fi
 447 else
 448   dnl We don't really need to check that the user-specified values work,
 449   dnl but it is a convenience to the user to bomb out early rather than
 450   dnl after configure and half the compile process.
 451   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 452 fi
 453
 454 if test "$nmh_ndbm_found" = "no"; then
 455   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 456 else
 457   dnl Now export the lib/header to our makefile/config.h:
 458   if test x"$nmh_ndbmheader" != x; then
 459     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 460       [Define to the header containing the ndbm API prototypes.])
 461   fi
 462   if test x"$nmh_ndbm" != x; then
 463     NDBM_LIBS="-l$nmh_ndbm"
 464   else
 465     NDBM_LIBS=
 466   fi
 467   AC_SUBST([NDBM_LIBS])
 468 fi
 469
 470 dnl ------------------
 471 dnl Set RPM build root
 472 dnl ------------------
 473 dnl nmhrpm is used in the final summary, see below.  The default value is
 474 dnl reported there as ./RPM, consistent with the reporting of the default
 475 dnl source code location as ., but its absolute path is used in the Makefile.
 476 AC_ARG_WITH([rpmdir],
 477   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 478   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 479           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 480 AC_SUBST([rpmdir])
 481
 482
 483 dnl --------------------
 484 dnl CHECK FOR CYRUS-SASL
 485 dnl --------------------
 486
 487 AS_IF([test x"$sasl_support" = x"yes"],[
 488   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 489   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 490     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 491 AC_SUBST([SASLLIB])
 492
 493 dnl -----------------
 494 dnl CHECK FOR OPENSSL
 495 dnl -----------------
 496
 497 AS_IF([test x"$tls_support" = x"yes"],[
 498   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 499   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 500   dnl automatically append -lcrypto when linking with -lssl.
 501   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 502   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 503     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 504   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 505     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 506   [TLSLIB=])
 507 AC_SUBST([TLSLIB])
 508
 509 dnl ----------------
 510 dnl CHECK FLEX FIXUP
 511 dnl ----------------
 512 dnl Use LFLAGS make variable setting to work around bugs in flex
 513 dnl 2.5.36 that cause signed/unsigned mismatch,
 514 dnl http://sourceforge.net/p/flex/bugs/140/
 515 AS_IF([test "$LEX" = flex],
 516       [AS_CASE([`$LEX -V`],
 517                [flex\ 2.5.35], [LFLAGS=\
 518 '; printf "%s\n" '\''1,$$s/(size_t) \(num_to_read\)/\1/'\'' w q | ed -s $@; \
 519 true'],
 520                [flex\ 2.5.36], [LFLAGS=\
 521 '; printf "%s\n" '\''1,$$s/\(   \)int i;/\1yy_size_t i;/'\'' w q | ed -s $@; \
 522 true'])
 523        AC_SUBST([LFLAGS])])
 524
 525 dnl ----------------
 526 dnl CHECK STRUCTURES
 527 dnl ----------------
 528
 529 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 530 dnl (FreeBSD has a timezone() function but not a timezone global
 531 dnl variable that is visible).
 532 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 533
 534 AC_STRUCT_DIRENT_D_TYPE
 535
 536 dnl Where is <signal.h> located?  Needed as input for signames.awk
 537 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 538 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 539                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 540                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 541                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 542                  /usr/include/sys/signal.h      dnl Almost everybody else
 543                  /dev/null;                     dnl Just in case we fall through
 544 do
 545   test -f $SIGNAL_H && \
 546   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 547   break
 548 done
 549 nmh_cv_path_signal_h=$SIGNAL_H
 550 ])
 551 SIGNAL_H=$nmh_cv_path_signal_h
 552 AC_SUBST(SIGNAL_H)dnl
 553
 554 dnl
 555 dnl Sigh, this is required because under the new world order autoconf has
 556 dnl nothing to create in a few of the build directories when doing an object
 557 dnl tree build.  So make sure we created certain directories if they don't
 558 dnl exist.
 559 dnl
 560
 561 AC_CONFIG_COMMANDS([build-directories],
 562 [test -d man || AS_MKDIR_P([man])])
 563
 564 AC_CONFIG_COMMANDS_POST([
 565
 566 dnl These odd looking assignments are done to expand out unexpanded
 567 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 568 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 569 dnl again to get the final answer.
 570 dnl We only use the expanded versions to print the install paths in
 571 dnl the final summary and should use them nowhere else (see the autoconf
 572 dnl docs for the rationale for bindir etc being unexpanded).
 573 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 574 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 575 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 576 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 577 eval "nmhrpm=${nmhrpm}";
 578
 579 AC_MSG_NOTICE([
 580 nmh configuration
 581 -----------------
 582 nmh version                : AC_PACKAGE_VERSION
 583 host os                    : ${host}
 584 compiler                   : ${CC}
 585 compiler flags             : ${CFLAGS}
 586 linker flags               : ${LDFLAGS}
 587 preprocessor flags         : ${CPPFLAGS}
 588 source code location       : ${srcdir}
 589 binary install path        : ${nmhbin}
 590 library install path       : ${nmhlib}
 591 config files install path  : ${nmhsysconf}
 592 man page install path      : ${nmhman}
 593 RPM build root             : ${nmhrpm}
 594 backup prefix              : ${backup_prefix}
 595 transport system           : ${MTS}
 596 spool default locking type : ${with_locking}
 597 default smtp servers       : ${smtpservers}
 598 SASL support               : ${sasl_support}
 599 TLS support                : ${tls_support}
 600 ])])dnl
 601
 602 dnl ---------------
 603 dnl OUTPUT MAKEFILE
 604 dnl ---------------
 605 AC_CONFIG_FILES([Makefile test/common.sh])
 606 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 607 AC_OUTPUT