diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*|openbsd*|darwin*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
 119       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
 120       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
 121       [MTS="smtp"])
 122 AC_SUBST([MTS])dnl
 123
 124 dnl What should be the default pager?
 125 AC_ARG_WITH([pager],
 126   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 127
 128 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 129
 130 dnl If a pager is not explicitly specified, then look for one.
 131 dnl Fall back to `cat', to avoid catastrophic failure of
 132 dnl `mhshow', et al., if pagerpath is set to `no'.
 133 if test -z "$pagerpath"; then
 134   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 135   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 136 fi
 137 AC_SUBST(pagerpath)dnl
 138
 139 dnl What should be the default mail server(s)?
 140 AC_ARG_WITH(smtpservers,
 141   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 142   [specify the default SMTP server(s) @<:@localhost@:>@]))
 143 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 144       [smtpservers="localhost"])
 145 AC_SUBST([smtpservers])dnl
 146
 147 dnl ----------------------------------------------------
 148 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 149 dnl ----------------------------------------------------
 150 AC_PREFIX_DEFAULT([/usr/local/nmh])
 151
 152 dnl ------------------
 153 dnl CHECK THE COMPILER
 154 dnl ------------------
 155 dnl We want these before the checks,
 156 dnl so the checks can modify their values.
 157 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 158 if test x"$enable_debug" = x"yes"; then
 159   test -z "$LDFLAGS" && LDFLAGS=-g
 160 fi
 161
 162 AC_PROG_CC
 163 AM_PROG_CC_C_O
 164
 165 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 166   [nmh_cv_has_unusedmacros],
 167   [nmh_saved_cppflags="$CPPFLAGS"
 168    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 169    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 170    CPPFLAGS="$nmh_saved_cppflags"])
 171
 172 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 173   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 174                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 175   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 176 fi
 177 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 178
 179 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 180   [nmh_cv_has_nosigncompare],
 181   [nmh_saved_cppflags="$CPPFLAGS"
 182    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 183    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 184                   nmh_cv_has_nosigncompare=no)
 185    CPPFLAGS="$nmh_saved_cppflags"])
 186
 187 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 188   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 189 fi
 190 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 191
 192 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 193 [nmh_saved_cflags="$CFLAGS"
 194  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 195  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 196  CFLAGS="$nmh_saved_cflags"])
 197
 198 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 199 [nmh_saved_cflags="$CFLAGS"
 200  CFLAGS="$CFLAGS -Wno-pointer-sign"
 201  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 202  CFLAGS="$nmh_saved_cflags"])
 203
 204 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 205 dnl setup version 2.763, because it disables some features in the
 206 dnl system system header files and warns about them with -Wall.  Try
 207 dnl to test for that generally, though still with gcc.
 208 if test "$GCC" = yes; then
 209   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 210     [nmh_saved_cppflags="$CPPFLAGS"
 211      nmh_saved_cflags="$CFLAGS"
 212      CPPFLAGS="-D_GNU_SOURCE"
 213      CFLAGS="-ansi -Wall -Werror"
 214      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 215        [nmh_cv_has_dash_ansi=yes],
 216        [nmh_cv_has_dash_ansi=no])
 217      CPPFLAGS="$nmh_saved_cppflags"
 218      CFLAGS="$nmh_saved_cflags"])
 219 else
 220   nmh_cv_has_dash_ansi=no
 221 fi
 222
 223 dnl if the user hasn't specified CFLAGS, then
 224 dnl   if compiler is gcc, then
 225 dnl    use -O2 and some warning flags
 226 dnl   else use -O
 227 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 228 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 229 dnl warnings which are probably mostly spurious and which in any case we
 230 dnl don't want to deal with now.
 231 if test "$nmh_cv_has_noptrsign" = "yes"; then
 232     if test "$nmh_cv_has_dash_ansi" = "yes"; then
 233         nmh_gcc_common_flags="-ansi -pedantic -Wall"
 234     else
 235         nmh_gcc_common_flags="-Wall"
 236     fi
 237     if test "$nmh_cv_has_wextra" = "yes"; then
 238         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 239 "-Wno-pointer-sign"
 240     else
 241         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 242     fi
 243 else
 244     if test "$nmh_cv_has_wextra" = "yes"; then
 245         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 246     else
 247         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 248     fi
 249 fi
 250
 251 if test -n "$auto_cflags"; then
 252   if test x"$enable_debug" = x"yes"; then
 253     if test -n "$GCC"; then
 254       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 255     else
 256       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 257     fi
 258   else
 259     if test -z "$LDFLAGS"; then
 260       case "$build_os" in
 261         darwin*)
 262           LDFLAGS=
 263           ;;
 264         *)
 265           LDFLAGS=-s
 266           ;;
 267       esac
 268     fi
 269     if test -n "$GCC"; then
 270       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 271     else
 272       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 273     fi
 274   fi
 275 fi
 276
 277 AC_C_CONST              dnl Does compiler support `const'.
 278
 279 dnl ------------------
 280 dnl CHECK FOR PROGRAMS
 281 dnl ------------------
 282 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 283 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 284 AC_PROG_RANLIB          dnl Check for `ranlib'
 285 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 286 AC_PROG_SED             dnl Check for Posix-compliant sed
 287 AC_PROG_LEX             dnl Check for lex/flex
 288
 289 dnl Look for `cut'
 290 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 291 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 292
 293 dnl
 294 dnl Check for MD5 program and formatting command
 295 dnl
 296 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 297 AS_CASE(["${MD5SUM}"],
 298         [md5sum], [MD5FMT="cat"],
 299         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 300         [MD5FMT="missing"])
 301 AC_SUBST([MD5FMT])
 302
 303 dnl ----------------------------------------------
 304 dnl check for lclint, and lint if it doesn't exist
 305 dnl ----------------------------------------------
 306 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 307 if test x$ac_cv_prog_linttmp1 != xno ; then
 308   LINT=$ac_cv_prog_linttmp1
 309   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 310 else
 311   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 312   if test x$ac_cv_prog_linttmp2 != xno ; then
 313     LINT=$ac_cv_prog_linttmp2
 314     LINTFLAGS=""
 315   else
 316     LINT="echo 'No lint program found'"
 317     LINTFLAGS=""
 318   fi
 319 fi
 320 AC_SUBST([LINT])dnl
 321 AC_SUBST([LINTFLAGS])dnl
 322
 323 dnl Look for `ls'
 324 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 325 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 326
 327 dnl See how we get ls to display the owner and the group
 328 if test "$lspath" != "no"; then
 329   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 330                  [nmh_cv_ls_grpopt],
 331   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 332     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 333     dnl ls, it would seem -l gave us both the user and group.  On this type of
 334     dnl ls, -g makes _only_ the group be displayed (and not the user).
 335     nmh_cv_ls_grpopt="-l"
 336   else
 337     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 338     nmh_cv_ls_grpopt="-lg"
 339   fi])
 340 fi
 341
 342 dnl Look for `sendmail'
 343 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 344 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 345
 346 dnl Look for `vi'
 347 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 348 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 349
 350 dnl If editor is not specified yet,
 351 dnl then use `vi' as the default.
 352 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 353 AC_SUBST([editorpath])dnl
 354
 355 dnl Cygwin FAT filesystems do not support hard links.  So default to
 356 dnl cp instead, even if running on an NTFS or other filesystem.
 357 AS_CASE(["$host_os"],
 358   [cygwin*],[LN=cp],
 359   [LN=ln])
 360 AC_SUBST([LN])
 361
 362 dnl ----------------------------------------------------------
 363 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 364 dnl ----------------------------------------------------------
 365 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 366 [for mailspool in /var/mail        dnl
 367                   /var/spool/mail  dnl
 368                   /usr/spool/mail  dnl
 369                   /dev/null;       dnl Just in case we fall through
 370 do
 371   test -d $mailspool && break
 372 done
 373 nmh_cv_mailspool=$mailspool
 374 ])
 375 mailspool=$nmh_cv_mailspool
 376 AC_SUBST([mailspool])dnl
 377
 378 dnl See whether the mail spool directory is world-writable.
 379 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 380   AC_CACHE_CHECK(whether the mail spool is world-writable,
 381                  nmh_cv_mailspool_world_writable,
 382   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 383     nmh_cv_mailspool_world_writable=no
 384   else
 385     nmh_cv_mailspool_world_writable=yes
 386   fi])
 387 fi
 388
 389 dnl Also, check for liblockfile (as found on Debian systems)
 390 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 391
 392 dnl and whether its companion program dotlockfile is setgid
 393 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 394 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 395   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 396     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 397     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 398         nmh_cv_dotlockfile_setgid=yes
 399       else
 400         nmh_cv_dotlockfile_setgid=no
 401       fi])
 402   fi
 403 fi
 404
 405 dnl Provide a way for distcheck to disable setgid_mail via
 406 dnl DISTCHECK_CONFIGURE_FLAGS.
 407 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 408   nmh_cv_dotlockfile_setgid=yes
 409 fi
 410
 411 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 412 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 413 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 414   dnl do we really need both of these?
 415   AC_DEFINE(MAILGROUP,1,
 416     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 417   SETGID_MAIL=1
 418 fi
 419 AC_SUBST(SETGID_MAIL)dnl
 420
 421 dnl Use ls to see which group owns the mail spool directory.
 422 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 423 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 424 ])
 425 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 426 AC_SUBST(MAIL_SPOOL_GRP)dnl
 427
 428 dnl ------------------
 429 dnl CHECK HEADER FILES
 430 dnl ------------------
 431
 432 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 433 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 434 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 435 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 436 dnl declared; if so they should have an entry added to this case statement.
 437 dnl NB that we must define this on the compiler command line, not in config.h,
 438 dnl because it must be set before any system header is included and there's no
 439 dnl portable way to make sure that files generated by lex include config.h
 440 dnl before system header files.
 441
 442 AS_CASE(["$host_os"],
 443         [linux*],
 444         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 445           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 446                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 447
 448 AC_HEADER_STDC
 449 AC_HEADER_TIOCGWINSZ
 450 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 451                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 452                   sys/param.h sys/time.h sys/stream.h])
 453
 454 dnl
 455 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 456 dnl really use a whole set of them, but this check should be
 457 dnl sufficient.
 458 dnl
 459 AC_CHECK_HEADER(libio.h, [
 460   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 461     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 462
 463 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 464   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 465 [[#if HAVE_SYS_STREAM_H
 466 #  include <sys/stream.h>
 467 #endif
 468 ]])
 469
 470 dnl ---------------
 471 dnl CHECK FUNCTIONS
 472 dnl ---------------
 473 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 474
 475 dnl Check for multibyte character set support
 476 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 477             "x$ac_cv_header_wctype_h" = "xyes" -a \
 478             "x$ac_cv_func_wcwidth" = "xyes" -a \
 479             "x$ac_cv_func_mbtowc" = "xyes"],
 480       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 481                  [Define to enable support for multibyte character sets.])
 482        MULTIBYTE_ENABLED=1],
 483       [MULTIBYTE_ENABLED=0])
 484 AC_SUBST([MULTIBYTE_ENABLED])
 485
 486 dnl -------------------
 487 dnl CHECK FOR LIBRARIES
 488 dnl -------------------
 489 dnl Check location of modf
 490 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 491
 492 dnl Checks for network libraries (nsl, socket)
 493 NMH_CHECK_NETLIBS
 494
 495 NMH_READLINE
 496
 497 termcap_curses_order="termcap curses ncurses"
 498 for lib in $termcap_curses_order; do
 499   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 500 done
 501 AC_SUBST([TERMLIB])dnl
 502 AS_IF([test "x$TERMLIB" = "x"],
 503       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 504 or ncurses library or package that you can install?])])
 505
 506
 507 dnl ---------------
 508 dnl CHECK FOR ICONV
 509 dnl ---------------
 510
 511 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 512 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 513   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 514   if test "x$ac_found_iconv" = "xno"; then
 515     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 516     if test "x$ac_found_iconv" = "xno"; then
 517       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 518     fi
 519     if test "x$ac_found_iconv" != "xno"; then
 520       ICONVLIB="-liconv"
 521     fi
 522   else
 523     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 524     AC_CHECK_DECL(_libiconv_version,
 525       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 526       [ #include <iconv.h> ])
 527   fi
 528 fi
 529 if test "x$ac_found_iconv" = xyes; then
 530   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 531 fi
 532 AC_SUBST([ICONVLIB])
 533
 534 dnl Check if iconv uses const in prototype declaration
 535 if test "x$ac_found_iconv" = "xyes"; then
 536   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 537     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 538         #include <iconv.h>]],
 539         [[#ifdef __cplusplus
 540           "C"
 541           #endif
 542           #if defined(__STDC__) || defined(__cplusplus)
 543           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 544           #else
 545           size_t iconv();
 546           #endif]])],
 547       [ac_cv_iconv_const=],
 548       [ac_cv_iconv_const=const])])
 549   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 550     [Define as const if the declaration of iconv() needs const.])
 551 fi
 552
 553 dnl --------------
 554 dnl CHECK FOR NDBM
 555 dnl --------------
 556
 557 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 558             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 559 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 560             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 561
 562 if test "$nmh_ndbm" = "autodetect"; then
 563   if test "$nmh_ndbmheader" != "autodetect"; then
 564     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 565   else
 566
 567     dnl There are at least four implementations of ndbm, and
 568     dnl several of those can be in different places at the whim
 569     dnl of the system integrator. A good summary of this mess
 570     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 571
 572     dnl Classic ndbm with no library required (eg NetBSD): try this
 573     dnl first so we don't accidentally link in a pointless but harmless
 574     dnl library in one of the later ndbm.h+libfoo tests:
 575     NMH_CHECK_NDBM(ndbm.h,,,
 576     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 577       NMH_CHECK_NDBM(db.h,db,,
 578     dnl Berkeley DBv1 emulating ndbm:
 579         NMH_CHECK_NDBM(ndbm.h,db,,
 580           NMH_CHECK_NDBM(ndbm.h,db1,,
 581     dnl Classic ndbm:
 582             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 583     dnl glibc2.1 systems put db1 in a subdir:
 584               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 585     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 586     dnl and possibly needing gbdm_compat library:
 587                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 588                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 589                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 590                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 591
 592   fi
 593 else
 594   dnl We don't really need to check that the user-specified values work,
 595   dnl but it is a convenience to the user to bomb out early rather than
 596   dnl after configure and half the compile process.
 597   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 598 fi
 599
 600 if test "$nmh_ndbm_found" = "no"; then
 601   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 602 else
 603   dnl Now export the lib/header to our makefile/config.h:
 604   if test x"$nmh_ndbmheader" != x; then
 605     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 606       [Define to the header containing the ndbm API prototypes.])
 607   fi
 608   if test x"$nmh_ndbm" != x; then
 609     NDBM_LIBS="-l$nmh_ndbm"
 610   else
 611     NDBM_LIBS=
 612   fi
 613   AC_SUBST([NDBM_LIBS])
 614 fi
 615
 616 dnl ------------------
 617 dnl Set RPM build root
 618 dnl ------------------
 619 dnl nmhrpm is used in the final summary, see below.  The default value is
 620 dnl reported there as ./RPM, consistent with the reporting of the default
 621 dnl source code location as ., but its absolute path is used in the Makefile.
 622 AC_ARG_WITH(rpmdir,
 623   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 624   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 625           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 626 AC_SUBST([rpmdir])
 627
 628
 629 dnl --------------------
 630 dnl CHECK FOR CYRUS-SASL
 631 dnl --------------------
 632
 633 AS_IF([test x"$sasl_support" = x"yes"],[
 634   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 635   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 636     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 637 AC_SUBST([SASLLIB])
 638
 639 dnl -----------------
 640 dnl CHECK FOR OPENSSL
 641 dnl -----------------
 642
 643 AS_IF([test x"$tls_support" = x"yes"],[
 644   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 645   AC_CHECK_LIB([crypto], [BIO_write], ,
 646     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 647   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 648     [AC_MSG_ERROR([OpenSSL library not found])])])
 649
 650 dnl ---------------------
 651 dnl CHECK TERMCAP LIBRARY
 652 dnl ---------------------
 653
 654 dnl Add the termcap library, so that the following configure
 655 dnl tests will find it when it tries to link test programs.
 656 nmh_save_LIBS="$LIBS"
 657 LIBS="$TERMLIB $LIBS"
 658
 659 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 660 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 661 dnl in tgetstr().
 662 dnl Under Cygwin test program crashes but exit code is still 0. So,
 663 dnl we test for a file that porgram should create
 664 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 665 [Define to 1 if tgetent() accepts NULL as a buffer.])
 666 AC_CACHE_CHECK(if tgetent accepts NULL,
 667 nmh_cv_func_tgetent_accepts_null,
 668 [AC_TRY_RUN([
 669 main()
 670 {
 671     char buf[4096];
 672     int r1 = tgetent(buf, "vt100");
 673     int r2 = tgetent((char*)0,"vt100");
 674     if (r1 >= 0 && r1 == r2) {
 675         char tbuf[1024], *u;
 676         u = tbuf;
 677         tgetstr("cl", &u);
 678         creat("conftest.tgetent", 0640);
 679     }
 680     exit((r1 != r2) || r2 == -1);
 681 }
 682 ],
 683   if test -f conftest.tgetent; then
 684     nmh_cv_func_tgetent_accepts_null=yes
 685   else
 686     nmh_cv_func_tgetent_accepts_null=no
 687   fi,
 688   nmh_cv_func_tgetent_accepts_null=no,
 689   nmh_cv_func_tgetent_accepts_null=no)])
 690 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 691   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 692 fi
 693 AC_CACHE_CHECK(if tgetent returns 0 on success,
 694 nmh_cv_func_tgetent_zero_success,
 695 [AC_TRY_RUN([
 696 main()
 697 {
 698     char buf[4096];
 699     int r1 = tgetent(buf, "!@#$%^&*");
 700     int r2 = tgetent(buf, "vt100");
 701     if (r1 < 0 && r2 == 0) {
 702         char tbuf[1024], *u;
 703         u = tbuf;
 704         tgetstr("cl", &u);
 705         creat("conftest.tgetent0", 0640);
 706     }
 707     exit(r1 == r2);
 708 }
 709 ],
 710   if test -f conftest.tgetent0; then
 711     nmh_cv_func_tgetent_zero_success=yes
 712   else
 713     nmh_cv_func_tgetent_zero_success=no
 714   fi,
 715   nmh_cv_func_tgetent_zero_success=no,
 716   nmh_cv_func_tgetent_zero_success=no)])
 717 AH_TEMPLATE([TGETENT_SUCCESS],
 718 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 719 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 720   AC_DEFINE(TGETENT_SUCCESS, 0)
 721 else
 722   AC_DEFINE(TGETENT_SUCCESS, 1)
 723 fi
 724
 725 dnl Now put the libraries back to what it was before we
 726 dnl starting checking the termcap library.
 727 LIBS="$nmh_save_LIBS"
 728
 729 dnl --------------
 730 dnl CHECK TYPEDEFS
 731 dnl --------------
 732 AC_TYPE_PID_T
 733 AC_TYPE_OFF_T
 734 AC_TYPE_UID_T
 735 AC_TYPE_MODE_T
 736 AC_TYPE_SIZE_T
 737
 738 dnl ----------------
 739 dnl CHECK STRUCTURES
 740 dnl ----------------
 741
 742 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 743 dnl (FreeBSD has a timezone() function but not a timezone global
 744 dnl variable that is visible).
 745 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 746
 747 AC_STRUCT_DIRENT_D_TYPE
 748
 749 dnl Where is <signal.h> located?  Needed as input for signames.awk
 750 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 751 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 752                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 753                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 754                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 755                  /usr/include/sys/signal.h      dnl Almost everybody else
 756                  /dev/null;                     dnl Just in case we fall through
 757 do
 758   test -f $SIGNAL_H && \
 759   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 760   break
 761 done
 762 nmh_cv_path_signal_h=$SIGNAL_H
 763 ])
 764 SIGNAL_H=$nmh_cv_path_signal_h
 765 AC_SUBST(SIGNAL_H)dnl
 766
 767 dnl
 768 dnl Sigh, this is required because under the new world order autoconf has
 769 dnl nothing to create in a few of the build directories when doing an object
 770 dnl tree build.  So make sure we created certain directories if they don't
 771 dnl exist.
 772 dnl
 773
 774 AC_CONFIG_COMMANDS([build-directories],
 775 [test -d etc || ${MKDIR_P} etc
 776 test -d man || ${MKDIR_P} man])
 777
 778 AC_CONFIG_COMMANDS_POST([
 779
 780 dnl These odd looking assignments are done to expand out unexpanded
 781 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 782 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 783 dnl again to get the final answer.
 784 dnl We only use the expanded versions to print the install paths in
 785 dnl the final summary and should use them nowhere else (see the autoconf
 786 dnl docs for the rationale for bindir etc being unexpanded).
 787 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 788 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 789 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 790 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 791 eval "nmhrpm=${nmhrpm}";
 792
 793 AC_MSG_NOTICE([
 794 nmh configuration
 795 -----------------
 796 nmh version                : AC_PACKAGE_VERSION
 797 host os                    : ${host}
 798 compiler                   : ${CC}
 799 compiler flags             : ${CFLAGS}
 800 linker flags               : ${LDFLAGS}
 801 preprocessor flags         : ${CPPFLAGS}
 802 source code location       : ${srcdir}
 803 binary install path        : ${nmhbin}
 804 library install path       : ${nmhlib}
 805 config files install path  : ${nmhsysconf}
 806 man page install path      : ${nmhman}
 807 RPM build root             : ${nmhrpm}
 808 backup prefix              : ${backup_prefix}
 809 transport system           : ${MTS}
 810 file locking type          : ${LOCKTYPE}
 811 default smtp servers       : ${smtpservers}
 812 default editor             : ${editorpath}
 813 default pager              : ${pagerpath}
 814 SASL support               : ${sasl_support}
 815 TLS support                : ${tls_support}
 816 ])])dnl
 817
 818 dnl ---------------
 819 dnl OUTPUT MAKEFILE
 820 dnl ---------------
 821 AC_CONFIG_FILES([Makefile test/common.sh])
 822 AC_OUTPUT