diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want client-side support for using SASL for authentication?
  27 dnl Note that this code will be enabled for both POP and SMTP
  28 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  29   [Enable SASL support via the Cyrus SASL library]))
  30 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != xyes -a \
  31             x"$with_cyrus_sasl" != xno],[
  32   AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  33   AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  34
  35 dnl Do you want client-side support for encryption with TLS?
  36 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  37
  38 dnl Do you want client-side support for using OAuth2 for SMTP & POP auth?
  39 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  40   [Enable OAuth2 support in SMTP and POP auth]))
  41
  42 dnl Set the backup prefix
  43 AC_ARG_WITH([hash-backup],
  44   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  45 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  46       [backup_prefix="#"], [backup_prefix=","])
  47 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  48     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  49
  50 dnl What method of posting should post use?
  51 AC_ARG_WITH([mts],
  52   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  53   [specify the default mail transport agent/service]))
  54
  55 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  56       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  57       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  58       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  59       [MTS="smtp"])
  60 AC_SUBST([MTS])dnl
  61
  62 dnl What should be the default mail server?
  63 AC_ARG_WITH([smtpserver],
  64   [AS_HELP_STRING([--with-smtpserver='SMTPSERVER'],
  65   [specify the default SMTP server @<:@localhost@:>@])])
  66 AS_IF([test -n "$with_smtpserver"], [smtpserver="$with_smtpserver"],
  67       [smtpserver="localhost"])
  68 AC_SUBST([smtpserver])dnl
  69
  70 dnl -------------------------------------------------------------------
  71 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  72 dnl find an existing installation, in which case we use its location.
  73 dnl -------------------------------------------------------------------
  74 AC_PREFIX_DEFAULT([/usr/local/nmh])
  75 AC_PREFIX_PROGRAM([mhparam])
  76
  77 dnl ------------------
  78 dnl CHECK THE COMPILER
  79 dnl ------------------
  80
  81 AC_PROG_CC([cc gcc])
  82 AM_PROG_CC_C_O
  83
  84 dnl ------------------
  85 dnl CHECK HEADER FILES
  86 dnl ------------------
  87
  88 AC_HEADER_TIOCGWINSZ
  89 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
  90                   sys/param.h sys/time.h sys/stream.h])
  91
  92 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
  93   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
  94 [[#if HAVE_SYS_STREAM_H
  95 #  include <sys/stream.h>
  96 #endif
  97 ]])
  98
  99 dnl ---------------
 100 dnl CHECK FUNCTIONS
 101 dnl ---------------
 102 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 103
 104 dnl Use custom getline for platforms that don't have it.
 105 AC_CONFIG_LIBOBJ_DIR([sbr])
 106 AC_REPLACE_FUNCS([getline])
 107
 108 dnl -----------------------
 109 dnl CHECK MULTIBYTE SUPPORT
 110 dnl -----------------------
 111 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 112             "x$ac_cv_header_wctype_h" = "xyes" -a \
 113             "x$ac_cv_func_wcwidth" = "xyes" -a \
 114             "x$ac_cv_func_mbtowc" = "xyes"],
 115       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 116                  [Define to enable support for multibyte character sets.])
 117        MULTIBYTE_ENABLED=1],
 118       [MULTIBYTE_ENABLED=0])
 119 AC_SUBST([MULTIBYTE_ENABLED])
 120
 121 dnl ----------------
 122 dnl CUSTOMIZE CFLAGS
 123 dnl ----------------
 124 dnl The user didn't specify CFLAGS, so customize them.
 125
 126 if test "$GCC" != yes; then
 127   dnl Use -v and some other options with SunStudio cc.  lex produces
 128   dnl code that causes unreachable-statement warnings.  It might be
 129   dnl better to use an autoconf test, except -v will probably succeed
 130   dnl with many other compilers but have different meaning.
 131   AS_CASE([`${CC} -V 2>&1`],
 132           [cc:*\ Sun\ C*], [CFLAGS=\
 133 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 134 fi
 135
 136 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 137                [nmh_saved_cflags="$CFLAGS"
 138                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 139                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 140                CFLAGS="$nmh_saved_cflags"])
 141 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 142
 143 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 144                [nmh_saved_cflags="$CFLAGS"
 145                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 146                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 147                               nmh_cv_has_wextra=no)
 148                CFLAGS="$nmh_saved_cflags"])
 149 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 150
 151 AC_SUBST([AM_CFLAGS])
 152
 153 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 154 dnl MULTIBYTE_ENABLED having already been set.
 155 NMH_ADDL_CPPFLAGS
 156
 157 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 158 dnl We do this here rather than in (say) h/mh.h because this macro must
 159 dnl be defined before <stdio.h> is pulled in.
 160 dnl
 161 dnl And while we're here, add the packages tree to the cpp and ld search
 162 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 163 dnl If /usr/ports is installed, we use its idea of where things are installed,
 164 dnl otherwise we assume /usr/local.
 165
 166 AS_IF([test `uname` = FreeBSD],
 167         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 168          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 169                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 170          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 171          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 172          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 173 ])
 174
 175 dnl --------------
 176 dnl CUSTOMIZE LINK
 177 dnl --------------
 178 AS_IF([test `uname` = OpenBSD],
 179       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 180       dnl so that they don't color the waterfall.
 181       [POSTLINK="2>&1 | sed -e \
 182 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 183 AC_SUBST([POSTLINK])
 184
 185 dnl -----------------
 186 dnl CUSTOMIZE LDFLAGS
 187 dnl -----------------
 188 dnl Disable clang complaint about unused -ansi when linking.
 189 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 190                [nmh_cv_has_q_unused_arguments],
 191                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 192                        grep clang >/dev/null`],
 193                       [nmh_saved_ldflags="$LDFLAGS"
 194                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 195                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 196                                          nmh_cv_has_q_unused_arguments=no)
 197                        LDFLAGS="$nmh_saved_ldflags"],
 198                        [nmh_cv_has_q_unused_arguments=no])])
 199 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 200   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 201 AC_SUBST([AM_LDFLAGS])
 202
 203 AC_HEADER_ASSERT
 204
 205 dnl ------------------
 206 dnl CHECK FOR PROGRAMS
 207 dnl ------------------
 208 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 209 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 210 AC_PROG_RANLIB          dnl Check for `ranlib'
 211 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 212 AC_PROG_SED             dnl Check for Posix-compliant sed
 213 AC_PROG_YACC            dnl Check for yacc/bison
 214 AM_PROG_LEX             dnl Check for lex/flex
 215
 216 AM_PROG_AR
 217
 218 dnl Look for `cut'
 219 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 220 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 221
 222 dnl
 223 dnl Check for MD5 program and formatting command
 224 dnl
 225 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 226 AS_CASE(["${MD5SUM}"],
 227         [md5sum], [MD5FMT="cat"],
 228         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 229         [MD5FMT="missing"])
 230 AC_SUBST([MD5FMT])
 231
 232 dnl Look for `ls'
 233 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 234 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 235
 236 dnl See how we get ls to display the owner and the group
 237 AS_IF([test "$lspath" != "no"],
 238   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 239                  [nmh_cv_ls_grpopt],
 240   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 241     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 242     dnl ls, it would seem -l gave us both the user and group.  On this type of
 243     dnl ls, -g makes _only_ the group be displayed (and not the user).
 244     nmh_cv_ls_grpopt="-l"],[
 245     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 246     nmh_cv_ls_grpopt="-lg"])])])
 247
 248 dnl Look for `sendmail'
 249 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 250 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 251
 252 dnl Cygwin FAT filesystems do not support hard links.  So default to
 253 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 254 dnl therefore, this cannot be made into a dynamic test, in order to
 255 dnl support the least common Cygwin denominator.
 256 AS_CASE(["$host_os"],
 257   [cygwin*], [LN=cp],
 258   [LN=ln])
 259 AC_SUBST([LN])
 260
 261 dnl ----------------------------------------------------------
 262 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 263 dnl ----------------------------------------------------------
 264 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 265 [for mailspool in /var/mail        dnl
 266                   /var/spool/mail  dnl
 267                   /usr/spool/mail  dnl
 268                   /dev/null;       dnl Just in case we fall through
 269 do
 270   test -d $mailspool && break
 271 done
 272 nmh_cv_mailspool=$mailspool
 273 ])
 274 mailspool=$nmh_cv_mailspool
 275 AC_SUBST([mailspool])dnl
 276
 277 dnl See whether the mail spool directory is world-writable.
 278 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 279   AC_CACHE_CHECK(whether the mail spool is world-writable,
 280                  nmh_cv_mailspool_world_writable,
 281   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 282     nmh_cv_mailspool_world_writable=no
 283   else
 284     nmh_cv_mailspool_world_writable=yes
 285   fi])
 286 fi
 287
 288 dnl Also, check for liblockfile (as found on Debian systems)
 289 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 290
 291 dnl and whether its companion program dotlockfile is setgid
 292 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 293 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 294   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 295     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 296     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 297         nmh_cv_dotlockfile_setgid=yes
 298       else
 299         nmh_cv_dotlockfile_setgid=no
 300       fi])
 301   fi
 302 fi
 303
 304 dnl Provide a way for distcheck to disable setgid_mail via
 305 dnl DISTCHECK_CONFIGURE_FLAGS.
 306 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 307   [nmh_cv_dotlockfile_setgid=yes])
 308
 309 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 310 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 311 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 312   dnl do we really need both of these?
 313   AC_DEFINE([MAILGROUP],[1],
 314     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 315   SETGID_MAIL=1
 316 fi
 317 AC_SUBST([SETGID_MAIL])dnl
 318
 319 dnl Use ls to see which group owns the mail spool directory.
 320 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 321 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 322 ])
 323 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 324 AC_SUBST([MAIL_SPOOL_GRP])dnl
 325
 326 NMH_MIMETYPEPROC
 327 NMH_MIMEENCODINGPROC
 328
 329 dnl -------------------
 330 dnl CHECK FOR LIBRARIES
 331 dnl -------------------
 332 dnl Checks for network libraries (nsl, socket)
 333 NMH_CHECK_NETLIBS
 334
 335 dnl Check the locking functions supported and what we should use by default
 336 NMH_LOCKING
 337
 338 dnl Check for iconv
 339 NMH_CHECK_ICONV
 340
 341 dnl Check for tputs() callback argument
 342 NMH_TPUTS_PUTC_ARG
 343
 344 termcap_curses_order="termcap curses ncurses"
 345 for lib in $termcap_curses_order; do
 346   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 347 done
 348 AC_SUBST([TERMLIB])dnl
 349 AS_IF([test "x$TERMLIB" = "x"],
 350       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 351 curses or ncurses library or package that you can install?])])
 352
 353 dnl Check for readline support
 354 NMH_READLINE
 355
 356 dnl --------------
 357 dnl CHECK FOR NDBM
 358 dnl --------------
 359
 360 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 361             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 362 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 363             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 364
 365 if test "$nmh_ndbm" = "autodetect"; then
 366   if test "$nmh_ndbmheader" != "autodetect"; then
 367     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 368   else
 369
 370     dnl There are at least four implementations of ndbm, and
 371     dnl several of those can be in different places at the whim
 372     dnl of the system integrator. A good summary of this mess
 373     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 374
 375     dnl Classic ndbm with no library required (eg NetBSD): try this
 376     dnl first so we don't accidentally link in a pointless but harmless
 377     dnl library in one of the later ndbm.h+libfoo tests:
 378     NMH_CHECK_NDBM(ndbm.h,,,
 379     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 380       NMH_CHECK_NDBM(db.h,db,,
 381     dnl Berkeley DBv1 emulating ndbm:
 382         NMH_CHECK_NDBM(ndbm.h,db,,
 383           NMH_CHECK_NDBM(ndbm.h,db1,,
 384     dnl Classic ndbm:
 385             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 386     dnl glibc2.1 systems put db1 in a subdir:
 387               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 388     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 389     dnl and possibly needing gbdm_compat library:
 390                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 391                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 392                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 393     dnl 64-bit Cygwin:
 394                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 395     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 396     dnl need to be explicit:
 397                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 398   fi
 399 else
 400   dnl We don't really need to check that the user-specified values work,
 401   dnl but it is a convenience to the user to bomb out early rather than
 402   dnl after configure and half the compile process.
 403   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 404 fi
 405
 406 if test "$nmh_ndbm_found" = "no"; then
 407   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 408 else
 409   dnl Now export the lib/header to our makefile/config.h:
 410   if test x"$nmh_ndbmheader" != x; then
 411     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 412       [Define to the header containing the ndbm API prototypes.])
 413   fi
 414   if test x"$nmh_ndbm" != x; then
 415     NDBM_LIBS="-l$nmh_ndbm"
 416   else
 417     NDBM_LIBS=
 418   fi
 419   AC_SUBST([NDBM_LIBS])
 420 fi
 421
 422 dnl ------------------
 423 dnl Set RPM build root
 424 dnl ------------------
 425 dnl nmhrpm is used in the final summary, see below.  The default value is
 426 dnl reported there as ./RPM, consistent with the reporting of the default
 427 dnl source code location as ., but its absolute path is used in the Makefile.
 428 AC_ARG_WITH([rpmdir],
 429   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 430   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 431           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 432 AC_SUBST([rpmdir])
 433
 434
 435 dnl --------------------
 436 dnl CHECK FOR CYRUS-SASL
 437 dnl --------------------
 438
 439 AS_IF([test x"$with_cyrus_sasl" != x"no"],[
 440   AC_CHECK_HEADER([sasl/sasl.h], HAVE_SASL_H=1)
 441   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"])])
 442 AC_SUBST([SASLLIB])
 443
 444 dnl -----------------
 445 dnl Enable SASL?
 446 dnl -----------------
 447 dnl By default (with_cyrus_sasl=''), enable SASL if header and lib are found.
 448 dnl If SASL requested (--with-cyrus-sasl with_cyrus_sasl=yes), error if header or lib not found.
 449 dnl If SASL disabled (--without-cyrus-sasl with_cyrus_sasl=no), don't enable it.
 450 sasl_support=no
 451 CYRUS_SASL=0
 452 AC_SUBST([CYRUS_SASL])
 453 AS_IF([test "x$with_cyrus_sasl" = xyes && test "x$HAVE_SASL_H" = x],
 454       [AC_MSG_ERROR([SASL requested but sasl.h not found])],
 455       [test "x$with_cyrus_sasl" = xyes && test "x$SASLLIB" = x],
 456       [AC_MSG_ERROR([SASL requested but Cyrus SASL library not found])],
 457       [test "x$with_cyrus_sasl" != xno && test "x$HAVE_SASL_H" = x1 &&
 458        test "x$SASLLIB" != x],
 459       [AC_DEFINE([CYRUS_SASL], [1],
 460         [Define to use the Cyrus SASL library for authentication of POP and SMTP.])
 461        CYRUS_SASL=1
 462        sasl_support=yes])
 463
 464 dnl -----------------
 465 dnl CHECK FOR OPENSSL
 466 dnl -----------------
 467
 468 AS_IF([test x"$with_tls" != x"no"],[
 469   dnl OpenBSD 5 needs the other-libraries (fifth argument) to the
 470   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 471   dnl automatically append -lcrypto when linking with -lssl.
 472   AC_CHECK_HEADER([openssl/ssl.h], HAVE_SSL_H=1)
 473   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"])
 474   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"], [TLSLIB=],
 475                [$TLSLIB])])
 476 AC_SUBST([TLSLIB])
 477
 478 dnl -----------------
 479 dnl Enable TLS?
 480 dnl -----------------
 481 dnl By default (with_tls=''), enable TLS if header and libs were found.
 482 dnl If TLS requested (--with-tls with_tls=yes), error if header/lib not found.
 483 dnl If TLS disabled (--without-tls with_tls=no), don't enable it.
 484 tls_support=no
 485 TLS_SUPPORT=0
 486 AC_SUBST([TLS_SUPPORT])
 487 AS_IF([test "x$with_tls" = xyes && test "x$HAVE_SSL_H" = x],
 488       [AC_MSG_ERROR([TLS requested but openssl/ssl.h not found])],
 489       [test "x$with_tls" = xyes && test "x$TLSLIB" = x],
 490       [AC_MSG_ERROR([TLS requested but crypto or ssl library not found])],
 491       [test "x$with_tls" != xno && test "x$HAVE_SSL_H" = x1 && test "x$TLSLIB" != x],
 492       [AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])
 493        TLS_SUPPORT=1
 494        tls_support=yes
 495        save_LIBS="$LIBS"
 496        LIBS="$LIBS $TLSLIB"
 497        AC_CHECK_FUNCS([X509_VERIFY_PARAM_set1_host])
 498        LIBS="$save_LIBS"])
 499
 500 dnl -----------------
 501 dnl CHECK FOR CURL
 502 dnl -----------------
 503 dnl Look for curl if oauth not disabled (--without-oauth).
 504 AC_PATH_PROG([curl_config], [curl-config])
 505 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 506     save_CFLAGS="$CFLAGS"
 507     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 508     AC_CHECK_HEADER([curl/curl.h], [
 509         HAVE_CURL_H=1
 510         AC_CHECK_LIB([curl], [curl_easy_init], [
 511             CURLLIB="`$curl_config --libs`"
 512             AC_SUBST([CURLLIB])
 513             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 514             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 515                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 516                    CURL_USER_AGENT=libcurl/UNKNOWN])
 517             AC_SUBST([CURL_USER_AGENT])
 518           ])
 519       ])
 520     CFLAGS="$save_CFLAGS"
 521   ])
 522
 523 dnl -----------------
 524 dnl Enable OAuth?
 525 dnl -----------------
 526 dnl By default (with_oauth=''), enable OAuth if curl is found.
 527 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 528 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 529 oauth_support=no
 530 OAUTH_SUPPORT=0
 531 AC_SUBST([OAUTH_SUPPORT])
 532 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 533       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 534       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 535       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 536       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 537       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 538        OAUTH_SUPPORT=1
 539        oauth_support=yes])
 540
 541 dnl ----------------
 542 dnl CHECK FLEX FIXUP
 543 dnl ----------------
 544 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 545 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 546 dnl http://sourceforge.net/p/flex/bugs/140/
 547 dnl 2.6.1 bug: https://github.com/westes/flex/issues/97
 548 AS_IF([test "$LEX" = flex],
 549       [AS_CASE([`$LEX -V`],
 550                [flex\ 2.5.35], [AM_LFLAGS=\
 551 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 552                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 553 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 554                [flex\ 2.6.0], [AM_LFLAGS=\
 555 '; sed "s/, num_to_read/, (size_t) num_to_read/" $@ >$@.tmp && mv -f $@.tmp $@;'],
 556                [flex\ 2.6.1], [AM_LFLAGS=\
 557 '; sed '\''/\<int num_to_read\>/s/int/size_t/; \
 558                 s/\<yy_size_t i\>/int i/; \
 559                 s/int n; \\/yy_size_t n; \\/'\'' $@ >$@.tmp && mv -f $@.tmp $@;'])
 560        AC_SUBST([AM_LFLAGS])])
 561
 562 dnl ------------------
 563 dnl FOR INTERNAL USE by the NMH test suite
 564 dnl ------------------
 565 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 566 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 567       AC_SUBST([nmhetcdirinst]))
 568
 569 dnl ----------------
 570 dnl CHECK STRUCTURES
 571 dnl ----------------
 572
 573 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 574 dnl (FreeBSD has a timezone() function but not a timezone global
 575 dnl variable that is visible).
 576 dnl On Linux, $AM_CPPFLAGS contains -D_GNU_SOURCE, which makes
 577 dnl tm_gmtoff visible.
 578 nmh_saved_CPPFLAGS="$CPPFLAGS"
 579 CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 580 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[[#include <time.h>]])
 581 CPPFLAGS="$nmh_saved_CPPFLAGS"
 582
 583 AC_STRUCT_DIRENT_D_TYPE
 584
 585 dnl
 586 dnl Sigh, this is required because under the new world order autoconf has
 587 dnl nothing to create in a few of the build directories when doing an object
 588 dnl tree build.  So make sure we created certain directories if they don't
 589 dnl exist.
 590 dnl
 591
 592 AC_CONFIG_COMMANDS([build-directories],
 593 [AS_MKDIR_P([etc]); AS_MKDIR_P([man])])
 594
 595 AC_CONFIG_COMMANDS_POST([
 596
 597 dnl These odd looking assignments are done to expand out unexpanded
 598 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 599 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 600 dnl again to get the final answer.
 601 dnl We only use the expanded versions to print the install paths in
 602 dnl the final summary and should use them nowhere else (see the autoconf
 603 dnl docs for the rationale for bindir etc being unexpanded).
 604 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 605 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 606 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 607 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 608 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 609 eval "nmhrpm=${nmhrpm}";
 610
 611 AC_MSG_NOTICE([
 612 nmh configuration
 613 -----------------
 614 nmh version                : AC_PACKAGE_VERSION
 615 host os                    : ${host}
 616 compiler                   : ${CC}
 617 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 618 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 619 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 620 source code location       : ${srcdir}
 621 binary install path        : ${nmhbin}
 622 libexec install path       : ${nmhlibexec}/nmh
 623 config files install path  : ${nmhsysconf}/nmh
 624 man page install path      : ${nmhman}
 625 docs install path          : ${nmhdoc}
 626 RPM build root             : ${nmhrpm}
 627 backup prefix              : ${backup_prefix}
 628 transport system           : ${MTS}
 629 spool default locking type : ${with_locking}
 630 default smtp server        : ${smtpserver}
 631 SASL support               : ${sasl_support}
 632 TLS support                : ${tls_support}
 633 OAuth support              : ${oauth_support}
 634 ])])dnl
 635
 636 dnl ---------------
 637 dnl OUTPUT MAKEFILE
 638 dnl ---------------
 639 AC_CONFIG_FILES([Makefile test/common.sh])
 640 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 641 AC_OUTPUT