diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl ----------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  79 dnl ----------------------------------------------------
  80 AC_PREFIX_DEFAULT([/usr/local/nmh])
  81
  82 dnl ------------------
  83 dnl CHECK THE COMPILER
  84 dnl ------------------
  85 dnl We want these before the checks,
  86 dnl so the checks can modify their values.
  87 test -z "$CFLAGS"  &&  auto_cflags=1
  88
  89 AC_PROG_CC([cc gcc])
  90 AM_PROG_CC_C_O
  91
  92 dnl ----------------
  93 dnl CUSTOMIZE CFLAGS
  94 dnl ----------------
  95 if test -n "$auto_cflags"; then
  96   dnl The user didn't specify CFLAGS, so customize them.
  97   if test "$GCC" = yes; then
  98     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
  99     dnl version 2.763, because it disables some features in the system
 100     dnl header files and warns about them with -Wall.  Try to test for
 101     dnl that generally, with gcc.
 102     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 103       [nmh_saved_cppflags="$CPPFLAGS"
 104        nmh_saved_cflags="$CFLAGS"
 105        CPPFLAGS="-D_GNU_SOURCE"
 106        CFLAGS="-ansi -Wall -Werror"
 107        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 108          [nmh_cv_has_dash_ansi=yes],
 109          [nmh_cv_has_dash_ansi=no])
 110        CPPFLAGS="$nmh_saved_cppflags"
 111        CFLAGS="$nmh_saved_cflags"])
 112     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 113       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 114   else
 115     dnl Use -v and some other options with SunStudio cc.  lex produces
 116     dnl code that causes unreachable-statement warnings.  It might be
 117     dnl better to use an autoconf test, except -v will probably succeed
 118     dnl with many other compilers but have different meaning.
 119     AS_CASE([`${CC} -V 2>&1`],
 120             [cc:\ Sun\ C*], [CFLAGS=\
 121 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 122   fi
 123
 124   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 125                  [nmh_saved_cflags="$CFLAGS"
 126                  CFLAGS="$CFLAGS -Wall -Werror"
 127                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 128                  CFLAGS="$nmh_saved_cflags"])
 129   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 130
 131   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 132                  [nmh_saved_cflags="$CFLAGS"
 133                  CFLAGS="$CFLAGS -Wextra -Werror"
 134                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 135                                 nmh_cv_has_wextra=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 138 fi
 139
 140 if test "$GCC" = yes; then
 141   dnl Do this regardless of auto_cflags value.
 142   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 143   dnl gcc 4.1 and later, but only when optimization is enabled.
 144   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 145   dnl If the user configures with a CFLAGS that contains a -O flag
 146   dnl but then removes it a make time, they'll also have to remove
 147   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 148   AS_CASE([$CFLAGS],
 149           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 150 fi
 151
 152 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 153 dnl We do this here rather than in (say) h/mh.h because this macro must
 154 dnl be defined before <stdio.h> is pulled in.
 155 dnl
 156 dnl And while we're here, add the packages tree to the cpp and ld search
 157 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 158 dnl If /usr/ports is installed, we use its idea of where things are installed,
 159 dnl otherwise we assume /usr/local.
 160
 161 AS_IF([test `uname` = FreeBSD],
 162         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 163          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 164                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 165          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 166          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 167          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 168 ])
 169
 170 dnl --------------
 171 dnl CUSTOMIZE LINK
 172 dnl --------------
 173 AS_IF([test `uname` = OpenBSD],
 174       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 175       dnl so that they don't color the waterfall.
 176       [POSTLINK="2>&1 | sed -e \
 177 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 178 AC_SUBST([POSTLINK])
 179
 180 dnl -----------------
 181 dnl CUSTOMIZE LDFLAGS
 182 dnl -----------------
 183 dnl Disable clang complaint about unused -ansi when linking.
 184 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 185                [nmh_cv_has_q_unused_arguments],
 186                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 187                        grep clang >/dev/null`],
 188                       [nmh_saved_ldflags="$LDFLAGS"
 189                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 190                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 191                                          nmh_cv_has_q_unused_arguments=no)
 192                        LDFLAGS="$nmh_saved_ldflags"],
 193                        [nmh_cv_has_q_unused_arguments=no])])
 194 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 195   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 196
 197 dnl This hack turns off assertions by default, assuming
 198 dnl that configure still uses this shell variable.  Without
 199 dnl it, AC_HEADER_ASSERT enables assertions by default.
 200 test -z "$enable_assert"  &&  enable_assert=no
 201
 202 AC_HEADER_ASSERT
 203
 204 dnl ------------------
 205 dnl CHECK FOR PROGRAMS
 206 dnl ------------------
 207 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 208 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 209 AC_PROG_RANLIB          dnl Check for `ranlib'
 210 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 211 AC_PROG_SED             dnl Check for Posix-compliant sed
 212 AM_PROG_LEX             dnl Check for lex/flex
 213
 214 AM_PROG_AR
 215
 216 dnl Look for `cut'
 217 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 218 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 219
 220 dnl
 221 dnl Check for MD5 program and formatting command
 222 dnl
 223 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 224 AS_CASE(["${MD5SUM}"],
 225         [md5sum], [MD5FMT="cat"],
 226         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 227         [MD5FMT="missing"])
 228 AC_SUBST([MD5FMT])
 229
 230 dnl Look for `ls'
 231 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 232 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 233
 234 dnl See how we get ls to display the owner and the group
 235 AS_IF([test "$lspath" != "no"],
 236   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 237                  [nmh_cv_ls_grpopt],
 238   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 239     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 240     dnl ls, it would seem -l gave us both the user and group.  On this type of
 241     dnl ls, -g makes _only_ the group be displayed (and not the user).
 242     nmh_cv_ls_grpopt="-l"],[
 243     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 244     nmh_cv_ls_grpopt="-lg"])])])
 245
 246 dnl Look for `sendmail'
 247 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 248 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 249
 250 dnl Cygwin FAT filesystems do not support hard links.  So default to
 251 dnl cp instead, even if running on an NTFS or other filesystem.
 252 AS_CASE(["$host_os"],
 253   [cygwin*], [LN=cp],
 254   [LN=ln])
 255 AC_SUBST([LN])
 256
 257 dnl ----------------------------------------------------------
 258 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 259 dnl ----------------------------------------------------------
 260 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 261 [for mailspool in /var/mail        dnl
 262                   /var/spool/mail  dnl
 263                   /usr/spool/mail  dnl
 264                   /dev/null;       dnl Just in case we fall through
 265 do
 266   test -d $mailspool && break
 267 done
 268 nmh_cv_mailspool=$mailspool
 269 ])
 270 mailspool=$nmh_cv_mailspool
 271 AC_SUBST([mailspool])dnl
 272
 273 dnl See whether the mail spool directory is world-writable.
 274 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 275   AC_CACHE_CHECK(whether the mail spool is world-writable,
 276                  nmh_cv_mailspool_world_writable,
 277   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 278     nmh_cv_mailspool_world_writable=no
 279   else
 280     nmh_cv_mailspool_world_writable=yes
 281   fi])
 282 fi
 283
 284 dnl Also, check for liblockfile (as found on Debian systems)
 285 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 286
 287 dnl and whether its companion program dotlockfile is setgid
 288 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 289 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 290   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 291     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 292     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 293         nmh_cv_dotlockfile_setgid=yes
 294       else
 295         nmh_cv_dotlockfile_setgid=no
 296       fi])
 297   fi
 298 fi
 299
 300 dnl Provide a way for distcheck to disable setgid_mail via
 301 dnl DISTCHECK_CONFIGURE_FLAGS.
 302 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 303   [nmh_cv_dotlockfile_setgid=yes])
 304
 305 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 306 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 307 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 308   dnl do we really need both of these?
 309   AC_DEFINE([MAILGROUP],[1],
 310     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 311   SETGID_MAIL=1
 312 fi
 313 AC_SUBST([SETGID_MAIL])dnl
 314
 315 dnl Use ls to see which group owns the mail spool directory.
 316 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 317 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 318 ])
 319 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 320 AC_SUBST([MAIL_SPOOL_GRP])dnl
 321
 322 NMH_MIMETYPEPROC
 323 NMH_MIMEENCODINGPROC
 324
 325 dnl ------------------
 326 dnl CHECK HEADER FILES
 327 dnl ------------------
 328
 329 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 330 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 331 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 332 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 333 dnl declared; if so they should have an entry added to this case statement.
 334 dnl NB that we must define this on the compiler command line, not in config.h,
 335 dnl because it must be set before any system header is included and there's no
 336 dnl portable way to make sure that files generated by lex include config.h
 337 dnl before system header files.
 338
 339 AS_CASE(["$host_os"],
 340         [linux*],
 341         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 342         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 343
 344 AC_HEADER_TIOCGWINSZ
 345 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 346
 347 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 348   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 349 [[#if HAVE_SYS_STREAM_H
 350 #  include <sys/stream.h>
 351 #endif
 352 ]])
 353
 354 dnl ---------------
 355 dnl CHECK FUNCTIONS
 356 dnl ---------------
 357 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 358
 359 dnl Check for multibyte character set support
 360 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 361             "x$ac_cv_header_wctype_h" = "xyes" -a \
 362             "x$ac_cv_func_wcwidth" = "xyes" -a \
 363             "x$ac_cv_func_mbtowc" = "xyes"],
 364       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 365                  [Define to enable support for multibyte character sets.])
 366        MULTIBYTE_ENABLED=1],
 367       [MULTIBYTE_ENABLED=0])
 368 AC_SUBST([MULTIBYTE_ENABLED])
 369
 370 dnl -------------------
 371 dnl CHECK FOR LIBRARIES
 372 dnl -------------------
 373 dnl Checks for network libraries (nsl, socket)
 374 NMH_CHECK_NETLIBS
 375
 376 dnl Check the locking functions supported and what we should use by default
 377 NMH_LOCKING
 378
 379 dnl Check for iconv
 380 NMH_CHECK_ICONV
 381
 382 dnl Check for tputs() callback argument
 383 NMH_TPUTS_PUTC_ARG
 384
 385 termcap_curses_order="termcap curses ncurses"
 386 for lib in $termcap_curses_order; do
 387   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 388 done
 389 AC_SUBST([TERMLIB])dnl
 390 AS_IF([test "x$TERMLIB" = "x"],
 391       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 392 curses or ncurses library or package that you can install?])])
 393
 394 dnl Check for readline support
 395 NMH_READLINE
 396
 397 dnl --------------
 398 dnl CHECK FOR NDBM
 399 dnl --------------
 400
 401 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 402             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 403 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 404             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 405
 406 if test "$nmh_ndbm" = "autodetect"; then
 407   if test "$nmh_ndbmheader" != "autodetect"; then
 408     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 409   else
 410
 411     dnl There are at least four implementations of ndbm, and
 412     dnl several of those can be in different places at the whim
 413     dnl of the system integrator. A good summary of this mess
 414     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 415
 416     dnl Classic ndbm with no library required (eg NetBSD): try this
 417     dnl first so we don't accidentally link in a pointless but harmless
 418     dnl library in one of the later ndbm.h+libfoo tests:
 419     NMH_CHECK_NDBM(ndbm.h,,,
 420     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 421       NMH_CHECK_NDBM(db.h,db,,
 422     dnl Berkeley DBv1 emulating ndbm:
 423         NMH_CHECK_NDBM(ndbm.h,db,,
 424           NMH_CHECK_NDBM(ndbm.h,db1,,
 425     dnl Classic ndbm:
 426             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 427     dnl glibc2.1 systems put db1 in a subdir:
 428               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 429     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 430     dnl and possibly needing gbdm_compat library:
 431                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 432                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 433                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 434     dnl 64-bit Cygwin:
 435                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 436     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 437     dnl need to be explicit:
 438                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 439   fi
 440 else
 441   dnl We don't really need to check that the user-specified values work,
 442   dnl but it is a convenience to the user to bomb out early rather than
 443   dnl after configure and half the compile process.
 444   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 445 fi
 446
 447 if test "$nmh_ndbm_found" = "no"; then
 448   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 449 else
 450   dnl Now export the lib/header to our makefile/config.h:
 451   if test x"$nmh_ndbmheader" != x; then
 452     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 453       [Define to the header containing the ndbm API prototypes.])
 454   fi
 455   if test x"$nmh_ndbm" != x; then
 456     NDBM_LIBS="-l$nmh_ndbm"
 457   else
 458     NDBM_LIBS=
 459   fi
 460   AC_SUBST([NDBM_LIBS])
 461 fi
 462
 463 dnl ------------------
 464 dnl Set RPM build root
 465 dnl ------------------
 466 dnl nmhrpm is used in the final summary, see below.  The default value is
 467 dnl reported there as ./RPM, consistent with the reporting of the default
 468 dnl source code location as ., but its absolute path is used in the Makefile.
 469 AC_ARG_WITH([rpmdir],
 470   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 471   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 472           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 473 AC_SUBST([rpmdir])
 474
 475
 476 dnl --------------------
 477 dnl CHECK FOR CYRUS-SASL
 478 dnl --------------------
 479
 480 AS_IF([test x"$sasl_support" = x"yes"],[
 481   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 482   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 483     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 484 AC_SUBST([SASLLIB])
 485
 486 dnl -----------------
 487 dnl CHECK FOR OPENSSL
 488 dnl -----------------
 489
 490 AS_IF([test x"$tls_support" = x"yes"],[
 491   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 492   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 493   dnl automatically append -lcrypto when linking with -lssl.
 494   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 495   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 496     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 497   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 498     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 499   [TLSLIB=])
 500 AC_SUBST([TLSLIB])
 501
 502 dnl ----------------
 503 dnl CHECK FLEX FIXUP
 504 dnl ----------------
 505 dnl Use LFLAGS make variable setting to work around bugs in flex
 506 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 507 dnl http://sourceforge.net/p/flex/bugs/140/
 508 AS_IF([test "$LEX" = flex],
 509       [AS_CASE([`$LEX -V`],
 510                [flex\ 2.5.35], [LFLAGS=\
 511 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 512                [flex\ 2.5.3[[67]]], [LFLAGS=\
 513 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 514        AC_SUBST([LFLAGS])])
 515
 516 dnl ----------------
 517 dnl CHECK STRUCTURES
 518 dnl ----------------
 519
 520 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 521 dnl (FreeBSD has a timezone() function but not a timezone global
 522 dnl variable that is visible).
 523 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 524
 525 AC_STRUCT_DIRENT_D_TYPE
 526
 527 dnl Where is <signal.h> located?  Needed as input for signames.awk
 528 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 529 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 530                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 531                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 532                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 533                  /usr/include/sys/signal.h      dnl Almost everybody else
 534                  /dev/null;                     dnl Just in case we fall through
 535 do
 536   test -f $SIGNAL_H && \
 537   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 538   break
 539 done
 540 nmh_cv_path_signal_h=$SIGNAL_H
 541 ])
 542 SIGNAL_H=$nmh_cv_path_signal_h
 543 AC_SUBST(SIGNAL_H)dnl
 544
 545 dnl
 546 dnl Sigh, this is required because under the new world order autoconf has
 547 dnl nothing to create in a few of the build directories when doing an object
 548 dnl tree build.  So make sure we created certain directories if they don't
 549 dnl exist.
 550 dnl
 551
 552 AC_CONFIG_COMMANDS([build-directories],
 553 [test -d man || AS_MKDIR_P([man])])
 554
 555 AC_CONFIG_COMMANDS_POST([
 556
 557 dnl These odd looking assignments are done to expand out unexpanded
 558 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 559 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 560 dnl again to get the final answer.
 561 dnl We only use the expanded versions to print the install paths in
 562 dnl the final summary and should use them nowhere else (see the autoconf
 563 dnl docs for the rationale for bindir etc being unexpanded).
 564 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 565 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 566 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 567 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 568 eval "nmhrpm=${nmhrpm}";
 569
 570 AC_MSG_NOTICE([
 571 nmh configuration
 572 -----------------
 573 nmh version                : AC_PACKAGE_VERSION
 574 host os                    : ${host}
 575 compiler                   : ${CC}
 576 compiler flags             : ${CFLAGS}
 577 linker flags               : ${LDFLAGS}
 578 preprocessor flags         : ${CPPFLAGS}
 579 source code location       : ${srcdir}
 580 binary install path        : ${nmhbin}
 581 library install path       : ${nmhlib}
 582 config files install path  : ${nmhsysconf}
 583 man page install path      : ${nmhman}
 584 RPM build root             : ${nmhrpm}
 585 backup prefix              : ${backup_prefix}
 586 transport system           : ${MTS}
 587 spool default locking type : ${with_locking}
 588 default smtp servers       : ${smtpservers}
 589 SASL support               : ${sasl_support}
 590 TLS support                : ${tls_support}
 591 ])])dnl
 592
 593 dnl ---------------
 594 dnl OUTPUT MAKEFILE
 595 dnl ---------------
 596 AC_CONFIG_FILES([Makefile test/common.sh])
 597 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 598 AC_OUTPUT