diplodocus.org Git - nmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl 2.13 definitely chokes; 2.53 is the earliest version I've tested.
   8 dnl 2.58 needed for help string macro but that only affects help output
   9 dnl 2.50 is the major breakpoint between the old autoconf and the new,
  10 dnl so require that. If there are bug reports about 2.50-2.52 not working
  11 dnl we can always move this up a little.
  12 AC_PREREQ(2.50)
  13
  14 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  15 AC_CONFIG_SRCDIR(h/nmh.h)
  16 AC_CONFIG_HEADER(config.h)
  17
  18 AC_CANONICAL_TARGET
  19
  20 dnl ---------------------
  21 dnl define a macro or two
  22 dnl ---------------------
  23
  24 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  25 if test -n "$LIBTOOL" ; then
  26   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  27   if test x"$tmptest" != x  ; then
  28     GNU_LIBTOOL=1
  29     AC_SUBST(GNU_LIBTOOL)dnl
  30   fi
  31 fi
  32 ] )
  33
  34 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  35 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  36
  37 dnl What date of nmh are we building?
  38 DATE=`cat ${srcdir}/DATE`
  39 echo "configuring for nmh dated $DATE"
  40 AC_SUBST(DATE)dnl
  41
  42 dnl --------------------------
  43 dnl CHECK COMMAND LINE OPTIONS
  44 dnl --------------------------
  45
  46 dnl Do you want client-side support for apop?
  47 AC_ARG_ENABLE(apop, AS_HELP_STRING([--enable-apop],
  48   [enable client-side support for POP3 and APOP]))
  49 if test x"$enable_apop" = x"yes"; then
  50   AC_DEFINE(APOP, 1,
  51     [Define to compile client-side support for apop into inc and msgchk.])dnl
  52   APOPLIB=md5.o
  53   enable_pop=yes
  54 fi
  55 AC_SUBST(APOPLIB)dnl
  56
  57 dnl Do you want to debug nmh?
  58 AC_ARG_ENABLE(debug,
  59   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  60 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  61 if test x"$enable_nmh_debug" = x"yes"; then
  62   enable_debug=yes
  63 fi
  64
  65 dnl Allow users to send email from addresses other than their default?
  66 AC_ARG_ENABLE(masquerade,
  67   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  68     [enable up to 3 types of address masquerading]),
  69   [if test x"$enable_masquerade" = x"yes"; then
  70     masquerade="draft_from mmailid username_extension"
  71   else
  72     masquerade="$enable_masquerade"
  73   fi],
  74   masquerade="draft_from mmailid username_extension")
  75 AC_SUBST(masquerade)dnl
  76
  77 dnl Do you want mhe support?
  78 AC_ARG_ENABLE(mhe,
  79   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  80
  81 dnl mhe support is on by default, so define it unless --disable-mhe or the
  82 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  83 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  84   AC_DEFINE(MHE, 1,
  85     [Define to compile in support for the Emacs front-end mh-e.])dnl
  86 fi
  87
  88 dnl Do you want client-side support for pop?
  89 AC_ARG_ENABLE(pop,
  90   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  91 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  92 if test x"$enable_nmh_pop" = x"yes"; then
  93   enable_pop=yes
  94 fi
  95
  96 dnl Do you want to disable use of locale functions
  97 AH_TEMPLATE([LOCALE],
  98 [Undefine if you don't want locale features.  By default this is defined.])
  99 AC_ARG_ENABLE([locale],
 100 AC_HELP_STRING([--disable-locale], [turn off locale features]),
 101 [if test x$enableval = xyes; then
 102   AC_DEFINE(LOCALE)
 103 fi],
 104 AC_DEFINE(LOCALE)
 105 )
 106
 107 dnl Do you want client-side support for using SASL for authentication?
 108 dnl Note that this code will be enabled for both POP and SMTP
 109 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl=DIR],
 110   [specify location of Cyrus SASL library]))
 111 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 112   AC_DEFINE(CYRUS_SASL, 1,
 113     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
 114   sasl_support=yes
 115 else
 116   sasl_support=no
 117 fi
 118
 119 dnl What should be the default editor?
 120 AC_ARG_WITH(editor,
 121   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 122
 123 if test -n "$with_editor"; then
 124   editorpath="$with_editor"
 125 fi
 126
 127 dnl Set the backup prefix
 128 AC_ARG_WITH([hash-backup],
 129   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 130 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 131   backup_prefix="#"
 132 else
 133   backup_prefix=","
 134 fi
 135 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 136     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 137
 138 dnl Do you want support for hesiod
 139 AC_ARG_WITH(hesiod,
 140   AS_HELP_STRING([--with-hesiod=DIR],[specify location of Hesiod]))
 141 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 142   AC_DEFINE(HESIOD,1,[Define this to compile support for using Hesiod.])dnl
 143 fi
 144
 145 dnl Do you want client-side support for kpop
 146 AC_ARG_WITH(krb4, AS_HELP_STRING([--with-krb4=DIR],
 147   [specify location of Kerberos V4 for KPOP support]))
 148 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 149   enable_pop=yes
 150   AC_DEFINE(KPOP, 1,
 151     [Define to compile client-side support for kpop (kerberized pop) into inc and msgchk.])dnl
 152   AC_DEFINE(KPOP_PRINCIPAL, "pop", [Define this to "pop" when using Kerberos V4])dnl
 153 fi
 154
 155 dnl After we know if we're including apop and kpop support, do pop stuff
 156 if test x"$enable_pop" = x"yes"; then
 157   AC_DEFINE(POP, 1,
 158     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 159   POPLIB=popsbr.o
 160   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 161 else
 162   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 163 fi
 164 AC_SUBST(POPLIB)dnl
 165 AC_SUBST(POPSED)dnl
 166
 167 dnl What method of locking to use?
 168 AC_ARG_WITH(locking,
 169   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 170   [specify the file locking method]))
 171
 172 if test x"$with_locking" = x"dot"; then
 173   LOCKTYPE="dot"
 174   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 175 elif test x"$with_locking" = x"flock"; then
 176   LOCKTYPE="flock"
 177   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 178 elif test x"$with_locking" = x"lockf"; then
 179   LOCKTYPE="lockf"
 180   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 181 elif test x"$with_locking" = x"fcntl"; then
 182   LOCKTYPE="fcntl"
 183   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 184 else
 185   LOCKTYPE="dot"
 186   AC_DEFINE(DOT_LOCKING)dnl
 187 fi
 188
 189 dnl What method of posting should post use?
 190 AC_ARG_WITH(mts,
 191   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 192   [specify the default mail transport agent/service]))
 193
 194 if test x"$with_mts" = x"smtp"; then
 195   MTS="smtp"
 196 elif test x"$with_mts" = x"sendmail"; then
 197   MTS="sendmail"
 198 else
 199   MTS="smtp"
 200 fi
 201 AC_SUBST(MTS)dnl
 202
 203 dnl Both the smtp and sendmail mail transport services use the smtp code
 204 AC_DEFINE(SMTPMTS, 1,
 205   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 206
 207 dnl What should be the default pager?
 208 AC_ARG_WITH(pager,
 209   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 210
 211 if test -n "$with_pager"; then
 212   pagerpath="$with_pager"
 213 fi
 214
 215 dnl What should be the default mail server(s)?
 216 AC_ARG_WITH(smtpservers,
 217   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 218   [specify the default SMTP server(s) @<:@localhost@:>@]))
 219 if test -n "$with_smtpservers"; then
 220   smtpservers="$with_smtpservers"
 221 else
 222   smtpservers="localhost"
 223 fi
 224 AC_SUBST(smtpservers)dnl
 225
 226 dnl ----------------------------------------------------
 227 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 228 dnl ----------------------------------------------------
 229 AC_PREFIX_DEFAULT(/usr/local/nmh)
 230
 231 dnl ------------------
 232 dnl CHECK THE COMPILER
 233 dnl ------------------
 234 dnl We want these before the checks,
 235 dnl so the checks can modify their values.
 236 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 237 if test x"$enable_debug" = x"yes"; then
 238   test -z "$LDFLAGS" && LDFLAGS=-g
 239 fi
 240
 241 AC_PROG_CC
 242
 243 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 244 [nmh_saved_cflags="$CFLAGS"
 245  CFLAGS="$CFLAGS -Wno-pointer-sign"
 246  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 247  CFLAGS="$nmh_saved_cflags"])
 248
 249 dnl if the user hasn't specified CFLAGS, then
 250 dnl   if compiler is gcc, then
 251 dnl     use -O2 and some warning flags
 252 dnl   else use -O
 253 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 254 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 255 dnl spurious and which in any case we don't want to deal with now.
 256 if test "$nmh_cv_has_noptrsign" = "yes"; then
 257         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 258 else
 259         nmh_gcc_warnflags="-Wall"
 260 fi
 261
 262 if test -n "$auto_cflags"; then
 263   if test x"$enable_debug" = x"yes"; then
 264     if test -n "$GCC"; then
 265       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 266     else
 267       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 268     fi
 269   else
 270     if test -z "$LDFLAGS"; then
 271       case "$build_os" in
 272         darwin*)
 273           LDFLAGS=
 274           ;;
 275         *)
 276           LDFLAGS=-s
 277           ;;
 278       esac
 279     fi
 280     if test -n "$GCC"; then
 281       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 282     else
 283       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 284     fi
 285   fi
 286 fi
 287
 288 AC_C_CONST              dnl Does compiler support `const'.
 289
 290 dnl ------------------
 291 dnl CHECK FOR PROGRAMS
 292 dnl ------------------
 293 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 294 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 295 AC_PROG_RANLIB          dnl Check for `ranlib'
 296 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 297 AC_PROG_LEX             dnl Check for lex/flex
 298
 299 dnl Look for `cut'
 300 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 301 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 302
 303 dnl ----------------------------------------------
 304 dnl check for lclint, and lint if it doesn't exist
 305 dnl ----------------------------------------------
 306 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 307 if test x$ac_cv_prog_linttmp1 != xno ; then
 308   LINT=$ac_cv_prog_linttmp1
 309   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 310 else
 311   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 312   if test x$ac_cv_prog_linttmp2 != xno ; then
 313     LINT=$ac_cv_prog_linttmp2
 314     LINTFLAGS=""
 315   else
 316     LINT="echo 'No lint program found'"
 317     LINTFLAGS=""
 318   fi
 319 fi
 320 AC_SUBST(LINT)dnl
 321 AC_SUBST(LINTFLAGS)dnl
 322
 323 dnl try to figure out which one we've got
 324 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 325 NMH_PROG_GNU_LIBTOOL
 326
 327 dnl Check for lorder and tsort commands
 328 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 329 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 330
 331 dnl If either doesn't exist, replace them with echo and cat
 332 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 333   LORDER=echo
 334   TSORT=cat
 335   AC_SUBST(LORDER)dnl
 336   AC_SUBST(TSORT)dnl
 337 dnl Mac OS X has lorder, but sh is too broken for it to work
 338 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 339 dnl   LORDER=echo
 340 dnl   TSORT=cat
 341 dnl   AC_SUBST(LORDER)dnl
 342 dnl   AC_SUBST(TSORT)dnl
 343 fi
 344
 345 dnl Check whether tsort can deal with loops
 346 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 347   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 348     nmh_cv_tsort_loop=no
 349   else
 350     nmh_cv_tsort_loop=yes
 351   fi])
 352 if test x$nmh_cv_tsort_loop = xno ; then
 353   LORDER=echo
 354   TSORT=cat
 355   AC_SUBST(LORDER)dnl
 356   AC_SUBST(TSORT)dnl
 357 fi
 358
 359 dnl Look for `ls'
 360 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 361 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 362
 363 dnl See how we get ls to display the owner and the group
 364 if test "$lspath" != "no"; then
 365   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 366                  nmh_cv_ls_grpopt,
 367   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 368     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 369     dnl ls, it would seem -l gave us both the user and group.  On this type of
 370     dnl ls, -g makes _only_ the group be displayed (and not the user).
 371     nmh_cv_ls_grpopt="-l"
 372   else
 373     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 374     nmh_cv_ls_grpopt="-lg"
 375   fi])
 376 fi
 377
 378 dnl Look for `more'
 379 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 380 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 381
 382 dnl If pager is not specified yet,
 383 dnl then use `more' as the default.
 384 if test -z "$pagerpath"; then
 385   pagerpath="$morepath"
 386 fi
 387 AC_SUBST(pagerpath)dnl
 388
 389 dnl Look for `sendmail'
 390 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 391 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 392
 393 dnl Look for `vi'
 394 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 395 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 396
 397 dnl If editor is not specified yet,
 398 dnl then use `vi' as the default.
 399 if test -z "$editorpath"; then
 400   editorpath="$vipath"
 401 fi
 402 AC_SUBST(editorpath)dnl
 403
 404 dnl ----------------------------------------------------------
 405 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 406 dnl ----------------------------------------------------------
 407 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 408 [for mailspool in /var/mail        dnl
 409                   /var/spool/mail  dnl
 410                   /usr/spool/mail  dnl
 411                   /dev/null;       dnl Just in case we fall through
 412 do
 413   test -d $mailspool && break
 414 done
 415 nmh_cv_mailspool=$mailspool
 416 ])
 417 mailspool=$nmh_cv_mailspool
 418 AC_SUBST(mailspool)dnl
 419
 420 dnl See whether the mail spool directory is world-writable.
 421 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 422   AC_CACHE_CHECK(whether the mail spool is world-writable,
 423                  nmh_cv_mailspool_world_writable,
 424   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 425     nmh_cv_mailspool_world_writable=no
 426   else
 427     nmh_cv_mailspool_world_writable=yes
 428   fi])
 429 fi
 430
 431 dnl Also, check for liblockfile (as found on Debian systems)
 432 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 433
 434 dnl and whether its companion program dotlockfile is setgid
 435 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 436 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 437   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 438     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 439     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 440         nmh_cv_dotlockfile_setgid=yes
 441       else
 442         nmh_cv_dotlockfile_setgid=no
 443       fi])
 444   fi
 445 fi
 446
 447 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 448 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 449 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 450   dnl do we really need both of these?
 451   AC_DEFINE(MAILGROUP,1,
 452     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 453   SETGID_MAIL=1
 454 fi
 455 AC_SUBST(SETGID_MAIL)dnl
 456
 457 dnl Use ls to see which group owns the mail spool directory.
 458 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 459 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 460 ])
 461 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 462 AC_SUBST(MAIL_SPOOL_GRP)dnl
 463
 464 dnl ------------------
 465 dnl CHECK HEADER FILES
 466 dnl ------------------
 467
 468 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 469 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 470 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 471 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 472 dnl declared; if so they should have an entry added to this case statement.
 473 dnl NB that we must define this on the compiler command line, not in config.h,
 474 dnl because it must be set before any system header is included and there's no
 475 dnl portable way to make sure that files generated by lex include config.h
 476 dnl before system header files.
 477
 478 case "$target_os" in
 479   linux*)
 480     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 481     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 482     ;;
 483 esac
 484 AC_SUBST(OURDEFS)
 485
 486 AC_HEADER_DIRENT
 487 AC_HEADER_STDC
 488 AC_HEADER_TIME
 489 AC_HEADER_SYS_WAIT
 490 AC_HEADER_STAT
 491 AC_HEADER_TIOCGWINSZ
 492 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 493                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 494                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 495                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 496                  arpa/inet.h arpa/ftp.h)
 497
 498 dnl
 499 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 500 dnl really use a whole set of them, but this check should be
 501 dnl sufficient.
 502 dnl
 503 AC_CHECK_HEADER(libio.h, [
 504   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 505     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 506
 507 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 508   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 509 [[#if HAVE_SYS_STREAM_H
 510 #  include <sys/stream.h>
 511 #endif
 512 ]])
 513
 514 dnl ---------------
 515 dnl CHECK FUNCTIONS
 516 dnl ---------------
 517 AC_FUNC_VFORK
 518 AC_CHECK_LIB(mkstemp,mkstemp)
 519 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 520                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 521                getutent nl_langinfo mbtowc wcwidth)
 522
 523 dnl solaris has these in the nsl library
 524 AC_SEARCH_LIBS(gethostbyname, nsl,
 525   [AC_DEFINE(HAVE_GETHOSTBYNAME,1,
 526     [Define to 1 if you have the `gethostbyname' function.])])
 527 AC_SEARCH_LIBS(sethostent, nsl,
 528   [AC_DEFINE(HAVE_SETHOSTENT,1,
 529     [Define to 1 if you have the `sethostent' function.])])
 530
 531 dnl sigsetjmp may be a macro
 532 AC_MSG_CHECKING(for sigsetjmp)
 533 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 534   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 535     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 536   [AC_MSG_RESULT(no)])
 537
 538 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 539
 540 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 541 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 542 dnl any system header.
 543 dnl
 544 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 545 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 546 dnl need to check?
 547 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 548 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 549                 AC_EGREP_HEADER(initgroups, unistd.h,
 550                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 551
 552 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 553 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 554 dnl seems to work perfectly and IBM apparently uses it in internal code).
 555 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 556 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 557 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 558 dnl prototype.
 559 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 560   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 561
 562 dnl Check for multibyte character set support
 563 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 564     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 565   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 566     [Define to enable support for multibyte character sets.])
 567 fi
 568
 569 dnl -------------------
 570 dnl CHECK FOR LIBRARIES
 571 dnl -------------------
 572 dnl Check location of modf
 573 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 574
 575 dnl Checks for network libraries (nsl, socket)
 576 AC_CHECK_NETLIBS
 577
 578 termcap_curses_order="termcap curses ncurses"
 579 for lib in $termcap_curses_order; do
 580   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 581 done
 582 AC_SUBST(TERMLIB)dnl
 583
 584 dnl ---------------
 585 dnl CHECK FOR ICONV
 586 dnl ---------------
 587
 588 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 589 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 590   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 591   if test "x$ac_found_iconv" = "xno"; then
 592     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 593     if test "x$ac_found_iconv" = "xno"; then
 594       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 595     fi
 596     if test "x$ac_found_iconv" != "xno"; then
 597       LIBS="-liconv $LIBS"
 598     fi
 599   else
 600     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 601     AC_CHECK_DECL(_libiconv_version,
 602       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 603       [ #include <iconv.h> ])
 604   fi
 605 fi
 606 if test "x$ac_found_iconv" = xyes; then
 607   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 608 fi
 609
 610 dnl Check if iconv uses const in prototype declaration
 611 if test "x$ac_found_iconv" = "xyes"; then
 612   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 613     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 614         #include <iconv.h>]],
 615         [[#ifdef __cplusplus
 616           "C"
 617           #endif
 618           #if defined(__STDC__) || defined(__cplusplus)
 619           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 620           #else
 621           size_t iconv();
 622           #endif]])],
 623       [ac_cv_iconv_const=],
 624       [ac_cv_iconv_const=const])])
 625   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 626     [Define as const if the declaration of iconv() needs const.])
 627 fi
 628
 629 dnl --------------
 630 dnl CHECK FOR NDBM
 631 dnl --------------
 632
 633 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 634             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 635 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 636             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 637
 638 if test "$nmh_ndbm" = "autodetect"; then
 639   if test "$nmh_ndbmheader" != "autodetect"; then
 640     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 641   else
 642
 643     dnl There are at least four implementations of ndbm, and
 644     dnl several of those can be in different places at the whim
 645     dnl of the system integrator. A good summary of this mess
 646     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 647
 648     dnl Classic ndbm with no library required (eg NetBSD): try this
 649     dnl first so we don't accidentally link in a pointless but harmless
 650     dnl library in one of the later ndbm.h+libfoo tests:
 651     NMH_CHECK_NDBM(ndbm.h,,,
 652     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 653       NMH_CHECK_NDBM(db.h,db,,
 654     dnl Berkeley DBv1 emulating ndbm:
 655         NMH_CHECK_NDBM(ndbm.h,db,,
 656           NMH_CHECK_NDBM(ndbm.h,db1,,
 657     dnl Classic ndbm:
 658             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 659     dnl glibc2.1 systems put db1 in a subdir:
 660               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 661     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 662     dnl and possibly needing gbdm_compat library:
 663                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 664                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 665                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 666                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 667
 668   fi
 669 else
 670   dnl We don't really need to check that the user-specified values work,
 671   dnl but it is a convenience to the user to bomb out early rather than
 672   dnl after configure and half the compile process.
 673   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 674 fi
 675
 676 if test "$nmh_ndbm_found" = "no"; then
 677   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 678 else
 679   dnl Now export the lib/header to our makefile/config.h:
 680   if test x"$nmh_ndbmheader" != x; then
 681     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 682       [Define to the header containing the ndbm API prototypes.])
 683   fi
 684   if test x"$nmh_ndbm" != x; then
 685     NDBM_LIBS="-l$nmh_ndbm"
 686   else
 687     NDBM_LIBS=
 688   fi
 689   AC_SUBST(NDBM_LIBS)
 690 fi
 691
 692
 693 dnl ----------------
 694 dnl CHECK FOR HESIOD
 695 dnl ----------------
 696 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 697   if test x"$with_hesiod" != x"yes"; then
 698     HESIOD_INCLUDES="-I$with_hesiod/include"
 699     HESIOD_LIBS="-L$with_hesiod/lib"
 700   fi
 701   AC_CHECK_FUNC(res_send,
 702         [AC_CHECK_LIB(hesiod, hes_resolve,
 703                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 704                 [AC_MSG_ERROR(Hesiod library not found)],
 705                 $HESIOD_LIBS)],
 706         [AC_CHECK_LIB(hesiod, hes_resolve,
 707                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 708                 [AC_MSG_ERROR(Hesiod library not found)],
 709                 $HESIOD_LIBS -lresolv)])
 710
 711 fi
 712 AC_SUBST(HESIOD_INCLUDES)dnl
 713 AC_SUBST(HESIOD_LIBS)dnl
 714
 715 dnl ----------------------------------
 716 dnl CHECK FOR KRB4 (Kerberos4 support)
 717 dnl ----------------------------------
 718 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 719   if test x"$with_krb4" != x"yes"; then
 720     KRB4_INCLUDES="-I$with_krb4/include"
 721     if test -d "$with_krb4/include/kerberosIV"; then
 722       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 723     fi
 724     KRB4_LIBS="-L$with_krb4/lib"
 725   elif test -d /usr/include/kerberosIV; then
 726     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 727   fi
 728 dnl First, check if we have -lk5crypto, since that means we have a recent krb5
 729
 730   AC_CHECK_LIB(k5crypto, krb5_encrypt,
 731         [AC_CHECK_LIB(krb4, krb_rd_req,
 732                 [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lk5crypto -lcom_err"],
 733                 [AC_MSG_ERROR(Kerberos 4 compatibility libraries not found)],
 734                 $KRB4_LIBS -ldes425 -lkrb5 -lk5crypto -lcom_err)],
 735
 736         [AC_CHECK_LIB(krb4, krb_rd_req,
 737             [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 738             [AC_CHECK_LIB(krb, krb_rd_req,
 739               [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 740               [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 741               $KRB4_LIBS -ldes)],
 742             $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)],
 743         $KRB4_LIBS)
 744
 745 fi
 746 AC_SUBST(KRB4_INCLUDES)dnl
 747 AC_SUBST(KRB4_LIBS)dnl
 748
 749 dnl --------------------
 750 dnl CHECK FOR CYRUS SASL
 751 dnl --------------------
 752 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 753   if test x"$with_cyrus_sasl" != x"yes"; then
 754     SASL_INCLUDES="-I$with_cyrus_sasl/include"
 755     SASL_LIBS="-L$with_cyrus_sasl/lib"
 756
 757     dnl Do OS-specific hardcoding of SASL shared library path into executables,
 758     dnl so user isn't forced to set environment variables like Solaris'
 759     dnl LD_LIBRARY_PATH.
 760     case "$target_os" in
 761       solaris*)
 762         SASL_LIBS="$SASL_LIBS -R$with_cyrus_sasl/lib"
 763         ;;
 764     esac
 765   fi
 766   save_LDFLAGS="$LDFLAGS"
 767   LDFLAGS="$LDFLAGS $SASL_LIBS"
 768   AC_CHECK_LIB(sasl2, sasl_client_new,
 769     [SASL_LIBS="$SASL_LIBS -lsasl2"],
 770     [AC_MSG_ERROR(Cyrus SASL library not found)])
 771   LDFLAGS="$save_LDFLAGS"
 772 fi
 773 AC_SUBST(SASL_INCLUDES)dnl
 774 AC_SUBST(SASL_LIBS)dnl
 775
 776 dnl ---------------------
 777 dnl CHECK TERMCAP LIBRARY
 778 dnl ---------------------
 779
 780 dnl Add the termcap library, so that the following configure
 781 dnl tests will find it when it tries to link test programs.
 782 nmh_save_LIBS="$LIBS"
 783 LIBS="$TERMLIB $LIBS"
 784
 785 dnl Checks for external variable ospeed in the termcap library.
 786 AC_CACHE_CHECK(if an include file defines ospeed,
 787 nmh_cv_decl_ospeed_include_defines,
 788 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 789 #if HAVE_TERMIOS_H
 790 #include <termios.h>
 791 #endif
 792 #if HAVE_TERMCAP_H
 793 #include <termcap.h>
 794 #endif]], [[ospeed = 0;]])],
 795 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 796
 797 if test $nmh_cv_decl_ospeed_include_defines = no; then
 798   AC_CACHE_CHECK(if you must define ospeed,
 799   nmh_cv_decl_ospeed_must_define,
 800   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 801   [[extern short ospeed; ospeed = 0;]])],
 802   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 803 fi
 804
 805 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 806 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 807   AC_DEFINE(HAVE_OSPEED)dnl
 808 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 809   AC_DEFINE(HAVE_OSPEED)
 810   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 811     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 812 fi
 813
 814 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 815 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 816 dnl in tgetstr().
 817 dnl Under Cygwin test program crashes but exit code is still 0. So,
 818 dnl we test for a file that porgram should create
 819 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 820 [Define to 1 if tgetent() accepts NULL as a buffer.])
 821 AC_CACHE_CHECK(if tgetent accepts NULL,
 822 nmh_cv_func_tgetent_accepts_null,
 823 [AC_TRY_RUN([
 824 main()
 825 {
 826     char buf[4096];
 827     int r1 = tgetent(buf, "vt100");
 828     int r2 = tgetent((char*)0,"vt100");
 829     if (r1 >= 0 && r1 == r2) {
 830         char tbuf[1024], *u;
 831         u = tbuf;
 832         tgetstr("cl", &u);
 833         creat("conftest.tgetent", 0640);
 834     }
 835     exit((r1 != r2) || r2 == -1);
 836 }
 837 ],
 838   if test -f conftest.tgetent; then
 839     nmh_cv_func_tgetent_accepts_null=yes
 840   else
 841     nmh_cv_func_tgetent_accepts_null=no
 842   fi,
 843   nmh_cv_func_tgetent_accepts_null=no,
 844   nmh_cv_func_tgetent_accepts_null=no)])
 845 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 846   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 847 fi
 848 AC_CACHE_CHECK(if tgetent returns 0 on success,
 849 nmh_cv_func_tgetent_zero_success,
 850 [AC_TRY_RUN([
 851 main()
 852 {
 853     char buf[4096];
 854     int r1 = tgetent(buf, "!@#$%^&*");
 855     int r2 = tgetent(buf, "vt100");
 856     if (r1 < 0 && r2 == 0) {
 857         char tbuf[1024], *u;
 858         u = tbuf;
 859         tgetstr("cl", &u);
 860         creat("conftest.tgetent0", 0640);
 861     }
 862     exit(r1 == r2);
 863 }
 864 ],
 865   if test -f conftest.tgetent0; then
 866     nmh_cv_func_tgetent_zero_success=yes
 867   else
 868     nmh_cv_func_tgetent_zero_success=no
 869   fi,
 870   nmh_cv_func_tgetent_zero_success=no,
 871   nmh_cv_func_tgetent_zero_success=no)])
 872 AH_TEMPLATE([TGETENT_SUCCESS],
 873 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 874 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 875   AC_DEFINE(TGETENT_SUCCESS, 0)
 876 else
 877   AC_DEFINE(TGETENT_SUCCESS, 1)
 878 fi
 879
 880 dnl Now put the libraries back to what it was before we
 881 dnl starting checking the termcap library.
 882 LIBS="$nmh_save_LIBS"
 883
 884 dnl --------------
 885 dnl CHECK TYPEDEFS
 886 dnl --------------
 887 AC_TYPE_SIGNAL
 888 AC_TYPE_PID_T
 889 AC_TYPE_OFF_T
 890 AC_TYPE_UID_T
 891 AC_TYPE_MODE_T
 892 AC_TYPE_SIZE_T
 893
 894 dnl Check for sigset_t.  Currently I'm looking in
 895 dnl <sys/types.h> and <signal.h>.  Others might need
 896 dnl to be added.
 897 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 898 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 899 #include <signal.h>]], [[sigset_t tempsigset;]])],
 900 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 901 if test $nmh_cv_type_sigset_t = no; then
 902   AC_DEFINE(sigset_t, unsigned int,
 903     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 904 fi
 905
 906 dnl ----------------
 907 dnl CHECK STRUCTURES
 908 dnl ----------------
 909 AC_CHECK_MEMBERS(struct stat.st_blksize)
 910
 911 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 912   [#ifdef TIME_WITH_SYS_TIME
 913 # include <sys/time.h>
 914 # include <time.h>
 915 #else
 916 # ifdef TM_IN_SYS_TIME
 917 #  include <sys/time.h>
 918 # else
 919 #  include <time.h>
 920 # endif
 921 #endif])
 922
 923 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 924
 925 AC_MSG_CHECKING(for union wait)
 926 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 927   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 928 #include <sys/wait.h>]],
 929     [[union wait status; int pid; pid = wait (&status);
 930 #ifdef WEXITSTATUS
 931 /* Some POSIXoid systems have both the new-style macros and the old
 932    union wait type, and they do not work together.  If union wait
 933    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 934         if (WEXITSTATUS (status) != 0) pid = -1;
 935 #ifdef WTERMSIG
 936         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 937         -- blow chunks here --
 938 #endif
 939 #endif
 940 #ifdef HAVE_WAITPID
 941         /* Make sure union wait works with waitpid.  */
 942         pid = waitpid (-1, &status, 0);
 943 #endif
 944       ]])],
 945     [nmh_cv_union_wait=yes],
 946     [nmh_cv_union_wait=no])])
 947 if test "$nmh_cv_union_wait" = yes; then
 948   AC_DEFINE(HAVE_UNION_WAIT, 1,
 949     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 950 fi
 951 AC_MSG_RESULT($nmh_cv_union_wait)
 952
 953 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 954
 955 dnl -------------
 956 dnl CHECK SIGNALS
 957 dnl -------------
 958 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 959 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 960 AC_MSG_CHECKING(what style of signals to use)
 961 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 962   signals_style=POSIX_SIGNALS
 963   AC_DEFINE(POSIX_SIGNALS, 1,
 964     [Define to 1 if you use POSIX style signal handling.])
 965   AC_DEFINE(RELIABLE_SIGNALS)
 966 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 967   signals_style=BSD_SIGNALS
 968   AC_DEFINE(BSD_SIGNALS,1,
 969     [Define to 1 if you use BSD style signal handling (and can block signals).])
 970   AC_DEFINE(RELIABLE_SIGNALS)
 971 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 972   signals_style=SYSV_SIGNALS
 973   AC_DEFINE(SYSV_SIGNALS,1,
 974     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 975 else
 976   signals_style=NO_SIGNAL_BLOCKING
 977   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 978     [Define to 1 if you have no signal blocking at all (bummer).])
 979 fi
 980
 981 AC_MSG_RESULT($signals_style)
 982
 983 dnl Where is <signal.h> located?  Needed as input for signames.awk
 984 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 985 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 986                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 987                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 988                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 989                  /usr/include/sys/signal.h      dnl Almost everybody else
 990                  /dev/null;                     dnl Just in case we fall through
 991 do
 992   test -f $SIGNAL_H && \
 993   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 994   break
 995 done
 996 nmh_cv_path_signal_h=$SIGNAL_H
 997 ])
 998 SIGNAL_H=$nmh_cv_path_signal_h
 999 AC_SUBST(SIGNAL_H)dnl
1000
1001 dnl ----------------
1002 dnl OS SPECIFIC DEFINES
1003 dnl ----------------
1004 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
1005 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
1006 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
1007 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
1008 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
1009
1010 case "$target_os" in
1011
1012   solaris2*)
1013     AC_DEFINE(SYS5)
1014     AC_DEFINE(SVR4)
1015     ;;
1016   irix*)
1017     AC_DEFINE(SYS5)
1018     AC_DEFINE(SVR4)
1019     ;;
1020   osf*)
1021     AC_DEFINE(SYS5)
1022     AC_DEFINE(SVR4)
1023     ;;
1024   aix*)
1025     AC_DEFINE(SYS5)
1026     AC_DEFINE(SVR4)
1027     ;;
1028   sunos4*)
1029     AC_DEFINE(BSD42)
1030     ;;
1031   freebsd*)
1032     AC_DEFINE(BSD42)
1033     AC_DEFINE(BSD44)
1034     ;;
1035   netbsd*)
1036     AC_DEFINE(BSD42)
1037     AC_DEFINE(BSD44)
1038     ;;
1039   openbsd*)
1040     AC_DEFINE(BSD42)
1041     AC_DEFINE(BSD44)
1042     ;;
1043   bsd/os*)
1044     AC_DEFINE(BSD42)
1045     AC_DEFINE(BSD44)
1046     ;;
1047   sco5*)
1048     AC_DEFINE(SYS5)
1049     AC_DEFINE(SCO_5_STDIO)
1050     ;;
1051 esac
1052
1053
1054 dnl ----------------
1055 dnl OUTPUT MAKEFILES
1056 dnl ----------------
1057 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
1058                 mts/Makefile mts/smtp/Makefile \
1059                 etc/Makefile docs/Makefile man/Makefile)
1060 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
1061 AC_OUTPUT
1062
1063 dnl Umm, what's the point of these assignments??  -- <dan-nmh@dilvish.speed.net>
1064 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
1065 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
1066 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
1067 eval "nmhman=${mandir}"
1068
1069 pop_kinds=no
1070 if test x"$enable_pop" = x"yes"; then
1071   pop_kinds="yes ("
1072
1073   if test x"$enable_apop" = x"yes"; then
1074     pop_kinds="${pop_kinds}APOP "
1075   fi
1076
1077   if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
1078     pop_kinds="${pop_kinds}KPOP "
1079   fi
1080
1081   pop_kinds="${pop_kinds}POP3)"
1082 fi
1083
1084 echo "
1085 nmh configuration
1086 -----------------
1087 nmh version                : AC_PACKAGE_VERSION
1088 target os                  : ${target}
1089 compiler                   : ${CC}
1090 compiler flags             : ${CFLAGS}
1091 linker flags               : ${LDFLAGS}
1092 definitions                : ${OURDEFS}
1093 source code location       : ${srcdir}
1094 binary install path        : ${nmhbin2}
1095 libary install path        : ${nmhlib2}
1096 config files install path  : ${nmhsysconf2}
1097 man page install path      : ${nmhman}
1098 backup prefix              : ${backup_prefix}
1099 transport system           : ${MTS}
1100 file locking type          : ${LOCKTYPE}
1101 default smtp servers       : ${smtpservers}
1102 default editor             : ${editorpath}
1103 default pager              : ${pagerpath}
1104 email address masquerading : ${masquerade}
1105 pop is enabled             : ${pop_kinds}
1106 SASL support               : ${sasl_support}"
1107 echo ""