diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122   else
 123     dnl Use -v and some other options with SunStudio cc.  lex produces
 124     dnl code that causes unreachable-statement warnings.  It might be
 125     dnl better to use an autoconf test, except -v will probably succeed
 126     dnl with many other compilers but have different meaning.
 127     AS_CASE([`${CC} -V 2>&1`],
 128             [cc:\ Sun\ C*], [CFLAGS=\
 129 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 130   fi
 131
 132   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 133                  [nmh_saved_cflags="$CFLAGS"
 134                  CFLAGS="$CFLAGS -Wall -Werror"
 135                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 138
 139   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 140                  [nmh_saved_cflags="$CFLAGS"
 141                  CFLAGS="$CFLAGS -Wextra -Werror"
 142                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 143                                 nmh_cv_has_wextra=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 146 fi
 147
 148 dnl --------------
 149 dnl CUSTOMIZE LINK
 150 dnl --------------
 151 if test `uname` = OpenBSD; then
 152   dnl Filter out "often/almost always misused" warnings from OpenBSD linker.
 153   [POSTLINK="2>&1 | egrep -v ': [w]arning: s[a-z]+\(\) is \
 154 (almost always|often) misused, please use'; true"]
 155 fi
 156 AC_SUBST([POSTLINK])
 157
 158 dnl -----------------
 159 dnl CUSTOMIZE LDFLAGS
 160 dnl -----------------
 161 if test "$GCC" = yes; then
 162   dnl Disable clang complaint about unused -ansi when linking.
 163   AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 164                  [nmh_cv_has_q_unused_arguments],
 165                  [nmh_saved_ldflags="$LDFLAGS"
 166                   LDFLAGS="$LDFLAGS -Qunused-arguments"
 167                   AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 168                                     nmh_cv_has_q_unused_arguments=no)
 169                   LDFLAGS="$nmh_saved_ldflags"])
 170   test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 171     LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 172 fi
 173
 174 dnl This really shouldn't be necessary.  And we really shouldn't add -s.
 175 if test x"$enable_debug" = x"yes"; then
 176   test -z "$LDFLAGS" && LDFLAGS=-g
 177 else
 178   if test -z "$LDFLAGS"; then
 179     case "$build_os" in
 180       darwin*) LDFLAGS= ;;
 181             *) LDFLAGS=-s ;;
 182     esac
 183   fi
 184 fi
 185
 186 dnl This hack turns off assertions by default, assuming
 187 dnl that configure still uses this shell variable.  Without
 188 dnl it, AC_HEADER_ASSERT enables assertions by default.
 189 test -z "$enable_assert"  &&  enable_assert=no
 190
 191 AC_HEADER_ASSERT
 192
 193 dnl ------------------
 194 dnl CHECK FOR PROGRAMS
 195 dnl ------------------
 196 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 197 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 198 AC_PROG_RANLIB          dnl Check for `ranlib'
 199 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 200 AC_PROG_SED             dnl Check for Posix-compliant sed
 201 AM_PROG_LEX             dnl Check for lex/flex
 202
 203 AM_PROG_AR
 204
 205 dnl Look for `cut'
 206 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 207 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 208
 209 dnl
 210 dnl Check for MD5 program and formatting command
 211 dnl
 212 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 213 AS_CASE(["${MD5SUM}"],
 214         [md5sum], [MD5FMT="cat"],
 215         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 216         [MD5FMT="missing"])
 217 AC_SUBST([MD5FMT])
 218
 219 dnl Look for `ls'
 220 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 221 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 222
 223 dnl See how we get ls to display the owner and the group
 224 AS_IF([test "$lspath" != "no"],
 225   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 226                  [nmh_cv_ls_grpopt],
 227   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 228     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 229     dnl ls, it would seem -l gave us both the user and group.  On this type of
 230     dnl ls, -g makes _only_ the group be displayed (and not the user).
 231     nmh_cv_ls_grpopt="-l"],[
 232     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 233     nmh_cv_ls_grpopt="-lg"])])])
 234
 235 dnl Look for `sendmail'
 236 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 237 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 238
 239 dnl Cygwin FAT filesystems do not support hard links.  So default to
 240 dnl cp instead, even if running on an NTFS or other filesystem.
 241 AS_CASE(["$host_os"],
 242   [cygwin*], [LN=cp],
 243   [LN=ln])
 244 AC_SUBST([LN])
 245
 246 dnl ----------------------------------------------------------
 247 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 248 dnl ----------------------------------------------------------
 249 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 250 [for mailspool in /var/mail        dnl
 251                   /var/spool/mail  dnl
 252                   /usr/spool/mail  dnl
 253                   /dev/null;       dnl Just in case we fall through
 254 do
 255   test -d $mailspool && break
 256 done
 257 nmh_cv_mailspool=$mailspool
 258 ])
 259 mailspool=$nmh_cv_mailspool
 260 AC_SUBST([mailspool])dnl
 261
 262 dnl See whether the mail spool directory is world-writable.
 263 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 264   AC_CACHE_CHECK(whether the mail spool is world-writable,
 265                  nmh_cv_mailspool_world_writable,
 266   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 267     nmh_cv_mailspool_world_writable=no
 268   else
 269     nmh_cv_mailspool_world_writable=yes
 270   fi])
 271 fi
 272
 273 dnl Also, check for liblockfile (as found on Debian systems)
 274 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 275
 276 dnl and whether its companion program dotlockfile is setgid
 277 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 278 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 279   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 280     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 281     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 282         nmh_cv_dotlockfile_setgid=yes
 283       else
 284         nmh_cv_dotlockfile_setgid=no
 285       fi])
 286   fi
 287 fi
 288
 289 dnl Provide a way for distcheck to disable setgid_mail via
 290 dnl DISTCHECK_CONFIGURE_FLAGS.
 291 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 292   [nmh_cv_dotlockfile_setgid=yes])
 293
 294 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 295 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 296 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 297   dnl do we really need both of these?
 298   AC_DEFINE([MAILGROUP],[1],
 299     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 300   SETGID_MAIL=1
 301 fi
 302 AC_SUBST([SETGID_MAIL])dnl
 303
 304 dnl Use ls to see which group owns the mail spool directory.
 305 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 306 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 307 ])
 308 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 309 AC_SUBST([MAIL_SPOOL_GRP])dnl
 310
 311 dnl ---------------------------------------------
 312 dnl CHECK FOR PROGRAM TO PROVIDE MIME TYPE STRING
 313 dnl ---------------------------------------------
 314 AS_IF([file --mime "${srcdir}"/configure >/dev/null 2>&1],
 315       [AS_IF([file --brief --mime "${srcdir}"/configure >/dev/null 2>&1],
 316              [nmh_mimetypeproc='"file --brief --mime"'],
 317              [nmh_mimetypeproc='"file --mime"'])])
 318 AS_CASE([$nmh_mimetypeproc], [?*],
 319         [AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$nmh_mimetypeproc],
 320           [Program, with arguments, that provides MIME type string.])])
 321 AS_ECHO_N(["AS_ESCAPE([checking program to provide MIME type string ... ])"])
 322 AS_ECHO(["AS_ESCAPE([$nmh_mimetypeproc], [""])"])
 323
 324 dnl ------------------
 325 dnl CHECK HEADER FILES
 326 dnl ------------------
 327
 328 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 329 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 330 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 331 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 332 dnl declared; if so they should have an entry added to this case statement.
 333 dnl NB that we must define this on the compiler command line, not in config.h,
 334 dnl because it must be set before any system header is included and there's no
 335 dnl portable way to make sure that files generated by lex include config.h
 336 dnl before system header files.
 337
 338 AS_CASE(["$host_os"],
 339         [linux*],
 340         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 341           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 342                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 343
 344 AC_HEADER_TIOCGWINSZ
 345 AC_CHECK_HEADERS([fcntl.h langinfo.h wchar.h wctype.h sys/param.h \
 346                   sys/time.h sys/stream.h])
 347
 348 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 349   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 350 [[#if HAVE_SYS_STREAM_H
 351 #  include <sys/stream.h>
 352 #endif
 353 ]])
 354
 355 dnl ---------------
 356 dnl CHECK FUNCTIONS
 357 dnl ---------------
 358 AC_CHECK_FUNCS([wcwidth mbtowc nl_langinfo getutxent arc4random])
 359
 360 dnl Check for multibyte character set support
 361 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 362             "x$ac_cv_header_wctype_h" = "xyes" -a \
 363             "x$ac_cv_func_wcwidth" = "xyes" -a \
 364             "x$ac_cv_func_mbtowc" = "xyes"],
 365       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 366                  [Define to enable support for multibyte character sets.])
 367        MULTIBYTE_ENABLED=1],
 368       [MULTIBYTE_ENABLED=0])
 369 AC_SUBST([MULTIBYTE_ENABLED])
 370
 371 dnl -------------------
 372 dnl CHECK FOR LIBRARIES
 373 dnl -------------------
 374 dnl Checks for network libraries (nsl, socket)
 375 NMH_CHECK_NETLIBS
 376
 377 dnl Check for readline support
 378 NMH_READLINE
 379
 380 dnl Check the locking functions supported and what we should use by default
 381 NMH_LOCKING
 382
 383 dnl Check for iconv
 384 NMH_CHECK_ICONV
 385
 386 dnl Check for tputs() callback argument
 387 NMH_TPUTS_PUTC_ARG
 388
 389 termcap_curses_order="termcap curses ncurses"
 390 for lib in $termcap_curses_order; do
 391   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 392 done
 393 AC_SUBST([TERMLIB])dnl
 394 AS_IF([test "x$TERMLIB" = "x"],
 395       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a curses
 396 or ncurses library or package that you can install?])])
 397
 398 dnl --------------
 399 dnl CHECK FOR NDBM
 400 dnl --------------
 401
 402 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 403             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 404 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 405             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 406
 407 if test "$nmh_ndbm" = "autodetect"; then
 408   if test "$nmh_ndbmheader" != "autodetect"; then
 409     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 410   else
 411
 412     dnl There are at least four implementations of ndbm, and
 413     dnl several of those can be in different places at the whim
 414     dnl of the system integrator. A good summary of this mess
 415     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 416
 417     dnl Classic ndbm with no library required (eg NetBSD): try this
 418     dnl first so we don't accidentally link in a pointless but harmless
 419     dnl library in one of the later ndbm.h+libfoo tests:
 420     NMH_CHECK_NDBM(ndbm.h,,,
 421     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 422       NMH_CHECK_NDBM(db.h,db,,
 423     dnl Berkeley DBv1 emulating ndbm:
 424         NMH_CHECK_NDBM(ndbm.h,db,,
 425           NMH_CHECK_NDBM(ndbm.h,db1,,
 426     dnl Classic ndbm:
 427             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 428     dnl glibc2.1 systems put db1 in a subdir:
 429               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 430     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 431     dnl and possibly needing gbdm_compat library:
 432                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 433                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 434                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 435                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 436
 437   fi
 438 else
 439   dnl We don't really need to check that the user-specified values work,
 440   dnl but it is a convenience to the user to bomb out early rather than
 441   dnl after configure and half the compile process.
 442   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 443 fi
 444
 445 if test "$nmh_ndbm_found" = "no"; then
 446   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 447 else
 448   dnl Now export the lib/header to our makefile/config.h:
 449   if test x"$nmh_ndbmheader" != x; then
 450     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 451       [Define to the header containing the ndbm API prototypes.])
 452   fi
 453   if test x"$nmh_ndbm" != x; then
 454     NDBM_LIBS="-l$nmh_ndbm"
 455   else
 456     NDBM_LIBS=
 457   fi
 458   AC_SUBST([NDBM_LIBS])
 459 fi
 460
 461 dnl ------------------
 462 dnl Set RPM build root
 463 dnl ------------------
 464 dnl nmhrpm is used in the final summary, see below.  The default value is
 465 dnl reported there as ./RPM, consistent with the reporting of the default
 466 dnl source code location as ., but its absolute path is used in the Makefile.
 467 AC_ARG_WITH([rpmdir],
 468   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 469   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 470           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 471 AC_SUBST([rpmdir])
 472
 473
 474 dnl --------------------
 475 dnl CHECK FOR CYRUS-SASL
 476 dnl --------------------
 477
 478 AS_IF([test x"$sasl_support" = x"yes"],[
 479   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 480   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 481     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 482 AC_SUBST([SASLLIB])
 483
 484 dnl -----------------
 485 dnl CHECK FOR OPENSSL
 486 dnl -----------------
 487
 488 AS_IF([test x"$tls_support" = x"yes"],[
 489   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 490   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 491     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 492   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 493     [AC_MSG_ERROR([OpenSSL library not found])])],
 494   [TLSLIB=])
 495 AC_SUBST([TLSLIB])
 496
 497 dnl ----------------
 498 dnl CHECK FLEX FIXUP
 499 dnl ----------------
 500 dnl Use LFLAGS make variable setting to work around bugs in flex
 501 dnl 2.5.36 that cause signed/unsigned mismatch,
 502 dnl http://sourceforge.net/p/flex/bugs/140/
 503 AS_IF([test "$LEX" = flex],
 504       [AS_CASE([`$LEX -V`],
 505                [flex\ 2.5.35], [LFLAGS=\
 506 '; printf "%s\n" '\''1,$$s/(size_t) \(num_to_read\)/\1/'\'' w q | ed -s $@; \
 507 true'],
 508                [flex\ 2.5.36], [LFLAGS=\
 509 '; printf "%s\n" '\''1,$$s/\(   \)int i;/\1yy_size_t i;/'\'' w q | ed -s $@; \
 510 true'])
 511        AC_SUBST([LFLAGS])])
 512
 513 dnl ----------------
 514 dnl CHECK STRUCTURES
 515 dnl ----------------
 516
 517 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 518 dnl (FreeBSD has a timezone() function but not a timezone global
 519 dnl variable that is visible).
 520 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 521
 522 AC_STRUCT_DIRENT_D_TYPE
 523
 524 dnl Where is <signal.h> located?  Needed as input for signames.awk
 525 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 526 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 527                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 528                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 529                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 530                  /usr/include/sys/signal.h      dnl Almost everybody else
 531                  /dev/null;                     dnl Just in case we fall through
 532 do
 533   test -f $SIGNAL_H && \
 534   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 535   break
 536 done
 537 nmh_cv_path_signal_h=$SIGNAL_H
 538 ])
 539 SIGNAL_H=$nmh_cv_path_signal_h
 540 AC_SUBST(SIGNAL_H)dnl
 541
 542 dnl
 543 dnl Sigh, this is required because under the new world order autoconf has
 544 dnl nothing to create in a few of the build directories when doing an object
 545 dnl tree build.  So make sure we created certain directories if they don't
 546 dnl exist.
 547 dnl
 548
 549 AC_CONFIG_COMMANDS([build-directories],
 550 [test -d man || AS_MKDIR_P([man])])
 551
 552 AC_CONFIG_COMMANDS_POST([
 553
 554 dnl These odd looking assignments are done to expand out unexpanded
 555 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 556 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 557 dnl again to get the final answer.
 558 dnl We only use the expanded versions to print the install paths in
 559 dnl the final summary and should use them nowhere else (see the autoconf
 560 dnl docs for the rationale for bindir etc being unexpanded).
 561 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 562 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 563 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 564 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 565 eval "nmhrpm=${nmhrpm}";
 566
 567 AC_MSG_NOTICE([
 568 nmh configuration
 569 -----------------
 570 nmh version                : AC_PACKAGE_VERSION
 571 host os                    : ${host}
 572 compiler                   : ${CC}
 573 compiler flags             : ${CFLAGS}
 574 linker flags               : ${LDFLAGS}
 575 preprocessor flags         : ${CPPFLAGS}
 576 source code location       : ${srcdir}
 577 binary install path        : ${nmhbin}
 578 library install path       : ${nmhlib}
 579 config files install path  : ${nmhsysconf}
 580 man page install path      : ${nmhman}
 581 RPM build root             : ${nmhrpm}
 582 backup prefix              : ${backup_prefix}
 583 transport system           : ${MTS}
 584 spool default locking type : ${with_locking}
 585 default smtp servers       : ${smtpservers}
 586 SASL support               : ${sasl_support}
 587 TLS support                : ${tls_support}
 588 ])])dnl
 589
 590 dnl ---------------
 591 dnl OUTPUT MAKEFILE
 592 dnl ---------------
 593 AC_CONFIG_FILES([Makefile test/common.sh])
 594 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 595 AC_OUTPUT