diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want client-side support for using SASL for authentication?
  27 dnl Note that this code will be enabled for both POP and SMTP
  28 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  29   [Enable SASL support via the Cyrus SASL library]))
  30 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != xyes -a \
  31             x"$with_cyrus_sasl" != xno],[
  32   AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  33   AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  34
  35 dnl Do you want client-side support for encryption with TLS?
  36 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  37
  38 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  39 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  40   [Enable OAuth2 support in SMTP auth]))
  41
  42 dnl Set the backup prefix
  43 AC_ARG_WITH([hash-backup],
  44   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  45 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  46       [backup_prefix="#"], [backup_prefix=","])
  47 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  48     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  49
  50 dnl What method of posting should post use?
  51 AC_ARG_WITH([mts],
  52   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  53   [specify the default mail transport agent/service]))
  54
  55 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  56       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  57       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  58       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  59       [MTS="smtp"])
  60 AC_SUBST([MTS])dnl
  61
  62 dnl What should be the default mail server?
  63 AC_ARG_WITH([smtpserver],
  64   [AS_HELP_STRING([--with-smtpserver='SMTPSERVER'],
  65   [specify the default SMTP server @<:@localhost@:>@])])
  66 AS_IF([test -n "$with_smtpserver"], [smtpserver="$with_smtpserver"],
  67       [smtpserver="localhost"])
  68 AC_SUBST([smtpserver])dnl
  69
  70 dnl -------------------------------------------------------------------
  71 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  72 dnl find an existing installation, in which case we use its location.
  73 dnl -------------------------------------------------------------------
  74 AC_PREFIX_DEFAULT([/usr/local/nmh])
  75 AC_PREFIX_PROGRAM([mhparam])
  76
  77 dnl ------------------
  78 dnl CHECK THE COMPILER
  79 dnl ------------------
  80
  81 AC_PROG_CC([cc gcc])
  82 AM_PROG_CC_C_O
  83
  84 dnl ------------------
  85 dnl CHECK HEADER FILES
  86 dnl ------------------
  87
  88 AC_HEADER_TIOCGWINSZ
  89 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
  90                   sys/param.h sys/time.h sys/stream.h])
  91
  92 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
  93   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
  94 [[#if HAVE_SYS_STREAM_H
  95 #  include <sys/stream.h>
  96 #endif
  97 ]])
  98
  99 dnl ---------------
 100 dnl CHECK FUNCTIONS
 101 dnl ---------------
 102 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 103
 104 dnl Use custom getline for platforms that don't have it.
 105 AC_CONFIG_LIBOBJ_DIR([sbr])
 106 AC_REPLACE_FUNCS([getline])
 107
 108 dnl -----------------------
 109 dnl CHECK MULTIBYTE SUPPORT
 110 dnl -----------------------
 111 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 112             "x$ac_cv_header_wctype_h" = "xyes" -a \
 113             "x$ac_cv_func_wcwidth" = "xyes" -a \
 114             "x$ac_cv_func_mbtowc" = "xyes"],
 115       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 116                  [Define to enable support for multibyte character sets.])
 117        MULTIBYTE_ENABLED=1],
 118       [MULTIBYTE_ENABLED=0])
 119 AC_SUBST([MULTIBYTE_ENABLED])
 120
 121 dnl ----------------
 122 dnl CUSTOMIZE CFLAGS
 123 dnl ----------------
 124 dnl The user didn't specify CFLAGS, so customize them.
 125
 126 if test "$GCC" != yes; then
 127   dnl Use -v and some other options with SunStudio cc.  lex produces
 128   dnl code that causes unreachable-statement warnings.  It might be
 129   dnl better to use an autoconf test, except -v will probably succeed
 130   dnl with many other compilers but have different meaning.
 131   AS_CASE([`${CC} -V 2>&1`],
 132           [cc:*\ Sun\ C*], [CFLAGS=\
 133 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 134 fi
 135
 136 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 137                [nmh_saved_cflags="$CFLAGS"
 138                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 139                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 140                CFLAGS="$nmh_saved_cflags"])
 141 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 142
 143 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 144                [nmh_saved_cflags="$CFLAGS"
 145                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 146                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 147                               nmh_cv_has_wextra=no)
 148                CFLAGS="$nmh_saved_cflags"])
 149 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 150
 151 AC_SUBST([AM_CFLAGS])
 152
 153 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 154 dnl MULTIBYTE_ENABLED having already been set.
 155 NMH_ADDL_CPPFLAGS
 156
 157 if test "$GCC" = yes; then
 158   dnl Do this regardless of auto_cflags value.
 159   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 160   dnl gcc 4.1 and later, but only when optimization is enabled.
 161   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 162   dnl If the user configures with a CFLAGS that contains a -O flag
 163   dnl but then removes it a make time, they'll also have to remove
 164   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 165   dnl Use "\ " instead of ' ' or " " for compatiblity with posh.
 166   AS_CASE([$CFLAGS],
 167           [-O|*\ -O|-O[[!0]]*|*\ -O[[!0]]*],
 168           [AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 169 fi
 170
 171 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 172 dnl We do this here rather than in (say) h/mh.h because this macro must
 173 dnl be defined before <stdio.h> is pulled in.
 174 dnl
 175 dnl And while we're here, add the packages tree to the cpp and ld search
 176 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 177 dnl If /usr/ports is installed, we use its idea of where things are installed,
 178 dnl otherwise we assume /usr/local.
 179
 180 AS_IF([test `uname` = FreeBSD],
 181         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 182          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 183                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 184          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 185          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 186          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 187 ])
 188
 189 dnl --------------
 190 dnl CUSTOMIZE LINK
 191 dnl --------------
 192 AS_IF([test `uname` = OpenBSD],
 193       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 194       dnl so that they don't color the waterfall.
 195       [POSTLINK="2>&1 | sed -e \
 196 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 197 AC_SUBST([POSTLINK])
 198
 199 dnl -----------------
 200 dnl CUSTOMIZE LDFLAGS
 201 dnl -----------------
 202 dnl Disable clang complaint about unused -ansi when linking.
 203 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 204                [nmh_cv_has_q_unused_arguments],
 205                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 206                        grep clang >/dev/null`],
 207                       [nmh_saved_ldflags="$LDFLAGS"
 208                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 209                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 210                                          nmh_cv_has_q_unused_arguments=no)
 211                        LDFLAGS="$nmh_saved_ldflags"],
 212                        [nmh_cv_has_q_unused_arguments=no])])
 213 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 214   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 215 AC_SUBST([AM_LDFLAGS])
 216
 217 dnl This hack turns off assertions by default, assuming
 218 dnl that configure still uses this shell variable.  Without
 219 dnl it, AC_HEADER_ASSERT enables assertions by default.
 220 test -z "$enable_assert"  &&  enable_assert=no
 221
 222 AC_HEADER_ASSERT
 223
 224 dnl ------------------
 225 dnl CHECK FOR PROGRAMS
 226 dnl ------------------
 227 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 228 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 229 AC_PROG_RANLIB          dnl Check for `ranlib'
 230 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 231 AC_PROG_SED             dnl Check for Posix-compliant sed
 232 AC_PROG_YACC            dnl Check for yacc/bison
 233 AM_PROG_LEX             dnl Check for lex/flex
 234
 235 AM_PROG_AR
 236
 237 dnl Look for `cut'
 238 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 239 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 240
 241 dnl
 242 dnl Check for MD5 program and formatting command
 243 dnl
 244 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 245 AS_CASE(["${MD5SUM}"],
 246         [md5sum], [MD5FMT="cat"],
 247         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 248         [MD5FMT="missing"])
 249 AC_SUBST([MD5FMT])
 250
 251 dnl Look for `ls'
 252 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 253 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 254
 255 dnl See how we get ls to display the owner and the group
 256 AS_IF([test "$lspath" != "no"],
 257   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 258                  [nmh_cv_ls_grpopt],
 259   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 260     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 261     dnl ls, it would seem -l gave us both the user and group.  On this type of
 262     dnl ls, -g makes _only_ the group be displayed (and not the user).
 263     nmh_cv_ls_grpopt="-l"],[
 264     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 265     nmh_cv_ls_grpopt="-lg"])])])
 266
 267 dnl Look for `sendmail'
 268 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 269 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 270
 271 dnl Cygwin FAT filesystems do not support hard links.  So default to
 272 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 273 dnl therefore, this cannot be made into a dynamic test, in order to
 274 dnl support the least common Cygwin denominator.
 275 AS_CASE(["$host_os"],
 276   [cygwin*], [LN=cp],
 277   [LN=ln])
 278 AC_SUBST([LN])
 279
 280 dnl ----------------------------------------------------------
 281 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 282 dnl ----------------------------------------------------------
 283 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 284 [for mailspool in /var/mail        dnl
 285                   /var/spool/mail  dnl
 286                   /usr/spool/mail  dnl
 287                   /dev/null;       dnl Just in case we fall through
 288 do
 289   test -d $mailspool && break
 290 done
 291 nmh_cv_mailspool=$mailspool
 292 ])
 293 mailspool=$nmh_cv_mailspool
 294 AC_SUBST([mailspool])dnl
 295
 296 dnl See whether the mail spool directory is world-writable.
 297 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 298   AC_CACHE_CHECK(whether the mail spool is world-writable,
 299                  nmh_cv_mailspool_world_writable,
 300   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 301     nmh_cv_mailspool_world_writable=no
 302   else
 303     nmh_cv_mailspool_world_writable=yes
 304   fi])
 305 fi
 306
 307 dnl Also, check for liblockfile (as found on Debian systems)
 308 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 309
 310 dnl and whether its companion program dotlockfile is setgid
 311 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 312 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 313   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 314     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 315     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 316         nmh_cv_dotlockfile_setgid=yes
 317       else
 318         nmh_cv_dotlockfile_setgid=no
 319       fi])
 320   fi
 321 fi
 322
 323 dnl Provide a way for distcheck to disable setgid_mail via
 324 dnl DISTCHECK_CONFIGURE_FLAGS.
 325 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 326   [nmh_cv_dotlockfile_setgid=yes])
 327
 328 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 329 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 330 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 331   dnl do we really need both of these?
 332   AC_DEFINE([MAILGROUP],[1],
 333     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 334   SETGID_MAIL=1
 335 fi
 336 AC_SUBST([SETGID_MAIL])dnl
 337
 338 dnl Use ls to see which group owns the mail spool directory.
 339 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 340 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 341 ])
 342 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 343 AC_SUBST([MAIL_SPOOL_GRP])dnl
 344
 345 NMH_MIMETYPEPROC
 346 NMH_MIMEENCODINGPROC
 347
 348 dnl -------------------
 349 dnl CHECK FOR LIBRARIES
 350 dnl -------------------
 351 dnl Checks for network libraries (nsl, socket)
 352 NMH_CHECK_NETLIBS
 353
 354 dnl Check the locking functions supported and what we should use by default
 355 NMH_LOCKING
 356
 357 dnl Check for iconv
 358 NMH_CHECK_ICONV
 359
 360 dnl Check for tputs() callback argument
 361 NMH_TPUTS_PUTC_ARG
 362
 363 termcap_curses_order="termcap curses ncurses"
 364 for lib in $termcap_curses_order; do
 365   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 366 done
 367 AC_SUBST([TERMLIB])dnl
 368 AS_IF([test "x$TERMLIB" = "x"],
 369       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 370 curses or ncurses library or package that you can install?])])
 371
 372 dnl Check for readline support
 373 NMH_READLINE
 374
 375 dnl --------------
 376 dnl CHECK FOR NDBM
 377 dnl --------------
 378
 379 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 380             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 381 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 382             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 383
 384 if test "$nmh_ndbm" = "autodetect"; then
 385   if test "$nmh_ndbmheader" != "autodetect"; then
 386     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 387   else
 388
 389     dnl There are at least four implementations of ndbm, and
 390     dnl several of those can be in different places at the whim
 391     dnl of the system integrator. A good summary of this mess
 392     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 393
 394     dnl Classic ndbm with no library required (eg NetBSD): try this
 395     dnl first so we don't accidentally link in a pointless but harmless
 396     dnl library in one of the later ndbm.h+libfoo tests:
 397     NMH_CHECK_NDBM(ndbm.h,,,
 398     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 399       NMH_CHECK_NDBM(db.h,db,,
 400     dnl Berkeley DBv1 emulating ndbm:
 401         NMH_CHECK_NDBM(ndbm.h,db,,
 402           NMH_CHECK_NDBM(ndbm.h,db1,,
 403     dnl Classic ndbm:
 404             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 405     dnl glibc2.1 systems put db1 in a subdir:
 406               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 407     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 408     dnl and possibly needing gbdm_compat library:
 409                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 410                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 411                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 412     dnl 64-bit Cygwin:
 413                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 414     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 415     dnl need to be explicit:
 416                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 417   fi
 418 else
 419   dnl We don't really need to check that the user-specified values work,
 420   dnl but it is a convenience to the user to bomb out early rather than
 421   dnl after configure and half the compile process.
 422   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 423 fi
 424
 425 if test "$nmh_ndbm_found" = "no"; then
 426   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 427 else
 428   dnl Now export the lib/header to our makefile/config.h:
 429   if test x"$nmh_ndbmheader" != x; then
 430     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 431       [Define to the header containing the ndbm API prototypes.])
 432   fi
 433   if test x"$nmh_ndbm" != x; then
 434     NDBM_LIBS="-l$nmh_ndbm"
 435   else
 436     NDBM_LIBS=
 437   fi
 438   AC_SUBST([NDBM_LIBS])
 439 fi
 440
 441 dnl ------------------
 442 dnl Set RPM build root
 443 dnl ------------------
 444 dnl nmhrpm is used in the final summary, see below.  The default value is
 445 dnl reported there as ./RPM, consistent with the reporting of the default
 446 dnl source code location as ., but its absolute path is used in the Makefile.
 447 AC_ARG_WITH([rpmdir],
 448   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 449   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 450           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 451 AC_SUBST([rpmdir])
 452
 453
 454 dnl --------------------
 455 dnl CHECK FOR CYRUS-SASL
 456 dnl --------------------
 457
 458 AS_IF([test x"$with_cyrus_sasl" != x"no"],[
 459   AC_CHECK_HEADER([sasl/sasl.h], HAVE_SASL_H=1)
 460   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"])])
 461 AC_SUBST([SASLLIB])
 462
 463 dnl -----------------
 464 dnl Enable SASL?
 465 dnl -----------------
 466 dnl By default (with_cyrus_sasl=''), enable SASL if header and lib are found.
 467 dnl If SASL requested (--with-cyrus-sasl with_cyrus_sasl=yes), error if header or lib not found.
 468 dnl If SASL disabled (--without-cyrus-sasl with_cyrus_sasl=no), don't enable it.
 469 sasl_support=no
 470 CYRUS_SASL=0
 471 AC_SUBST([CYRUS_SASL])
 472 AS_IF([test "x$with_cyrus_sasl" = xyes && test "x$HAVE_SASL_H" = x],
 473       [AC_MSG_ERROR([SASL requested but sasl.h not found])],
 474       [test "x$with_cyrus_sasl" = xyes && test "x$SASLLIB" = x],
 475       [AC_MSG_ERROR([SASL requested but Cyrus SASL library not found])],
 476       [test "x$with_cyrus_sasl" != xno && test "x$HAVE_SASL_H" = x1 &&
 477        test "x$SASLLIB" != x],
 478       [AC_DEFINE([CYRUS_SASL], [1],
 479         [Define to use the Cyrus SASL library for authentication of POP and SMTP.])
 480        CYRUS_SASL=1
 481        sasl_support=yes])
 482
 483 dnl -----------------
 484 dnl CHECK FOR OPENSSL
 485 dnl -----------------
 486
 487 AS_IF([test x"$with_tls" != x"no"],[
 488   dnl OpenBSD 5 needs the other-libraries (fifth argument) to the
 489   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 490   dnl automatically append -lcrypto when linking with -lssl.
 491   AC_CHECK_HEADER([openssl/ssl.h], HAVE_SSL_H=1)
 492   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"])
 493   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"], [TLSLIB=],
 494                [$TLSLIB])])
 495 AC_SUBST([TLSLIB])
 496
 497 dnl -----------------
 498 dnl Enable TLS?
 499 dnl -----------------
 500 dnl By default (with_tls=''), enable TLS if header and libs were found.
 501 dnl If TLS requested (--with-tls with_tls=yes), error if header/lib not found.
 502 dnl If TLS disabled (--without-tls with_tls=no), don't enable it.
 503 tls_support=no
 504 TLS_SUPPORT=0
 505 AC_SUBST([TLS_SUPPORT])
 506 AS_IF([test "x$with_tls" = xyes && test "x$HAVE_SSL_H" = x],
 507       [AC_MSG_ERROR([TLS requested but openssl/ssl.h not found])],
 508       [test "x$with_tls" = xyes && test "x$TLSLIB" = x],
 509       [AC_MSG_ERROR([TLS requested but crypto or ssl library not found])],
 510       [test "x$with_tls" != xno && test "x$HAVE_SSL_H" = x1 && test "x$TLSLIB" != x],
 511       [AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])
 512        TLS_SUPPORT=1
 513        tls_support=yes
 514        save_LIBS="$LIBS"
 515        LIBS="$LIBS $TLSLIB"
 516        AC_CHECK_FUNCS([X509_VERIFY_PARAM_set1_host])
 517        LIBS="$save_LIBS"])
 518
 519 dnl -----------------
 520 dnl CHECK FOR CURL
 521 dnl -----------------
 522 dnl Look for curl if oauth not disabled (--without-oauth).
 523 AC_PATH_PROG([curl_config], [curl-config])
 524 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 525     save_CFLAGS="$CFLAGS"
 526     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 527     AC_CHECK_HEADER([curl/curl.h], [
 528         HAVE_CURL_H=1
 529         AC_CHECK_LIB([curl], [curl_easy_init], [
 530             CURLLIB="`$curl_config --libs`"
 531             AC_SUBST([CURLLIB])
 532             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 533             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 534                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 535                    CURL_USER_AGENT=libcurl/UNKNOWN])
 536             AC_SUBST([CURL_USER_AGENT])
 537           ])
 538       ])
 539     CFLAGS="$save_CFLAGS"
 540   ])
 541
 542 dnl -----------------
 543 dnl Enable OAuth?
 544 dnl -----------------
 545 dnl By default (with_oauth=''), enable OAuth if curl is found.
 546 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 547 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 548 oauth_support=no
 549 OAUTH_SUPPORT=0
 550 AC_SUBST([OAUTH_SUPPORT])
 551 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 552       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 553       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 554       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 555       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 556       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 557        OAUTH_SUPPORT=1
 558        oauth_support=yes])
 559
 560 dnl ----------------
 561 dnl CHECK FLEX FIXUP
 562 dnl ----------------
 563 dnl BUG: This stops $(LFLAGS) working as it comes after $(AM_FLAGS).
 564 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 565 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 566 dnl http://sourceforge.net/p/flex/bugs/140/
 567 dnl 2.6.1 bug: https://github.com/westes/flex/issues/97
 568 AS_IF([test "$LEX" = flex],
 569       [AS_CASE([`$LEX -V`],
 570                [flex\ 2.5.35], [AM_LFLAGS=\
 571 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 572                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 573 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 574                [flex\ 2.6.0], [AM_LFLAGS=\
 575 '; sed "s/, num_to_read/, (size_t) num_to_read/" $@ >$@.tmp && mv -f $@.tmp $@'],
 576                [flex\ 2.6.1], [AM_LFLAGS=\
 577 '; sed '\''/\<int num_to_read\>/s/int/size_t/; s/\<yy_size_t i\>/int i/'\'' $@ >$@.tmp && mv -f $@.tmp $@'])
 578        AC_SUBST([AM_LFLAGS])])
 579
 580 dnl ------------------
 581 dnl FOR INTERNAL USE by the NMH test suite
 582 dnl ------------------
 583 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 584 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 585       AC_SUBST([nmhetcdirinst]))
 586
 587 dnl ----------------
 588 dnl CHECK STRUCTURES
 589 dnl ----------------
 590
 591 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 592 dnl (FreeBSD has a timezone() function but not a timezone global
 593 dnl variable that is visible).
 594 dnl On Linux, $AM_CPPFLAGS contains -D_GNU_SOURCE, which makes
 595 dnl tm_gmtoff visible.
 596 nmh_saved_CPPFLAGS="$CPPFLAGS"
 597 CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 598 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[[#include <time.h>]])
 599 CPPFLAGS="$nmh_saved_CPPFLAGS"
 600
 601 AC_STRUCT_DIRENT_D_TYPE
 602
 603 dnl
 604 dnl Sigh, this is required because under the new world order autoconf has
 605 dnl nothing to create in a few of the build directories when doing an object
 606 dnl tree build.  So make sure we created certain directories if they don't
 607 dnl exist.
 608 dnl
 609
 610 AC_CONFIG_COMMANDS([build-directories],
 611 [test -d man || AS_MKDIR_P([man])])
 612
 613 AC_CONFIG_COMMANDS_POST([
 614
 615 dnl These odd looking assignments are done to expand out unexpanded
 616 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 617 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 618 dnl again to get the final answer.
 619 dnl We only use the expanded versions to print the install paths in
 620 dnl the final summary and should use them nowhere else (see the autoconf
 621 dnl docs for the rationale for bindir etc being unexpanded).
 622 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 623 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 624 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 625 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 626 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 627 eval "nmhrpm=${nmhrpm}";
 628
 629 AC_MSG_NOTICE([
 630 nmh configuration
 631 -----------------
 632 nmh version                : AC_PACKAGE_VERSION
 633 host os                    : ${host}
 634 compiler                   : ${CC}
 635 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 636 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 637 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 638 source code location       : ${srcdir}
 639 binary install path        : ${nmhbin}
 640 libexec install path       : ${nmhlibexec}/nmh
 641 config files install path  : ${nmhsysconf}/nmh
 642 man page install path      : ${nmhman}
 643 docs install path          : ${nmhdoc}
 644 RPM build root             : ${nmhrpm}
 645 backup prefix              : ${backup_prefix}
 646 transport system           : ${MTS}
 647 spool default locking type : ${with_locking}
 648 default smtp server        : ${smtpserver}
 649 SASL support               : ${sasl_support}
 650 TLS support                : ${tls_support}
 651 OAuth support              : ${oauth_support}
 652 ])])dnl
 653
 654 dnl ---------------
 655 dnl OUTPUT MAKEFILE
 656 dnl ---------------
 657 AC_CONFIG_FILES([Makefile test/common.sh])
 658 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 659 AC_OUTPUT