diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want client-side support for using SASL for authentication?
  27 dnl Note that this code will be enabled for both POP and SMTP
  28 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  29   [Enable SASL support via the Cyrus SASL library]))
  30 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != xyes -a \
  31             x"$with_cyrus_sasl" != xno],[
  32   AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  33   AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  34
  35 dnl Do you want client-side support for encryption with TLS?
  36 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  37
  38 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  39 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  40   [Enable OAuth2 support in SMTP auth]))
  41
  42 dnl Set the backup prefix
  43 AC_ARG_WITH([hash-backup],
  44   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  45 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  46       [backup_prefix="#"], [backup_prefix=","])
  47 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  48     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  49
  50 dnl What method of posting should post use?
  51 AC_ARG_WITH([mts],
  52   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  53   [specify the default mail transport agent/service]))
  54
  55 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  56       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  57       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  58       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  59       [MTS="smtp"])
  60 AC_SUBST([MTS])dnl
  61
  62 dnl What should be the default mail server(s)?
  63 AC_ARG_WITH([smtpservers],
  64   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  65   [specify the default SMTP server(s) @<:@localhost@:>@])])
  66 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  67       [smtpservers="localhost"])
  68 AC_SUBST([smtpservers])dnl
  69
  70 dnl -------------------------------------------------------------------
  71 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  72 dnl find an existing installation, in which case we use its location.
  73 dnl -------------------------------------------------------------------
  74 AC_PREFIX_DEFAULT([/usr/local/nmh])
  75 AC_PREFIX_PROGRAM([mhparam])
  76
  77 dnl ------------------
  78 dnl CHECK THE COMPILER
  79 dnl ------------------
  80
  81 AC_PROG_CC([cc gcc])
  82 AM_PROG_CC_C_O
  83
  84 dnl ------------------
  85 dnl CHECK HEADER FILES
  86 dnl ------------------
  87
  88 AC_HEADER_TIOCGWINSZ
  89 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
  90                   sys/param.h sys/time.h sys/stream.h])
  91
  92 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
  93   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
  94 [[#if HAVE_SYS_STREAM_H
  95 #  include <sys/stream.h>
  96 #endif
  97 ]])
  98
  99 dnl ---------------
 100 dnl CHECK FUNCTIONS
 101 dnl ---------------
 102 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 103
 104 dnl Use custom getline for platforms that don't have it.
 105 AC_CONFIG_LIBOBJ_DIR([sbr])
 106 AC_REPLACE_FUNCS([getline])
 107
 108 dnl -----------------------
 109 dnl CHECK MULTIBYTE SUPPORT
 110 dnl -----------------------
 111 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 112             "x$ac_cv_header_wctype_h" = "xyes" -a \
 113             "x$ac_cv_func_wcwidth" = "xyes" -a \
 114             "x$ac_cv_func_mbtowc" = "xyes"],
 115       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 116                  [Define to enable support for multibyte character sets.])
 117        MULTIBYTE_ENABLED=1],
 118       [MULTIBYTE_ENABLED=0])
 119 AC_SUBST([MULTIBYTE_ENABLED])
 120
 121 dnl ----------------
 122 dnl CUSTOMIZE CFLAGS
 123 dnl ----------------
 124 dnl The user didn't specify CFLAGS, so customize them.
 125
 126 if test "$GCC" != yes; then
 127   dnl Use -v and some other options with SunStudio cc.  lex produces
 128   dnl code that causes unreachable-statement warnings.  It might be
 129   dnl better to use an autoconf test, except -v will probably succeed
 130   dnl with many other compilers but have different meaning.
 131   AS_CASE([`${CC} -V 2>&1`],
 132           [cc:*\ Sun\ C*], [CFLAGS=\
 133 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 134 fi
 135
 136 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 137                [nmh_saved_cflags="$CFLAGS"
 138                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 139                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 140                CFLAGS="$nmh_saved_cflags"])
 141 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 142
 143 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 144                [nmh_saved_cflags="$CFLAGS"
 145                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 146                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 147                               nmh_cv_has_wextra=no)
 148                CFLAGS="$nmh_saved_cflags"])
 149 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 150
 151 AC_SUBST([AM_CFLAGS])
 152
 153 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 154 dnl MULTIBYTE_ENABLED having already been set.
 155 NMH_ADDL_CPPFLAGS
 156
 157 if test "$GCC" = yes; then
 158   dnl Do this regardless of auto_cflags value.
 159   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 160   dnl gcc 4.1 and later, but only when optimization is enabled.
 161   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 162   dnl If the user configures with a CFLAGS that contains a -O flag
 163   dnl but then removes it a make time, they'll also have to remove
 164   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 165   dnl Use "\ " instead of ' ' or " " for compatiblity with posh.
 166   AS_CASE([$CFLAGS],
 167           [-O|*\ -O|-O[[!0]]*|*\ -O[[!0]]*],
 168           [AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 169 fi
 170
 171 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 172 dnl We do this here rather than in (say) h/mh.h because this macro must
 173 dnl be defined before <stdio.h> is pulled in.
 174 dnl
 175 dnl And while we're here, add the packages tree to the cpp and ld search
 176 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 177 dnl If /usr/ports is installed, we use its idea of where things are installed,
 178 dnl otherwise we assume /usr/local.
 179
 180 AS_IF([test `uname` = FreeBSD],
 181         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 182          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 183                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 184          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 185          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 186          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 187 ])
 188
 189 dnl --------------
 190 dnl CUSTOMIZE LINK
 191 dnl --------------
 192 AS_IF([test `uname` = OpenBSD],
 193       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 194       dnl so that they don't color the waterfall.
 195       [POSTLINK="2>&1 | sed -e \
 196 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 197 AC_SUBST([POSTLINK])
 198
 199 dnl -----------------
 200 dnl CUSTOMIZE LDFLAGS
 201 dnl -----------------
 202 dnl Disable clang complaint about unused -ansi when linking.
 203 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 204                [nmh_cv_has_q_unused_arguments],
 205                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 206                        grep clang >/dev/null`],
 207                       [nmh_saved_ldflags="$LDFLAGS"
 208                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 209                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 210                                          nmh_cv_has_q_unused_arguments=no)
 211                        LDFLAGS="$nmh_saved_ldflags"],
 212                        [nmh_cv_has_q_unused_arguments=no])])
 213 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 214   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 215
 216 dnl This hack turns off assertions by default, assuming
 217 dnl that configure still uses this shell variable.  Without
 218 dnl it, AC_HEADER_ASSERT enables assertions by default.
 219 test -z "$enable_assert"  &&  enable_assert=no
 220
 221 AC_HEADER_ASSERT
 222
 223 dnl ------------------
 224 dnl CHECK FOR PROGRAMS
 225 dnl ------------------
 226 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 227 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 228 AC_PROG_RANLIB          dnl Check for `ranlib'
 229 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 230 AC_PROG_SED             dnl Check for Posix-compliant sed
 231 AC_PROG_YACC            dnl Check for yacc/bison
 232 AM_PROG_LEX             dnl Check for lex/flex
 233
 234 AM_PROG_AR
 235
 236 dnl Look for `cut'
 237 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 238 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 239
 240 dnl
 241 dnl Check for MD5 program and formatting command
 242 dnl
 243 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 244 AS_CASE(["${MD5SUM}"],
 245         [md5sum], [MD5FMT="cat"],
 246         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 247         [MD5FMT="missing"])
 248 AC_SUBST([MD5FMT])
 249
 250 dnl Look for `ls'
 251 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 252 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 253
 254 dnl See how we get ls to display the owner and the group
 255 AS_IF([test "$lspath" != "no"],
 256   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 257                  [nmh_cv_ls_grpopt],
 258   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 259     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 260     dnl ls, it would seem -l gave us both the user and group.  On this type of
 261     dnl ls, -g makes _only_ the group be displayed (and not the user).
 262     nmh_cv_ls_grpopt="-l"],[
 263     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 264     nmh_cv_ls_grpopt="-lg"])])])
 265
 266 dnl Look for `sendmail'
 267 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 268 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 269
 270 dnl Cygwin FAT filesystems do not support hard links.  So default to
 271 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 272 dnl therefore, this cannot be made into a dynamic test, in order to
 273 dnl support the least common Cygwin denominator.
 274 AS_CASE(["$host_os"],
 275   [cygwin*], [LN=cp],
 276   [LN=ln])
 277 AC_SUBST([LN])
 278
 279 dnl ----------------------------------------------------------
 280 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 281 dnl ----------------------------------------------------------
 282 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 283 [for mailspool in /var/mail        dnl
 284                   /var/spool/mail  dnl
 285                   /usr/spool/mail  dnl
 286                   /dev/null;       dnl Just in case we fall through
 287 do
 288   test -d $mailspool && break
 289 done
 290 nmh_cv_mailspool=$mailspool
 291 ])
 292 mailspool=$nmh_cv_mailspool
 293 AC_SUBST([mailspool])dnl
 294
 295 dnl See whether the mail spool directory is world-writable.
 296 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 297   AC_CACHE_CHECK(whether the mail spool is world-writable,
 298                  nmh_cv_mailspool_world_writable,
 299   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 300     nmh_cv_mailspool_world_writable=no
 301   else
 302     nmh_cv_mailspool_world_writable=yes
 303   fi])
 304 fi
 305
 306 dnl Also, check for liblockfile (as found on Debian systems)
 307 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 308
 309 dnl and whether its companion program dotlockfile is setgid
 310 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 311 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 312   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 313     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 314     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 315         nmh_cv_dotlockfile_setgid=yes
 316       else
 317         nmh_cv_dotlockfile_setgid=no
 318       fi])
 319   fi
 320 fi
 321
 322 dnl Provide a way for distcheck to disable setgid_mail via
 323 dnl DISTCHECK_CONFIGURE_FLAGS.
 324 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 325   [nmh_cv_dotlockfile_setgid=yes])
 326
 327 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 328 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 329 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 330   dnl do we really need both of these?
 331   AC_DEFINE([MAILGROUP],[1],
 332     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 333   SETGID_MAIL=1
 334 fi
 335 AC_SUBST([SETGID_MAIL])dnl
 336
 337 dnl Use ls to see which group owns the mail spool directory.
 338 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 339 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 340 ])
 341 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 342 AC_SUBST([MAIL_SPOOL_GRP])dnl
 343
 344 NMH_MIMETYPEPROC
 345 NMH_MIMEENCODINGPROC
 346
 347 dnl -------------------
 348 dnl CHECK FOR LIBRARIES
 349 dnl -------------------
 350 dnl Checks for network libraries (nsl, socket)
 351 NMH_CHECK_NETLIBS
 352
 353 dnl Check the locking functions supported and what we should use by default
 354 NMH_LOCKING
 355
 356 dnl Check for iconv
 357 NMH_CHECK_ICONV
 358
 359 dnl Check for tputs() callback argument
 360 NMH_TPUTS_PUTC_ARG
 361
 362 termcap_curses_order="termcap curses ncurses"
 363 for lib in $termcap_curses_order; do
 364   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 365 done
 366 AC_SUBST([TERMLIB])dnl
 367 AS_IF([test "x$TERMLIB" = "x"],
 368       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 369 curses or ncurses library or package that you can install?])])
 370
 371 dnl Check for readline support
 372 NMH_READLINE
 373
 374 dnl --------------
 375 dnl CHECK FOR NDBM
 376 dnl --------------
 377
 378 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 379             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 380 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 381             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 382
 383 if test "$nmh_ndbm" = "autodetect"; then
 384   if test "$nmh_ndbmheader" != "autodetect"; then
 385     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 386   else
 387
 388     dnl There are at least four implementations of ndbm, and
 389     dnl several of those can be in different places at the whim
 390     dnl of the system integrator. A good summary of this mess
 391     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 392
 393     dnl Classic ndbm with no library required (eg NetBSD): try this
 394     dnl first so we don't accidentally link in a pointless but harmless
 395     dnl library in one of the later ndbm.h+libfoo tests:
 396     NMH_CHECK_NDBM(ndbm.h,,,
 397     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 398       NMH_CHECK_NDBM(db.h,db,,
 399     dnl Berkeley DBv1 emulating ndbm:
 400         NMH_CHECK_NDBM(ndbm.h,db,,
 401           NMH_CHECK_NDBM(ndbm.h,db1,,
 402     dnl Classic ndbm:
 403             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 404     dnl glibc2.1 systems put db1 in a subdir:
 405               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 406     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 407     dnl and possibly needing gbdm_compat library:
 408                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 409                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 410                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 411     dnl 64-bit Cygwin:
 412                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 413     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 414     dnl need to be explicit:
 415                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 416   fi
 417 else
 418   dnl We don't really need to check that the user-specified values work,
 419   dnl but it is a convenience to the user to bomb out early rather than
 420   dnl after configure and half the compile process.
 421   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 422 fi
 423
 424 if test "$nmh_ndbm_found" = "no"; then
 425   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 426 else
 427   dnl Now export the lib/header to our makefile/config.h:
 428   if test x"$nmh_ndbmheader" != x; then
 429     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 430       [Define to the header containing the ndbm API prototypes.])
 431   fi
 432   if test x"$nmh_ndbm" != x; then
 433     NDBM_LIBS="-l$nmh_ndbm"
 434   else
 435     NDBM_LIBS=
 436   fi
 437   AC_SUBST([NDBM_LIBS])
 438 fi
 439
 440 dnl ------------------
 441 dnl Set RPM build root
 442 dnl ------------------
 443 dnl nmhrpm is used in the final summary, see below.  The default value is
 444 dnl reported there as ./RPM, consistent with the reporting of the default
 445 dnl source code location as ., but its absolute path is used in the Makefile.
 446 AC_ARG_WITH([rpmdir],
 447   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 448   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 449           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 450 AC_SUBST([rpmdir])
 451
 452
 453 dnl --------------------
 454 dnl CHECK FOR CYRUS-SASL
 455 dnl --------------------
 456
 457 AS_IF([test x"$with_cyrus_sasl" != x"no"],[
 458   AC_CHECK_HEADER([sasl/sasl.h], HAVE_SASL_H=1)
 459   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"])])
 460 AC_SUBST([SASLLIB])
 461
 462 dnl -----------------
 463 dnl Enable SASL?
 464 dnl -----------------
 465 dnl By default (with_cyrus_sasl=''), enable SASL if header and lib are found.
 466 dnl If SASL requested (--with-sasl with_cyrus_sasl=yes), error if header or lib not found.
 467 dnl If SASL disabled (--without-sasl with_cyrus_sasl=no), don't enable it.
 468 sasl_support=no
 469 CYRUS_SASL=0
 470 AC_SUBST([CYRUS_SASL])
 471 AS_IF([test "x$with_cyrus_sasl" = xyes && test "x$HAVE_SASL_H" = x],
 472       [AC_MSG_ERROR([SASL requested but sasl.h not found])],
 473       [test "x$with_cyrus_sasl" = xyes && test "x$SASLLIB" = x],
 474       [AC_MSG_ERROR([SASL requested but Cyrus SASL library not found])],
 475       [test "x$with_cyrus_sasl" != xno && test "x$HAVE_SASL_H" = x1 &&
 476        test "x$SASLLIB" != x],
 477       [AC_DEFINE([CYRUS_SASL], [1],
 478         [Define to use the Cyrus SASL library for authentication of POP and SMTP.])
 479        CYRUS_SASL=1
 480        sasl_support=yes])
 481
 482 dnl -----------------
 483 dnl CHECK FOR OPENSSL
 484 dnl -----------------
 485
 486 AS_IF([test x"$with_tls" != x"no"],[
 487   dnl OpenBSD 5 needs the other-libraries (fifth argument) to the
 488   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 489   dnl automatically append -lcrypto when linking with -lssl.
 490   AC_CHECK_HEADER([openssl/ssl.h], HAVE_SSL_H=1)
 491   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"])
 492   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"], [TLSLIB=],
 493                [$TLSLIB])])
 494 AC_SUBST([TLSLIB])
 495
 496 dnl -----------------
 497 dnl Enable TLS?
 498 dnl -----------------
 499 dnl By default (with_tls=''), enable TLS if header and libs were found.
 500 dnl If TLS requested (--with-tls with_tls=yes), error if header/lib not found.
 501 dnl If TLS disabled (--without-tls with_tls=no), don't enable it.
 502 tls_support=no
 503 TLS_SUPPORT=0
 504 AC_SUBST([TLS_SUPPORT])
 505 AS_IF([test "x$with_tls" = xyes && test "x$HAVE_SSL_H" = x],
 506       [AC_MSG_ERROR([TLS requested but openssl/ssl.h not found])],
 507       [test "x$with_tls" = xyes && test "x$TLSLIB" = x],
 508       [AC_MSG_ERROR([TLS requested but crypto or ssl library not found])],
 509       [test "x$with_tls" != xno && test "x$HAVE_SSL_H" = x1 && test "x$TLSLIB" != x],
 510       [AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])
 511        TLS_SUPPORT=1
 512        tls_support=yes])
 513
 514 dnl -----------------
 515 dnl CHECK FOR CURL
 516 dnl -----------------
 517 dnl Look for curl if oauth not disabled (--without-oauth).
 518 AC_PATH_PROG([curl_config], [curl-config])
 519 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 520     save_CFLAGS="$CFLAGS"
 521     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 522     AC_CHECK_HEADER([curl/curl.h], [
 523         HAVE_CURL_H=1
 524         AC_CHECK_LIB([curl], [curl_easy_init], [
 525             CURLLIB="`$curl_config --libs`"
 526             AC_SUBST([CURLLIB])
 527             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 528             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 529                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 530                    CURL_USER_AGENT=libcurl/UNKNOWN])
 531             AC_SUBST([CURL_USER_AGENT])
 532           ])
 533       ])
 534     CFLAGS="$save_CFLAGS"
 535   ])
 536
 537 dnl -----------------
 538 dnl Enable OAuth?
 539 dnl -----------------
 540 dnl By default (with_oauth=''), enable OAuth if curl is found.
 541 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 542 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 543 oauth_support=no
 544 OAUTH_SUPPORT=0
 545 AC_SUBST([OAUTH_SUPPORT])
 546 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 547       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 548       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 549       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 550       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 551       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 552        OAUTH_SUPPORT=1
 553        oauth_support=yes])
 554
 555 dnl ----------------
 556 dnl CHECK FLEX FIXUP
 557 dnl ----------------
 558 dnl BUG: This stops $(LFLAGS) working as it comes after $(AM_FLAGS).
 559 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 560 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 561 dnl http://sourceforge.net/p/flex/bugs/140/
 562 dnl 2.6.1 bug: https://github.com/westes/flex/issues/97
 563 AS_IF([test "$LEX" = flex],
 564       [AS_CASE([`$LEX -V`],
 565                [flex\ 2.5.35], [AM_LFLAGS=\
 566 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 567                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 568 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 569                [flex\ 2.6.1], [AM_LFLAGS=\
 570 '; sed '\''/\<int num_to_read\>/s/int/size_t/; s/\<yy_size_t i\>/int i/'\'' $@ >$@.tmp && mv -f $@.tmp $@'])
 571        AC_SUBST([AM_LFLAGS])])
 572
 573 dnl ------------------
 574 dnl FOR INTERNAL USE by the NMH test suite
 575 dnl ------------------
 576 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 577 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 578       AC_SUBST([nmhetcdirinst]))
 579
 580 dnl ----------------
 581 dnl CHECK STRUCTURES
 582 dnl ----------------
 583
 584 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 585 dnl (FreeBSD has a timezone() function but not a timezone global
 586 dnl variable that is visible).
 587 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 588
 589 AC_STRUCT_DIRENT_D_TYPE
 590
 591 dnl
 592 dnl Sigh, this is required because under the new world order autoconf has
 593 dnl nothing to create in a few of the build directories when doing an object
 594 dnl tree build.  So make sure we created certain directories if they don't
 595 dnl exist.
 596 dnl
 597
 598 AC_CONFIG_COMMANDS([build-directories],
 599 [test -d man || AS_MKDIR_P([man])])
 600
 601 AC_CONFIG_COMMANDS_POST([
 602
 603 dnl These odd looking assignments are done to expand out unexpanded
 604 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 605 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 606 dnl again to get the final answer.
 607 dnl We only use the expanded versions to print the install paths in
 608 dnl the final summary and should use them nowhere else (see the autoconf
 609 dnl docs for the rationale for bindir etc being unexpanded).
 610 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 611 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 612 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 613 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 614 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 615 eval "nmhrpm=${nmhrpm}";
 616
 617 AC_MSG_NOTICE([
 618 nmh configuration
 619 -----------------
 620 nmh version                : AC_PACKAGE_VERSION
 621 host os                    : ${host}
 622 compiler                   : ${CC}
 623 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 624 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 625 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 626 source code location       : ${srcdir}
 627 binary install path        : ${nmhbin}
 628 libexec install path       : ${nmhlibexec}/nmh
 629 config files install path  : ${nmhsysconf}/nmh
 630 man page install path      : ${nmhman}
 631 docs install path          : ${nmhdoc}
 632 RPM build root             : ${nmhrpm}
 633 backup prefix              : ${backup_prefix}
 634 transport system           : ${MTS}
 635 spool default locking type : ${with_locking}
 636 default smtp servers       : ${smtpservers}
 637 SASL support               : ${sasl_support}
 638 TLS support                : ${tls_support}
 639 OAuth support              : ${oauth_support}
 640 ])])dnl
 641
 642 dnl ---------------
 643 dnl OUTPUT MAKEFILE
 644 dnl ---------------
 645 AC_CONFIG_FILES([Makefile test/common.sh])
 646 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 647 AC_OUTPUT