diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122   else
 123     dnl Use -v and some other options with SunStudio cc.  lex produces
 124     dnl code that causes unreachable-statement warnings.  It might be
 125     dnl better to use an autoconf test, except -v will probably succeed
 126     dnl with many other compilers but have different meaning.
 127     AS_CASE([`${CC} -V 2>&1`],
 128             [cc:\ Sun\ C*], [CFLAGS=\
 129 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 130   fi
 131
 132   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 133                  [nmh_saved_cflags="$CFLAGS"
 134                  CFLAGS="$CFLAGS -Wall -Werror"
 135                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 138
 139   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 140                  [nmh_saved_cflags="$CFLAGS"
 141                  CFLAGS="$CFLAGS -Wextra -Werror"
 142                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 143                                 nmh_cv_has_wextra=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 146 fi
 147
 148 dnl --------------
 149 dnl CUSTOMIZE LINK
 150 dnl --------------
 151 if test `uname` = OpenBSD; then
 152   dnl Filter out "often/almost always misused" warnings from OpenBSD linker.
 153   [POSTLINK="2>&1 | egrep -v ': [w]arning: s[a-z]+\(\) is \
 154 (almost always|often) misused, please use'; true"]
 155 fi
 156 AC_SUBST([POSTLINK])
 157
 158 dnl -----------------
 159 dnl CUSTOMIZE LDFLAGS
 160 dnl -----------------
 161 if test "$GCC" = yes; then
 162   dnl Disable clang complaint about unused -ansi when linking.
 163   AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 164                  [nmh_cv_has_q_unused_arguments],
 165                  [nmh_saved_ldflags="$LDFLAGS"
 166                   LDFLAGS="$LDFLAGS -Qunused-arguments"
 167                   AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 168                                     nmh_cv_has_q_unused_arguments=no)
 169                   LDFLAGS="$nmh_saved_ldflags"])
 170   test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 171     LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 172 fi
 173
 174 dnl This really shouldn't be necessary.  And we really shouldn't add -s.
 175 if test x"$enable_debug" = x"yes"; then
 176   test -z "$LDFLAGS" && LDFLAGS=-g
 177 else
 178   if test -z "$LDFLAGS"; then
 179     case "$build_os" in
 180       darwin*) LDFLAGS= ;;
 181             *) LDFLAGS=-s ;;
 182     esac
 183   fi
 184 fi
 185
 186 dnl This hack turns off assertions by default, assuming
 187 dnl that configure still uses this shell variable.  Without
 188 dnl it, AC_HEADER_ASSERT enables assertions by default.
 189 test -z "$enable_assert"  &&  enable_assert=no
 190
 191 AC_HEADER_ASSERT
 192
 193 dnl ------------------
 194 dnl CHECK FOR PROGRAMS
 195 dnl ------------------
 196 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 197 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 198 AC_PROG_RANLIB          dnl Check for `ranlib'
 199 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 200 AC_PROG_SED             dnl Check for Posix-compliant sed
 201 AM_PROG_LEX             dnl Check for lex/flex
 202
 203 AM_PROG_AR
 204
 205 dnl Look for `cut'
 206 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 207 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 208
 209 dnl
 210 dnl Check for MD5 program and formatting command
 211 dnl
 212 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 213 AS_CASE(["${MD5SUM}"],
 214         [md5sum], [MD5FMT="cat"],
 215         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 216         [MD5FMT="missing"])
 217 AC_SUBST([MD5FMT])
 218
 219 dnl ----------------------------------------------
 220 dnl check for lclint, and lint if it doesn't exist
 221 dnl ----------------------------------------------
 222 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 223 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 224   [LINT=$ac_cv_prog_linttmp1
 225   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 226   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 227   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 228     [LINT=$ac_cv_prog_linttmp2
 229     LINTFLAGS=""],
 230     [LINT="echo 'No lint program found'"
 231     LINTFLAGS=""])])
 232 AC_SUBST([LINT])dnl
 233 AC_SUBST([LINTFLAGS])dnl
 234
 235 dnl Look for `ls'
 236 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 237 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 238
 239 dnl See how we get ls to display the owner and the group
 240 AS_IF([test "$lspath" != "no"],
 241   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 242                  [nmh_cv_ls_grpopt],
 243   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 244     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 245     dnl ls, it would seem -l gave us both the user and group.  On this type of
 246     dnl ls, -g makes _only_ the group be displayed (and not the user).
 247     nmh_cv_ls_grpopt="-l"],[
 248     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 249     nmh_cv_ls_grpopt="-lg"])])])
 250
 251 dnl Look for `sendmail'
 252 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 253 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 254
 255 dnl Cygwin FAT filesystems do not support hard links.  So default to
 256 dnl cp instead, even if running on an NTFS or other filesystem.
 257 AS_CASE(["$host_os"],
 258   [cygwin*], [LN=cp],
 259   [LN=ln])
 260 AC_SUBST([LN])
 261
 262 dnl ----------------------------------------------------------
 263 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 264 dnl ----------------------------------------------------------
 265 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 266 [for mailspool in /var/mail        dnl
 267                   /var/spool/mail  dnl
 268                   /usr/spool/mail  dnl
 269                   /dev/null;       dnl Just in case we fall through
 270 do
 271   test -d $mailspool && break
 272 done
 273 nmh_cv_mailspool=$mailspool
 274 ])
 275 mailspool=$nmh_cv_mailspool
 276 AC_SUBST([mailspool])dnl
 277
 278 dnl See whether the mail spool directory is world-writable.
 279 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 280   AC_CACHE_CHECK(whether the mail spool is world-writable,
 281                  nmh_cv_mailspool_world_writable,
 282   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 283     nmh_cv_mailspool_world_writable=no
 284   else
 285     nmh_cv_mailspool_world_writable=yes
 286   fi])
 287 fi
 288
 289 dnl Also, check for liblockfile (as found on Debian systems)
 290 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 291
 292 dnl and whether its companion program dotlockfile is setgid
 293 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 294 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 295   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 296     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 297     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 298         nmh_cv_dotlockfile_setgid=yes
 299       else
 300         nmh_cv_dotlockfile_setgid=no
 301       fi])
 302   fi
 303 fi
 304
 305 dnl Provide a way for distcheck to disable setgid_mail via
 306 dnl DISTCHECK_CONFIGURE_FLAGS.
 307 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 308   [nmh_cv_dotlockfile_setgid=yes])
 309
 310 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 311 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 312 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 313   dnl do we really need both of these?
 314   AC_DEFINE(MAILGROUP,1,
 315     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 316   SETGID_MAIL=1
 317 fi
 318 AC_SUBST([SETGID_MAIL])dnl
 319
 320 dnl Use ls to see which group owns the mail spool directory.
 321 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 322 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 323 ])
 324 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 325 AC_SUBST(MAIL_SPOOL_GRP)dnl
 326
 327 dnl ---------------------------------------------
 328 dnl CHECK FOR PROGRAM TO PROVIDE MIME TYPE STRING
 329 dnl ---------------------------------------------
 330 AS_IF([file --mime "${srcdir}"/configure >/dev/null 2>&1],
 331       [AS_IF([file --brief --mime "${srcdir}"/configure >/dev/null 2>&1],
 332              [nmh_mimetypeproc='"file --brief --mime"'],
 333              [nmh_mimetypeproc='"file --mime"'])])
 334 AS_CASE([$nmh_mimetypeproc], [?*],
 335         [AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$nmh_mimetypeproc],
 336           [Program, with arguments, that provides MIME type string.])])
 337 AS_ECHO_N(["AS_ESCAPE([checking program to provide MIME type string ... ])"])
 338 AS_ECHO(["AS_ESCAPE([$nmh_mimetypeproc], [""])"])
 339
 340 dnl ------------------
 341 dnl CHECK HEADER FILES
 342 dnl ------------------
 343
 344 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 345 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 346 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 347 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 348 dnl declared; if so they should have an entry added to this case statement.
 349 dnl NB that we must define this on the compiler command line, not in config.h,
 350 dnl because it must be set before any system header is included and there's no
 351 dnl portable way to make sure that files generated by lex include config.h
 352 dnl before system header files.
 353
 354 AS_CASE(["$host_os"],
 355         [linux*],
 356         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 357           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 358                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 359
 360 AC_HEADER_TIOCGWINSZ
 361 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 362                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 363
 364 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 365   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 366 [[#if HAVE_SYS_STREAM_H
 367 #  include <sys/stream.h>
 368 #endif
 369 ]])
 370
 371 dnl ---------------
 372 dnl CHECK FUNCTIONS
 373 dnl ---------------
 374 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent arc4random])
 375
 376 dnl Check for multibyte character set support
 377 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 378             "x$ac_cv_header_wctype_h" = "xyes" -a \
 379             "x$ac_cv_func_wcwidth" = "xyes" -a \
 380             "x$ac_cv_func_mbtowc" = "xyes"],
 381       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 382                  [Define to enable support for multibyte character sets.])
 383        MULTIBYTE_ENABLED=1],
 384       [MULTIBYTE_ENABLED=0])
 385 AC_SUBST([MULTIBYTE_ENABLED])
 386
 387 dnl -------------------
 388 dnl CHECK FOR LIBRARIES
 389 dnl -------------------
 390 dnl Check location of modf
 391 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 392
 393 dnl Checks for network libraries (nsl, socket)
 394 NMH_CHECK_NETLIBS
 395
 396 dnl Check for readline support
 397 NMH_READLINE
 398
 399 dnl Check the locking functions supported and what we should use by default
 400 NMH_LOCKING
 401
 402 dnl Check for iconv
 403 NMH_CHECK_ICONV
 404
 405 termcap_curses_order="termcap curses ncurses"
 406 for lib in $termcap_curses_order; do
 407   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 408 done
 409 AC_SUBST([TERMLIB])dnl
 410 AS_IF([test "x$TERMLIB" = "x"],
 411       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 412 or ncurses library or package that you can install?])])
 413
 414 dnl --------------
 415 dnl CHECK FOR NDBM
 416 dnl --------------
 417
 418 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 419             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 420 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 421             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 422
 423 if test "$nmh_ndbm" = "autodetect"; then
 424   if test "$nmh_ndbmheader" != "autodetect"; then
 425     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 426   else
 427
 428     dnl There are at least four implementations of ndbm, and
 429     dnl several of those can be in different places at the whim
 430     dnl of the system integrator. A good summary of this mess
 431     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 432
 433     dnl Classic ndbm with no library required (eg NetBSD): try this
 434     dnl first so we don't accidentally link in a pointless but harmless
 435     dnl library in one of the later ndbm.h+libfoo tests:
 436     NMH_CHECK_NDBM(ndbm.h,,,
 437     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 438       NMH_CHECK_NDBM(db.h,db,,
 439     dnl Berkeley DBv1 emulating ndbm:
 440         NMH_CHECK_NDBM(ndbm.h,db,,
 441           NMH_CHECK_NDBM(ndbm.h,db1,,
 442     dnl Classic ndbm:
 443             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 444     dnl glibc2.1 systems put db1 in a subdir:
 445               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 446     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 447     dnl and possibly needing gbdm_compat library:
 448                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 449                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 450                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 451                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 452
 453   fi
 454 else
 455   dnl We don't really need to check that the user-specified values work,
 456   dnl but it is a convenience to the user to bomb out early rather than
 457   dnl after configure and half the compile process.
 458   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 459 fi
 460
 461 if test "$nmh_ndbm_found" = "no"; then
 462   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 463 else
 464   dnl Now export the lib/header to our makefile/config.h:
 465   if test x"$nmh_ndbmheader" != x; then
 466     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 467       [Define to the header containing the ndbm API prototypes.])
 468   fi
 469   if test x"$nmh_ndbm" != x; then
 470     NDBM_LIBS="-l$nmh_ndbm"
 471   else
 472     NDBM_LIBS=
 473   fi
 474   AC_SUBST([NDBM_LIBS])
 475 fi
 476
 477 dnl ------------------
 478 dnl Set RPM build root
 479 dnl ------------------
 480 dnl nmhrpm is used in the final summary, see below.  The default value is
 481 dnl reported there as ./RPM, consistent with the reporting of the default
 482 dnl source code location as ., but its absolute path is used in the Makefile.
 483 AC_ARG_WITH([rpmdir],
 484   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 485   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 486           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 487 AC_SUBST([rpmdir])
 488
 489
 490 dnl --------------------
 491 dnl CHECK FOR CYRUS-SASL
 492 dnl --------------------
 493
 494 AS_IF([test x"$sasl_support" = x"yes"],[
 495   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 496   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 497     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 498 AC_SUBST([SASLLIB])
 499
 500 dnl -----------------
 501 dnl CHECK FOR OPENSSL
 502 dnl -----------------
 503
 504 AS_IF([test x"$tls_support" = x"yes"],[
 505   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 506   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 507     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 508   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 509     [AC_MSG_ERROR([OpenSSL library not found])])],
 510   [TLSLIB=])
 511 AC_SUBST([TLSLIB])
 512
 513 dnl ---------------------
 514 dnl CHECK TERMCAP LIBRARY
 515 dnl ---------------------
 516
 517 dnl Add the termcap library, so that the following configure
 518 dnl tests will find it when it tries to link test programs.
 519 nmh_save_LIBS="$LIBS"
 520 LIBS="$TERMLIB $LIBS"
 521
 522 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 523 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 524 dnl in tgetstr().
 525 dnl Under Cygwin test program crashes but exit code is still 0. So,
 526 dnl we test for a file that porgram should create
 527 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 528 [Define to 1 if tgetent() accepts NULL as a buffer.])
 529 AC_CACHE_CHECK(if tgetent accepts NULL,
 530 nmh_cv_func_tgetent_accepts_null,
 531 [AC_TRY_RUN([
 532 main()
 533 {
 534     char buf[4096];
 535     int r1 = tgetent(buf, "vt100");
 536     int r2 = tgetent((char*)0,"vt100");
 537     if (r1 >= 0 && r1 == r2) {
 538         char tbuf[1024], *u;
 539         u = tbuf;
 540         tgetstr("cl", &u);
 541         creat("conftest.tgetent", 0640);
 542     }
 543     exit((r1 != r2) || r2 == -1);
 544 }
 545 ],
 546   if test -f conftest.tgetent; then
 547     nmh_cv_func_tgetent_accepts_null=yes
 548   else
 549     nmh_cv_func_tgetent_accepts_null=no
 550   fi,
 551   nmh_cv_func_tgetent_accepts_null=no,
 552   nmh_cv_func_tgetent_accepts_null=no)])
 553 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 554   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 555 fi
 556 AC_CACHE_CHECK(if tgetent returns 0 on success,
 557 nmh_cv_func_tgetent_zero_success,
 558 [AC_TRY_RUN([
 559 main()
 560 {
 561     char buf[4096];
 562     int r1 = tgetent(buf, "!@#$%^&*");
 563     int r2 = tgetent(buf, "vt100");
 564     if (r1 < 0 && r2 == 0) {
 565         char tbuf[1024], *u;
 566         u = tbuf;
 567         tgetstr("cl", &u);
 568         creat("conftest.tgetent0", 0640);
 569     }
 570     exit(r1 == r2);
 571 }
 572 ],
 573   if test -f conftest.tgetent0; then
 574     nmh_cv_func_tgetent_zero_success=yes
 575   else
 576     nmh_cv_func_tgetent_zero_success=no
 577   fi,
 578   nmh_cv_func_tgetent_zero_success=no,
 579   nmh_cv_func_tgetent_zero_success=no)])
 580 AH_TEMPLATE([TGETENT_SUCCESS],
 581 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 582 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 583   AC_DEFINE(TGETENT_SUCCESS, 0)
 584 else
 585   AC_DEFINE(TGETENT_SUCCESS, 1)
 586 fi
 587
 588 dnl Now put the libraries back to what it was before we
 589 dnl starting checking the termcap library.
 590 LIBS="$nmh_save_LIBS"
 591
 592 dnl ----------------
 593 dnl CHECK FLEX FIXUP
 594 dnl ----------------
 595 dnl Use LFLAGS make variable setting to work around bugs in flex
 596 dnl 2.5.36 that cause signed/unsigned mismatch,
 597 dnl http://sourceforge.net/p/flex/bugs/140/
 598 AS_IF([test "$LEX" = flex],
 599       [AS_CASE([`$LEX -V`],
 600                [flex\ 2.5.35], [LFLAGS=\
 601 '; printf "%s\n" '\''1,$$s/(size_t) \(num_to_read\)/\1/'\'' w q | ed -s $@; \
 602 true'],
 603                [flex\ 2.5.36], [LFLAGS=\
 604 '; printf "%s\n" '\''1,$$s/\(   \)int i;/\1yy_size_t i;/'\'' w q | ed -s $@; \
 605 true'])
 606        AC_SUBST([LFLAGS])])
 607
 608 dnl --------------
 609 dnl CHECK TYPEDEFS
 610 dnl --------------
 611 AC_TYPE_PID_T
 612 AC_TYPE_OFF_T
 613 AC_TYPE_UID_T
 614 AC_TYPE_MODE_T
 615 AC_TYPE_SIZE_T
 616
 617 dnl ----------------
 618 dnl CHECK STRUCTURES
 619 dnl ----------------
 620
 621 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 622 dnl (FreeBSD has a timezone() function but not a timezone global
 623 dnl variable that is visible).
 624 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 625
 626 AC_STRUCT_DIRENT_D_TYPE
 627
 628 dnl Where is <signal.h> located?  Needed as input for signames.awk
 629 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 630 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 631                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 632                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 633                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 634                  /usr/include/sys/signal.h      dnl Almost everybody else
 635                  /dev/null;                     dnl Just in case we fall through
 636 do
 637   test -f $SIGNAL_H && \
 638   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 639   break
 640 done
 641 nmh_cv_path_signal_h=$SIGNAL_H
 642 ])
 643 SIGNAL_H=$nmh_cv_path_signal_h
 644 AC_SUBST(SIGNAL_H)dnl
 645
 646 dnl
 647 dnl Sigh, this is required because under the new world order autoconf has
 648 dnl nothing to create in a few of the build directories when doing an object
 649 dnl tree build.  So make sure we created certain directories if they don't
 650 dnl exist.
 651 dnl
 652
 653 AC_CONFIG_COMMANDS([build-directories],
 654 [test -d etc || AS_MKDIR_P([etc])
 655 test -d man || AS_MKDIR_P([man])])
 656
 657 AC_CONFIG_COMMANDS_POST([
 658
 659 dnl These odd looking assignments are done to expand out unexpanded
 660 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 661 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 662 dnl again to get the final answer.
 663 dnl We only use the expanded versions to print the install paths in
 664 dnl the final summary and should use them nowhere else (see the autoconf
 665 dnl docs for the rationale for bindir etc being unexpanded).
 666 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 667 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 668 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 669 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 670 eval "nmhrpm=${nmhrpm}";
 671
 672 AC_MSG_NOTICE([
 673 nmh configuration
 674 -----------------
 675 nmh version                : AC_PACKAGE_VERSION
 676 host os                    : ${host}
 677 compiler                   : ${CC}
 678 compiler flags             : ${CFLAGS}
 679 linker flags               : ${LDFLAGS}
 680 preprocessor flags         : ${CPPFLAGS}
 681 source code location       : ${srcdir}
 682 binary install path        : ${nmhbin}
 683 library install path       : ${nmhlib}
 684 config files install path  : ${nmhsysconf}
 685 man page install path      : ${nmhman}
 686 RPM build root             : ${nmhrpm}
 687 backup prefix              : ${backup_prefix}
 688 transport system           : ${MTS}
 689 spool default locking type : ${with_locking}
 690 default smtp servers       : ${smtpservers}
 691 SASL support               : ${sasl_support}
 692 TLS support                : ${tls_support}
 693 ])])dnl
 694
 695 dnl ---------------
 696 dnl OUTPUT MAKEFILE
 697 dnl ---------------
 698 AC_CONFIG_FILES([Makefile test/common.sh])
 699 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 700 AC_OUTPUT