diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  96 if test x"$enable_debug" = x"yes"; then
  97   test -z "$LDFLAGS" && LDFLAGS=-g
  98 fi
  99
 100 AC_PROG_CC
 101 AM_PROG_CC_C_O
 102
 103 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 104 [nmh_saved_cflags="$CFLAGS"
 105  CFLAGS="$CFLAGS -Wextra -Werror"
 106  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 107  CFLAGS="$nmh_saved_cflags"])
 108
 109 AC_CACHE_CHECK([whether compiler supports -Wno-clobbered], [nmh_cv_has_noclobbered],
 110 [nmh_saved_cflags="$CFLAGS"
 111  CFLAGS="$CFLAGS -Wno-clobbered -Werror"
 112  AC_TRY_COMPILE([],[],nmh_cv_has_noclobbered=yes,nmh_cv_has_noclobbered=no)
 113  CFLAGS="$nmh_saved_cflags"])
 114
 115 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 116 dnl setup version 2.763, because it disables some features in the
 117 dnl system system header files and warns about them with -Wall.  Try
 118 dnl to test for that generally, though still with gcc.
 119 if test "$GCC" = yes; then
 120   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 121     [nmh_saved_cppflags="$CPPFLAGS"
 122      nmh_saved_cflags="$CFLAGS"
 123      CPPFLAGS="-D_GNU_SOURCE"
 124      CFLAGS="-ansi -Wall -Werror"
 125      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 126        [nmh_cv_has_dash_ansi=yes],
 127        [nmh_cv_has_dash_ansi=no])
 128      CPPFLAGS="$nmh_saved_cppflags"
 129      CFLAGS="$nmh_saved_cflags"])
 130 else
 131   nmh_cv_has_dash_ansi=no
 132 fi
 133
 134 dnl if the user hasn't specified CFLAGS, then
 135 dnl   if compiler is gcc, then
 136 dnl    use -O2 and some warning flags
 137 dnl   else use -O
 138 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 139 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 140 dnl warnings which are probably mostly spurious and which in any case we
 141 dnl don't want to deal with now.
 142 if test "$nmh_cv_has_dash_ansi" = "yes"; then
 143     nmh_gcc_warnflags="-ansi -pedantic -Wall"
 144 else
 145     nmh_gcc_warnflags="-Wall"
 146 fi
 147 if test "$nmh_cv_has_wextra" = "yes"; then
 148     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wextra"
 149 fi
 150 if test "$nmh_cv_has_noclobbered" = "yes"; then
 151     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wno-clobbered"
 152 fi
 153
 154 if test -n "$auto_cflags"; then
 155   if test x"$enable_debug" = x"yes"; then
 156     if test -n "$GCC"; then
 157       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 158     else
 159       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 160     fi
 161   else
 162     if test -z "$LDFLAGS"; then
 163       case "$build_os" in
 164         darwin*)
 165           LDFLAGS=
 166           ;;
 167         *)
 168           LDFLAGS=-s
 169           ;;
 170       esac
 171     fi
 172     if test -n "$GCC"; then
 173       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 174     else
 175       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 176     fi
 177     AC_DEFINE([NDEBUG], [1],
 178               [Define to disable run-time debugging and asserts.])
 179   fi
 180 fi
 181
 182 dnl ------------------
 183 dnl CHECK FOR PROGRAMS
 184 dnl ------------------
 185 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 186 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 187 AC_PROG_RANLIB          dnl Check for `ranlib'
 188 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 189 AC_PROG_SED             dnl Check for Posix-compliant sed
 190 AM_PROG_LEX             dnl Check for lex/flex
 191
 192 AM_PROG_AR
 193
 194 dnl Look for `cut'
 195 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 196 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 197
 198 dnl
 199 dnl Check for MD5 program and formatting command
 200 dnl
 201 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 202 AS_CASE(["${MD5SUM}"],
 203         [md5sum], [MD5FMT="cat"],
 204         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 205         [MD5FMT="missing"])
 206 AC_SUBST([MD5FMT])
 207
 208 dnl ----------------------------------------------
 209 dnl check for lclint, and lint if it doesn't exist
 210 dnl ----------------------------------------------
 211 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 212 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 213   [LINT=$ac_cv_prog_linttmp1
 214   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 215   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 216   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 217     [LINT=$ac_cv_prog_linttmp2
 218     LINTFLAGS=""],
 219     [LINT="echo 'No lint program found'"
 220     LINTFLAGS=""])])
 221 AC_SUBST([LINT])dnl
 222 AC_SUBST([LINTFLAGS])dnl
 223
 224 dnl Look for `ls'
 225 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 226 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 227
 228 dnl See how we get ls to display the owner and the group
 229 AS_IF([test "$lspath" != "no"],
 230   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 231                  [nmh_cv_ls_grpopt],
 232   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 233     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 234     dnl ls, it would seem -l gave us both the user and group.  On this type of
 235     dnl ls, -g makes _only_ the group be displayed (and not the user).
 236     nmh_cv_ls_grpopt="-l"],[
 237     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 238     nmh_cv_ls_grpopt="-lg"])])])
 239
 240 dnl Look for `sendmail'
 241 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 242 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 243
 244 dnl Cygwin FAT filesystems do not support hard links.  So default to
 245 dnl cp instead, even if running on an NTFS or other filesystem.
 246 AS_CASE(["$host_os"],
 247   [cygwin*],[LN=cp],
 248   [LN=ln])
 249 AC_SUBST([LN])
 250
 251 dnl ----------------------------------------------------------
 252 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 253 dnl ----------------------------------------------------------
 254 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 255 [for mailspool in /var/mail        dnl
 256                   /var/spool/mail  dnl
 257                   /usr/spool/mail  dnl
 258                   /dev/null;       dnl Just in case we fall through
 259 do
 260   test -d $mailspool && break
 261 done
 262 nmh_cv_mailspool=$mailspool
 263 ])
 264 mailspool=$nmh_cv_mailspool
 265 AC_SUBST([mailspool])dnl
 266
 267 dnl See whether the mail spool directory is world-writable.
 268 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 269   AC_CACHE_CHECK(whether the mail spool is world-writable,
 270                  nmh_cv_mailspool_world_writable,
 271   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 272     nmh_cv_mailspool_world_writable=no
 273   else
 274     nmh_cv_mailspool_world_writable=yes
 275   fi])
 276 fi
 277
 278 dnl Also, check for liblockfile (as found on Debian systems)
 279 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 280
 281 dnl and whether its companion program dotlockfile is setgid
 282 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 283 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 284   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 285     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 286     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 287         nmh_cv_dotlockfile_setgid=yes
 288       else
 289         nmh_cv_dotlockfile_setgid=no
 290       fi])
 291   fi
 292 fi
 293
 294 dnl Provide a way for distcheck to disable setgid_mail via
 295 dnl DISTCHECK_CONFIGURE_FLAGS.
 296 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 297   [nmh_cv_dotlockfile_setgid=yes])
 298
 299 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 300 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 301 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 302   dnl do we really need both of these?
 303   AC_DEFINE(MAILGROUP,1,
 304     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 305   SETGID_MAIL=1
 306 fi
 307 AC_SUBST([SETGID_MAIL])dnl
 308
 309 dnl Use ls to see which group owns the mail spool directory.
 310 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 311 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 312 ])
 313 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 314 AC_SUBST(MAIL_SPOOL_GRP)dnl
 315
 316 dnl ------------------
 317 dnl CHECK HEADER FILES
 318 dnl ------------------
 319
 320 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 321 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 322 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 323 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 324 dnl declared; if so they should have an entry added to this case statement.
 325 dnl NB that we must define this on the compiler command line, not in config.h,
 326 dnl because it must be set before any system header is included and there's no
 327 dnl portable way to make sure that files generated by lex include config.h
 328 dnl before system header files.
 329
 330 AS_CASE(["$host_os"],
 331         [linux*],
 332         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 333           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 334                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 335
 336 AC_HEADER_TIOCGWINSZ
 337 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 338                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 339
 340 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 341   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 342 [[#if HAVE_SYS_STREAM_H
 343 #  include <sys/stream.h>
 344 #endif
 345 ]])
 346
 347 dnl ---------------
 348 dnl CHECK FUNCTIONS
 349 dnl ---------------
 350 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 351
 352 dnl Check for multibyte character set support
 353 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 354             "x$ac_cv_header_wctype_h" = "xyes" -a \
 355             "x$ac_cv_func_wcwidth" = "xyes" -a \
 356             "x$ac_cv_func_mbtowc" = "xyes"],
 357       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 358                  [Define to enable support for multibyte character sets.])
 359        MULTIBYTE_ENABLED=1],
 360       [MULTIBYTE_ENABLED=0])
 361 AC_SUBST([MULTIBYTE_ENABLED])
 362
 363 dnl -------------------
 364 dnl CHECK FOR LIBRARIES
 365 dnl -------------------
 366 dnl Check location of modf
 367 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 368
 369 dnl Checks for network libraries (nsl, socket)
 370 NMH_CHECK_NETLIBS
 371
 372 dnl Check for readline support
 373 NMH_READLINE
 374
 375 dnl Check the locking functions supported and what we should use by default
 376 NMH_LOCKING
 377
 378 dnl Check for iconv
 379 NMH_CHECK_ICONV
 380
 381 termcap_curses_order="termcap curses ncurses"
 382 for lib in $termcap_curses_order; do
 383   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 384 done
 385 AC_SUBST([TERMLIB])dnl
 386 AS_IF([test "x$TERMLIB" = "x"],
 387       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 388 or ncurses library or package that you can install?])])
 389
 390 dnl --------------
 391 dnl CHECK FOR NDBM
 392 dnl --------------
 393
 394 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 395             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 396 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 397             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 398
 399 if test "$nmh_ndbm" = "autodetect"; then
 400   if test "$nmh_ndbmheader" != "autodetect"; then
 401     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 402   else
 403
 404     dnl There are at least four implementations of ndbm, and
 405     dnl several of those can be in different places at the whim
 406     dnl of the system integrator. A good summary of this mess
 407     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 408
 409     dnl Classic ndbm with no library required (eg NetBSD): try this
 410     dnl first so we don't accidentally link in a pointless but harmless
 411     dnl library in one of the later ndbm.h+libfoo tests:
 412     NMH_CHECK_NDBM(ndbm.h,,,
 413     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 414       NMH_CHECK_NDBM(db.h,db,,
 415     dnl Berkeley DBv1 emulating ndbm:
 416         NMH_CHECK_NDBM(ndbm.h,db,,
 417           NMH_CHECK_NDBM(ndbm.h,db1,,
 418     dnl Classic ndbm:
 419             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 420     dnl glibc2.1 systems put db1 in a subdir:
 421               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 422     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 423     dnl and possibly needing gbdm_compat library:
 424                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 425                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 426                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 427                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 428
 429   fi
 430 else
 431   dnl We don't really need to check that the user-specified values work,
 432   dnl but it is a convenience to the user to bomb out early rather than
 433   dnl after configure and half the compile process.
 434   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 435 fi
 436
 437 if test "$nmh_ndbm_found" = "no"; then
 438   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 439 else
 440   dnl Now export the lib/header to our makefile/config.h:
 441   if test x"$nmh_ndbmheader" != x; then
 442     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 443       [Define to the header containing the ndbm API prototypes.])
 444   fi
 445   if test x"$nmh_ndbm" != x; then
 446     NDBM_LIBS="-l$nmh_ndbm"
 447   else
 448     NDBM_LIBS=
 449   fi
 450   AC_SUBST([NDBM_LIBS])
 451 fi
 452
 453 dnl ------------------
 454 dnl Set RPM build root
 455 dnl ------------------
 456 dnl nmhrpm is used in the final summary, see below.  The default value is
 457 dnl reported there as ./RPM, consistent with the reporting of the default
 458 dnl source code location as ., but its absolute path is used in the Makefile.
 459 AC_ARG_WITH([rpmdir],
 460   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 461   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 462           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 463 AC_SUBST([rpmdir])
 464
 465
 466 dnl --------------------
 467 dnl CHECK FOR CYRUS-SASL
 468 dnl --------------------
 469
 470 AS_IF([test x"$sasl_support" = x"yes"],[
 471   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 472   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 473     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 474 AC_SUBST([SASLLIB])
 475
 476 dnl -----------------
 477 dnl CHECK FOR OPENSSL
 478 dnl -----------------
 479
 480 AS_IF([test x"$tls_support" = x"yes"],[
 481   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 482   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 483     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 484   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 485     [AC_MSG_ERROR([OpenSSL library not found])])],
 486   [TLSLIB=])
 487 AC_SUBST([TLSLIB])
 488
 489 dnl ---------------------
 490 dnl CHECK TERMCAP LIBRARY
 491 dnl ---------------------
 492
 493 dnl Add the termcap library, so that the following configure
 494 dnl tests will find it when it tries to link test programs.
 495 nmh_save_LIBS="$LIBS"
 496 LIBS="$TERMLIB $LIBS"
 497
 498 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 499 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 500 dnl in tgetstr().
 501 dnl Under Cygwin test program crashes but exit code is still 0. So,
 502 dnl we test for a file that porgram should create
 503 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 504 [Define to 1 if tgetent() accepts NULL as a buffer.])
 505 AC_CACHE_CHECK(if tgetent accepts NULL,
 506 nmh_cv_func_tgetent_accepts_null,
 507 [AC_TRY_RUN([
 508 main()
 509 {
 510     char buf[4096];
 511     int r1 = tgetent(buf, "vt100");
 512     int r2 = tgetent((char*)0,"vt100");
 513     if (r1 >= 0 && r1 == r2) {
 514         char tbuf[1024], *u;
 515         u = tbuf;
 516         tgetstr("cl", &u);
 517         creat("conftest.tgetent", 0640);
 518     }
 519     exit((r1 != r2) || r2 == -1);
 520 }
 521 ],
 522   if test -f conftest.tgetent; then
 523     nmh_cv_func_tgetent_accepts_null=yes
 524   else
 525     nmh_cv_func_tgetent_accepts_null=no
 526   fi,
 527   nmh_cv_func_tgetent_accepts_null=no,
 528   nmh_cv_func_tgetent_accepts_null=no)])
 529 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 530   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 531 fi
 532 AC_CACHE_CHECK(if tgetent returns 0 on success,
 533 nmh_cv_func_tgetent_zero_success,
 534 [AC_TRY_RUN([
 535 main()
 536 {
 537     char buf[4096];
 538     int r1 = tgetent(buf, "!@#$%^&*");
 539     int r2 = tgetent(buf, "vt100");
 540     if (r1 < 0 && r2 == 0) {
 541         char tbuf[1024], *u;
 542         u = tbuf;
 543         tgetstr("cl", &u);
 544         creat("conftest.tgetent0", 0640);
 545     }
 546     exit(r1 == r2);
 547 }
 548 ],
 549   if test -f conftest.tgetent0; then
 550     nmh_cv_func_tgetent_zero_success=yes
 551   else
 552     nmh_cv_func_tgetent_zero_success=no
 553   fi,
 554   nmh_cv_func_tgetent_zero_success=no,
 555   nmh_cv_func_tgetent_zero_success=no)])
 556 AH_TEMPLATE([TGETENT_SUCCESS],
 557 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 558 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 559   AC_DEFINE(TGETENT_SUCCESS, 0)
 560 else
 561   AC_DEFINE(TGETENT_SUCCESS, 1)
 562 fi
 563
 564 dnl Now put the libraries back to what it was before we
 565 dnl starting checking the termcap library.
 566 LIBS="$nmh_save_LIBS"
 567
 568 dnl --------------
 569 dnl CHECK TYPEDEFS
 570 dnl --------------
 571 AC_TYPE_PID_T
 572 AC_TYPE_OFF_T
 573 AC_TYPE_UID_T
 574 AC_TYPE_MODE_T
 575 AC_TYPE_SIZE_T
 576
 577 dnl ----------------
 578 dnl CHECK STRUCTURES
 579 dnl ----------------
 580
 581 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 582 dnl (FreeBSD has a timezone() function but not a timezone global
 583 dnl variable that is visible).
 584 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 585
 586 AC_STRUCT_DIRENT_D_TYPE
 587
 588 dnl Where is <signal.h> located?  Needed as input for signames.awk
 589 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 590 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 591                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 592                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 593                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 594                  /usr/include/sys/signal.h      dnl Almost everybody else
 595                  /dev/null;                     dnl Just in case we fall through
 596 do
 597   test -f $SIGNAL_H && \
 598   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 599   break
 600 done
 601 nmh_cv_path_signal_h=$SIGNAL_H
 602 ])
 603 SIGNAL_H=$nmh_cv_path_signal_h
 604 AC_SUBST(SIGNAL_H)dnl
 605
 606 dnl
 607 dnl Sigh, this is required because under the new world order autoconf has
 608 dnl nothing to create in a few of the build directories when doing an object
 609 dnl tree build.  So make sure we created certain directories if they don't
 610 dnl exist.
 611 dnl
 612
 613 AC_CONFIG_COMMANDS([build-directories],
 614 [test -d etc || AS_MKDIR_P([etc])
 615 test -d man || AS_MKDIR_P([man])])
 616
 617 AC_CONFIG_COMMANDS_POST([
 618
 619 dnl These odd looking assignments are done to expand out unexpanded
 620 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 621 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 622 dnl again to get the final answer.
 623 dnl We only use the expanded versions to print the install paths in
 624 dnl the final summary and should use them nowhere else (see the autoconf
 625 dnl docs for the rationale for bindir etc being unexpanded).
 626 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 627 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 628 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 629 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 630 eval "nmhrpm=${nmhrpm}";
 631
 632 AC_MSG_NOTICE([
 633 nmh configuration
 634 -----------------
 635 nmh version                : AC_PACKAGE_VERSION
 636 host os                    : ${host}
 637 compiler                   : ${CC}
 638 compiler flags             : ${CFLAGS}
 639 linker flags               : ${LDFLAGS}
 640 preprocessor flags         : ${CPPFLAGS}
 641 source code location       : ${srcdir}
 642 binary install path        : ${nmhbin}
 643 library install path       : ${nmhlib}
 644 config files install path  : ${nmhsysconf}
 645 man page install path      : ${nmhman}
 646 RPM build root             : ${nmhrpm}
 647 backup prefix              : ${backup_prefix}
 648 transport system           : ${MTS}
 649 spool default locking type : ${with_locking}
 650 default smtp servers       : ${smtpservers}
 651 SASL support               : ${sasl_support}
 652 TLS support                : ${tls_support}
 653 ])])dnl
 654
 655 dnl ---------------
 656 dnl OUTPUT MAKEFILE
 657 dnl ---------------
 658 AC_CONFIG_FILES([Makefile test/common.sh])
 659 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 660 AC_OUTPUT