diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  44 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  45   [Enable OAuth2 support in SMTP auth]))
  46
  47 dnl Do you want client-side support for encryption with TLS?
  48 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  49 AS_IF([test x"$with_tls" != x"no"],[
  50       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  51       tls_support=yes],[tls_support=no])
  52
  53 dnl Set the backup prefix
  54 AC_ARG_WITH([hash-backup],
  55   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  56 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  57       [backup_prefix="#"], [backup_prefix=","])
  58 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  59     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  60
  61 dnl What method of posting should post use?
  62 AC_ARG_WITH([mts],
  63   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  64   [specify the default mail transport agent/service]))
  65
  66 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  67       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  68       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  69       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  70       [MTS="smtp"])
  71 AC_SUBST([MTS])dnl
  72
  73 dnl What should be the default mail server(s)?
  74 AC_ARG_WITH([smtpservers],
  75   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  76   [specify the default SMTP server(s) @<:@localhost@:>@])])
  77 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  78       [smtpservers="localhost"])
  79 AC_SUBST([smtpservers])dnl
  80
  81 dnl -------------------------------------------------------------------
  82 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  83 dnl find an existing installation, in which case we use its location.
  84 dnl -------------------------------------------------------------------
  85 AC_PREFIX_DEFAULT([/usr/local/nmh])
  86 AC_PREFIX_PROGRAM([mhparam])
  87
  88 dnl ------------------
  89 dnl CHECK THE COMPILER
  90 dnl ------------------
  91
  92 AC_PROG_CC([cc gcc])
  93 AM_PROG_CC_C_O
  94
  95 dnl ------------------
  96 dnl CHECK HEADER FILES
  97 dnl ------------------
  98
  99 AC_HEADER_TIOCGWINSZ
 100 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 101
 102 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 103   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 104 [[#if HAVE_SYS_STREAM_H
 105 #  include <sys/stream.h>
 106 #endif
 107 ]])
 108
 109 dnl ---------------
 110 dnl CHECK FUNCTIONS
 111 dnl ---------------
 112 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 113
 114 dnl -----------------------
 115 dnl CHECK MULTIBYTE SUPPORT
 116 dnl -----------------------
 117 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 118             "x$ac_cv_header_wctype_h" = "xyes" -a \
 119             "x$ac_cv_func_wcwidth" = "xyes" -a \
 120             "x$ac_cv_func_mbtowc" = "xyes"],
 121       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 122                  [Define to enable support for multibyte character sets.])
 123        MULTIBYTE_ENABLED=1],
 124       [MULTIBYTE_ENABLED=0])
 125 AC_SUBST([MULTIBYTE_ENABLED])
 126
 127 dnl ----------------
 128 dnl CUSTOMIZE CFLAGS
 129 dnl ----------------
 130 dnl The user didn't specify CFLAGS, so customize them.
 131
 132 if test "$GCC" != yes; then
 133   dnl Use -v and some other options with SunStudio cc.  lex produces
 134   dnl code that causes unreachable-statement warnings.  It might be
 135   dnl better to use an autoconf test, except -v will probably succeed
 136   dnl with many other compilers but have different meaning.
 137   AS_CASE([`${CC} -V 2>&1`],
 138           [cc:\ Sun\ C*], [CFLAGS=\
 139 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 140 fi
 141
 142 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 143                [nmh_saved_cflags="$CFLAGS"
 144                CFLAGS="$CFLAGS -Wall -Werror"
 145                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 146                CFLAGS="$nmh_saved_cflags"])
 147 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 148
 149 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 150                [nmh_saved_cflags="$CFLAGS"
 151                CFLAGS="$CFLAGS -Wextra -Werror"
 152                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 153                               nmh_cv_has_wextra=no)
 154                CFLAGS="$nmh_saved_cflags"])
 155 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 156
 157 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 158 dnl MULTIBYTE_ENABLED having already been set.
 159 NMH_ADDL_CPPFLAGS
 160
 161 if test "$GCC" = yes; then
 162   dnl Do this regardless of auto_cflags value.
 163   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 164   dnl gcc 4.1 and later, but only when optimization is enabled.
 165   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 166   dnl If the user configures with a CFLAGS that contains a -O flag
 167   dnl but then removes it a make time, they'll also have to remove
 168   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 169   AS_CASE([$CFLAGS],
 170           [-O*|*' -O'*],[AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 171 fi
 172
 173 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 174 dnl We do this here rather than in (say) h/mh.h because this macro must
 175 dnl be defined before <stdio.h> is pulled in.
 176 dnl
 177 dnl And while we're here, add the packages tree to the cpp and ld search
 178 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 179 dnl If /usr/ports is installed, we use its idea of where things are installed,
 180 dnl otherwise we assume /usr/local.
 181
 182 AS_IF([test `uname` = FreeBSD],
 183         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 184          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 185                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 186          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 187          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 188          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 189 ])
 190
 191 dnl --------------
 192 dnl CUSTOMIZE LINK
 193 dnl --------------
 194 AS_IF([test `uname` = OpenBSD],
 195       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 196       dnl so that they don't color the waterfall.
 197       [POSTLINK="2>&1 | sed -e \
 198 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 199 AC_SUBST([POSTLINK])
 200
 201 dnl -----------------
 202 dnl CUSTOMIZE LDFLAGS
 203 dnl -----------------
 204 dnl Disable clang complaint about unused -ansi when linking.
 205 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 206                [nmh_cv_has_q_unused_arguments],
 207                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 208                        grep clang >/dev/null`],
 209                       [nmh_saved_ldflags="$LDFLAGS"
 210                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 211                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 212                                          nmh_cv_has_q_unused_arguments=no)
 213                        LDFLAGS="$nmh_saved_ldflags"],
 214                        [nmh_cv_has_q_unused_arguments=no])])
 215 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 216   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 217
 218 dnl This hack turns off assertions by default, assuming
 219 dnl that configure still uses this shell variable.  Without
 220 dnl it, AC_HEADER_ASSERT enables assertions by default.
 221 test -z "$enable_assert"  &&  enable_assert=no
 222
 223 AC_HEADER_ASSERT
 224
 225 dnl ------------------
 226 dnl CHECK FOR PROGRAMS
 227 dnl ------------------
 228 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 229 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 230 AC_PROG_RANLIB          dnl Check for `ranlib'
 231 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 232 AC_PROG_SED             dnl Check for Posix-compliant sed
 233 AC_PROG_YACC            dnl Check for yacc/bison
 234 AM_PROG_LEX             dnl Check for lex/flex
 235
 236 AM_PROG_AR
 237
 238 dnl Look for `cut'
 239 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 240 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 241
 242 dnl
 243 dnl Check for MD5 program and formatting command
 244 dnl
 245 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 246 AS_CASE(["${MD5SUM}"],
 247         [md5sum], [MD5FMT="cat"],
 248         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 249         [MD5FMT="missing"])
 250 AC_SUBST([MD5FMT])
 251
 252 dnl Look for `ls'
 253 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 254 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 255
 256 dnl See how we get ls to display the owner and the group
 257 AS_IF([test "$lspath" != "no"],
 258   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 259                  [nmh_cv_ls_grpopt],
 260   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 261     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 262     dnl ls, it would seem -l gave us both the user and group.  On this type of
 263     dnl ls, -g makes _only_ the group be displayed (and not the user).
 264     nmh_cv_ls_grpopt="-l"],[
 265     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 266     nmh_cv_ls_grpopt="-lg"])])])
 267
 268 dnl Look for `sendmail'
 269 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 270 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 271
 272 dnl Cygwin FAT filesystems do not support hard links.  So default to
 273 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 274 dnl therefore, this cannot be made into a dynamic test, in order to
 275 dnl support the least common Cygwin denominator.
 276 AS_CASE(["$host_os"],
 277   [cygwin*], [LN=cp],
 278   [LN=ln])
 279 AC_SUBST([LN])
 280
 281 dnl ----------------------------------------------------------
 282 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 283 dnl ----------------------------------------------------------
 284 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 285 [for mailspool in /var/mail        dnl
 286                   /var/spool/mail  dnl
 287                   /usr/spool/mail  dnl
 288                   /dev/null;       dnl Just in case we fall through
 289 do
 290   test -d $mailspool && break
 291 done
 292 nmh_cv_mailspool=$mailspool
 293 ])
 294 mailspool=$nmh_cv_mailspool
 295 AC_SUBST([mailspool])dnl
 296
 297 dnl See whether the mail spool directory is world-writable.
 298 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 299   AC_CACHE_CHECK(whether the mail spool is world-writable,
 300                  nmh_cv_mailspool_world_writable,
 301   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 302     nmh_cv_mailspool_world_writable=no
 303   else
 304     nmh_cv_mailspool_world_writable=yes
 305   fi])
 306 fi
 307
 308 dnl Also, check for liblockfile (as found on Debian systems)
 309 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 310
 311 dnl and whether its companion program dotlockfile is setgid
 312 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 313 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 314   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 315     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 316     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 317         nmh_cv_dotlockfile_setgid=yes
 318       else
 319         nmh_cv_dotlockfile_setgid=no
 320       fi])
 321   fi
 322 fi
 323
 324 dnl Provide a way for distcheck to disable setgid_mail via
 325 dnl DISTCHECK_CONFIGURE_FLAGS.
 326 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 327   [nmh_cv_dotlockfile_setgid=yes])
 328
 329 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 330 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 331 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 332   dnl do we really need both of these?
 333   AC_DEFINE([MAILGROUP],[1],
 334     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 335   SETGID_MAIL=1
 336 fi
 337 AC_SUBST([SETGID_MAIL])dnl
 338
 339 dnl Use ls to see which group owns the mail spool directory.
 340 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 341 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 342 ])
 343 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 344 AC_SUBST([MAIL_SPOOL_GRP])dnl
 345
 346 NMH_MIMETYPEPROC
 347 NMH_MIMEENCODINGPROC
 348
 349 dnl -------------------
 350 dnl CHECK FOR LIBRARIES
 351 dnl -------------------
 352 dnl Checks for network libraries (nsl, socket)
 353 NMH_CHECK_NETLIBS
 354
 355 dnl Check the locking functions supported and what we should use by default
 356 NMH_LOCKING
 357
 358 dnl Check for iconv
 359 NMH_CHECK_ICONV
 360
 361 dnl Check for tputs() callback argument
 362 NMH_TPUTS_PUTC_ARG
 363
 364 termcap_curses_order="termcap curses ncurses"
 365 for lib in $termcap_curses_order; do
 366   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 367 done
 368 AC_SUBST([TERMLIB])dnl
 369 AS_IF([test "x$TERMLIB" = "x"],
 370       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 371 curses or ncurses library or package that you can install?])])
 372
 373 dnl Check for readline support
 374 NMH_READLINE
 375
 376 dnl --------------
 377 dnl CHECK FOR NDBM
 378 dnl --------------
 379
 380 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 381             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 382 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 383             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 384
 385 if test "$nmh_ndbm" = "autodetect"; then
 386   if test "$nmh_ndbmheader" != "autodetect"; then
 387     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 388   else
 389
 390     dnl There are at least four implementations of ndbm, and
 391     dnl several of those can be in different places at the whim
 392     dnl of the system integrator. A good summary of this mess
 393     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 394
 395     dnl Classic ndbm with no library required (eg NetBSD): try this
 396     dnl first so we don't accidentally link in a pointless but harmless
 397     dnl library in one of the later ndbm.h+libfoo tests:
 398     NMH_CHECK_NDBM(ndbm.h,,,
 399     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 400       NMH_CHECK_NDBM(db.h,db,,
 401     dnl Berkeley DBv1 emulating ndbm:
 402         NMH_CHECK_NDBM(ndbm.h,db,,
 403           NMH_CHECK_NDBM(ndbm.h,db1,,
 404     dnl Classic ndbm:
 405             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 406     dnl glibc2.1 systems put db1 in a subdir:
 407               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 408     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 409     dnl and possibly needing gbdm_compat library:
 410                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 411                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 412                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 413     dnl 64-bit Cygwin:
 414                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 415     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 416     dnl need to be explicit:
 417                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 418   fi
 419 else
 420   dnl We don't really need to check that the user-specified values work,
 421   dnl but it is a convenience to the user to bomb out early rather than
 422   dnl after configure and half the compile process.
 423   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 424 fi
 425
 426 if test "$nmh_ndbm_found" = "no"; then
 427   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 428 else
 429   dnl Now export the lib/header to our makefile/config.h:
 430   if test x"$nmh_ndbmheader" != x; then
 431     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 432       [Define to the header containing the ndbm API prototypes.])
 433   fi
 434   if test x"$nmh_ndbm" != x; then
 435     NDBM_LIBS="-l$nmh_ndbm"
 436   else
 437     NDBM_LIBS=
 438   fi
 439   AC_SUBST([NDBM_LIBS])
 440 fi
 441
 442 dnl ------------------
 443 dnl Set RPM build root
 444 dnl ------------------
 445 dnl nmhrpm is used in the final summary, see below.  The default value is
 446 dnl reported there as ./RPM, consistent with the reporting of the default
 447 dnl source code location as ., but its absolute path is used in the Makefile.
 448 AC_ARG_WITH([rpmdir],
 449   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 450   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 451           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 452 AC_SUBST([rpmdir])
 453
 454
 455 dnl --------------------
 456 dnl CHECK FOR CYRUS-SASL
 457 dnl --------------------
 458
 459 AS_IF([test x"$sasl_support" = x"yes"],[
 460   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 461   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 462     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 463 AC_SUBST([SASLLIB])
 464
 465 dnl -----------------
 466 dnl CHECK FOR OPENSSL
 467 dnl -----------------
 468
 469 AS_IF([test x"$tls_support" = x"yes"],[
 470   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 471   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 472   dnl automatically append -lcrypto when linking with -lssl.
 473   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 474   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 475     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 476   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 477     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 478   [TLSLIB=])
 479 AC_SUBST([TLSLIB])
 480
 481 dnl -----------------
 482 dnl CHECK FOR CURL
 483 dnl -----------------
 484 dnl Look for curl if oauth not disabled (--without-oauth).
 485 AC_PATH_PROG([curl_config], [curl-config])
 486 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 487     save_CFLAGS="$CFLAGS"
 488     CFLAGS="$CFLAGS `$curl_config --cflags`"
 489     AC_CHECK_HEADER([curl/curl.h], [
 490         HAVE_CURL_H=1
 491         AC_CHECK_LIB([curl], [curl_easy_init], [
 492             CURLLIB="`$curl_config --libs`"
 493             AC_SUBST([CURLLIB])
 494             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 495             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 496                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 497                    CURL_USER_AGENT=libcurl/UNKNOWN])
 498                    echo "HEYEPG ($CURL_USER_AGENT)"
 499             AC_SUBST([CURL_USER_AGENT])
 500           ])
 501       ], [
 502         CFLAGS="$save_CFLAGS"
 503       ])
 504   ])
 505
 506 dnl -----------------
 507 dnl Enable OAuth?
 508 dnl -----------------
 509 dnl By default (with_oauth=''), enable OAuth if curl is found.
 510 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 511 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 512 oauth_support=no
 513 OAUTH_SUPPORT=0
 514 AC_SUBST([OAUTH_SUPPORT])
 515 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 516       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 517       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 518       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 519       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 520       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 521        OAUTH_SUPPORT=1
 522        oauth_support=yes])
 523
 524 dnl ----------------
 525 dnl CHECK FLEX FIXUP
 526 dnl ----------------
 527 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 528 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 529 dnl http://sourceforge.net/p/flex/bugs/140/
 530 AS_IF([test "$LEX" = flex],
 531       [AS_CASE([`$LEX -V`],
 532                [flex\ 2.5.35], [AM_LFLAGS=\
 533 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 534                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 535 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 536        AC_SUBST([AM_LFLAGS])])
 537
 538 dnl ------------------
 539 dnl FOR INTERNAL USE by the NMH test suite
 540 dnl ------------------
 541 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 542 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 543       AC_SUBST([nmhetcdirinst]))
 544
 545 dnl ----------------
 546 dnl CHECK STRUCTURES
 547 dnl ----------------
 548
 549 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 550 dnl (FreeBSD has a timezone() function but not a timezone global
 551 dnl variable that is visible).
 552 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 553
 554 AC_STRUCT_DIRENT_D_TYPE
 555
 556 dnl
 557 dnl Sigh, this is required because under the new world order autoconf has
 558 dnl nothing to create in a few of the build directories when doing an object
 559 dnl tree build.  So make sure we created certain directories if they don't
 560 dnl exist.
 561 dnl
 562
 563 AC_CONFIG_COMMANDS([build-directories],
 564 [test -d man || AS_MKDIR_P([man])])
 565
 566 AC_CONFIG_COMMANDS_POST([
 567
 568 dnl These odd looking assignments are done to expand out unexpanded
 569 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 570 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 571 dnl again to get the final answer.
 572 dnl We only use the expanded versions to print the install paths in
 573 dnl the final summary and should use them nowhere else (see the autoconf
 574 dnl docs for the rationale for bindir etc being unexpanded).
 575 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 576 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 577 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 578 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 579 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 580 eval "nmhrpm=${nmhrpm}";
 581
 582 AC_MSG_NOTICE([
 583 nmh configuration
 584 -----------------
 585 nmh version                : AC_PACKAGE_VERSION
 586 host os                    : ${host}
 587 compiler                   : ${CC}
 588 compiler flags             : ${CFLAGS}
 589 linker flags               : ${LDFLAGS}
 590 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 591 source code location       : ${srcdir}
 592 binary install path        : ${nmhbin}
 593 libexec install path       : ${nmhlibexec}/nmh
 594 config files install path  : ${nmhsysconf}/nmh
 595 man page install path      : ${nmhman}
 596 docs install path          : ${nmhdoc}
 597 RPM build root             : ${nmhrpm}
 598 backup prefix              : ${backup_prefix}
 599 transport system           : ${MTS}
 600 spool default locking type : ${with_locking}
 601 default smtp servers       : ${smtpservers}
 602 SASL support               : ${sasl_support}
 603 TLS support                : ${tls_support}
 604 OAuth support              : ${oauth_support}
 605 ])])dnl
 606
 607 dnl ---------------
 608 dnl OUTPUT MAKEFILE
 609 dnl ---------------
 610 AC_CONFIG_FILES([Makefile test/common.sh])
 611 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 612 AC_OUTPUT