diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 AC_PREREQ([2.68])
   6
   7 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   8 AC_CONFIG_SRCDIR([h/nmh.h])
   9 AC_CONFIG_HEADER([config.h])
  10 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  15 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  16
  17 dnl What date of nmh are we building?
  18 DATE=`cat ${srcdir}/DATE`
  19 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  20 AC_SUBST([DATE])dnl
  21
  22 dnl --------------------------
  23 dnl CHECK COMMAND LINE OPTIONS
  24 dnl --------------------------
  25
  26 dnl Do you want client-side support for using SASL for authentication?
  27 dnl Note that this code will be enabled for both POP and SMTP
  28 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  29   [Enable SASL support via the Cyrus SASL library]))
  30 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  31       AC_DEFINE([CYRUS_SASL], [1],
  32                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  33       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  34             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  35             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  36       sasl_support=yes], [sasl_support=no])
  37
  38 dnl Do you want client-side support for using OAuth2 for SMTP authentication?
  39 AC_ARG_WITH([oauth], AS_HELP_STRING([--with-oauth],
  40   [Enable OAuth2 support in SMTP auth]))
  41
  42 dnl Do you want client-side support for encryption with TLS?
  43 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  44 AS_IF([test x"$with_tls" != x"no"],[
  45       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  46       tls_support=yes],[tls_support=no])
  47
  48 dnl Set the backup prefix
  49 AC_ARG_WITH([hash-backup],
  50   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  51 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  52       [backup_prefix="#"], [backup_prefix=","])
  53 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  54     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  55
  56 dnl What method of posting should post use?
  57 AC_ARG_WITH([mts],
  58   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  59   [specify the default mail transport agent/service]))
  60
  61 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  62       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  63       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  65       [MTS="smtp"])
  66 AC_SUBST([MTS])dnl
  67
  68 dnl What should be the default mail server(s)?
  69 AC_ARG_WITH([smtpservers],
  70   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  71   [specify the default SMTP server(s) @<:@localhost@:>@])])
  72 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  73       [smtpservers="localhost"])
  74 AC_SUBST([smtpservers])dnl
  75
  76 dnl -------------------------------------------------------------------
  77 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  78 dnl find an existing installation, in which case we use its location.
  79 dnl -------------------------------------------------------------------
  80 AC_PREFIX_DEFAULT([/usr/local/nmh])
  81 AC_PREFIX_PROGRAM([mhparam])
  82
  83 dnl ------------------
  84 dnl CHECK THE COMPILER
  85 dnl ------------------
  86
  87 AC_PROG_CC([cc gcc])
  88 AM_PROG_CC_C_O
  89
  90 dnl ------------------
  91 dnl CHECK HEADER FILES
  92 dnl ------------------
  93
  94 AC_HEADER_TIOCGWINSZ
  95 AC_CHECK_HEADERS([fcntl.h stdbool.h wchar.h wctype.h \
  96                   sys/param.h sys/time.h sys/stream.h])
  97
  98 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
  99   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 100 [[#if HAVE_SYS_STREAM_H
 101 #  include <sys/stream.h>
 102 #endif
 103 ]])
 104
 105 dnl ---------------
 106 dnl CHECK FUNCTIONS
 107 dnl ---------------
 108 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 109
 110 dnl Use custom getline for platforms that don't have it.
 111 AC_CONFIG_LIBOBJ_DIR([sbr])
 112 AC_REPLACE_FUNCS([getline])
 113
 114 dnl -----------------------
 115 dnl CHECK MULTIBYTE SUPPORT
 116 dnl -----------------------
 117 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 118             "x$ac_cv_header_wctype_h" = "xyes" -a \
 119             "x$ac_cv_func_wcwidth" = "xyes" -a \
 120             "x$ac_cv_func_mbtowc" = "xyes"],
 121       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 122                  [Define to enable support for multibyte character sets.])
 123        MULTIBYTE_ENABLED=1],
 124       [MULTIBYTE_ENABLED=0])
 125 AC_SUBST([MULTIBYTE_ENABLED])
 126
 127 dnl ----------------
 128 dnl CUSTOMIZE CFLAGS
 129 dnl ----------------
 130 dnl The user didn't specify CFLAGS, so customize them.
 131
 132 if test "$GCC" != yes; then
 133   dnl Use -v and some other options with SunStudio cc.  lex produces
 134   dnl code that causes unreachable-statement warnings.  It might be
 135   dnl better to use an autoconf test, except -v will probably succeed
 136   dnl with many other compilers but have different meaning.
 137   AS_CASE([`${CC} -V 2>&1`],
 138           [cc:*\ Sun\ C*], [CFLAGS=\
 139 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 140 fi
 141
 142 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 143                [nmh_saved_cflags="$CFLAGS"
 144                CFLAGS="$AM_CFLAGS $CFLAGS -Wall -Werror"
 145                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 146                CFLAGS="$nmh_saved_cflags"])
 147 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 148
 149 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 150                [nmh_saved_cflags="$CFLAGS"
 151                CFLAGS="$AM_CFLAGS $CFLAGS -Wextra -Werror"
 152                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 153                               nmh_cv_has_wextra=no)
 154                CFLAGS="$nmh_saved_cflags"])
 155 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 156
 157 AC_SUBST([AM_CFLAGS])
 158
 159 dnl Check for any platform-specific additional AM_CPPFLAGS.  This depends on
 160 dnl MULTIBYTE_ENABLED having already been set.
 161 NMH_ADDL_CPPFLAGS
 162
 163 if test "$GCC" = yes; then
 164   dnl Do this regardless of auto_cflags value.
 165   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 166   dnl gcc 4.1 and later, but only when optimization is enabled.
 167   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 168   dnl If the user configures with a CFLAGS that contains a -O flag
 169   dnl but then removes it a make time, they'll also have to remove
 170   dnl -D_FORTIFY_SOURCE from AM_CPPFLAGS because it requires optimization.
 171   AS_CASE([$CFLAGS],
 172           [-O*|*' -O'*],[AM_CPPFLAGS="${AM_CPPFLAGS:+$AM_CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 173 fi
 174
 175 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 176 dnl We do this here rather than in (say) h/mh.h because this macro must
 177 dnl be defined before <stdio.h> is pulled in.
 178 dnl
 179 dnl And while we're here, add the packages tree to the cpp and ld search
 180 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 181 dnl If /usr/ports is installed, we use its idea of where things are installed,
 182 dnl otherwise we assume /usr/local.
 183
 184 AS_IF([test `uname` = FreeBSD],
 185         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 186          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 187                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 188          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 189          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 190          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 191 ])
 192
 193 dnl --------------
 194 dnl CUSTOMIZE LINK
 195 dnl --------------
 196 AS_IF([test `uname` = OpenBSD],
 197       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 198       dnl so that they don't color the waterfall.
 199       [POSTLINK="2>&1 | sed -e \
 200 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 201 AC_SUBST([POSTLINK])
 202
 203 dnl -----------------
 204 dnl CUSTOMIZE LDFLAGS
 205 dnl -----------------
 206 dnl Disable clang complaint about unused -ansi when linking.
 207 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 208                [nmh_cv_has_q_unused_arguments],
 209                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 210                        grep clang >/dev/null`],
 211                       [nmh_saved_ldflags="$LDFLAGS"
 212                        LDFLAGS="$AM_LDFLAGS $LDFLAGS -Qunused-arguments"
 213                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 214                                          nmh_cv_has_q_unused_arguments=no)
 215                        LDFLAGS="$nmh_saved_ldflags"],
 216                        [nmh_cv_has_q_unused_arguments=no])])
 217 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 218   AM_LDFLAGS="${AM_LDFLAGS:+$AM_LDFLAGS }-Qunused-arguments"
 219
 220 dnl This hack turns off assertions by default, assuming
 221 dnl that configure still uses this shell variable.  Without
 222 dnl it, AC_HEADER_ASSERT enables assertions by default.
 223 test -z "$enable_assert"  &&  enable_assert=no
 224
 225 AC_HEADER_ASSERT
 226
 227 dnl ------------------
 228 dnl CHECK FOR PROGRAMS
 229 dnl ------------------
 230 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 231 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 232 AC_PROG_RANLIB          dnl Check for `ranlib'
 233 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 234 AC_PROG_SED             dnl Check for Posix-compliant sed
 235 AC_PROG_YACC            dnl Check for yacc/bison
 236 AM_PROG_LEX             dnl Check for lex/flex
 237
 238 AM_PROG_AR
 239
 240 dnl Look for `cut'
 241 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 242 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 243
 244 dnl
 245 dnl Check for MD5 program and formatting command
 246 dnl
 247 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 248 AS_CASE(["${MD5SUM}"],
 249         [md5sum], [MD5FMT="cat"],
 250         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 251         [MD5FMT="missing"])
 252 AC_SUBST([MD5FMT])
 253
 254 dnl Look for `ls'
 255 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 256 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 257
 258 dnl See how we get ls to display the owner and the group
 259 AS_IF([test "$lspath" != "no"],
 260   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 261                  [nmh_cv_ls_grpopt],
 262   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 263     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 264     dnl ls, it would seem -l gave us both the user and group.  On this type of
 265     dnl ls, -g makes _only_ the group be displayed (and not the user).
 266     nmh_cv_ls_grpopt="-l"],[
 267     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 268     nmh_cv_ls_grpopt="-lg"])])])
 269
 270 dnl Look for `sendmail'
 271 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 272 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 273
 274 dnl Cygwin FAT filesystems do not support hard links.  So default to
 275 dnl cp instead, even if running on an NTFS or other filesystem.  (And
 276 dnl therefore, this cannot be made into a dynamic test, in order to
 277 dnl support the least common Cygwin denominator.
 278 AS_CASE(["$host_os"],
 279   [cygwin*], [LN=cp],
 280   [LN=ln])
 281 AC_SUBST([LN])
 282
 283 dnl ----------------------------------------------------------
 284 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 285 dnl ----------------------------------------------------------
 286 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 287 [for mailspool in /var/mail        dnl
 288                   /var/spool/mail  dnl
 289                   /usr/spool/mail  dnl
 290                   /dev/null;       dnl Just in case we fall through
 291 do
 292   test -d $mailspool && break
 293 done
 294 nmh_cv_mailspool=$mailspool
 295 ])
 296 mailspool=$nmh_cv_mailspool
 297 AC_SUBST([mailspool])dnl
 298
 299 dnl See whether the mail spool directory is world-writable.
 300 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 301   AC_CACHE_CHECK(whether the mail spool is world-writable,
 302                  nmh_cv_mailspool_world_writable,
 303   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 304     nmh_cv_mailspool_world_writable=no
 305   else
 306     nmh_cv_mailspool_world_writable=yes
 307   fi])
 308 fi
 309
 310 dnl Also, check for liblockfile (as found on Debian systems)
 311 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 312
 313 dnl and whether its companion program dotlockfile is setgid
 314 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 315 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 316   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 317     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 318     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 319         nmh_cv_dotlockfile_setgid=yes
 320       else
 321         nmh_cv_dotlockfile_setgid=no
 322       fi])
 323   fi
 324 fi
 325
 326 dnl Provide a way for distcheck to disable setgid_mail via
 327 dnl DISTCHECK_CONFIGURE_FLAGS.
 328 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 329   [nmh_cv_dotlockfile_setgid=yes])
 330
 331 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 332 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 333 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 334   dnl do we really need both of these?
 335   AC_DEFINE([MAILGROUP],[1],
 336     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 337   SETGID_MAIL=1
 338 fi
 339 AC_SUBST([SETGID_MAIL])dnl
 340
 341 dnl Use ls to see which group owns the mail spool directory.
 342 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 343 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 344 ])
 345 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 346 AC_SUBST([MAIL_SPOOL_GRP])dnl
 347
 348 NMH_MIMETYPEPROC
 349 NMH_MIMEENCODINGPROC
 350
 351 dnl -------------------
 352 dnl CHECK FOR LIBRARIES
 353 dnl -------------------
 354 dnl Checks for network libraries (nsl, socket)
 355 NMH_CHECK_NETLIBS
 356
 357 dnl Check the locking functions supported and what we should use by default
 358 NMH_LOCKING
 359
 360 dnl Check for iconv
 361 NMH_CHECK_ICONV
 362
 363 dnl Check for tputs() callback argument
 364 NMH_TPUTS_PUTC_ARG
 365
 366 termcap_curses_order="termcap curses ncurses"
 367 for lib in $termcap_curses_order; do
 368   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 369 done
 370 AC_SUBST([TERMLIB])dnl
 371 AS_IF([test "x$TERMLIB" = "x"],
 372       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 373 curses or ncurses library or package that you can install?])])
 374
 375 dnl Check for readline support
 376 NMH_READLINE
 377
 378 dnl --------------
 379 dnl CHECK FOR NDBM
 380 dnl --------------
 381
 382 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 383             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 384 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 385             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 386
 387 if test "$nmh_ndbm" = "autodetect"; then
 388   if test "$nmh_ndbmheader" != "autodetect"; then
 389     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 390   else
 391
 392     dnl There are at least four implementations of ndbm, and
 393     dnl several of those can be in different places at the whim
 394     dnl of the system integrator. A good summary of this mess
 395     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 396
 397     dnl Classic ndbm with no library required (eg NetBSD): try this
 398     dnl first so we don't accidentally link in a pointless but harmless
 399     dnl library in one of the later ndbm.h+libfoo tests:
 400     NMH_CHECK_NDBM(ndbm.h,,,
 401     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 402       NMH_CHECK_NDBM(db.h,db,,
 403     dnl Berkeley DBv1 emulating ndbm:
 404         NMH_CHECK_NDBM(ndbm.h,db,,
 405           NMH_CHECK_NDBM(ndbm.h,db1,,
 406     dnl Classic ndbm:
 407             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 408     dnl glibc2.1 systems put db1 in a subdir:
 409               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 410     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 411     dnl and possibly needing gbdm_compat library:
 412                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 413                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 414                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 415     dnl 64-bit Cygwin:
 416                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 417     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 418     dnl need to be explicit:
 419                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 420   fi
 421 else
 422   dnl We don't really need to check that the user-specified values work,
 423   dnl but it is a convenience to the user to bomb out early rather than
 424   dnl after configure and half the compile process.
 425   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 426 fi
 427
 428 if test "$nmh_ndbm_found" = "no"; then
 429   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 430 else
 431   dnl Now export the lib/header to our makefile/config.h:
 432   if test x"$nmh_ndbmheader" != x; then
 433     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 434       [Define to the header containing the ndbm API prototypes.])
 435   fi
 436   if test x"$nmh_ndbm" != x; then
 437     NDBM_LIBS="-l$nmh_ndbm"
 438   else
 439     NDBM_LIBS=
 440   fi
 441   AC_SUBST([NDBM_LIBS])
 442 fi
 443
 444 dnl ------------------
 445 dnl Set RPM build root
 446 dnl ------------------
 447 dnl nmhrpm is used in the final summary, see below.  The default value is
 448 dnl reported there as ./RPM, consistent with the reporting of the default
 449 dnl source code location as ., but its absolute path is used in the Makefile.
 450 AC_ARG_WITH([rpmdir],
 451   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 452   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 453           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 454 AC_SUBST([rpmdir])
 455
 456
 457 dnl --------------------
 458 dnl CHECK FOR CYRUS-SASL
 459 dnl --------------------
 460
 461 AS_IF([test x"$sasl_support" = x"yes"],[
 462   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 463   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 464     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 465 AC_SUBST([SASLLIB])
 466
 467 dnl -----------------
 468 dnl CHECK FOR OPENSSL
 469 dnl -----------------
 470
 471 AS_IF([test x"$tls_support" = x"yes"],[
 472   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 473   dnl AC_CHECK_LIB for SSL_new, because it doesn't
 474   dnl automatically append -lcrypto when linking with -lssl.
 475   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 476   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 477     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 478   AC_CHECK_LIB([ssl], [SSL_new], [TLSLIB="-lssl $TLSLIB"],
 479     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 480   [TLSLIB=])
 481 AC_SUBST([TLSLIB])
 482
 483 dnl -----------------
 484 dnl CHECK FOR CURL
 485 dnl -----------------
 486 dnl Look for curl if oauth not disabled (--without-oauth).
 487 AC_PATH_PROG([curl_config], [curl-config])
 488 AS_IF([test "x$with_oauth" != xno && test -n "$curl_config"], [
 489     save_CFLAGS="$CFLAGS"
 490     CFLAGS="$AM_CPPFLAGS $AM_CFLAGS $CFLAGS `$curl_config --cflags`"
 491     AC_CHECK_HEADER([curl/curl.h], [
 492         HAVE_CURL_H=1
 493         AC_CHECK_LIB([curl], [curl_easy_init], [
 494             CURLLIB="`$curl_config --libs`"
 495             AC_SUBST([CURLLIB])
 496             CURL_USER_AGENT="`$curl_config --version | sed 's|^libcurl  *|libcurl/|; q'`"
 497             AS_IF([test "x$CURL_USER_AGENT" != "x`echo $CURL_USER_AGENT | sed 's/ //'`"],
 498                   [AC_MSG_WARN([unexpected curl-config --version: $CURL_USER_AGENT])
 499                    CURL_USER_AGENT=libcurl/UNKNOWN])
 500             AC_SUBST([CURL_USER_AGENT])
 501           ])
 502       ])
 503     CFLAGS="$save_CFLAGS"
 504   ])
 505
 506 dnl -----------------
 507 dnl Enable OAuth?
 508 dnl -----------------
 509 dnl By default (with_oauth=''), enable OAuth if curl is found.
 510 dnl If OAuth requested (--with-oauth with_oauth=yes), error if curl not found.
 511 dnl If OAuth disabled (--without-oauth with_oauth=no), don't enable it.
 512 oauth_support=no
 513 OAUTH_SUPPORT=0
 514 AC_SUBST([OAUTH_SUPPORT])
 515 AS_IF([test "x$with_oauth" = xyes && test "x$HAVE_CURL_H" = x],
 516       [AC_MSG_ERROR([OAuth requested but curl/curl.h not found])],
 517       [test "x$with_oauth" = xyes && test "x$CURLLIB" = x],
 518       [AC_MSG_ERROR([OAuth requested but curl library not found])],
 519       [test "x$with_oauth" != xno && test "x$HAVE_CURL_H" = x1 && test "x$CURLLIB" != x],
 520       [AC_DEFINE([OAUTH_SUPPORT], [1], [Support OAuth2 in SMTP auth.])
 521        OAUTH_SUPPORT=1
 522        oauth_support=yes])
 523
 524 dnl ----------------
 525 dnl CHECK FLEX FIXUP
 526 dnl ----------------
 527 dnl Use AM_LFLAGS make variable setting to work around bugs in flex
 528 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 529 dnl http://sourceforge.net/p/flex/bugs/140/
 530 AS_IF([test "$LEX" = flex],
 531       [AS_CASE([`$LEX -V`],
 532                [flex\ 2.5.35], [AM_LFLAGS=\
 533 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 534                [flex\ 2.5.3[[67]]], [AM_LFLAGS=\
 535 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 536        AC_SUBST([AM_LFLAGS])])
 537
 538 dnl ------------------
 539 dnl FOR INTERNAL USE by the NMH test suite
 540 dnl ------------------
 541 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 542 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 543       AC_SUBST([nmhetcdirinst]))
 544
 545 dnl ----------------
 546 dnl CHECK STRUCTURES
 547 dnl ----------------
 548
 549 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 550 dnl (FreeBSD has a timezone() function but not a timezone global
 551 dnl variable that is visible).
 552 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 553
 554 AC_STRUCT_DIRENT_D_TYPE
 555
 556 dnl
 557 dnl Sigh, this is required because under the new world order autoconf has
 558 dnl nothing to create in a few of the build directories when doing an object
 559 dnl tree build.  So make sure we created certain directories if they don't
 560 dnl exist.
 561 dnl
 562
 563 AC_CONFIG_COMMANDS([build-directories],
 564 [test -d man || AS_MKDIR_P([man])])
 565
 566 AC_CONFIG_COMMANDS_POST([
 567
 568 dnl These odd looking assignments are done to expand out unexpanded
 569 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 570 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 571 dnl again to get the final answer.
 572 dnl We only use the expanded versions to print the install paths in
 573 dnl the final summary and should use them nowhere else (see the autoconf
 574 dnl docs for the rationale for bindir etc being unexpanded).
 575 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 576 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 577 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 578 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 579 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 580 eval "nmhrpm=${nmhrpm}";
 581
 582 AC_MSG_NOTICE([
 583 nmh configuration
 584 -----------------
 585 nmh version                : AC_PACKAGE_VERSION
 586 host os                    : ${host}
 587 compiler                   : ${CC}
 588 compiler flags             : ${AM_CFLAGS} ${CFLAGS}
 589 linker flags               : ${AM_LDFLAGS} ${LDFLAGS}
 590 preprocessor flags         : ${AM_CPPFLAGS} ${CPPFLAGS}
 591 source code location       : ${srcdir}
 592 binary install path        : ${nmhbin}
 593 libexec install path       : ${nmhlibexec}/nmh
 594 config files install path  : ${nmhsysconf}/nmh
 595 man page install path      : ${nmhman}
 596 docs install path          : ${nmhdoc}
 597 RPM build root             : ${nmhrpm}
 598 backup prefix              : ${backup_prefix}
 599 transport system           : ${MTS}
 600 spool default locking type : ${with_locking}
 601 default smtp servers       : ${smtpservers}
 602 SASL support               : ${sasl_support}
 603 TLS support                : ${tls_support}
 604 OAuth support              : ${oauth_support}
 605 ])])dnl
 606
 607 dnl ---------------
 608 dnl OUTPUT MAKEFILE
 609 dnl ---------------
 610 AC_CONFIG_FILES([Makefile test/common.sh])
 611 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 612 AC_OUTPUT