diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122   else
 123     dnl Use -v and some other options with SunStudio cc.  lex produces
 124     dnl code that causes unreachable-statement warnings.  It might be
 125     dnl better to use an autoconf test, except -v will probably succeed
 126     dnl with many other compilers but have different meaning.
 127     AS_CASE([`${CC} -V 2>&1`],
 128             [cc:\ Sun\ C*], [CFLAGS=\
 129 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 130   fi
 131
 132   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 133                  [nmh_saved_cflags="$CFLAGS"
 134                  CFLAGS="$CFLAGS -Wall -Werror"
 135                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 138
 139   AC_CACHE_CHECK([whether compiler supports -Wno-unused-result],
 140                  [nmh_cv_has_wnur],
 141                  [nmh_saved_cflags="$CFLAGS"
 142                  CFLAGS="$CFLAGS -Wno-unused-result -Werror"
 143                  AC_TRY_COMPILE([],[],nmh_cv_has_wnur=yes,nmh_cv_has_wnur=no)
 144                  CFLAGS="$nmh_saved_cflags"])
 145   test "$nmh_cv_has_wnur" = "yes"  && \
 146     CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"
 147
 148   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 149                  [nmh_saved_cflags="$CFLAGS"
 150                  CFLAGS="$CFLAGS -Wextra -Werror"
 151                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 152                                 nmh_cv_has_wextra=no)
 153                  CFLAGS="$nmh_saved_cflags"])
 154   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 155 fi
 156
 157 dnl --------------
 158 dnl CUSTOMIZE LINK
 159 dnl --------------
 160 if test `uname` = OpenBSD; then
 161   dnl Filter out "often/almost always misused" warnings from OpenBSD linker.
 162   [POSTLINK="2>&1 | egrep -v ': [w]arning: s[a-z]+\(\) is \
 163 (almost always|often) misused, please use' || true"]
 164 fi
 165 AC_SUBST([POSTLINK])
 166
 167 dnl -----------------
 168 dnl CUSTOMIZE LDFLAGS
 169 dnl -----------------
 170 AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | grep clang >/dev/null`],
 171   dnl Disable clang complaint about unused -ansi when linking.
 172   [AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 173                   [nmh_cv_has_q_unused_arguments],
 174                   [nmh_saved_ldflags="$LDFLAGS"
 175                    LDFLAGS="$LDFLAGS -Qunused-arguments"
 176                    AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 177                                      nmh_cv_has_q_unused_arguments=no)
 178                    LDFLAGS="$nmh_saved_ldflags"])])
 179 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 180   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 181
 182 dnl This hack turns off assertions by default, assuming
 183 dnl that configure still uses this shell variable.  Without
 184 dnl it, AC_HEADER_ASSERT enables assertions by default.
 185 test -z "$enable_assert"  &&  enable_assert=no
 186
 187 AC_HEADER_ASSERT
 188
 189 dnl ------------------
 190 dnl CHECK FOR PROGRAMS
 191 dnl ------------------
 192 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 193 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 194 AC_PROG_RANLIB          dnl Check for `ranlib'
 195 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 196 AC_PROG_SED             dnl Check for Posix-compliant sed
 197 AM_PROG_LEX             dnl Check for lex/flex
 198
 199 AM_PROG_AR
 200
 201 dnl Look for `cut'
 202 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 203 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 204
 205 dnl
 206 dnl Check for MD5 program and formatting command
 207 dnl
 208 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 209 AS_CASE(["${MD5SUM}"],
 210         [md5sum], [MD5FMT="cat"],
 211         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 212         [MD5FMT="missing"])
 213 AC_SUBST([MD5FMT])
 214
 215 dnl Look for `ls'
 216 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 217 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 218
 219 dnl See how we get ls to display the owner and the group
 220 AS_IF([test "$lspath" != "no"],
 221   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 222                  [nmh_cv_ls_grpopt],
 223   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 224     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 225     dnl ls, it would seem -l gave us both the user and group.  On this type of
 226     dnl ls, -g makes _only_ the group be displayed (and not the user).
 227     nmh_cv_ls_grpopt="-l"],[
 228     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 229     nmh_cv_ls_grpopt="-lg"])])])
 230
 231 dnl Look for `sendmail'
 232 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 233 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 234
 235 dnl Cygwin FAT filesystems do not support hard links.  So default to
 236 dnl cp instead, even if running on an NTFS or other filesystem.
 237 AS_CASE(["$host_os"],
 238   [cygwin*], [LN=cp],
 239   [LN=ln])
 240 AC_SUBST([LN])
 241
 242 dnl ----------------------------------------------------------
 243 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 244 dnl ----------------------------------------------------------
 245 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 246 [for mailspool in /var/mail        dnl
 247                   /var/spool/mail  dnl
 248                   /usr/spool/mail  dnl
 249                   /dev/null;       dnl Just in case we fall through
 250 do
 251   test -d $mailspool && break
 252 done
 253 nmh_cv_mailspool=$mailspool
 254 ])
 255 mailspool=$nmh_cv_mailspool
 256 AC_SUBST([mailspool])dnl
 257
 258 dnl See whether the mail spool directory is world-writable.
 259 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 260   AC_CACHE_CHECK(whether the mail spool is world-writable,
 261                  nmh_cv_mailspool_world_writable,
 262   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 263     nmh_cv_mailspool_world_writable=no
 264   else
 265     nmh_cv_mailspool_world_writable=yes
 266   fi])
 267 fi
 268
 269 dnl Also, check for liblockfile (as found on Debian systems)
 270 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 271
 272 dnl and whether its companion program dotlockfile is setgid
 273 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 274 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 275   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 276     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 277     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 278         nmh_cv_dotlockfile_setgid=yes
 279       else
 280         nmh_cv_dotlockfile_setgid=no
 281       fi])
 282   fi
 283 fi
 284
 285 dnl Provide a way for distcheck to disable setgid_mail via
 286 dnl DISTCHECK_CONFIGURE_FLAGS.
 287 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 288   [nmh_cv_dotlockfile_setgid=yes])
 289
 290 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 291 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 292 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 293   dnl do we really need both of these?
 294   AC_DEFINE([MAILGROUP],[1],
 295     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 296   SETGID_MAIL=1
 297 fi
 298 AC_SUBST([SETGID_MAIL])dnl
 299
 300 dnl Use ls to see which group owns the mail spool directory.
 301 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 302 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 303 ])
 304 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 305 AC_SUBST([MAIL_SPOOL_GRP])dnl
 306
 307 dnl ---------------------------------------------
 308 dnl CHECK FOR PROGRAM TO PROVIDE MIME TYPE STRING
 309 dnl ---------------------------------------------
 310 AS_IF([file --mime "${srcdir}"/configure >/dev/null 2>&1],
 311       [AS_IF([file --brief --mime "${srcdir}"/configure >/dev/null 2>&1],
 312              [nmh_mimetypeproc='"file --brief --mime"'],
 313              [nmh_mimetypeproc='"file --mime"'])])
 314 AS_CASE([$nmh_mimetypeproc], [?*],
 315         [AC_DEFINE_UNQUOTED([MIMETYPEPROC], [$nmh_mimetypeproc],
 316           [Program, with arguments, that provides MIME type string.])])
 317 AS_ECHO_N(["AS_ESCAPE([checking program to provide MIME type string ... ])"])
 318 AS_ECHO(["AS_ESCAPE([$nmh_mimetypeproc], [""])"])
 319
 320 dnl ------------------
 321 dnl CHECK HEADER FILES
 322 dnl ------------------
 323
 324 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 325 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 326 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 327 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 328 dnl declared; if so they should have an entry added to this case statement.
 329 dnl NB that we must define this on the compiler command line, not in config.h,
 330 dnl because it must be set before any system header is included and there's no
 331 dnl portable way to make sure that files generated by lex include config.h
 332 dnl before system header files.
 333
 334 AS_CASE(["$host_os"],
 335         [linux*],
 336         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 337           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 338                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 339
 340 AC_HEADER_TIOCGWINSZ
 341 AC_CHECK_HEADERS([fcntl.h langinfo.h wchar.h wctype.h sys/param.h \
 342                   sys/time.h sys/stream.h])
 343
 344 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 345   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 346 [[#if HAVE_SYS_STREAM_H
 347 #  include <sys/stream.h>
 348 #endif
 349 ]])
 350
 351 dnl ---------------
 352 dnl CHECK FUNCTIONS
 353 dnl ---------------
 354 AC_CHECK_FUNCS([wcwidth mbtowc nl_langinfo getutxent arc4random])
 355
 356 dnl Check for multibyte character set support
 357 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 358             "x$ac_cv_header_wctype_h" = "xyes" -a \
 359             "x$ac_cv_func_wcwidth" = "xyes" -a \
 360             "x$ac_cv_func_mbtowc" = "xyes"],
 361       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 362                  [Define to enable support for multibyte character sets.])
 363        MULTIBYTE_ENABLED=1],
 364       [MULTIBYTE_ENABLED=0])
 365 AC_SUBST([MULTIBYTE_ENABLED])
 366
 367 dnl -------------------
 368 dnl CHECK FOR LIBRARIES
 369 dnl -------------------
 370 dnl Checks for network libraries (nsl, socket)
 371 NMH_CHECK_NETLIBS
 372
 373 dnl Check for readline support
 374 NMH_READLINE
 375
 376 dnl Check the locking functions supported and what we should use by default
 377 NMH_LOCKING
 378
 379 dnl Check for iconv
 380 NMH_CHECK_ICONV
 381
 382 dnl Check for tputs() callback argument
 383 NMH_TPUTS_PUTC_ARG
 384
 385 termcap_curses_order="termcap curses ncurses"
 386 for lib in $termcap_curses_order; do
 387   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 388 done
 389 AC_SUBST([TERMLIB])dnl
 390 AS_IF([test "x$TERMLIB" = "x"],
 391       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a curses
 392 or ncurses library or package that you can install?])])
 393
 394 dnl --------------
 395 dnl CHECK FOR NDBM
 396 dnl --------------
 397
 398 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 399             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 400 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 401             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 402
 403 if test "$nmh_ndbm" = "autodetect"; then
 404   if test "$nmh_ndbmheader" != "autodetect"; then
 405     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 406   else
 407
 408     dnl There are at least four implementations of ndbm, and
 409     dnl several of those can be in different places at the whim
 410     dnl of the system integrator. A good summary of this mess
 411     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 412
 413     dnl Classic ndbm with no library required (eg NetBSD): try this
 414     dnl first so we don't accidentally link in a pointless but harmless
 415     dnl library in one of the later ndbm.h+libfoo tests:
 416     NMH_CHECK_NDBM(ndbm.h,,,
 417     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 418       NMH_CHECK_NDBM(db.h,db,,
 419     dnl Berkeley DBv1 emulating ndbm:
 420         NMH_CHECK_NDBM(ndbm.h,db,,
 421           NMH_CHECK_NDBM(ndbm.h,db1,,
 422     dnl Classic ndbm:
 423             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 424     dnl glibc2.1 systems put db1 in a subdir:
 425               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 426     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 427     dnl and possibly needing gbdm_compat library:
 428                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 429                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 430                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 431                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 432
 433   fi
 434 else
 435   dnl We don't really need to check that the user-specified values work,
 436   dnl but it is a convenience to the user to bomb out early rather than
 437   dnl after configure and half the compile process.
 438   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 439 fi
 440
 441 if test "$nmh_ndbm_found" = "no"; then
 442   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 443 else
 444   dnl Now export the lib/header to our makefile/config.h:
 445   if test x"$nmh_ndbmheader" != x; then
 446     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 447       [Define to the header containing the ndbm API prototypes.])
 448   fi
 449   if test x"$nmh_ndbm" != x; then
 450     NDBM_LIBS="-l$nmh_ndbm"
 451   else
 452     NDBM_LIBS=
 453   fi
 454   AC_SUBST([NDBM_LIBS])
 455 fi
 456
 457 dnl ------------------
 458 dnl Set RPM build root
 459 dnl ------------------
 460 dnl nmhrpm is used in the final summary, see below.  The default value is
 461 dnl reported there as ./RPM, consistent with the reporting of the default
 462 dnl source code location as ., but its absolute path is used in the Makefile.
 463 AC_ARG_WITH([rpmdir],
 464   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 465   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 466           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 467 AC_SUBST([rpmdir])
 468
 469
 470 dnl --------------------
 471 dnl CHECK FOR CYRUS-SASL
 472 dnl --------------------
 473
 474 AS_IF([test x"$sasl_support" = x"yes"],[
 475   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 476   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 477     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 478 AC_SUBST([SASLLIB])
 479
 480 dnl -----------------
 481 dnl CHECK FOR OPENSSL
 482 dnl -----------------
 483
 484 AS_IF([test x"$tls_support" = x"yes"],[
 485   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 486   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 487   dnl automatically append -lcrypto when linking with -lssl.
 488   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 489   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 490     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 491   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 492     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 493   [TLSLIB=])
 494 AC_SUBST([TLSLIB])
 495
 496 dnl ----------------
 497 dnl CHECK FLEX FIXUP
 498 dnl ----------------
 499 dnl Use LFLAGS make variable setting to work around bugs in flex
 500 dnl 2.5.36 that cause signed/unsigned mismatch,
 501 dnl http://sourceforge.net/p/flex/bugs/140/
 502 AS_IF([test "$LEX" = flex],
 503       [AS_CASE([`$LEX -V`],
 504                [flex\ 2.5.35], [LFLAGS=\
 505 '; sed -e "s/   int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@; true'],
 506                [flex\ 2.5.36], [LFLAGS=\
 507 '; sed -s "s/\( \)int i;/\1yy_size_t i;/" $@ >$.tmp && mv -f $@.tmp $@; true'])
 508        AC_SUBST([LFLAGS])])
 509
 510 dnl ----------------
 511 dnl CHECK STRUCTURES
 512 dnl ----------------
 513
 514 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 515 dnl (FreeBSD has a timezone() function but not a timezone global
 516 dnl variable that is visible).
 517 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 518
 519 AC_STRUCT_DIRENT_D_TYPE
 520
 521 dnl Where is <signal.h> located?  Needed as input for signames.awk
 522 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 523 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 524                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 525                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 526                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 527                  /usr/include/sys/signal.h      dnl Almost everybody else
 528                  /dev/null;                     dnl Just in case we fall through
 529 do
 530   test -f $SIGNAL_H && \
 531   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 532   break
 533 done
 534 nmh_cv_path_signal_h=$SIGNAL_H
 535 ])
 536 SIGNAL_H=$nmh_cv_path_signal_h
 537 AC_SUBST(SIGNAL_H)dnl
 538
 539 dnl
 540 dnl Sigh, this is required because under the new world order autoconf has
 541 dnl nothing to create in a few of the build directories when doing an object
 542 dnl tree build.  So make sure we created certain directories if they don't
 543 dnl exist.
 544 dnl
 545
 546 AC_CONFIG_COMMANDS([build-directories],
 547 [test -d man || AS_MKDIR_P([man])])
 548
 549 AC_CONFIG_COMMANDS_POST([
 550
 551 dnl These odd looking assignments are done to expand out unexpanded
 552 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 553 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 554 dnl again to get the final answer.
 555 dnl We only use the expanded versions to print the install paths in
 556 dnl the final summary and should use them nowhere else (see the autoconf
 557 dnl docs for the rationale for bindir etc being unexpanded).
 558 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 559 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 560 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 561 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 562 eval "nmhrpm=${nmhrpm}";
 563
 564 AC_MSG_NOTICE([
 565 nmh configuration
 566 -----------------
 567 nmh version                : AC_PACKAGE_VERSION
 568 host os                    : ${host}
 569 compiler                   : ${CC}
 570 compiler flags             : ${CFLAGS}
 571 linker flags               : ${LDFLAGS}
 572 preprocessor flags         : ${CPPFLAGS}
 573 source code location       : ${srcdir}
 574 binary install path        : ${nmhbin}
 575 library install path       : ${nmhlib}
 576 config files install path  : ${nmhsysconf}
 577 man page install path      : ${nmhman}
 578 RPM build root             : ${nmhrpm}
 579 backup prefix              : ${backup_prefix}
 580 transport system           : ${MTS}
 581 spool default locking type : ${with_locking}
 582 default smtp servers       : ${smtpservers}
 583 SASL support               : ${sasl_support}
 584 TLS support                : ${tls_support}
 585 ])])dnl
 586
 587 dnl ---------------
 588 dnl OUTPUT MAKEFILE
 589 dnl ---------------
 590 AC_CONFIG_FILES([Makefile test/common.sh])
 591 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 592 AC_OUTPUT