diplodocus.org Git - nmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_DIRENT
 465 AC_HEADER_STDC
 466 AC_HEADER_TIME
 467 AC_HEADER_SYS_WAIT
 468 AC_HEADER_STAT
 469 AC_HEADER_TIOCGWINSZ
 470 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 471                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 472                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 473                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 474                  arpa/inet.h arpa/ftp.h)
 475
 476 dnl
 477 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 478 dnl really use a whole set of them, but this check should be
 479 dnl sufficient.
 480 dnl
 481 AC_CHECK_HEADER(libio.h, [
 482   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 483     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 484
 485 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 486   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 487 [[#if HAVE_SYS_STREAM_H
 488 #  include <sys/stream.h>
 489 #endif
 490 ]])
 491
 492 dnl ---------------
 493 dnl CHECK FUNCTIONS
 494 dnl ---------------
 495 AC_FUNC_VFORK
 496 AC_CHECK_LIB(mkstemp,mkstemp)
 497 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 498                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 499                getutent nl_langinfo mbtowc wcwidth)
 500
 501 dnl sigsetjmp may be a macro
 502 AC_MSG_CHECKING(for sigsetjmp)
 503 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 504   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 505     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 506   [AC_MSG_RESULT(no)])
 507
 508 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 509
 510 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 511 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 512 dnl any system header.
 513 dnl
 514 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 515 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 516 dnl need to check?
 517 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 518 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 519                 AC_EGREP_HEADER(initgroups, unistd.h,
 520                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 521
 522 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 523 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 524 dnl seems to work perfectly and IBM apparently uses it in internal code).
 525 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 526 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 527 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 528 dnl prototype.
 529 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 530   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 531
 532 dnl Check for multibyte character set support
 533 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 534     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 535   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 536     [Define to enable support for multibyte character sets.])
 537 fi
 538
 539 dnl -------------------
 540 dnl CHECK FOR LIBRARIES
 541 dnl -------------------
 542 dnl Check location of modf
 543 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 544
 545 dnl Checks for network libraries (nsl, socket)
 546 AC_CHECK_NETLIBS
 547
 548 termcap_curses_order="termcap curses ncurses"
 549 for lib in $termcap_curses_order; do
 550   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 551 done
 552 AC_SUBST(TERMLIB)dnl
 553
 554 dnl ---------------
 555 dnl CHECK FOR ICONV
 556 dnl ---------------
 557
 558 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 559 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 560   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 561   if test "x$ac_found_iconv" = "xno"; then
 562     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 563     if test "x$ac_found_iconv" = "xno"; then
 564       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 565     fi
 566     if test "x$ac_found_iconv" != "xno"; then
 567       LIBS="-liconv $LIBS"
 568     fi
 569   else
 570     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 571     AC_CHECK_DECL(_libiconv_version,
 572       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 573       [ #include <iconv.h> ])
 574   fi
 575 fi
 576 if test "x$ac_found_iconv" = xyes; then
 577   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 578 fi
 579
 580 dnl Check if iconv uses const in prototype declaration
 581 if test "x$ac_found_iconv" = "xyes"; then
 582   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 583     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 584         #include <iconv.h>]],
 585         [[#ifdef __cplusplus
 586           "C"
 587           #endif
 588           #if defined(__STDC__) || defined(__cplusplus)
 589           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 590           #else
 591           size_t iconv();
 592           #endif]])],
 593       [ac_cv_iconv_const=],
 594       [ac_cv_iconv_const=const])])
 595   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 596     [Define as const if the declaration of iconv() needs const.])
 597 fi
 598
 599 dnl --------------
 600 dnl CHECK FOR NDBM
 601 dnl --------------
 602
 603 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 604             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 605 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 606             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 607
 608 if test "$nmh_ndbm" = "autodetect"; then
 609   if test "$nmh_ndbmheader" != "autodetect"; then
 610     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 611   else
 612
 613     dnl There are at least four implementations of ndbm, and
 614     dnl several of those can be in different places at the whim
 615     dnl of the system integrator. A good summary of this mess
 616     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 617
 618     dnl Classic ndbm with no library required (eg NetBSD): try this
 619     dnl first so we don't accidentally link in a pointless but harmless
 620     dnl library in one of the later ndbm.h+libfoo tests:
 621     NMH_CHECK_NDBM(ndbm.h,,,
 622     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 623       NMH_CHECK_NDBM(db.h,db,,
 624     dnl Berkeley DBv1 emulating ndbm:
 625         NMH_CHECK_NDBM(ndbm.h,db,,
 626           NMH_CHECK_NDBM(ndbm.h,db1,,
 627     dnl Classic ndbm:
 628             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 629     dnl glibc2.1 systems put db1 in a subdir:
 630               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 631     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 632     dnl and possibly needing gbdm_compat library:
 633                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 634                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 635                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 636                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 637
 638   fi
 639 else
 640   dnl We don't really need to check that the user-specified values work,
 641   dnl but it is a convenience to the user to bomb out early rather than
 642   dnl after configure and half the compile process.
 643   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 644 fi
 645
 646 if test "$nmh_ndbm_found" = "no"; then
 647   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 648 else
 649   dnl Now export the lib/header to our makefile/config.h:
 650   if test x"$nmh_ndbmheader" != x; then
 651     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 652       [Define to the header containing the ndbm API prototypes.])
 653   fi
 654   if test x"$nmh_ndbm" != x; then
 655     NDBM_LIBS="-l$nmh_ndbm"
 656   else
 657     NDBM_LIBS=
 658   fi
 659   AC_SUBST(NDBM_LIBS)
 660 fi
 661
 662
 663 dnl --------------------
 664 dnl CHECK FOR CYRUS-SASL
 665 dnl --------------------
 666
 667 AS_IF([test x"$sasl_support" = x"yes"],[
 668   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 669   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 670     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 671
 672 dnl -----------------
 673 dnl CHECK FOR OPENSSL
 674 dnl -----------------
 675
 676 AS_IF([test x"$tls_support" = x"yes"],[
 677   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 678   AC_CHECK_LIB([crypto], [BIO_write], ,
 679     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 680   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 681     [AC_MSG_ERROR([OpenSSL library not found])])])
 682
 683 dnl ---------------------
 684 dnl CHECK TERMCAP LIBRARY
 685 dnl ---------------------
 686
 687 dnl Add the termcap library, so that the following configure
 688 dnl tests will find it when it tries to link test programs.
 689 nmh_save_LIBS="$LIBS"
 690 LIBS="$TERMLIB $LIBS"
 691
 692 dnl Checks for external variable ospeed in the termcap library.
 693 AC_CACHE_CHECK(if an include file defines ospeed,
 694 nmh_cv_decl_ospeed_include_defines,
 695 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 696 #if HAVE_TERMIOS_H
 697 #include <termios.h>
 698 #endif
 699 #if HAVE_TERMCAP_H
 700 #include <termcap.h>
 701 #endif]], [[ospeed = 0;]])],
 702 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 703
 704 if test $nmh_cv_decl_ospeed_include_defines = no; then
 705   AC_CACHE_CHECK(if you must define ospeed,
 706   nmh_cv_decl_ospeed_must_define,
 707   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 708   [[extern short ospeed; ospeed = 0;]])],
 709   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 710 fi
 711
 712 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 713 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 714   AC_DEFINE(HAVE_OSPEED)dnl
 715 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 716   AC_DEFINE(HAVE_OSPEED)
 717   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 718     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 719 fi
 720
 721 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 722 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 723 dnl in tgetstr().
 724 dnl Under Cygwin test program crashes but exit code is still 0. So,
 725 dnl we test for a file that porgram should create
 726 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 727 [Define to 1 if tgetent() accepts NULL as a buffer.])
 728 AC_CACHE_CHECK(if tgetent accepts NULL,
 729 nmh_cv_func_tgetent_accepts_null,
 730 [AC_TRY_RUN([
 731 main()
 732 {
 733     char buf[4096];
 734     int r1 = tgetent(buf, "vt100");
 735     int r2 = tgetent((char*)0,"vt100");
 736     if (r1 >= 0 && r1 == r2) {
 737         char tbuf[1024], *u;
 738         u = tbuf;
 739         tgetstr("cl", &u);
 740         creat("conftest.tgetent", 0640);
 741     }
 742     exit((r1 != r2) || r2 == -1);
 743 }
 744 ],
 745   if test -f conftest.tgetent; then
 746     nmh_cv_func_tgetent_accepts_null=yes
 747   else
 748     nmh_cv_func_tgetent_accepts_null=no
 749   fi,
 750   nmh_cv_func_tgetent_accepts_null=no,
 751   nmh_cv_func_tgetent_accepts_null=no)])
 752 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 753   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 754 fi
 755 AC_CACHE_CHECK(if tgetent returns 0 on success,
 756 nmh_cv_func_tgetent_zero_success,
 757 [AC_TRY_RUN([
 758 main()
 759 {
 760     char buf[4096];
 761     int r1 = tgetent(buf, "!@#$%^&*");
 762     int r2 = tgetent(buf, "vt100");
 763     if (r1 < 0 && r2 == 0) {
 764         char tbuf[1024], *u;
 765         u = tbuf;
 766         tgetstr("cl", &u);
 767         creat("conftest.tgetent0", 0640);
 768     }
 769     exit(r1 == r2);
 770 }
 771 ],
 772   if test -f conftest.tgetent0; then
 773     nmh_cv_func_tgetent_zero_success=yes
 774   else
 775     nmh_cv_func_tgetent_zero_success=no
 776   fi,
 777   nmh_cv_func_tgetent_zero_success=no,
 778   nmh_cv_func_tgetent_zero_success=no)])
 779 AH_TEMPLATE([TGETENT_SUCCESS],
 780 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 781 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 782   AC_DEFINE(TGETENT_SUCCESS, 0)
 783 else
 784   AC_DEFINE(TGETENT_SUCCESS, 1)
 785 fi
 786
 787 dnl Now put the libraries back to what it was before we
 788 dnl starting checking the termcap library.
 789 LIBS="$nmh_save_LIBS"
 790
 791 dnl --------------
 792 dnl CHECK TYPEDEFS
 793 dnl --------------
 794 AC_TYPE_SIGNAL
 795 AC_TYPE_PID_T
 796 AC_TYPE_OFF_T
 797 AC_TYPE_UID_T
 798 AC_TYPE_MODE_T
 799 AC_TYPE_SIZE_T
 800
 801 dnl Check for sigset_t.  Currently I'm looking in
 802 dnl <sys/types.h> and <signal.h>.  Others might need
 803 dnl to be added.
 804 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 805 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 806 #include <signal.h>]], [[sigset_t tempsigset;]])],
 807 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 808 if test $nmh_cv_type_sigset_t = no; then
 809   AC_DEFINE(sigset_t, unsigned int,
 810     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 811 fi
 812
 813 dnl ----------------
 814 dnl CHECK STRUCTURES
 815 dnl ----------------
 816 AC_CHECK_MEMBERS(struct stat.st_blksize)
 817
 818 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 819   [#ifdef TIME_WITH_SYS_TIME
 820 # include <sys/time.h>
 821 # include <time.h>
 822 #else
 823 # ifdef TM_IN_SYS_TIME
 824 #  include <sys/time.h>
 825 # else
 826 #  include <time.h>
 827 # endif
 828 #endif])
 829
 830 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 831
 832 AC_MSG_CHECKING(for union wait)
 833 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 834   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 835 #include <sys/wait.h>]],
 836     [[union wait status; int pid; pid = wait (&status);
 837 #ifdef WEXITSTATUS
 838 /* Some POSIXoid systems have both the new-style macros and the old
 839    union wait type, and they do not work together.  If union wait
 840    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 841         if (WEXITSTATUS (status) != 0) pid = -1;
 842 #ifdef WTERMSIG
 843         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 844         -- blow chunks here --
 845 #endif
 846 #endif
 847 #ifdef HAVE_WAITPID
 848         /* Make sure union wait works with waitpid.  */
 849         pid = waitpid (-1, &status, 0);
 850 #endif
 851       ]])],
 852     [nmh_cv_union_wait=yes],
 853     [nmh_cv_union_wait=no])])
 854 if test "$nmh_cv_union_wait" = yes; then
 855   AC_DEFINE(HAVE_UNION_WAIT, 1,
 856     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 857 fi
 858 AC_MSG_RESULT($nmh_cv_union_wait)
 859
 860 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 861
 862 dnl -------------
 863 dnl CHECK SIGNALS
 864 dnl -------------
 865 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 866 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 867 AC_MSG_CHECKING(what style of signals to use)
 868 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 869   signals_style=POSIX_SIGNALS
 870   AC_DEFINE(POSIX_SIGNALS, 1,
 871     [Define to 1 if you use POSIX style signal handling.])
 872   AC_DEFINE(RELIABLE_SIGNALS)
 873 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 874   signals_style=BSD_SIGNALS
 875   AC_DEFINE(BSD_SIGNALS,1,
 876     [Define to 1 if you use BSD style signal handling (and can block signals).])
 877   AC_DEFINE(RELIABLE_SIGNALS)
 878 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 879   signals_style=SYSV_SIGNALS
 880   AC_DEFINE(SYSV_SIGNALS,1,
 881     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 882 else
 883   signals_style=NO_SIGNAL_BLOCKING
 884   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 885     [Define to 1 if you have no signal blocking at all (bummer).])
 886 fi
 887
 888 AC_MSG_RESULT($signals_style)
 889
 890 dnl Where is <signal.h> located?  Needed as input for signames.awk
 891 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 892 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 893                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 894                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 895                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 896                  /usr/include/sys/signal.h      dnl Almost everybody else
 897                  /dev/null;                     dnl Just in case we fall through
 898 do
 899   test -f $SIGNAL_H && \
 900   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 901   break
 902 done
 903 nmh_cv_path_signal_h=$SIGNAL_H
 904 ])
 905 SIGNAL_H=$nmh_cv_path_signal_h
 906 AC_SUBST(SIGNAL_H)dnl
 907
 908 dnl ----------------
 909 dnl OS SPECIFIC DEFINES
 910 dnl ----------------
 911 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 912 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 913 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 914 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 915 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 916
 917 case "$target_os" in
 918
 919   solaris2*)
 920     AC_DEFINE(SYS5)
 921     AC_DEFINE(SVR4)
 922     ;;
 923   irix*)
 924     AC_DEFINE(SYS5)
 925     AC_DEFINE(SVR4)
 926     ;;
 927   osf*)
 928     AC_DEFINE(SYS5)
 929     AC_DEFINE(SVR4)
 930     ;;
 931   aix*)
 932     AC_DEFINE(SYS5)
 933     AC_DEFINE(SVR4)
 934     ;;
 935   sunos4*)
 936     AC_DEFINE(BSD42)
 937     ;;
 938   freebsd*)
 939     AC_DEFINE(BSD42)
 940     AC_DEFINE(BSD44)
 941     ;;
 942   netbsd*)
 943     AC_DEFINE(BSD42)
 944     AC_DEFINE(BSD44)
 945     ;;
 946   openbsd*)
 947     AC_DEFINE(BSD42)
 948     AC_DEFINE(BSD44)
 949     ;;
 950   bsd/os*)
 951     AC_DEFINE(BSD42)
 952     AC_DEFINE(BSD44)
 953     ;;
 954   sco5*)
 955     AC_DEFINE(SYS5)
 956     AC_DEFINE(SCO_5_STDIO)
 957     ;;
 958 esac
 959
 960
 961 dnl ----------------
 962 dnl OUTPUT MAKEFILES
 963 dnl ----------------
 964 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 965                 mts/Makefile mts/smtp/Makefile \
 966                 etc/Makefile docs/Makefile man/Makefile)
 967 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 968 AC_OUTPUT
 969
 970 dnl These odd looking assignments are done to expand out unexpanded
 971 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 972 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 973 dnl again to get the final answer.
 974 dnl We only use the expanded versions to print the install paths in
 975 dnl the final summary and should use them nowhere else (see the autoconf
 976 dnl docs for the rationale for bindir etc being unexpanded).
 977 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 978 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 979 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 980 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 981
 982 pop_kinds=no
 983 if test x"$enable_pop" = x"yes"; then
 984   pop_kinds="yes ("
 985
 986   if test x"$enable_apop" = x"yes"; then
 987     pop_kinds="${pop_kinds}APOP "
 988   fi
 989
 990   pop_kinds="${pop_kinds}POP3)"
 991 fi
 992
 993 echo "
 994 nmh configuration
 995 -----------------
 996 nmh version                : AC_PACKAGE_VERSION
 997 target os                  : ${target}
 998 compiler                   : ${CC}
 999 compiler flags             : ${CFLAGS}
1000 linker flags               : ${LDFLAGS}
1001 definitions                : ${OURDEFS}
1002 source code location       : ${srcdir}
1003 binary install path        : ${nmhbin}
1004 library install path       : ${nmhlib}
1005 config files install path  : ${nmhsysconf}
1006 man page install path      : ${nmhman}
1007 backup prefix              : ${backup_prefix}
1008 transport system           : ${MTS}
1009 file locking type          : ${LOCKTYPE}
1010 default smtp servers       : ${smtpservers}
1011 default editor             : ${editorpath}
1012 default pager              : ${pagerpath}
1013 email address masquerading : ${masquerade}
1014 pop is enabled             : ${pop_kinds}
1015 SASL support               : ${sasl_support}
1016 TLS support                : ${tls_support}"
1017 echo ""