diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl What should be the default editor?
  58 AC_ARG_WITH([editor],
  59   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  60
  61 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  62
  63 dnl Set the backup prefix
  64 AC_ARG_WITH([hash-backup],
  65   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  66 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  67       [backup_prefix="#"], [backup_prefix=","])
  68 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  69     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  70
  71 dnl What method of locking to use?
  72 AS_CASE(["$host_os"],
  73   [aix*|cygwin*|linux*],
  74     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  75   [freebsd*|openbsd*|darwin*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  76   [default_locktype="dot"; default_locking=DOT_LOCKING])
  77
  78 AC_ARG_WITH([locking],
  79   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  80   [specify the file locking method]))
  81
  82 AS_IF([test x"$with_locking" = x"dot"],
  83     [LOCKTYPE="dot"
  84     AC_DEFINE([DOT_LOCKING], [1], [Define to use dot based file locking.])],
  85   [test x"$with_locking" = x"flock"],
  86     [LOCKTYPE="flock"
  87     AC_DEFINE([FLOCK_LOCKING], [1], [Define to use flock() based locking.])],
  88   [test x"$with_locking" = x"lockf"],
  89     [LOCKTYPE="lockf"
  90     AC_DEFINE([LOCKF_LOCKING], [1], [Define to use lockf() based locking.])],
  91   [test x"$with_locking" = x"fcntl"],
  92     [LOCKTYPE="fcntl"
  93     AC_DEFINE([FCNTL_LOCKING], [1], [Define to use fnctl() based locking.])],
  94   [LOCKTYPE="$default_locktype"
  95   AC_DEFINE_UNQUOTED([$default_locking], [1])])
  96
  97 dnl Should we use a locking directory?
  98 AC_ARG_ENABLE([lockdir],
  99   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 100   AS_IF([test "x$enableval" = xyes],[
 101     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 102   AS_IF([test "x$LOCKTYPE" != xdot],[
 103     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 104   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 105                      [Directory to store dot-locking lock files])
 106 ])
 107
 108 dnl What method of posting should post use?
 109 AC_ARG_WITH([mts],
 110   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
 111   [specify the default mail transport agent/service]))
 112
 113 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 114       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
 115       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
 116       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
 117       [MTS="smtp"])
 118 AC_SUBST([MTS])dnl
 119
 120 dnl What should be the default pager?
 121 AC_ARG_WITH([pager],
 122   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 123
 124 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 125
 126 dnl If a pager is not explicitly specified, then look for one.
 127 dnl Fall back to `cat', to avoid catastrophic failure of
 128 dnl `mhshow', et al., if pagerpath is set to `no'.
 129 AS_IF([test -z "$pagerpath"],
 130   [pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 131   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])])
 132 AC_SUBST([pagerpath])dnl
 133
 134 dnl What should be the default mail server(s)?
 135 AC_ARG_WITH([smtpservers],
 136   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 137   [specify the default SMTP server(s) @<:@localhost@:>@])])
 138 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 139       [smtpservers="localhost"])
 140 AC_SUBST([smtpservers])dnl
 141
 142 dnl ----------------------------------------------------
 143 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 144 dnl ----------------------------------------------------
 145 AC_PREFIX_DEFAULT([/usr/local/nmh])
 146
 147 dnl ------------------
 148 dnl CHECK THE COMPILER
 149 dnl ------------------
 150 dnl We want these before the checks,
 151 dnl so the checks can modify their values.
 152 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 153 if test x"$enable_debug" = x"yes"; then
 154   test -z "$LDFLAGS" && LDFLAGS=-g
 155 fi
 156
 157 AC_PROG_CC
 158 AM_PROG_CC_C_O
 159
 160 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 161   [nmh_cv_has_unusedmacros],
 162   [nmh_saved_cppflags="$CPPFLAGS"
 163    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 164    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 165    CPPFLAGS="$nmh_saved_cppflags"])
 166
 167 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 168   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 169                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 170   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 171 fi
 172 AC_SUBST([DISABLE_UNUSED_MACROS_WARNING])dnl
 173
 174 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 175   [nmh_cv_has_nosigncompare],
 176   [nmh_saved_cppflags="$CPPFLAGS"
 177    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 178    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 179                   nmh_cv_has_nosigncompare=no)
 180    CPPFLAGS="$nmh_saved_cppflags"])
 181
 182 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 183   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 184 fi
 185 AC_SUBST([DISABLE_SIGN_COMPARE_WARNING])dnl
 186
 187 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 188 [nmh_saved_cflags="$CFLAGS"
 189  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 190  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 191  CFLAGS="$nmh_saved_cflags"])
 192
 193 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 194 [nmh_saved_cflags="$CFLAGS"
 195  CFLAGS="$CFLAGS -Wno-pointer-sign"
 196  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 197  CFLAGS="$nmh_saved_cflags"])
 198
 199 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 200 dnl setup version 2.763, because it disables some features in the
 201 dnl system system header files and warns about them with -Wall.  Try
 202 dnl to test for that generally, though still with gcc.
 203 if test "$GCC" = yes; then
 204   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 205     [nmh_saved_cppflags="$CPPFLAGS"
 206      nmh_saved_cflags="$CFLAGS"
 207      CPPFLAGS="-D_GNU_SOURCE"
 208      CFLAGS="-ansi -Wall -Werror"
 209      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 210        [nmh_cv_has_dash_ansi=yes],
 211        [nmh_cv_has_dash_ansi=no])
 212      CPPFLAGS="$nmh_saved_cppflags"
 213      CFLAGS="$nmh_saved_cflags"])
 214 else
 215   nmh_cv_has_dash_ansi=no
 216 fi
 217
 218 dnl if the user hasn't specified CFLAGS, then
 219 dnl   if compiler is gcc, then
 220 dnl    use -O2 and some warning flags
 221 dnl   else use -O
 222 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 223 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 224 dnl warnings which are probably mostly spurious and which in any case we
 225 dnl don't want to deal with now.
 226 if test "$nmh_cv_has_noptrsign" = "yes"; then
 227     if test "$nmh_cv_has_dash_ansi" = "yes"; then
 228         nmh_gcc_common_flags="-ansi -pedantic -Wall"
 229     else
 230         nmh_gcc_common_flags="-Wall"
 231     fi
 232     if test "$nmh_cv_has_wextra" = "yes"; then
 233         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 234 "-Wno-pointer-sign"
 235     else
 236         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 237     fi
 238 else
 239     if test "$nmh_cv_has_wextra" = "yes"; then
 240         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 241     else
 242         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 243     fi
 244 fi
 245
 246 if test -n "$auto_cflags"; then
 247   if test x"$enable_debug" = x"yes"; then
 248     if test -n "$GCC"; then
 249       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 250     else
 251       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 252     fi
 253   else
 254     if test -z "$LDFLAGS"; then
 255       case "$build_os" in
 256         darwin*)
 257           LDFLAGS=
 258           ;;
 259         *)
 260           LDFLAGS=-s
 261           ;;
 262       esac
 263     fi
 264     if test -n "$GCC"; then
 265       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 266     else
 267       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 268     fi
 269   fi
 270 fi
 271
 272 AC_C_CONST              dnl Does compiler support `const'.
 273
 274 dnl ------------------
 275 dnl CHECK FOR PROGRAMS
 276 dnl ------------------
 277 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 278 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 279 AC_PROG_RANLIB          dnl Check for `ranlib'
 280 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 281 AC_PROG_SED             dnl Check for Posix-compliant sed
 282 AM_PROG_LEX             dnl Check for lex/flex
 283
 284 AM_PROG_AR
 285
 286 dnl Look for `cut'
 287 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 288 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 289
 290 dnl
 291 dnl Check for MD5 program and formatting command
 292 dnl
 293 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 294 AS_CASE(["${MD5SUM}"],
 295         [md5sum], [MD5FMT="cat"],
 296         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 297         [MD5FMT="missing"])
 298 AC_SUBST([MD5FMT])
 299
 300 dnl ----------------------------------------------
 301 dnl check for lclint, and lint if it doesn't exist
 302 dnl ----------------------------------------------
 303 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 304 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 305   [LINT=$ac_cv_prog_linttmp1
 306   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 307   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 308   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 309     [LINT=$ac_cv_prog_linttmp2
 310     LINTFLAGS=""],
 311     [LINT="echo 'No lint program found'"
 312     LINTFLAGS=""])])
 313 AC_SUBST([LINT])dnl
 314 AC_SUBST([LINTFLAGS])dnl
 315
 316 dnl Look for `ls'
 317 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 318 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 319
 320 dnl See how we get ls to display the owner and the group
 321 AS_IF([test "$lspath" != "no"],
 322   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 323                  [nmh_cv_ls_grpopt],
 324   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 325     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 326     dnl ls, it would seem -l gave us both the user and group.  On this type of
 327     dnl ls, -g makes _only_ the group be displayed (and not the user).
 328     nmh_cv_ls_grpopt="-l"],[
 329     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 330     nmh_cv_ls_grpopt="-lg"])])])
 331
 332 dnl Look for `sendmail'
 333 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 334 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 335
 336 dnl Look for `vi'
 337 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 338 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 339
 340 dnl If editor is not specified yet,
 341 dnl then use `vi' as the default.
 342 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 343 AC_SUBST([editorpath])dnl
 344
 345 dnl Cygwin FAT filesystems do not support hard links.  So default to
 346 dnl cp instead, even if running on an NTFS or other filesystem.
 347 AS_CASE(["$host_os"],
 348   [cygwin*],[LN=cp],
 349   [LN=ln])
 350 AC_SUBST([LN])
 351
 352 dnl ----------------------------------------------------------
 353 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 354 dnl ----------------------------------------------------------
 355 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 356 [for mailspool in /var/mail        dnl
 357                   /var/spool/mail  dnl
 358                   /usr/spool/mail  dnl
 359                   /dev/null;       dnl Just in case we fall through
 360 do
 361   test -d $mailspool && break
 362 done
 363 nmh_cv_mailspool=$mailspool
 364 ])
 365 mailspool=$nmh_cv_mailspool
 366 AC_SUBST([mailspool])dnl
 367
 368 dnl See whether the mail spool directory is world-writable.
 369 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 370   AC_CACHE_CHECK(whether the mail spool is world-writable,
 371                  nmh_cv_mailspool_world_writable,
 372   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 373     nmh_cv_mailspool_world_writable=no
 374   else
 375     nmh_cv_mailspool_world_writable=yes
 376   fi])
 377 fi
 378
 379 dnl Also, check for liblockfile (as found on Debian systems)
 380 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 381
 382 dnl and whether its companion program dotlockfile is setgid
 383 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 384 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 385   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 386     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 387     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 388         nmh_cv_dotlockfile_setgid=yes
 389       else
 390         nmh_cv_dotlockfile_setgid=no
 391       fi])
 392   fi
 393 fi
 394
 395 dnl Provide a way for distcheck to disable setgid_mail via
 396 dnl DISTCHECK_CONFIGURE_FLAGS.
 397 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 398   [nmh_cv_dotlockfile_setgid=yes])
 399
 400 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 401 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 402 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 403   dnl do we really need both of these?
 404   AC_DEFINE(MAILGROUP,1,
 405     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 406   SETGID_MAIL=1
 407 fi
 408 AC_SUBST([SETGID_MAIL])dnl
 409
 410 dnl Use ls to see which group owns the mail spool directory.
 411 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 412 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 413 ])
 414 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 415 AC_SUBST(MAIL_SPOOL_GRP)dnl
 416
 417 dnl ------------------
 418 dnl CHECK HEADER FILES
 419 dnl ------------------
 420
 421 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 422 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 423 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 424 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 425 dnl declared; if so they should have an entry added to this case statement.
 426 dnl NB that we must define this on the compiler command line, not in config.h,
 427 dnl because it must be set before any system header is included and there's no
 428 dnl portable way to make sure that files generated by lex include config.h
 429 dnl before system header files.
 430
 431 AS_CASE(["$host_os"],
 432         [linux*],
 433         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 434           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 435                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 436
 437 AC_HEADER_STDC
 438 AC_HEADER_TIOCGWINSZ
 439 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 440                   langinfo.h wchar.h wctype.h netdb.h \
 441                   sys/param.h sys/time.h sys/stream.h])
 442
 443 dnl
 444 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 445 dnl really use a whole set of them, but this check should be
 446 dnl sufficient.
 447 dnl
 448 AC_CHECK_HEADER(libio.h, [
 449   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 450     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 451
 452 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 453   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 454 [[#if HAVE_SYS_STREAM_H
 455 #  include <sys/stream.h>
 456 #endif
 457 ]])
 458
 459 dnl ---------------
 460 dnl CHECK FUNCTIONS
 461 dnl ---------------
 462 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 463
 464 dnl Check for multibyte character set support
 465 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 466             "x$ac_cv_header_wctype_h" = "xyes" -a \
 467             "x$ac_cv_func_wcwidth" = "xyes" -a \
 468             "x$ac_cv_func_mbtowc" = "xyes"],
 469       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 470                  [Define to enable support for multibyte character sets.])
 471        MULTIBYTE_ENABLED=1],
 472       [MULTIBYTE_ENABLED=0])
 473 AC_SUBST([MULTIBYTE_ENABLED])
 474
 475 dnl -------------------
 476 dnl CHECK FOR LIBRARIES
 477 dnl -------------------
 478 dnl Check location of modf
 479 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 480
 481 dnl Checks for network libraries (nsl, socket)
 482 NMH_CHECK_NETLIBS
 483
 484 dnl Check for readline support
 485 NMH_READLINE
 486
 487 dnl Check for iconv
 488 NMH_CHECK_ICONV
 489
 490 termcap_curses_order="termcap curses ncurses"
 491 for lib in $termcap_curses_order; do
 492   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 493 done
 494 AC_SUBST([TERMLIB])dnl
 495 AS_IF([test "x$TERMLIB" = "x"],
 496       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 497 or ncurses library or package that you can install?])])
 498
 499 dnl --------------
 500 dnl CHECK FOR NDBM
 501 dnl --------------
 502
 503 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 504             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 505 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 506             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 507
 508 if test "$nmh_ndbm" = "autodetect"; then
 509   if test "$nmh_ndbmheader" != "autodetect"; then
 510     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 511   else
 512
 513     dnl There are at least four implementations of ndbm, and
 514     dnl several of those can be in different places at the whim
 515     dnl of the system integrator. A good summary of this mess
 516     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 517
 518     dnl Classic ndbm with no library required (eg NetBSD): try this
 519     dnl first so we don't accidentally link in a pointless but harmless
 520     dnl library in one of the later ndbm.h+libfoo tests:
 521     NMH_CHECK_NDBM(ndbm.h,,,
 522     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 523       NMH_CHECK_NDBM(db.h,db,,
 524     dnl Berkeley DBv1 emulating ndbm:
 525         NMH_CHECK_NDBM(ndbm.h,db,,
 526           NMH_CHECK_NDBM(ndbm.h,db1,,
 527     dnl Classic ndbm:
 528             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 529     dnl glibc2.1 systems put db1 in a subdir:
 530               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 531     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 532     dnl and possibly needing gbdm_compat library:
 533                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 534                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 535                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 536                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 537
 538   fi
 539 else
 540   dnl We don't really need to check that the user-specified values work,
 541   dnl but it is a convenience to the user to bomb out early rather than
 542   dnl after configure and half the compile process.
 543   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 544 fi
 545
 546 if test "$nmh_ndbm_found" = "no"; then
 547   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 548 else
 549   dnl Now export the lib/header to our makefile/config.h:
 550   if test x"$nmh_ndbmheader" != x; then
 551     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 552       [Define to the header containing the ndbm API prototypes.])
 553   fi
 554   if test x"$nmh_ndbm" != x; then
 555     NDBM_LIBS="-l$nmh_ndbm"
 556   else
 557     NDBM_LIBS=
 558   fi
 559   AC_SUBST([NDBM_LIBS])
 560 fi
 561
 562 dnl ------------------
 563 dnl Set RPM build root
 564 dnl ------------------
 565 dnl nmhrpm is used in the final summary, see below.  The default value is
 566 dnl reported there as ./RPM, consistent with the reporting of the default
 567 dnl source code location as ., but its absolute path is used in the Makefile.
 568 AC_ARG_WITH([rpmdir],
 569   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 570   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 571           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 572 AC_SUBST([rpmdir])
 573
 574
 575 dnl --------------------
 576 dnl CHECK FOR CYRUS-SASL
 577 dnl --------------------
 578
 579 AS_IF([test x"$sasl_support" = x"yes"],[
 580   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 581   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 582     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 583 AC_SUBST([SASLLIB])
 584
 585 dnl -----------------
 586 dnl CHECK FOR OPENSSL
 587 dnl -----------------
 588
 589 AS_IF([test x"$tls_support" = x"yes"],[
 590   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 591   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 592     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 593   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 594     [AC_MSG_ERROR([OpenSSL library not found])])],
 595   [TLSLIB=])
 596 AC_SUBST([TLSLIB])
 597
 598 dnl ---------------------
 599 dnl CHECK TERMCAP LIBRARY
 600 dnl ---------------------
 601
 602 dnl Add the termcap library, so that the following configure
 603 dnl tests will find it when it tries to link test programs.
 604 nmh_save_LIBS="$LIBS"
 605 LIBS="$TERMLIB $LIBS"
 606
 607 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 608 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 609 dnl in tgetstr().
 610 dnl Under Cygwin test program crashes but exit code is still 0. So,
 611 dnl we test for a file that porgram should create
 612 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 613 [Define to 1 if tgetent() accepts NULL as a buffer.])
 614 AC_CACHE_CHECK(if tgetent accepts NULL,
 615 nmh_cv_func_tgetent_accepts_null,
 616 [AC_TRY_RUN([
 617 main()
 618 {
 619     char buf[4096];
 620     int r1 = tgetent(buf, "vt100");
 621     int r2 = tgetent((char*)0,"vt100");
 622     if (r1 >= 0 && r1 == r2) {
 623         char tbuf[1024], *u;
 624         u = tbuf;
 625         tgetstr("cl", &u);
 626         creat("conftest.tgetent", 0640);
 627     }
 628     exit((r1 != r2) || r2 == -1);
 629 }
 630 ],
 631   if test -f conftest.tgetent; then
 632     nmh_cv_func_tgetent_accepts_null=yes
 633   else
 634     nmh_cv_func_tgetent_accepts_null=no
 635   fi,
 636   nmh_cv_func_tgetent_accepts_null=no,
 637   nmh_cv_func_tgetent_accepts_null=no)])
 638 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 639   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 640 fi
 641 AC_CACHE_CHECK(if tgetent returns 0 on success,
 642 nmh_cv_func_tgetent_zero_success,
 643 [AC_TRY_RUN([
 644 main()
 645 {
 646     char buf[4096];
 647     int r1 = tgetent(buf, "!@#$%^&*");
 648     int r2 = tgetent(buf, "vt100");
 649     if (r1 < 0 && r2 == 0) {
 650         char tbuf[1024], *u;
 651         u = tbuf;
 652         tgetstr("cl", &u);
 653         creat("conftest.tgetent0", 0640);
 654     }
 655     exit(r1 == r2);
 656 }
 657 ],
 658   if test -f conftest.tgetent0; then
 659     nmh_cv_func_tgetent_zero_success=yes
 660   else
 661     nmh_cv_func_tgetent_zero_success=no
 662   fi,
 663   nmh_cv_func_tgetent_zero_success=no,
 664   nmh_cv_func_tgetent_zero_success=no)])
 665 AH_TEMPLATE([TGETENT_SUCCESS],
 666 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 667 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 668   AC_DEFINE(TGETENT_SUCCESS, 0)
 669 else
 670   AC_DEFINE(TGETENT_SUCCESS, 1)
 671 fi
 672
 673 dnl Now put the libraries back to what it was before we
 674 dnl starting checking the termcap library.
 675 LIBS="$nmh_save_LIBS"
 676
 677 dnl --------------
 678 dnl CHECK TYPEDEFS
 679 dnl --------------
 680 AC_TYPE_PID_T
 681 AC_TYPE_OFF_T
 682 AC_TYPE_UID_T
 683 AC_TYPE_MODE_T
 684 AC_TYPE_SIZE_T
 685
 686 dnl ----------------
 687 dnl CHECK STRUCTURES
 688 dnl ----------------
 689
 690 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 691 dnl (FreeBSD has a timezone() function but not a timezone global
 692 dnl variable that is visible).
 693 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 694
 695 AC_STRUCT_DIRENT_D_TYPE
 696
 697 dnl Where is <signal.h> located?  Needed as input for signames.awk
 698 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 699 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 700                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 701                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 702                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 703                  /usr/include/sys/signal.h      dnl Almost everybody else
 704                  /dev/null;                     dnl Just in case we fall through
 705 do
 706   test -f $SIGNAL_H && \
 707   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 708   break
 709 done
 710 nmh_cv_path_signal_h=$SIGNAL_H
 711 ])
 712 SIGNAL_H=$nmh_cv_path_signal_h
 713 AC_SUBST(SIGNAL_H)dnl
 714
 715 dnl
 716 dnl Sigh, this is required because under the new world order autoconf has
 717 dnl nothing to create in a few of the build directories when doing an object
 718 dnl tree build.  So make sure we created certain directories if they don't
 719 dnl exist.
 720 dnl
 721
 722 AC_CONFIG_COMMANDS([build-directories],
 723 [test -d etc || AS_MKDIR_P([etc])
 724 test -d man || AS_MKDIR_P([man])])
 725
 726 AC_CONFIG_COMMANDS_POST([
 727
 728 dnl These odd looking assignments are done to expand out unexpanded
 729 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 730 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 731 dnl again to get the final answer.
 732 dnl We only use the expanded versions to print the install paths in
 733 dnl the final summary and should use them nowhere else (see the autoconf
 734 dnl docs for the rationale for bindir etc being unexpanded).
 735 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 736 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 737 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 738 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 739 eval "nmhrpm=${nmhrpm}";
 740
 741 AC_MSG_NOTICE([
 742 nmh configuration
 743 -----------------
 744 nmh version                : AC_PACKAGE_VERSION
 745 host os                    : ${host}
 746 compiler                   : ${CC}
 747 compiler flags             : ${CFLAGS}
 748 linker flags               : ${LDFLAGS}
 749 preprocessor flags         : ${CPPFLAGS}
 750 source code location       : ${srcdir}
 751 binary install path        : ${nmhbin}
 752 library install path       : ${nmhlib}
 753 config files install path  : ${nmhsysconf}
 754 man page install path      : ${nmhman}
 755 RPM build root             : ${nmhrpm}
 756 backup prefix              : ${backup_prefix}
 757 transport system           : ${MTS}
 758 file locking type          : ${LOCKTYPE}
 759 default smtp servers       : ${smtpservers}
 760 default editor             : ${editorpath}
 761 default pager              : ${pagerpath}
 762 SASL support               : ${sasl_support}
 763 TLS support                : ${tls_support}
 764 ])])dnl
 765
 766 dnl ---------------
 767 dnl OUTPUT MAKEFILE
 768 dnl ---------------
 769 AC_CONFIG_FILES([Makefile test/common.sh])
 770 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 771 AC_OUTPUT