diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall color-tests foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of locking to use?
  66 AS_CASE(["$host_os"],
  67   [aix*|cygwin*|linux*],
  68     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  69   [freebsd*|openbsd*|darwin*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  70   [default_locktype="dot"; default_locking=DOT_LOCKING])
  71
  72 AC_ARG_WITH([locking],
  73   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  74   [specify the file locking method]))
  75
  76 AS_IF([test x"$with_locking" = x"dot"],
  77     [LOCKTYPE="dot"
  78     AC_DEFINE([DOT_LOCKING], [1], [Define to use dot based file locking.])],
  79   [test x"$with_locking" = x"flock"],
  80     [LOCKTYPE="flock"
  81     AC_DEFINE([FLOCK_LOCKING], [1], [Define to use flock() based locking.])],
  82   [test x"$with_locking" = x"lockf"],
  83     [LOCKTYPE="lockf"
  84     AC_DEFINE([LOCKF_LOCKING], [1], [Define to use lockf() based locking.])],
  85   [test x"$with_locking" = x"fcntl"],
  86     [LOCKTYPE="fcntl"
  87     AC_DEFINE([FCNTL_LOCKING], [1], [Define to use fnctl() based locking.])],
  88   [LOCKTYPE="$default_locktype"
  89   AC_DEFINE_UNQUOTED([$default_locking], [1])])
  90
  91 dnl Should we use a locking directory?
  92 AC_ARG_ENABLE([lockdir],
  93   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
  94   AS_IF([test "x$enableval" = xyes],[
  95     AC_MSG_ERROR([--enable-lockdir requires an argument])])
  96   AS_IF([test "x$LOCKTYPE" != xdot],[
  97     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
  98   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
  99                      [Directory to store dot-locking lock files])
 100 ])
 101
 102 dnl What method of posting should post use?
 103 AC_ARG_WITH([mts],
 104   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
 105   [specify the default mail transport agent/service]))
 106
 107 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 108       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
 109       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
 110       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
 111       [MTS="smtp"])
 112 AC_SUBST([MTS])dnl
 113
 114 dnl What should be the default mail server(s)?
 115 AC_ARG_WITH([smtpservers],
 116   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 117   [specify the default SMTP server(s) @<:@localhost@:>@])])
 118 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 119       [smtpservers="localhost"])
 120 AC_SUBST([smtpservers])dnl
 121
 122 dnl ----------------------------------------------------
 123 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 124 dnl ----------------------------------------------------
 125 AC_PREFIX_DEFAULT([/usr/local/nmh])
 126
 127 dnl ------------------
 128 dnl CHECK THE COMPILER
 129 dnl ------------------
 130 dnl We want these before the checks,
 131 dnl so the checks can modify their values.
 132 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 133 if test x"$enable_debug" = x"yes"; then
 134   test -z "$LDFLAGS" && LDFLAGS=-g
 135 fi
 136
 137 AC_PROG_CC
 138 AM_PROG_CC_C_O
 139
 140 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 141   [nmh_cv_has_nosigncompare],
 142   [nmh_saved_cppflags="$CPPFLAGS"
 143    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 144    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 145                   nmh_cv_has_nosigncompare=no)
 146    CPPFLAGS="$nmh_saved_cppflags"])
 147
 148 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 149   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 150 fi
 151 AC_SUBST([DISABLE_SIGN_COMPARE_WARNING])dnl
 152
 153 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 154 [nmh_saved_cflags="$CFLAGS"
 155  CFLAGS="$CFLAGS -Wextra -Werror"
 156  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 157  CFLAGS="$nmh_saved_cflags"])
 158
 159 AC_CACHE_CHECK([whether compiler supports -Wno-clobbered], [nmh_cv_has_noclobbered],
 160 [nmh_saved_cflags="$CFLAGS"
 161  CFLAGS="$CFLAGS -Wno-clobbered -Werror"
 162  AC_TRY_COMPILE([],[],nmh_cv_has_noclobbered=yes,nmh_cv_has_noclobbered=no)
 163  CFLAGS="$nmh_saved_cflags"])
 164
 165 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 166 [nmh_saved_cflags="$CFLAGS"
 167  CFLAGS="$CFLAGS -Wno-pointer-sign -Werror"
 168  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 169  CFLAGS="$nmh_saved_cflags"])
 170
 171 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 172 dnl setup version 2.763, because it disables some features in the
 173 dnl system system header files and warns about them with -Wall.  Try
 174 dnl to test for that generally, though still with gcc.
 175 if test "$GCC" = yes; then
 176   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 177     [nmh_saved_cppflags="$CPPFLAGS"
 178      nmh_saved_cflags="$CFLAGS"
 179      CPPFLAGS="-D_GNU_SOURCE"
 180      CFLAGS="-ansi -Wall -Werror"
 181      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 182        [nmh_cv_has_dash_ansi=yes],
 183        [nmh_cv_has_dash_ansi=no])
 184      CPPFLAGS="$nmh_saved_cppflags"
 185      CFLAGS="$nmh_saved_cflags"])
 186 else
 187   nmh_cv_has_dash_ansi=no
 188 fi
 189
 190 dnl if the user hasn't specified CFLAGS, then
 191 dnl   if compiler is gcc, then
 192 dnl    use -O2 and some warning flags
 193 dnl   else use -O
 194 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 195 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 196 dnl warnings which are probably mostly spurious and which in any case we
 197 dnl don't want to deal with now.
 198 if test "$nmh_cv_has_dash_ansi" = "yes"; then
 199     nmh_gcc_warnflags="-ansi -pedantic -Wall"
 200 else
 201     nmh_gcc_warnflags="-Wall"
 202 fi
 203 if test "$nmh_cv_has_wextra" = "yes"; then
 204     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wextra"
 205 fi
 206 if test "$nmh_cv_has_noptrsign" = "yes"; then
 207     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wno-pointer-sign"
 208 fi
 209 if test "$nmh_cv_has_noclobbered" = "yes"; then
 210     nmh_gcc_warnflags="${nmh_gcc_warnflags} -Wno-clobbered"
 211 fi
 212
 213 if test -n "$auto_cflags"; then
 214   if test x"$enable_debug" = x"yes"; then
 215     if test -n "$GCC"; then
 216       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 217     else
 218       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 219     fi
 220   else
 221     if test -z "$LDFLAGS"; then
 222       case "$build_os" in
 223         darwin*)
 224           LDFLAGS=
 225           ;;
 226         *)
 227           LDFLAGS=-s
 228           ;;
 229       esac
 230     fi
 231     if test -n "$GCC"; then
 232       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 233     else
 234       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 235     fi
 236   fi
 237 fi
 238
 239 dnl ------------------
 240 dnl CHECK FOR PROGRAMS
 241 dnl ------------------
 242 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 243 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 244 AC_PROG_RANLIB          dnl Check for `ranlib'
 245 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 246 AC_PROG_SED             dnl Check for Posix-compliant sed
 247 AM_PROG_LEX             dnl Check for lex/flex
 248
 249 AM_PROG_AR
 250
 251 dnl Look for `cut'
 252 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 253 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 254
 255 dnl
 256 dnl Check for MD5 program and formatting command
 257 dnl
 258 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 259 AS_CASE(["${MD5SUM}"],
 260         [md5sum], [MD5FMT="cat"],
 261         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 262         [MD5FMT="missing"])
 263 AC_SUBST([MD5FMT])
 264
 265 dnl ----------------------------------------------
 266 dnl check for lclint, and lint if it doesn't exist
 267 dnl ----------------------------------------------
 268 AC_CHECK_PROG([linttmp1], [lclint], [lclint], [no])dnl
 269 AS_IF([test x$ac_cv_prog_linttmp1 != xno],
 270   [LINT=$ac_cv_prog_linttmp1
 271   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"],
 272   [AC_CHECK_PROG([linttmp2], [lint], [lint], [no])dnl
 273   AS_IF([test x$ac_cv_prog_linttmp2 != xno],
 274     [LINT=$ac_cv_prog_linttmp2
 275     LINTFLAGS=""],
 276     [LINT="echo 'No lint program found'"
 277     LINTFLAGS=""])])
 278 AC_SUBST([LINT])dnl
 279 AC_SUBST([LINTFLAGS])dnl
 280
 281 dnl Look for `ls'
 282 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 283 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 284
 285 dnl See how we get ls to display the owner and the group
 286 AS_IF([test "$lspath" != "no"],
 287   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 288                  [nmh_cv_ls_grpopt],
 289   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 290     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 291     dnl ls, it would seem -l gave us both the user and group.  On this type of
 292     dnl ls, -g makes _only_ the group be displayed (and not the user).
 293     nmh_cv_ls_grpopt="-l"],[
 294     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 295     nmh_cv_ls_grpopt="-lg"])])])
 296
 297 dnl Look for `sendmail'
 298 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 299 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 300
 301 dnl Cygwin FAT filesystems do not support hard links.  So default to
 302 dnl cp instead, even if running on an NTFS or other filesystem.
 303 AS_CASE(["$host_os"],
 304   [cygwin*],[LN=cp],
 305   [LN=ln])
 306 AC_SUBST([LN])
 307
 308 dnl ----------------------------------------------------------
 309 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 310 dnl ----------------------------------------------------------
 311 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 312 [for mailspool in /var/mail        dnl
 313                   /var/spool/mail  dnl
 314                   /usr/spool/mail  dnl
 315                   /dev/null;       dnl Just in case we fall through
 316 do
 317   test -d $mailspool && break
 318 done
 319 nmh_cv_mailspool=$mailspool
 320 ])
 321 mailspool=$nmh_cv_mailspool
 322 AC_SUBST([mailspool])dnl
 323
 324 dnl See whether the mail spool directory is world-writable.
 325 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 326   AC_CACHE_CHECK(whether the mail spool is world-writable,
 327                  nmh_cv_mailspool_world_writable,
 328   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 329     nmh_cv_mailspool_world_writable=no
 330   else
 331     nmh_cv_mailspool_world_writable=yes
 332   fi])
 333 fi
 334
 335 dnl Also, check for liblockfile (as found on Debian systems)
 336 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 337
 338 dnl and whether its companion program dotlockfile is setgid
 339 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 340 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 341   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 342     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 343     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 344         nmh_cv_dotlockfile_setgid=yes
 345       else
 346         nmh_cv_dotlockfile_setgid=no
 347       fi])
 348   fi
 349 fi
 350
 351 dnl Provide a way for distcheck to disable setgid_mail via
 352 dnl DISTCHECK_CONFIGURE_FLAGS.
 353 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 354   [nmh_cv_dotlockfile_setgid=yes])
 355
 356 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 357 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 358 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 359   dnl do we really need both of these?
 360   AC_DEFINE(MAILGROUP,1,
 361     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 362   SETGID_MAIL=1
 363 fi
 364 AC_SUBST([SETGID_MAIL])dnl
 365
 366 dnl Use ls to see which group owns the mail spool directory.
 367 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 368 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 369 ])
 370 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 371 AC_SUBST(MAIL_SPOOL_GRP)dnl
 372
 373 dnl ------------------
 374 dnl CHECK HEADER FILES
 375 dnl ------------------
 376
 377 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 378 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 379 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 380 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 381 dnl declared; if so they should have an entry added to this case statement.
 382 dnl NB that we must define this on the compiler command line, not in config.h,
 383 dnl because it must be set before any system header is included and there's no
 384 dnl portable way to make sure that files generated by lex include config.h
 385 dnl before system header files.
 386
 387 AS_CASE(["$host_os"],
 388         [linux*],
 389         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 390           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 391                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 392
 393 AC_HEADER_TIOCGWINSZ
 394 AC_CHECK_HEADERS([fcntl.h ncurses/termcap.h termcap.h langinfo.h \
 395                   wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 396
 397 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 398   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 399 [[#if HAVE_SYS_STREAM_H
 400 #  include <sys/stream.h>
 401 #endif
 402 ]])
 403
 404 dnl ---------------
 405 dnl CHECK FUNCTIONS
 406 dnl ---------------
 407 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 408
 409 dnl Check for multibyte character set support
 410 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 411             "x$ac_cv_header_wctype_h" = "xyes" -a \
 412             "x$ac_cv_func_wcwidth" = "xyes" -a \
 413             "x$ac_cv_func_mbtowc" = "xyes"],
 414       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 415                  [Define to enable support for multibyte character sets.])
 416        MULTIBYTE_ENABLED=1],
 417       [MULTIBYTE_ENABLED=0])
 418 AC_SUBST([MULTIBYTE_ENABLED])
 419
 420 dnl -------------------
 421 dnl CHECK FOR LIBRARIES
 422 dnl -------------------
 423 dnl Check location of modf
 424 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 425
 426 dnl Checks for network libraries (nsl, socket)
 427 NMH_CHECK_NETLIBS
 428
 429 dnl Check for readline support
 430 NMH_READLINE
 431
 432 dnl Check for iconv
 433 NMH_CHECK_ICONV
 434
 435 termcap_curses_order="termcap curses ncurses"
 436 for lib in $termcap_curses_order; do
 437   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 438 done
 439 AC_SUBST([TERMLIB])dnl
 440 AS_IF([test "x$TERMLIB" = "x"],
 441       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 442 or ncurses library or package that you can install?])])
 443
 444 dnl --------------
 445 dnl CHECK FOR NDBM
 446 dnl --------------
 447
 448 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 449             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 450 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 451             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 452
 453 if test "$nmh_ndbm" = "autodetect"; then
 454   if test "$nmh_ndbmheader" != "autodetect"; then
 455     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 456   else
 457
 458     dnl There are at least four implementations of ndbm, and
 459     dnl several of those can be in different places at the whim
 460     dnl of the system integrator. A good summary of this mess
 461     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 462
 463     dnl Classic ndbm with no library required (eg NetBSD): try this
 464     dnl first so we don't accidentally link in a pointless but harmless
 465     dnl library in one of the later ndbm.h+libfoo tests:
 466     NMH_CHECK_NDBM(ndbm.h,,,
 467     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 468       NMH_CHECK_NDBM(db.h,db,,
 469     dnl Berkeley DBv1 emulating ndbm:
 470         NMH_CHECK_NDBM(ndbm.h,db,,
 471           NMH_CHECK_NDBM(ndbm.h,db1,,
 472     dnl Classic ndbm:
 473             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 474     dnl glibc2.1 systems put db1 in a subdir:
 475               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 476     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 477     dnl and possibly needing gbdm_compat library:
 478                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 479                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 480                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 481                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 482
 483   fi
 484 else
 485   dnl We don't really need to check that the user-specified values work,
 486   dnl but it is a convenience to the user to bomb out early rather than
 487   dnl after configure and half the compile process.
 488   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 489 fi
 490
 491 if test "$nmh_ndbm_found" = "no"; then
 492   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 493 else
 494   dnl Now export the lib/header to our makefile/config.h:
 495   if test x"$nmh_ndbmheader" != x; then
 496     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 497       [Define to the header containing the ndbm API prototypes.])
 498   fi
 499   if test x"$nmh_ndbm" != x; then
 500     NDBM_LIBS="-l$nmh_ndbm"
 501   else
 502     NDBM_LIBS=
 503   fi
 504   AC_SUBST([NDBM_LIBS])
 505 fi
 506
 507 dnl ------------------
 508 dnl Set RPM build root
 509 dnl ------------------
 510 dnl nmhrpm is used in the final summary, see below.  The default value is
 511 dnl reported there as ./RPM, consistent with the reporting of the default
 512 dnl source code location as ., but its absolute path is used in the Makefile.
 513 AC_ARG_WITH([rpmdir],
 514   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 515   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 516           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 517 AC_SUBST([rpmdir])
 518
 519
 520 dnl --------------------
 521 dnl CHECK FOR CYRUS-SASL
 522 dnl --------------------
 523
 524 AS_IF([test x"$sasl_support" = x"yes"],[
 525   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 526   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 527     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 528 AC_SUBST([SASLLIB])
 529
 530 dnl -----------------
 531 dnl CHECK FOR OPENSSL
 532 dnl -----------------
 533
 534 AS_IF([test x"$tls_support" = x"yes"],[
 535   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 536   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 537     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 538   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 539     [AC_MSG_ERROR([OpenSSL library not found])])],
 540   [TLSLIB=])
 541 AC_SUBST([TLSLIB])
 542
 543 dnl ---------------------
 544 dnl CHECK TERMCAP LIBRARY
 545 dnl ---------------------
 546
 547 dnl Add the termcap library, so that the following configure
 548 dnl tests will find it when it tries to link test programs.
 549 nmh_save_LIBS="$LIBS"
 550 LIBS="$TERMLIB $LIBS"
 551
 552 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 553 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 554 dnl in tgetstr().
 555 dnl Under Cygwin test program crashes but exit code is still 0. So,
 556 dnl we test for a file that porgram should create
 557 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 558 [Define to 1 if tgetent() accepts NULL as a buffer.])
 559 AC_CACHE_CHECK(if tgetent accepts NULL,
 560 nmh_cv_func_tgetent_accepts_null,
 561 [AC_TRY_RUN([
 562 main()
 563 {
 564     char buf[4096];
 565     int r1 = tgetent(buf, "vt100");
 566     int r2 = tgetent((char*)0,"vt100");
 567     if (r1 >= 0 && r1 == r2) {
 568         char tbuf[1024], *u;
 569         u = tbuf;
 570         tgetstr("cl", &u);
 571         creat("conftest.tgetent", 0640);
 572     }
 573     exit((r1 != r2) || r2 == -1);
 574 }
 575 ],
 576   if test -f conftest.tgetent; then
 577     nmh_cv_func_tgetent_accepts_null=yes
 578   else
 579     nmh_cv_func_tgetent_accepts_null=no
 580   fi,
 581   nmh_cv_func_tgetent_accepts_null=no,
 582   nmh_cv_func_tgetent_accepts_null=no)])
 583 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 584   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 585 fi
 586 AC_CACHE_CHECK(if tgetent returns 0 on success,
 587 nmh_cv_func_tgetent_zero_success,
 588 [AC_TRY_RUN([
 589 main()
 590 {
 591     char buf[4096];
 592     int r1 = tgetent(buf, "!@#$%^&*");
 593     int r2 = tgetent(buf, "vt100");
 594     if (r1 < 0 && r2 == 0) {
 595         char tbuf[1024], *u;
 596         u = tbuf;
 597         tgetstr("cl", &u);
 598         creat("conftest.tgetent0", 0640);
 599     }
 600     exit(r1 == r2);
 601 }
 602 ],
 603   if test -f conftest.tgetent0; then
 604     nmh_cv_func_tgetent_zero_success=yes
 605   else
 606     nmh_cv_func_tgetent_zero_success=no
 607   fi,
 608   nmh_cv_func_tgetent_zero_success=no,
 609   nmh_cv_func_tgetent_zero_success=no)])
 610 AH_TEMPLATE([TGETENT_SUCCESS],
 611 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 612 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 613   AC_DEFINE(TGETENT_SUCCESS, 0)
 614 else
 615   AC_DEFINE(TGETENT_SUCCESS, 1)
 616 fi
 617
 618 dnl Now put the libraries back to what it was before we
 619 dnl starting checking the termcap library.
 620 LIBS="$nmh_save_LIBS"
 621
 622 dnl --------------
 623 dnl CHECK TYPEDEFS
 624 dnl --------------
 625 AC_TYPE_PID_T
 626 AC_TYPE_OFF_T
 627 AC_TYPE_UID_T
 628 AC_TYPE_MODE_T
 629 AC_TYPE_SIZE_T
 630
 631 dnl ----------------
 632 dnl CHECK STRUCTURES
 633 dnl ----------------
 634
 635 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 636 dnl (FreeBSD has a timezone() function but not a timezone global
 637 dnl variable that is visible).
 638 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 639
 640 AC_STRUCT_DIRENT_D_TYPE
 641
 642 dnl Where is <signal.h> located?  Needed as input for signames.awk
 643 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 644 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 645                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 646                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 647                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 648                  /usr/include/sys/signal.h      dnl Almost everybody else
 649                  /dev/null;                     dnl Just in case we fall through
 650 do
 651   test -f $SIGNAL_H && \
 652   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 653   break
 654 done
 655 nmh_cv_path_signal_h=$SIGNAL_H
 656 ])
 657 SIGNAL_H=$nmh_cv_path_signal_h
 658 AC_SUBST(SIGNAL_H)dnl
 659
 660 dnl
 661 dnl Sigh, this is required because under the new world order autoconf has
 662 dnl nothing to create in a few of the build directories when doing an object
 663 dnl tree build.  So make sure we created certain directories if they don't
 664 dnl exist.
 665 dnl
 666
 667 AC_CONFIG_COMMANDS([build-directories],
 668 [test -d etc || AS_MKDIR_P([etc])
 669 test -d man || AS_MKDIR_P([man])])
 670
 671 AC_CONFIG_COMMANDS_POST([
 672
 673 dnl These odd looking assignments are done to expand out unexpanded
 674 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 675 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 676 dnl again to get the final answer.
 677 dnl We only use the expanded versions to print the install paths in
 678 dnl the final summary and should use them nowhere else (see the autoconf
 679 dnl docs for the rationale for bindir etc being unexpanded).
 680 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 681 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 682 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 683 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 684 eval "nmhrpm=${nmhrpm}";
 685
 686 AC_MSG_NOTICE([
 687 nmh configuration
 688 -----------------
 689 nmh version                : AC_PACKAGE_VERSION
 690 host os                    : ${host}
 691 compiler                   : ${CC}
 692 compiler flags             : ${CFLAGS}
 693 linker flags               : ${LDFLAGS}
 694 preprocessor flags         : ${CPPFLAGS}
 695 source code location       : ${srcdir}
 696 binary install path        : ${nmhbin}
 697 library install path       : ${nmhlib}
 698 config files install path  : ${nmhsysconf}
 699 man page install path      : ${nmhman}
 700 RPM build root             : ${nmhrpm}
 701 backup prefix              : ${backup_prefix}
 702 transport system           : ${MTS}
 703 file locking type          : ${LOCKTYPE}
 704 default smtp servers       : ${smtpservers}
 705 default editor             : ${editorpath}
 706 SASL support               : ${sasl_support}
 707 TLS support                : ${tls_support}
 708 ])])dnl
 709
 710 dnl ---------------
 711 dnl OUTPUT MAKEFILE
 712 dnl ---------------
 713 AC_CONFIG_FILES([Makefile test/common.sh])
 714 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 715 AC_OUTPUT