diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*|openbsd*|darwin*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail|pipe@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 119       [test x"$with_mts" = x"pipe"], [MTS="pipe"],
 120       [MTS="smtp"])
 121 AC_SUBST([MTS])dnl
 122
 123 dnl What should be the default pager?
 124 AC_ARG_WITH([pager],
 125   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 126
 127 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 128
 129 dnl If a pager is not explicitly specified, then look for one.
 130 dnl Fall back to `cat', to avoid catastrophic failure of
 131 dnl `mhshow', et al., if pagerpath is set to `no'.
 132 if test -z "$pagerpath"; then
 133   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 134   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 135 fi
 136 AC_SUBST(pagerpath)dnl
 137
 138 dnl What should be the default mail server(s)?
 139 AC_ARG_WITH(smtpservers,
 140   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 141   [specify the default SMTP server(s) @<:@localhost@:>@]))
 142 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 143       [smtpservers="localhost"])
 144 AC_SUBST([smtpservers])dnl
 145
 146 dnl ----------------------------------------------------
 147 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 148 dnl ----------------------------------------------------
 149 AC_PREFIX_DEFAULT([/usr/local/nmh])
 150
 151 dnl ------------------
 152 dnl CHECK THE COMPILER
 153 dnl ------------------
 154 dnl We want these before the checks,
 155 dnl so the checks can modify their values.
 156 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 157 if test x"$enable_debug" = x"yes"; then
 158   test -z "$LDFLAGS" && LDFLAGS=-g
 159 fi
 160
 161 AC_PROG_CC
 162 AM_PROG_CC_C_O
 163
 164 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 165   [nmh_cv_has_unusedmacros],
 166   [nmh_saved_cppflags="$CPPFLAGS"
 167    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 168    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 169    CPPFLAGS="$nmh_saved_cppflags"])
 170
 171 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 172   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 173                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 174   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 175 fi
 176 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 177
 178 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 179   [nmh_cv_has_nosigncompare],
 180   [nmh_saved_cppflags="$CPPFLAGS"
 181    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 182    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 183                   nmh_cv_has_nosigncompare=no)
 184    CPPFLAGS="$nmh_saved_cppflags"])
 185
 186 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 187   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 188 fi
 189 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 190
 191 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 192 [nmh_saved_cflags="$CFLAGS"
 193  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 194  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 195  CFLAGS="$nmh_saved_cflags"])
 196
 197 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 198 [nmh_saved_cflags="$CFLAGS"
 199  CFLAGS="$CFLAGS -Wno-pointer-sign"
 200  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 201  CFLAGS="$nmh_saved_cflags"])
 202
 203 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 204 dnl setup version 2.763, because it disables some features in the
 205 dnl system system header files and warns about them with -Wall.  Try
 206 dnl to test for that generally, though still with gcc.
 207 if test "$GCC" = yes; then
 208   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 209     [nmh_saved_cppflags="$CPPFLAGS"
 210      nmh_saved_cflags="$CFLAGS"
 211      CPPFLAGS="-D_GNU_SOURCE"
 212      CFLAGS="-ansi -Wall -Werror"
 213      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 214        [nmh_cv_has_dash_ansi=yes],
 215        [nmh_cv_has_dash_ansi=no])
 216      CPPFLAGS="$nmh_saved_cppflags"
 217      CFLAGS="$nmh_saved_cflags"])
 218 else
 219   nmh_cv_has_dash_ansi=no
 220 fi
 221
 222 dnl if the user hasn't specified CFLAGS, then
 223 dnl   if compiler is gcc, then
 224 dnl    use -O2 and some warning flags
 225 dnl   else use -O
 226 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 227 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 228 dnl warnings which are probably mostly spurious and which in any case we
 229 dnl don't want to deal with now.
 230 if test "$nmh_cv_has_noptrsign" = "yes"; then
 231     if test "$nmh_cv_has_dash_ansi" = "yes"; then
 232         nmh_gcc_common_flags="-ansi -pedantic -Wall"
 233     else
 234         nmh_gcc_common_flags="-Wall"
 235     fi
 236     if test "$nmh_cv_has_wextra" = "yes"; then
 237         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 238 "-Wno-pointer-sign"
 239     else
 240         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 241     fi
 242 else
 243     if test "$nmh_cv_has_wextra" = "yes"; then
 244         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 245     else
 246         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 247     fi
 248 fi
 249
 250 if test -n "$auto_cflags"; then
 251   if test x"$enable_debug" = x"yes"; then
 252     if test -n "$GCC"; then
 253       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 254     else
 255       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 256     fi
 257   else
 258     if test -z "$LDFLAGS"; then
 259       case "$build_os" in
 260         darwin*)
 261           LDFLAGS=
 262           ;;
 263         *)
 264           LDFLAGS=-s
 265           ;;
 266       esac
 267     fi
 268     if test -n "$GCC"; then
 269       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 270     else
 271       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 272     fi
 273   fi
 274 fi
 275
 276 AC_C_CONST              dnl Does compiler support `const'.
 277
 278 dnl ------------------
 279 dnl CHECK FOR PROGRAMS
 280 dnl ------------------
 281 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 282 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 283 AC_PROG_RANLIB          dnl Check for `ranlib'
 284 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 285 AC_PROG_SED             dnl Check for Posix-compliant sed
 286 AC_PROG_LEX             dnl Check for lex/flex
 287
 288 dnl Look for `cut'
 289 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 290 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 291
 292 dnl
 293 dnl Check for MD5 program and formatting command
 294 dnl
 295 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 296 AS_CASE(["${MD5SUM}"],
 297         [md5sum], [MD5FMT="cat"],
 298         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 299         [MD5FMT="missing"])
 300 AC_SUBST([MD5FMT])
 301
 302 dnl ----------------------------------------------
 303 dnl check for lclint, and lint if it doesn't exist
 304 dnl ----------------------------------------------
 305 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 306 if test x$ac_cv_prog_linttmp1 != xno ; then
 307   LINT=$ac_cv_prog_linttmp1
 308   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 309 else
 310   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 311   if test x$ac_cv_prog_linttmp2 != xno ; then
 312     LINT=$ac_cv_prog_linttmp2
 313     LINTFLAGS=""
 314   else
 315     LINT="echo 'No lint program found'"
 316     LINTFLAGS=""
 317   fi
 318 fi
 319 AC_SUBST([LINT])dnl
 320 AC_SUBST([LINTFLAGS])dnl
 321
 322 dnl Look for `ls'
 323 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 324 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 325
 326 dnl See how we get ls to display the owner and the group
 327 if test "$lspath" != "no"; then
 328   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 329                  [nmh_cv_ls_grpopt],
 330   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 331     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 332     dnl ls, it would seem -l gave us both the user and group.  On this type of
 333     dnl ls, -g makes _only_ the group be displayed (and not the user).
 334     nmh_cv_ls_grpopt="-l"
 335   else
 336     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 337     nmh_cv_ls_grpopt="-lg"
 338   fi])
 339 fi
 340
 341 dnl Look for `sendmail'
 342 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 343 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 344
 345 dnl Look for `vi'
 346 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 347 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 348
 349 dnl If editor is not specified yet,
 350 dnl then use `vi' as the default.
 351 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 352 AC_SUBST([editorpath])dnl
 353
 354 dnl Cygwin FAT filesystems do not support hard links.  So default to
 355 dnl cp instead, even if running on an NTFS or other filesystem.
 356 AS_CASE(["$host_os"],
 357   [cygwin*],[LN=cp],
 358   [LN=ln])
 359 AC_SUBST([LN])
 360
 361 dnl ----------------------------------------------------------
 362 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 363 dnl ----------------------------------------------------------
 364 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 365 [for mailspool in /var/mail        dnl
 366                   /var/spool/mail  dnl
 367                   /usr/spool/mail  dnl
 368                   /dev/null;       dnl Just in case we fall through
 369 do
 370   test -d $mailspool && break
 371 done
 372 nmh_cv_mailspool=$mailspool
 373 ])
 374 mailspool=$nmh_cv_mailspool
 375 AC_SUBST([mailspool])dnl
 376
 377 dnl See whether the mail spool directory is world-writable.
 378 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 379   AC_CACHE_CHECK(whether the mail spool is world-writable,
 380                  nmh_cv_mailspool_world_writable,
 381   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 382     nmh_cv_mailspool_world_writable=no
 383   else
 384     nmh_cv_mailspool_world_writable=yes
 385   fi])
 386 fi
 387
 388 dnl Also, check for liblockfile (as found on Debian systems)
 389 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 390
 391 dnl and whether its companion program dotlockfile is setgid
 392 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 393 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 394   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 395     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 396     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 397         nmh_cv_dotlockfile_setgid=yes
 398       else
 399         nmh_cv_dotlockfile_setgid=no
 400       fi])
 401   fi
 402 fi
 403
 404 dnl Provide a way for distcheck to disable setgid_mail via
 405 dnl DISTCHECK_CONFIGURE_FLAGS.
 406 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 407   nmh_cv_dotlockfile_setgid=yes
 408 fi
 409
 410 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 411 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 412 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 413   dnl do we really need both of these?
 414   AC_DEFINE(MAILGROUP,1,
 415     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 416   SETGID_MAIL=1
 417 fi
 418 AC_SUBST(SETGID_MAIL)dnl
 419
 420 dnl Use ls to see which group owns the mail spool directory.
 421 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 422 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 423 ])
 424 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 425 AC_SUBST(MAIL_SPOOL_GRP)dnl
 426
 427 dnl ------------------
 428 dnl CHECK HEADER FILES
 429 dnl ------------------
 430
 431 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 432 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 433 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 434 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 435 dnl declared; if so they should have an entry added to this case statement.
 436 dnl NB that we must define this on the compiler command line, not in config.h,
 437 dnl because it must be set before any system header is included and there's no
 438 dnl portable way to make sure that files generated by lex include config.h
 439 dnl before system header files.
 440
 441 AS_CASE(["$host_os"],
 442         [linux*],
 443         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 444           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 445                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 446
 447 AC_HEADER_STDC
 448 AC_HEADER_TIOCGWINSZ
 449 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 450                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 451                   sys/param.h sys/time.h sys/stream.h])
 452
 453 dnl
 454 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 455 dnl really use a whole set of them, but this check should be
 456 dnl sufficient.
 457 dnl
 458 AC_CHECK_HEADER(libio.h, [
 459   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 460     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 461
 462 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 463   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 464 [[#if HAVE_SYS_STREAM_H
 465 #  include <sys/stream.h>
 466 #endif
 467 ]])
 468
 469 dnl ---------------
 470 dnl CHECK FUNCTIONS
 471 dnl ---------------
 472 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 473
 474 dnl Check for multibyte character set support
 475 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 476             "x$ac_cv_header_wctype_h" = "xyes" -a \
 477             "x$ac_cv_func_wcwidth" = "xyes" -a \
 478             "x$ac_cv_func_mbtowc" = "xyes"],
 479       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 480                  [Define to enable support for multibyte character sets.])
 481        MULTIBYTE_ENABLED=1],
 482       [MULTIBYTE_ENABLED=0])
 483 AC_SUBST([MULTIBYTE_ENABLED])
 484
 485 dnl -------------------
 486 dnl CHECK FOR LIBRARIES
 487 dnl -------------------
 488 dnl Check location of modf
 489 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 490
 491 dnl Checks for network libraries (nsl, socket)
 492 NMH_CHECK_NETLIBS
 493
 494 NMH_READLINE
 495
 496 termcap_curses_order="termcap curses ncurses"
 497 for lib in $termcap_curses_order; do
 498   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 499 done
 500 AC_SUBST([TERMLIB])dnl
 501 AS_IF([test "x$TERMLIB" = "x"],
 502       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 503 or ncurses library or package that you can install?])])
 504
 505
 506 dnl ---------------
 507 dnl CHECK FOR ICONV
 508 dnl ---------------
 509
 510 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 511 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 512   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 513   if test "x$ac_found_iconv" = "xno"; then
 514     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 515     if test "x$ac_found_iconv" = "xno"; then
 516       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 517     fi
 518     if test "x$ac_found_iconv" != "xno"; then
 519       ICONVLIB="-liconv"
 520     fi
 521   else
 522     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 523     AC_CHECK_DECL(_libiconv_version,
 524       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 525       [ #include <iconv.h> ])
 526   fi
 527 fi
 528 if test "x$ac_found_iconv" = xyes; then
 529   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 530 fi
 531 AC_SUBST([ICONVLIB])
 532
 533 dnl Check if iconv uses const in prototype declaration
 534 if test "x$ac_found_iconv" = "xyes"; then
 535   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 536     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 537         #include <iconv.h>]],
 538         [[#ifdef __cplusplus
 539           "C"
 540           #endif
 541           #if defined(__STDC__) || defined(__cplusplus)
 542           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 543           #else
 544           size_t iconv();
 545           #endif]])],
 546       [ac_cv_iconv_const=],
 547       [ac_cv_iconv_const=const])])
 548   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 549     [Define as const if the declaration of iconv() needs const.])
 550 fi
 551
 552 dnl --------------
 553 dnl CHECK FOR NDBM
 554 dnl --------------
 555
 556 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 557             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 558 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 559             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 560
 561 if test "$nmh_ndbm" = "autodetect"; then
 562   if test "$nmh_ndbmheader" != "autodetect"; then
 563     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 564   else
 565
 566     dnl There are at least four implementations of ndbm, and
 567     dnl several of those can be in different places at the whim
 568     dnl of the system integrator. A good summary of this mess
 569     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 570
 571     dnl Classic ndbm with no library required (eg NetBSD): try this
 572     dnl first so we don't accidentally link in a pointless but harmless
 573     dnl library in one of the later ndbm.h+libfoo tests:
 574     NMH_CHECK_NDBM(ndbm.h,,,
 575     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 576       NMH_CHECK_NDBM(db.h,db,,
 577     dnl Berkeley DBv1 emulating ndbm:
 578         NMH_CHECK_NDBM(ndbm.h,db,,
 579           NMH_CHECK_NDBM(ndbm.h,db1,,
 580     dnl Classic ndbm:
 581             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 582     dnl glibc2.1 systems put db1 in a subdir:
 583               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 584     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 585     dnl and possibly needing gbdm_compat library:
 586                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 587                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 588                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 589                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 590
 591   fi
 592 else
 593   dnl We don't really need to check that the user-specified values work,
 594   dnl but it is a convenience to the user to bomb out early rather than
 595   dnl after configure and half the compile process.
 596   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 597 fi
 598
 599 if test "$nmh_ndbm_found" = "no"; then
 600   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 601 else
 602   dnl Now export the lib/header to our makefile/config.h:
 603   if test x"$nmh_ndbmheader" != x; then
 604     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 605       [Define to the header containing the ndbm API prototypes.])
 606   fi
 607   if test x"$nmh_ndbm" != x; then
 608     NDBM_LIBS="-l$nmh_ndbm"
 609   else
 610     NDBM_LIBS=
 611   fi
 612   AC_SUBST([NDBM_LIBS])
 613 fi
 614
 615 dnl ------------------
 616 dnl Set RPM build root
 617 dnl ------------------
 618 dnl nmhrpm is used in the final summary, see below.  The default value is
 619 dnl reported there as ./RPM, consistent with the reporting of the default
 620 dnl source code location as ., but its absolute path is used in the Makefile.
 621 AC_ARG_WITH(rpmdir,
 622   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 623   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 624           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 625 AC_SUBST([rpmdir])
 626
 627
 628 dnl --------------------
 629 dnl CHECK FOR CYRUS-SASL
 630 dnl --------------------
 631
 632 AS_IF([test x"$sasl_support" = x"yes"],[
 633   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 634   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 635     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 636 AC_SUBST([SASLLIB])
 637
 638 dnl -----------------
 639 dnl CHECK FOR OPENSSL
 640 dnl -----------------
 641
 642 AS_IF([test x"$tls_support" = x"yes"],[
 643   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 644   AC_CHECK_LIB([crypto], [BIO_write], ,
 645     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 646   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 647     [AC_MSG_ERROR([OpenSSL library not found])])])
 648
 649 dnl ---------------------
 650 dnl CHECK TERMCAP LIBRARY
 651 dnl ---------------------
 652
 653 dnl Add the termcap library, so that the following configure
 654 dnl tests will find it when it tries to link test programs.
 655 nmh_save_LIBS="$LIBS"
 656 LIBS="$TERMLIB $LIBS"
 657
 658 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 659 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 660 dnl in tgetstr().
 661 dnl Under Cygwin test program crashes but exit code is still 0. So,
 662 dnl we test for a file that porgram should create
 663 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 664 [Define to 1 if tgetent() accepts NULL as a buffer.])
 665 AC_CACHE_CHECK(if tgetent accepts NULL,
 666 nmh_cv_func_tgetent_accepts_null,
 667 [AC_TRY_RUN([
 668 main()
 669 {
 670     char buf[4096];
 671     int r1 = tgetent(buf, "vt100");
 672     int r2 = tgetent((char*)0,"vt100");
 673     if (r1 >= 0 && r1 == r2) {
 674         char tbuf[1024], *u;
 675         u = tbuf;
 676         tgetstr("cl", &u);
 677         creat("conftest.tgetent", 0640);
 678     }
 679     exit((r1 != r2) || r2 == -1);
 680 }
 681 ],
 682   if test -f conftest.tgetent; then
 683     nmh_cv_func_tgetent_accepts_null=yes
 684   else
 685     nmh_cv_func_tgetent_accepts_null=no
 686   fi,
 687   nmh_cv_func_tgetent_accepts_null=no,
 688   nmh_cv_func_tgetent_accepts_null=no)])
 689 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 690   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 691 fi
 692 AC_CACHE_CHECK(if tgetent returns 0 on success,
 693 nmh_cv_func_tgetent_zero_success,
 694 [AC_TRY_RUN([
 695 main()
 696 {
 697     char buf[4096];
 698     int r1 = tgetent(buf, "!@#$%^&*");
 699     int r2 = tgetent(buf, "vt100");
 700     if (r1 < 0 && r2 == 0) {
 701         char tbuf[1024], *u;
 702         u = tbuf;
 703         tgetstr("cl", &u);
 704         creat("conftest.tgetent0", 0640);
 705     }
 706     exit(r1 == r2);
 707 }
 708 ],
 709   if test -f conftest.tgetent0; then
 710     nmh_cv_func_tgetent_zero_success=yes
 711   else
 712     nmh_cv_func_tgetent_zero_success=no
 713   fi,
 714   nmh_cv_func_tgetent_zero_success=no,
 715   nmh_cv_func_tgetent_zero_success=no)])
 716 AH_TEMPLATE([TGETENT_SUCCESS],
 717 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 718 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 719   AC_DEFINE(TGETENT_SUCCESS, 0)
 720 else
 721   AC_DEFINE(TGETENT_SUCCESS, 1)
 722 fi
 723
 724 dnl Now put the libraries back to what it was before we
 725 dnl starting checking the termcap library.
 726 LIBS="$nmh_save_LIBS"
 727
 728 dnl --------------
 729 dnl CHECK TYPEDEFS
 730 dnl --------------
 731 AC_TYPE_PID_T
 732 AC_TYPE_OFF_T
 733 AC_TYPE_UID_T
 734 AC_TYPE_MODE_T
 735 AC_TYPE_SIZE_T
 736
 737 dnl ----------------
 738 dnl CHECK STRUCTURES
 739 dnl ----------------
 740
 741 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 742 dnl (FreeBSD has a timezone() function but not a timezone global
 743 dnl variable that is visible).
 744 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 745
 746 AC_STRUCT_DIRENT_D_TYPE
 747
 748 dnl Where is <signal.h> located?  Needed as input for signames.awk
 749 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 750 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 751                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 752                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 753                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 754                  /usr/include/sys/signal.h      dnl Almost everybody else
 755                  /dev/null;                     dnl Just in case we fall through
 756 do
 757   test -f $SIGNAL_H && \
 758   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 759   break
 760 done
 761 nmh_cv_path_signal_h=$SIGNAL_H
 762 ])
 763 SIGNAL_H=$nmh_cv_path_signal_h
 764 AC_SUBST(SIGNAL_H)dnl
 765
 766 dnl
 767 dnl Sigh, this is required because under the new world order autoconf has
 768 dnl nothing to create in a few of the build directories when doing an object
 769 dnl tree build.  So make sure we created certain directories if they don't
 770 dnl exist.
 771 dnl
 772
 773 AC_CONFIG_COMMANDS([build-directories],
 774 [test -d etc || ${MKDIR_P} etc
 775 test -d man || ${MKDIR_P} man])
 776
 777 AC_CONFIG_COMMANDS_POST([
 778
 779 dnl These odd looking assignments are done to expand out unexpanded
 780 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 781 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 782 dnl again to get the final answer.
 783 dnl We only use the expanded versions to print the install paths in
 784 dnl the final summary and should use them nowhere else (see the autoconf
 785 dnl docs for the rationale for bindir etc being unexpanded).
 786 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 787 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 788 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 789 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 790 eval "nmhrpm=${nmhrpm}";
 791
 792 AC_MSG_NOTICE([
 793 nmh configuration
 794 -----------------
 795 nmh version                : AC_PACKAGE_VERSION
 796 host os                    : ${host}
 797 compiler                   : ${CC}
 798 compiler flags             : ${CFLAGS}
 799 linker flags               : ${LDFLAGS}
 800 preprocessor flags         : ${CPPFLAGS}
 801 source code location       : ${srcdir}
 802 binary install path        : ${nmhbin}
 803 library install path       : ${nmhlib}
 804 config files install path  : ${nmhsysconf}
 805 man page install path      : ${nmhman}
 806 RPM build root             : ${nmhrpm}
 807 backup prefix              : ${backup_prefix}
 808 transport system           : ${MTS}
 809 file locking type          : ${LOCKTYPE}
 810 default smtp servers       : ${smtpservers}
 811 default editor             : ${editorpath}
 812 default pager              : ${pagerpath}
 813 SASL support               : ${sasl_support}
 814 TLS support                : ${tls_support}
 815 ])])dnl
 816
 817 dnl ---------------
 818 dnl OUTPUT MAKEFILE
 819 dnl ---------------
 820 AC_CONFIG_FILES([Makefile test/common.sh])
 821 AC_OUTPUT