diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want to disable use of locale functions
  32 AH_TEMPLATE([LOCALE],
  33 [Undefine if you don't want locale features.  By default this is defined.])
  34 AC_ARG_ENABLE([locale],
  35   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  36   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  37   [AC_DEFINE(LOCALE)])
  38
  39 dnl Do you want client-side support for using SASL for authentication?
  40 dnl Note that this code will be enabled for both POP and SMTP
  41 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  42   [Enable SASL support via the Cyrus SASL library]))
  43 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  44       AC_DEFINE([CYRUS_SASL], [1],
  45                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  46       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  47             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  48             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  49       sasl_support=yes], [sasl_support=no])
  50
  51 dnl Do you want client-side support for encryption with TLS?
  52 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  53 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  54       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  55       tls_support=yes],[tls_support=no])
  56
  57 dnl Set the backup prefix
  58 AC_ARG_WITH([hash-backup],
  59   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  60 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  61       [backup_prefix="#"], [backup_prefix=","])
  62 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  63     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  64
  65 dnl What method of posting should post use?
  66 AC_ARG_WITH([mts],
  67   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  68   [specify the default mail transport agent/service]))
  69
  70 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  71       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  72       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  73       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  74       [MTS="smtp"])
  75 AC_SUBST([MTS])dnl
  76
  77 dnl What should be the default mail server(s)?
  78 AC_ARG_WITH([smtpservers],
  79   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  80   [specify the default SMTP server(s) @<:@localhost@:>@])])
  81 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  82       [smtpservers="localhost"])
  83 AC_SUBST([smtpservers])dnl
  84
  85 dnl ----------------------------------------------------
  86 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
  87 dnl ----------------------------------------------------
  88 AC_PREFIX_DEFAULT([/usr/local/nmh])
  89
  90 dnl ------------------
  91 dnl CHECK THE COMPILER
  92 dnl ------------------
  93 dnl We want these before the checks,
  94 dnl so the checks can modify their values.
  95 test -z "$CFLAGS"  &&  auto_cflags=1
  96
  97 AC_PROG_CC([cc gcc])
  98 AM_PROG_CC_C_O
  99
 100 dnl ----------------
 101 dnl CUSTOMIZE CFLAGS
 102 dnl ----------------
 103 if test -n "$auto_cflags"; then
 104   dnl The user didn't specify CFLAGS, so customize them.
 105   if test "$GCC" = yes; then
 106     dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 107     dnl version 2.763, because it disables some features in the system
 108     dnl header files and warns about them with -Wall.  Try to test for
 109     dnl that generally, with gcc.
 110     AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 111       [nmh_saved_cppflags="$CPPFLAGS"
 112        nmh_saved_cflags="$CFLAGS"
 113        CPPFLAGS="-D_GNU_SOURCE"
 114        CFLAGS="-ansi -Wall -Werror"
 115        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 116          [nmh_cv_has_dash_ansi=yes],
 117          [nmh_cv_has_dash_ansi=no])
 118        CPPFLAGS="$nmh_saved_cppflags"
 119        CFLAGS="$nmh_saved_cflags"])
 120     test "$nmh_cv_has_dash_ansi" = "yes"  &&  \
 121       CFLAGS="${CFLAGS:+$CFLAGS }-ansi -pedantic"
 122   else
 123     dnl Use -v and some other options with SunStudio cc.  lex produces
 124     dnl code that causes unreachable-statement warnings.  It might be
 125     dnl better to use an autoconf test, except -v will probably succeed
 126     dnl with many other compilers but have different meaning.
 127     AS_CASE([`${CC} -V 2>&1`],
 128             [cc:\ Sun\ C*], [CFLAGS=\
 129 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 130   fi
 131
 132   AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 133                  [nmh_saved_cflags="$CFLAGS"
 134                  CFLAGS="$CFLAGS -Wall -Werror"
 135                  AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 136                  CFLAGS="$nmh_saved_cflags"])
 137   test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 138
 139   dnl for Ubuntu
 140   AC_CACHE_CHECK([whether compiler supports -Wno-unused-result],
 141                  [nmh_cv_has_wnur],
 142                  [nmh_saved_cflags="$CFLAGS"
 143                  CFLAGS="$CFLAGS -Wno-unused-result -Werror"
 144                  AC_TRY_COMPILE([],[],nmh_cv_has_wnur=yes,nmh_cv_has_wnur=no)
 145                  CFLAGS="$nmh_saved_cflags"])
 146   test "$nmh_cv_has_wnur" = "yes"  && \
 147     CFLAGS="${CFLAGS:+$CFLAGS }-Wno-unused-result"
 148
 149   AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 150                  [nmh_saved_cflags="$CFLAGS"
 151                  CFLAGS="$CFLAGS -Wextra -Werror"
 152                  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 153                                 nmh_cv_has_wextra=no)
 154                  CFLAGS="$nmh_saved_cflags"])
 155   test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 156 fi
 157
 158 dnl --------------
 159 dnl CUSTOMIZE LINK
 160 dnl --------------
 161 if test `uname` = OpenBSD; then
 162   dnl Filter out "often/almost always misused" warnings from OpenBSD linker.
 163   [POSTLINK="2>&1 | egrep -v ': [w]arning: s[a-z]+\(\) is \
 164 (almost always|often) misused, please use' || true"]
 165 fi
 166 AC_SUBST([POSTLINK])
 167
 168 dnl -----------------
 169 dnl CUSTOMIZE LDFLAGS
 170 dnl -----------------
 171 dnl Disable clang complaint about unused -ansi when linking.
 172 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 173                [nmh_cv_has_q_unused_arguments],
 174                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 175                        grep clang >/dev/null`],
 176                       [nmh_saved_ldflags="$LDFLAGS"
 177                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 178                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 179                                          nmh_cv_has_q_unused_arguments=no)
 180                        LDFLAGS="$nmh_saved_ldflags"],
 181                        [nmh_cv_has_q_unused_arguments=no])])
 182 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 183   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 184
 185 dnl This hack turns off assertions by default, assuming
 186 dnl that configure still uses this shell variable.  Without
 187 dnl it, AC_HEADER_ASSERT enables assertions by default.
 188 test -z "$enable_assert"  &&  enable_assert=no
 189
 190 AC_HEADER_ASSERT
 191
 192 dnl ------------------
 193 dnl CHECK FOR PROGRAMS
 194 dnl ------------------
 195 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 196 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 197 AC_PROG_RANLIB          dnl Check for `ranlib'
 198 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 199 AC_PROG_SED             dnl Check for Posix-compliant sed
 200 AM_PROG_LEX             dnl Check for lex/flex
 201
 202 AM_PROG_AR
 203
 204 dnl Look for `cut'
 205 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 206 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 207
 208 dnl
 209 dnl Check for MD5 program and formatting command
 210 dnl
 211 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 212 AS_CASE(["${MD5SUM}"],
 213         [md5sum], [MD5FMT="cat"],
 214         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 215         [MD5FMT="missing"])
 216 AC_SUBST([MD5FMT])
 217
 218 dnl Look for `ls'
 219 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 220 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 221
 222 dnl See how we get ls to display the owner and the group
 223 AS_IF([test "$lspath" != "no"],
 224   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 225                  [nmh_cv_ls_grpopt],
 226   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 227     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 228     dnl ls, it would seem -l gave us both the user and group.  On this type of
 229     dnl ls, -g makes _only_ the group be displayed (and not the user).
 230     nmh_cv_ls_grpopt="-l"],[
 231     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 232     nmh_cv_ls_grpopt="-lg"])])])
 233
 234 dnl Look for `sendmail'
 235 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 236 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 237
 238 dnl Cygwin FAT filesystems do not support hard links.  So default to
 239 dnl cp instead, even if running on an NTFS or other filesystem.
 240 AS_CASE(["$host_os"],
 241   [cygwin*], [LN=cp],
 242   [LN=ln])
 243 AC_SUBST([LN])
 244
 245 dnl ----------------------------------------------------------
 246 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 247 dnl ----------------------------------------------------------
 248 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 249 [for mailspool in /var/mail        dnl
 250                   /var/spool/mail  dnl
 251                   /usr/spool/mail  dnl
 252                   /dev/null;       dnl Just in case we fall through
 253 do
 254   test -d $mailspool && break
 255 done
 256 nmh_cv_mailspool=$mailspool
 257 ])
 258 mailspool=$nmh_cv_mailspool
 259 AC_SUBST([mailspool])dnl
 260
 261 dnl See whether the mail spool directory is world-writable.
 262 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 263   AC_CACHE_CHECK(whether the mail spool is world-writable,
 264                  nmh_cv_mailspool_world_writable,
 265   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 266     nmh_cv_mailspool_world_writable=no
 267   else
 268     nmh_cv_mailspool_world_writable=yes
 269   fi])
 270 fi
 271
 272 dnl Also, check for liblockfile (as found on Debian systems)
 273 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 274
 275 dnl and whether its companion program dotlockfile is setgid
 276 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 277 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 278   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 279     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 280     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 281         nmh_cv_dotlockfile_setgid=yes
 282       else
 283         nmh_cv_dotlockfile_setgid=no
 284       fi])
 285   fi
 286 fi
 287
 288 dnl Provide a way for distcheck to disable setgid_mail via
 289 dnl DISTCHECK_CONFIGURE_FLAGS.
 290 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 291   [nmh_cv_dotlockfile_setgid=yes])
 292
 293 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 294 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 295 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 296   dnl do we really need both of these?
 297   AC_DEFINE([MAILGROUP],[1],
 298     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 299   SETGID_MAIL=1
 300 fi
 301 AC_SUBST([SETGID_MAIL])dnl
 302
 303 dnl Use ls to see which group owns the mail spool directory.
 304 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 305 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 306 ])
 307 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 308 AC_SUBST([MAIL_SPOOL_GRP])dnl
 309
 310 NMH_MIMETYPEPROC
 311
 312 dnl ------------------
 313 dnl CHECK HEADER FILES
 314 dnl ------------------
 315
 316 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 317 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 318 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 319 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 320 dnl declared; if so they should have an entry added to this case statement.
 321 dnl NB that we must define this on the compiler command line, not in config.h,
 322 dnl because it must be set before any system header is included and there's no
 323 dnl portable way to make sure that files generated by lex include config.h
 324 dnl before system header files.
 325
 326 AS_CASE(["$host_os"],
 327         [linux*],
 328         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 329           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 330                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 331
 332 AC_HEADER_TIOCGWINSZ
 333 AC_CHECK_HEADERS([fcntl.h langinfo.h wchar.h wctype.h sys/param.h \
 334                   sys/time.h sys/stream.h])
 335
 336 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 337   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 338 [[#if HAVE_SYS_STREAM_H
 339 #  include <sys/stream.h>
 340 #endif
 341 ]])
 342
 343 dnl ---------------
 344 dnl CHECK FUNCTIONS
 345 dnl ---------------
 346 AC_CHECK_FUNCS([wcwidth mbtowc nl_langinfo getutxent arc4random])
 347
 348 dnl Check for multibyte character set support
 349 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 350             "x$ac_cv_header_wctype_h" = "xyes" -a \
 351             "x$ac_cv_func_wcwidth" = "xyes" -a \
 352             "x$ac_cv_func_mbtowc" = "xyes"],
 353       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 354                  [Define to enable support for multibyte character sets.])
 355        MULTIBYTE_ENABLED=1],
 356       [MULTIBYTE_ENABLED=0])
 357 AC_SUBST([MULTIBYTE_ENABLED])
 358
 359 dnl -------------------
 360 dnl CHECK FOR LIBRARIES
 361 dnl -------------------
 362 dnl Checks for network libraries (nsl, socket)
 363 NMH_CHECK_NETLIBS
 364
 365 dnl Check for readline support
 366 NMH_READLINE
 367
 368 dnl Check the locking functions supported and what we should use by default
 369 NMH_LOCKING
 370
 371 dnl Check for iconv
 372 NMH_CHECK_ICONV
 373
 374 dnl Check for tputs() callback argument
 375 NMH_TPUTS_PUTC_ARG
 376
 377 termcap_curses_order="termcap curses ncurses"
 378 for lib in $termcap_curses_order; do
 379   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 380 done
 381 AC_SUBST([TERMLIB])dnl
 382 AS_IF([test "x$TERMLIB" = "x"],
 383       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a curses
 384 or ncurses library or package that you can install?])])
 385
 386 dnl --------------
 387 dnl CHECK FOR NDBM
 388 dnl --------------
 389
 390 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 391             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 392 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 393             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 394
 395 if test "$nmh_ndbm" = "autodetect"; then
 396   if test "$nmh_ndbmheader" != "autodetect"; then
 397     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 398   else
 399
 400     dnl There are at least four implementations of ndbm, and
 401     dnl several of those can be in different places at the whim
 402     dnl of the system integrator. A good summary of this mess
 403     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 404
 405     dnl Classic ndbm with no library required (eg NetBSD): try this
 406     dnl first so we don't accidentally link in a pointless but harmless
 407     dnl library in one of the later ndbm.h+libfoo tests:
 408     NMH_CHECK_NDBM(ndbm.h,,,
 409     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 410       NMH_CHECK_NDBM(db.h,db,,
 411     dnl Berkeley DBv1 emulating ndbm:
 412         NMH_CHECK_NDBM(ndbm.h,db,,
 413           NMH_CHECK_NDBM(ndbm.h,db1,,
 414     dnl Classic ndbm:
 415             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 416     dnl glibc2.1 systems put db1 in a subdir:
 417               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 418     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 419     dnl and possibly needing gbdm_compat library:
 420                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 421                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 422                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 423                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 424
 425   fi
 426 else
 427   dnl We don't really need to check that the user-specified values work,
 428   dnl but it is a convenience to the user to bomb out early rather than
 429   dnl after configure and half the compile process.
 430   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 431 fi
 432
 433 if test "$nmh_ndbm_found" = "no"; then
 434   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 435 else
 436   dnl Now export the lib/header to our makefile/config.h:
 437   if test x"$nmh_ndbmheader" != x; then
 438     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 439       [Define to the header containing the ndbm API prototypes.])
 440   fi
 441   if test x"$nmh_ndbm" != x; then
 442     NDBM_LIBS="-l$nmh_ndbm"
 443   else
 444     NDBM_LIBS=
 445   fi
 446   AC_SUBST([NDBM_LIBS])
 447 fi
 448
 449 dnl ------------------
 450 dnl Set RPM build root
 451 dnl ------------------
 452 dnl nmhrpm is used in the final summary, see below.  The default value is
 453 dnl reported there as ./RPM, consistent with the reporting of the default
 454 dnl source code location as ., but its absolute path is used in the Makefile.
 455 AC_ARG_WITH([rpmdir],
 456   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 457   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 458           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 459 AC_SUBST([rpmdir])
 460
 461
 462 dnl --------------------
 463 dnl CHECK FOR CYRUS-SASL
 464 dnl --------------------
 465
 466 AS_IF([test x"$sasl_support" = x"yes"],[
 467   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 468   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 469     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 470 AC_SUBST([SASLLIB])
 471
 472 dnl -----------------
 473 dnl CHECK FOR OPENSSL
 474 dnl -----------------
 475
 476 AS_IF([test x"$tls_support" = x"yes"],[
 477   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 478   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 479   dnl automatically append -lcrypto when linking with -lssl.
 480   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 481   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 482     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 483   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 484     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 485   [TLSLIB=])
 486 AC_SUBST([TLSLIB])
 487
 488 dnl ----------------
 489 dnl CHECK FLEX FIXUP
 490 dnl ----------------
 491 dnl Use LFLAGS make variable setting to work around bugs in flex
 492 dnl 2.5.36 that cause signed/unsigned mismatch,
 493 dnl http://sourceforge.net/p/flex/bugs/140/
 494 AS_IF([test "$LEX" = flex],
 495       [AS_CASE([`$LEX -V`],
 496                [flex\ 2.5.35], [LFLAGS=\
 497 '; sed -e "s/   int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@; true'],
 498                [flex\ 2.5.36], [LFLAGS=\
 499 '; sed -s "s/\( \)int i;/\1yy_size_t i;/" $@ >$.tmp && mv -f $@.tmp $@; true'])
 500        AC_SUBST([LFLAGS])])
 501
 502 dnl ----------------
 503 dnl CHECK STRUCTURES
 504 dnl ----------------
 505
 506 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 507 dnl (FreeBSD has a timezone() function but not a timezone global
 508 dnl variable that is visible).
 509 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 510
 511 AC_STRUCT_DIRENT_D_TYPE
 512
 513 dnl Where is <signal.h> located?  Needed as input for signames.awk
 514 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 515 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 516                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 517                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 518                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 519                  /usr/include/sys/signal.h      dnl Almost everybody else
 520                  /dev/null;                     dnl Just in case we fall through
 521 do
 522   test -f $SIGNAL_H && \
 523   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 524   break
 525 done
 526 nmh_cv_path_signal_h=$SIGNAL_H
 527 ])
 528 SIGNAL_H=$nmh_cv_path_signal_h
 529 AC_SUBST(SIGNAL_H)dnl
 530
 531 dnl
 532 dnl Sigh, this is required because under the new world order autoconf has
 533 dnl nothing to create in a few of the build directories when doing an object
 534 dnl tree build.  So make sure we created certain directories if they don't
 535 dnl exist.
 536 dnl
 537
 538 AC_CONFIG_COMMANDS([build-directories],
 539 [test -d man || AS_MKDIR_P([man])])
 540
 541 AC_CONFIG_COMMANDS_POST([
 542
 543 dnl These odd looking assignments are done to expand out unexpanded
 544 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 545 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 546 dnl again to get the final answer.
 547 dnl We only use the expanded versions to print the install paths in
 548 dnl the final summary and should use them nowhere else (see the autoconf
 549 dnl docs for the rationale for bindir etc being unexpanded).
 550 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 551 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 552 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 553 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 554 eval "nmhrpm=${nmhrpm}";
 555
 556 AC_MSG_NOTICE([
 557 nmh configuration
 558 -----------------
 559 nmh version                : AC_PACKAGE_VERSION
 560 host os                    : ${host}
 561 compiler                   : ${CC}
 562 compiler flags             : ${CFLAGS}
 563 linker flags               : ${LDFLAGS}
 564 preprocessor flags         : ${CPPFLAGS}
 565 source code location       : ${srcdir}
 566 binary install path        : ${nmhbin}
 567 library install path       : ${nmhlib}
 568 config files install path  : ${nmhsysconf}
 569 man page install path      : ${nmhman}
 570 RPM build root             : ${nmhrpm}
 571 backup prefix              : ${backup_prefix}
 572 transport system           : ${MTS}
 573 spool default locking type : ${with_locking}
 574 default smtp servers       : ${smtpservers}
 575 SASL support               : ${sasl_support}
 576 TLS support                : ${tls_support}
 577 ])])dnl
 578
 579 dnl ---------------
 580 dnl OUTPUT MAKEFILE
 581 dnl ---------------
 582 AC_CONFIG_FILES([Makefile test/common.sh])
 583 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 584 AC_OUTPUT