diplodocus.org Git - nmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.68])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall foreign serial-tests subdir-objects 1.12])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30
  31 dnl Do you want client-side support for using SASL for authentication?
  32 dnl Note that this code will be enabled for both POP and SMTP
  33 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  34   [Enable SASL support via the Cyrus SASL library]))
  35 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  36       AC_DEFINE([CYRUS_SASL], [1],
  37                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  38       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  39             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  40             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  41       sasl_support=yes], [sasl_support=no])
  42
  43 dnl Do you want client-side support for encryption with TLS?
  44 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  45 AS_IF([test x"$with_tls" != x"no"],[
  46       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  47       tls_support=yes],[tls_support=no])
  48
  49 dnl Set the backup prefix
  50 AC_ARG_WITH([hash-backup],
  51   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  52 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  53       [backup_prefix="#"], [backup_prefix=","])
  54 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  55     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  56
  57 dnl What method of posting should post use?
  58 AC_ARG_WITH([mts],
  59   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail/smtp|sendmail/pipe@:>@],
  60   [specify the default mail transport agent/service]))
  61
  62 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
  63       [test x"$with_mts" = x"sendmail"], [MTS="sendmail/smtp"],
  64       [test x"$with_mts" = x"sendmail/smtp"], [MTS="sendmail/smtp"],
  65       [test x"$with_mts" = x"sendmail/pipe"], [MTS="sendmail/pipe"],
  66       [MTS="smtp"])
  67 AC_SUBST([MTS])dnl
  68
  69 dnl What should be the default mail server(s)?
  70 AC_ARG_WITH([smtpservers],
  71   [AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
  72   [specify the default SMTP server(s) @<:@localhost@:>@])])
  73 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
  74       [smtpservers="localhost"])
  75 AC_SUBST([smtpservers])dnl
  76
  77 dnl -------------------------------------------------------------------
  78 dnl Default location is /usr/local/nmh/{bin,etc,libexec,man}, unless we
  79 dnl find an existing installation, in which case we use its location.
  80 dnl -------------------------------------------------------------------
  81 AC_PREFIX_DEFAULT([/usr/local/nmh])
  82 AC_PREFIX_PROGRAM([mhparam])
  83
  84 dnl ------------------
  85 dnl CHECK THE COMPILER
  86 dnl ------------------
  87
  88 AC_PROG_CC([cc gcc])
  89 AM_PROG_CC_C_O
  90
  91 dnl ----------------
  92 dnl CUSTOMIZE CFLAGS
  93 dnl ----------------
  94 dnl The user didn't specify CFLAGS, so customize them.
  95 if test "$GCC" != yes; then
  96   dnl Use -v and some other options with SunStudio cc.  lex produces
  97   dnl code that causes unreachable-statement warnings.  It might be
  98   dnl better to use an autoconf test, except -v will probably succeed
  99   dnl with many other compilers but have different meaning.
 100   AS_CASE([`${CC} -V 2>&1`],
 101           [cc:\ Sun\ C*], [CFLAGS=\
 102 "${CFLAGS:+$CFLAGS }-v -errtags=yes -erroff=E_STATEMENT_NOT_REACHED"])
 103 fi
 104
 105 AC_CACHE_CHECK([whether compiler supports -Wall], [nmh_cv_has_wall],
 106                [nmh_saved_cflags="$CFLAGS"
 107                CFLAGS="$CFLAGS -Wall -Werror"
 108                AC_TRY_COMPILE([],[],nmh_cv_has_wall=yes,nmh_cv_has_wall=no)
 109                CFLAGS="$nmh_saved_cflags"])
 110 test "$nmh_cv_has_wall" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wall"
 111
 112 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 113                [nmh_saved_cflags="$CFLAGS"
 114                CFLAGS="$CFLAGS -Wextra -Werror"
 115                AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,
 116                               nmh_cv_has_wextra=no)
 117                CFLAGS="$nmh_saved_cflags"])
 118 test "$nmh_cv_has_wextra" = "yes"  &&  CFLAGS="${CFLAGS:+$CFLAGS }-Wextra"
 119
 120 if test "$GCC" = yes; then
 121   dnl Do this regardless of auto_cflags value.
 122   dnl Enable _FORTIFY_SOURCE checking, which is supported by
 123   dnl gcc 4.1 and later, but only when optimization is enabled.
 124   dnl It shouldn't hurt with earlier versions because it's a cpp macro.
 125   dnl If the user configures with a CFLAGS that contains a -O flag
 126   dnl but then removes it a make time, they'll also have to remove
 127   dnl -D_FORTIFY_SOURCE from CPPFLAGS because it requires optimization.
 128   AS_CASE([$CFLAGS],
 129           [-O*|*' -O'*],[CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_FORTIFY_SOURCE=2"])
 130 fi
 131
 132 dnl FreeBSD needs a bit of magic to bring getline() into scope.
 133 dnl We do this here rather than in (say) h/mh.h because this macro must
 134 dnl be defined before <stdio.h> is pulled in.
 135 dnl
 136 dnl And while we're here, add the packages tree to the cpp and ld search
 137 dnl paths.  Note that FreeBSD's pkg(8) seems to be hardwired to use /usr/local.
 138 dnl If /usr/ports is installed, we use its idea of where things are installed,
 139 dnl otherwise we assume /usr/local.
 140
 141 AS_IF([test `uname` = FreeBSD],
 142         [CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_WITH_GETLINE"
 143          nmh_cv_freebsd_localbase=`echo '.include <bsd.port.mk>' \
 144                 | make -k -f /dev/stdin -V LOCALBASE 2>/dev/null | sed 1q`
 145          test -z "$nmh_cv_freebsd_localbase" && nmh_cv_freebsd_localbase=/usr/local
 146          CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-I$nmh_cv_freebsd_localbase/include"
 147          LDFLAGS="${LDFLAGS:+$LDFLAGS }-L$nmh_cv_freebsd_localbase/lib"
 148 ])
 149
 150 dnl --------------
 151 dnl CUSTOMIZE LINK
 152 dnl --------------
 153 AS_IF([test `uname` = OpenBSD],
 154       dnl Munge "often/almost always misused" warnings from OpenBSD linker
 155       dnl so that they don't color the waterfall.
 156       [POSTLINK="2>&1 | sed -e \
 157 's/: w\(arning: s.*() is .* misused, please use\)/: W\1/'"])
 158 AC_SUBST([POSTLINK])
 159
 160 dnl -----------------
 161 dnl CUSTOMIZE LDFLAGS
 162 dnl -----------------
 163 dnl Disable clang complaint about unused -ansi when linking.
 164 AC_CACHE_CHECK([whether linker supports -Qunused-arguments],
 165                [nmh_cv_has_q_unused_arguments],
 166                [AS_IF([test "$GCC" = yes  &&  `${CC} --version 2>&1 | \
 167                        grep clang >/dev/null`],
 168                       [nmh_saved_ldflags="$LDFLAGS"
 169                        LDFLAGS="$LDFLAGS -Qunused-arguments"
 170                        AC_TRY_LINK([],[],nmh_cv_has_q_unused_arguments=yes,
 171                                          nmh_cv_has_q_unused_arguments=no)
 172                        LDFLAGS="$nmh_saved_ldflags"],
 173                        [nmh_cv_has_q_unused_arguments=no])])
 174 test "$nmh_cv_has_q_unused_arguments" = "yes"  &&  \
 175   LDFLAGS="${LDFLAGS:+$LDFLAGS }-Qunused-arguments"
 176
 177 dnl This hack turns off assertions by default, assuming
 178 dnl that configure still uses this shell variable.  Without
 179 dnl it, AC_HEADER_ASSERT enables assertions by default.
 180 test -z "$enable_assert"  &&  enable_assert=no
 181
 182 AC_HEADER_ASSERT
 183
 184 dnl ------------------
 185 dnl CHECK FOR PROGRAMS
 186 dnl ------------------
 187 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 188 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 189 AC_PROG_RANLIB          dnl Check for `ranlib'
 190 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 191 AC_PROG_SED             dnl Check for Posix-compliant sed
 192 AC_PROG_YACC            dnl Check for yacc/bison
 193 AM_PROG_LEX             dnl Check for lex/flex
 194
 195 AM_PROG_AR
 196
 197 dnl Look for `cut'
 198 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 199 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 200
 201 dnl
 202 dnl Check for MD5 program and formatting command
 203 dnl
 204 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 205 AS_CASE(["${MD5SUM}"],
 206         [md5sum], [MD5FMT="cat"],
 207         [md5], [[MD5FMT="${SED} -e 's/MD5 *(.*) *= \([0-9a-f]*\)/\1/'"]],
 208         [MD5FMT="missing"])
 209 AC_SUBST([MD5FMT])
 210
 211 dnl Look for `ls'
 212 pathtmp=/usr/xpg4/bin:/usr/bin:/bin:/usr/local/bin:/usr/ucb
 213 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 214
 215 dnl See how we get ls to display the owner and the group
 216 AS_IF([test "$lspath" != "no"],
 217   [AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 218                  [nmh_cv_ls_grpopt],
 219   [AS_IF([test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"],[
 220     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 221     dnl ls, it would seem -l gave us both the user and group.  On this type of
 222     dnl ls, -g makes _only_ the group be displayed (and not the user).
 223     nmh_cv_ls_grpopt="-l"],[
 224     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 225     nmh_cv_ls_grpopt="-lg"])])])
 226
 227 dnl Look for `sendmail'
 228 pathtmp=/usr/sbin:/usr/lib:/usr/etc:/usr/ucblib:/usr/bin:/bin
 229 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 230
 231 dnl Cygwin FAT filesystems do not support hard links.  So default to
 232 dnl cp instead, even if running on an NTFS or other filesystem.
 233 AS_CASE(["$host_os"],
 234   [cygwin*], [LN=cp],
 235   [LN=ln])
 236 AC_SUBST([LN])
 237
 238 dnl ----------------------------------------------------------
 239 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 240 dnl ----------------------------------------------------------
 241 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 242 [for mailspool in /var/mail        dnl
 243                   /var/spool/mail  dnl
 244                   /usr/spool/mail  dnl
 245                   /dev/null;       dnl Just in case we fall through
 246 do
 247   test -d $mailspool && break
 248 done
 249 nmh_cv_mailspool=$mailspool
 250 ])
 251 mailspool=$nmh_cv_mailspool
 252 AC_SUBST([mailspool])dnl
 253
 254 dnl See whether the mail spool directory is world-writable.
 255 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 256   AC_CACHE_CHECK(whether the mail spool is world-writable,
 257                  nmh_cv_mailspool_world_writable,
 258   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 259     nmh_cv_mailspool_world_writable=no
 260   else
 261     nmh_cv_mailspool_world_writable=yes
 262   fi])
 263 fi
 264
 265 dnl Also, check for liblockfile (as found on Debian systems)
 266 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 267
 268 dnl and whether its companion program dotlockfile is setgid
 269 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 270 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 271   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 272     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 273     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 274         nmh_cv_dotlockfile_setgid=yes
 275       else
 276         nmh_cv_dotlockfile_setgid=no
 277       fi])
 278   fi
 279 fi
 280
 281 dnl Provide a way for distcheck to disable setgid_mail via
 282 dnl DISTCHECK_CONFIGURE_FLAGS.
 283 AS_IF([test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0],
 284   [nmh_cv_dotlockfile_setgid=yes])
 285
 286 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 287 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 288 if test x"$with_locking" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 289   dnl do we really need both of these?
 290   AC_DEFINE([MAILGROUP],[1],
 291     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 292   SETGID_MAIL=1
 293 fi
 294 AC_SUBST([SETGID_MAIL])dnl
 295
 296 dnl Use ls to see which group owns the mail spool directory.
 297 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 298 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 299 ])
 300 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 301 AC_SUBST([MAIL_SPOOL_GRP])dnl
 302
 303 NMH_MIMETYPEPROC
 304 NMH_MIMEENCODINGPROC
 305
 306 dnl ------------------
 307 dnl CHECK HEADER FILES
 308 dnl ------------------
 309
 310 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 311 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 312 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 313 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 314 dnl declared; if so they should have an entry added to this case statement.
 315 dnl NB that we must define this on the compiler command line, not in config.h,
 316 dnl because it must be set before any system header is included and there's no
 317 dnl portable way to make sure that files generated by lex include config.h
 318 dnl before system header files.
 319
 320 AS_CASE(["$host_os"],
 321         [linux*],
 322         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 323         CPPFLAGS="${CPPFLAGS:+$CPPFLAGS }-D_GNU_SOURCE"])
 324
 325 AC_HEADER_TIOCGWINSZ
 326 AC_CHECK_HEADERS([fcntl.h wchar.h wctype.h sys/param.h sys/time.h sys/stream.h])
 327
 328 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 329   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 330 [[#if HAVE_SYS_STREAM_H
 331 #  include <sys/stream.h>
 332 #endif
 333 ]])
 334
 335 dnl ---------------
 336 dnl CHECK FUNCTIONS
 337 dnl ---------------
 338 AC_CHECK_FUNCS([wcwidth mbtowc getutxent arc4random mkstemps])
 339
 340 dnl Check for multibyte character set support
 341 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 342             "x$ac_cv_header_wctype_h" = "xyes" -a \
 343             "x$ac_cv_func_wcwidth" = "xyes" -a \
 344             "x$ac_cv_func_mbtowc" = "xyes"],
 345       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 346                  [Define to enable support for multibyte character sets.])
 347        MULTIBYTE_ENABLED=1],
 348       [MULTIBYTE_ENABLED=0])
 349 AC_SUBST([MULTIBYTE_ENABLED])
 350
 351 dnl -------------------
 352 dnl CHECK FOR LIBRARIES
 353 dnl -------------------
 354 dnl Checks for network libraries (nsl, socket)
 355 NMH_CHECK_NETLIBS
 356
 357 dnl Check the locking functions supported and what we should use by default
 358 NMH_LOCKING
 359
 360 dnl Check for iconv
 361 NMH_CHECK_ICONV
 362
 363 dnl Check for tputs() callback argument
 364 NMH_TPUTS_PUTC_ARG
 365
 366 termcap_curses_order="termcap curses ncurses"
 367 for lib in $termcap_curses_order; do
 368   AC_CHECK_LIB([${lib}], [setupterm], [TERMLIB="-l$lib"; break])
 369 done
 370 AC_SUBST([TERMLIB])dnl
 371 AS_IF([test "x$TERMLIB" = "x"],
 372       [AC_MSG_FAILURE([Could not find setupterm in any library.  Is there a
 373 curses or ncurses library or package that you can install?])])
 374
 375 dnl Check for readline support
 376 NMH_READLINE
 377
 378 dnl --------------
 379 dnl CHECK FOR NDBM
 380 dnl --------------
 381
 382 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 383             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 384 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 385             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 386
 387 if test "$nmh_ndbm" = "autodetect"; then
 388   if test "$nmh_ndbmheader" != "autodetect"; then
 389     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 390   else
 391
 392     dnl There are at least four implementations of ndbm, and
 393     dnl several of those can be in different places at the whim
 394     dnl of the system integrator. A good summary of this mess
 395     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 396
 397     dnl Classic ndbm with no library required (eg NetBSD): try this
 398     dnl first so we don't accidentally link in a pointless but harmless
 399     dnl library in one of the later ndbm.h+libfoo tests:
 400     NMH_CHECK_NDBM(ndbm.h,,,
 401     dnl Berkeley DBv2 emulating ndbm: header in db.h, e.g., 32-bit Cygwin:
 402       NMH_CHECK_NDBM(db.h,db,,
 403     dnl Berkeley DBv1 emulating ndbm:
 404         NMH_CHECK_NDBM(ndbm.h,db,,
 405           NMH_CHECK_NDBM(ndbm.h,db1,,
 406     dnl Classic ndbm:
 407             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 408     dnl glibc2.1 systems put db1 in a subdir:
 409               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 410     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 411     dnl and possibly needing gbdm_compat library:
 412                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 413                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 414                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 415     dnl 64-bit Cygwin:
 416                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm,,
 417     dnl On Linux, libgdbm_compat.so loads libgdbm.so as well, so it doesn't
 418     dnl need to be explicit:
 419                         NMH_CHECK_NDBM(gdbm-ndbm.h,gdbm_compat)))))))))))
 420   fi
 421 else
 422   dnl We don't really need to check that the user-specified values work,
 423   dnl but it is a convenience to the user to bomb out early rather than
 424   dnl after configure and half the compile process.
 425   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 426 fi
 427
 428 if test "$nmh_ndbm_found" = "no"; then
 429   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 430 else
 431   dnl Now export the lib/header to our makefile/config.h:
 432   if test x"$nmh_ndbmheader" != x; then
 433     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 434       [Define to the header containing the ndbm API prototypes.])
 435   fi
 436   if test x"$nmh_ndbm" != x; then
 437     NDBM_LIBS="-l$nmh_ndbm"
 438   else
 439     NDBM_LIBS=
 440   fi
 441   AC_SUBST([NDBM_LIBS])
 442 fi
 443
 444 dnl ------------------
 445 dnl Set RPM build root
 446 dnl ------------------
 447 dnl nmhrpm is used in the final summary, see below.  The default value is
 448 dnl reported there as ./RPM, consistent with the reporting of the default
 449 dnl source code location as ., but its absolute path is used in the Makefile.
 450 AC_ARG_WITH([rpmdir],
 451   [AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@])])
 452   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 453           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 454 AC_SUBST([rpmdir])
 455
 456
 457 dnl --------------------
 458 dnl CHECK FOR CYRUS-SASL
 459 dnl --------------------
 460
 461 AS_IF([test x"$sasl_support" = x"yes"],[
 462   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 463   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 464     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 465 AC_SUBST([SASLLIB])
 466
 467 dnl -----------------
 468 dnl CHECK FOR OPENSSL
 469 dnl -----------------
 470
 471 AS_IF([test x"$tls_support" = x"yes"],[
 472   dnl OpenBSD 5 needs the other-libraries (fourth argument) to the
 473   dnl AC_CHECK_LIB for SSL_library_init, because it doesn't
 474   dnl automatically append -lcrypto when linking with -lssl.
 475   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 476   AC_CHECK_LIB([crypto], [BIO_write], [TLSLIB="-lcrypto"],
 477     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 478   AC_CHECK_LIB([ssl], [SSL_library_init], [TLSLIB="-lssl $TLSLIB"],
 479     [AC_MSG_ERROR([OpenSSL library not found])],[$TLSLIB])],
 480   [TLSLIB=])
 481 AC_SUBST([TLSLIB])
 482
 483 dnl ----------------
 484 dnl CHECK FLEX FIXUP
 485 dnl ----------------
 486 dnl Use LFLAGS make variable setting to work around bugs in flex
 487 dnl 2.5.36-37 that cause signed/unsigned mismatch,
 488 dnl http://sourceforge.net/p/flex/bugs/140/
 489 AS_IF([test "$LEX" = flex],
 490       [AS_CASE([`$LEX -V`],
 491                [flex\ 2.5.35], [LFLAGS=\
 492 '; sed "s/      int n;/ size_t n;/" $@ >$@.tmp && mv -f $@.tmp $@'],
 493                [flex\ 2.5.3[[67]]], [LFLAGS=\
 494 '; sed "s/\(    \)int i;/\1yy_size_t i;/" $@ >$@.tmp && mv -f $@.tmp $@'])
 495        AC_SUBST([LFLAGS])])
 496
 497 dnl ------------------
 498 dnl FOR INTERNAL USE by the NMH test suite
 499 dnl ------------------
 500 AC_ARG_VAR([NMHETCDIRINST], [for internal use by nmh test suite])
 501 AS_IF([test -n "$NMHETCDIRINST"], [nmhetcdirinst=$NMHETCDIRINST]
 502       AC_SUBST([nmhetcdirinst]))
 503
 504 dnl ----------------
 505 dnl CHECK STRUCTURES
 506 dnl ----------------
 507
 508 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 509 dnl (FreeBSD has a timezone() function but not a timezone global
 510 dnl variable that is visible).
 511 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 512
 513 AC_STRUCT_DIRENT_D_TYPE
 514
 515 dnl Where is <signal.h> located?  Needed as input for signames.awk
 516 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 517 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 518                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 519                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 520                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 521                  /usr/include/sys/signal.h      dnl Almost everybody else
 522                  /dev/null;                     dnl Just in case we fall through
 523 do
 524   test -f $SIGNAL_H && \
 525   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 526   break
 527 done
 528 nmh_cv_path_signal_h=$SIGNAL_H
 529 ])
 530 SIGNAL_H=$nmh_cv_path_signal_h
 531 AC_SUBST(SIGNAL_H)dnl
 532
 533 dnl
 534 dnl Sigh, this is required because under the new world order autoconf has
 535 dnl nothing to create in a few of the build directories when doing an object
 536 dnl tree build.  So make sure we created certain directories if they don't
 537 dnl exist.
 538 dnl
 539
 540 AC_CONFIG_COMMANDS([build-directories],
 541 [test -d man || AS_MKDIR_P([man])])
 542
 543 AC_CONFIG_COMMANDS_POST([
 544
 545 dnl These odd looking assignments are done to expand out unexpanded
 546 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 547 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 548 dnl again to get the final answer.
 549 dnl We only use the expanded versions to print the install paths in
 550 dnl the final summary and should use them nowhere else (see the autoconf
 551 dnl docs for the rationale for bindir etc being unexpanded).
 552 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 553 eval "nmhlibexec=${libexecdir}"; eval "nmhlibexec=${nmhlibexec}"
 554 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 555 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 556 eval "nmhdoc=${docdir}";         eval "nmhdoc=${nmhdoc}"
 557 eval "nmhrpm=${nmhrpm}";
 558
 559 AC_MSG_NOTICE([
 560 nmh configuration
 561 -----------------
 562 nmh version                : AC_PACKAGE_VERSION
 563 host os                    : ${host}
 564 compiler                   : ${CC}
 565 compiler flags             : ${CFLAGS}
 566 linker flags               : ${LDFLAGS}
 567 preprocessor flags         : ${CPPFLAGS}
 568 source code location       : ${srcdir}
 569 binary install path        : ${nmhbin}
 570 libexec install path       : ${nmhlibexec}/nmh
 571 config files install path  : ${nmhsysconf}/nmh
 572 man page install path      : ${nmhman}
 573 docs install path          : ${nmhdoc}
 574 RPM build root             : ${nmhrpm}
 575 backup prefix              : ${backup_prefix}
 576 transport system           : ${MTS}
 577 spool default locking type : ${with_locking}
 578 default smtp servers       : ${smtpservers}
 579 SASL support               : ${sasl_support}
 580 TLS support                : ${tls_support}
 581 ])])dnl
 582
 583 dnl ---------------
 584 dnl OUTPUT MAKEFILE
 585 dnl ---------------
 586 AC_CONFIG_FILES([Makefile test/common.sh])
 587 AC_CONFIG_FILES([uip/spost], [chmod +x uip/spost])
 588 AC_OUTPUT