diplodocus.org Git - flac-archive/blob - tags.pl

   1 package epg::flac::archive::tags;
   2
   3 =head1 NAME tags.pl
   4
   5 subroutines for tag processing
   6
   7 =head1 DESCRIPTION
   8
   9 TODO
  10
  11 =cut
  12
  13 # POSIX.1-2017, Base Definitions, 3.282  Portable Filename Character Set says
  14 #   [A-Za-z0-9._-]
  15 # https://pubs.opengroup.org/onlinepubs/9699919799/basedefs/V1_chap03.html#tag_03_282
  16
  17 # Flac tags (set with `flac -T fieldname=...`) are Vorbis comments.
  18 # https://www.xiph.org/vorbis/doc/v-comment.html#fieldnames field names we care about:
  19 # - TITLE - Track/Work name
  20 # - VERSION - may be used to differentiate multiple versions of the same track title in a single collection. (e.g. remix info)
  21 # - ALBUM - The collection name to which this track belongs
  22 # - TRACKNUMBER - The track number of this piece
  23 # - ARTIST - The artist generally considered responsible for the track
  24 # - DATE - Date the track was recorded (XXX I use US release date)
  25 # https://age.hobba.nl/audio/mirroredpages/ogg-tagging.html (supposedly mirrored from http://reactor-core.org/ogg-tagging.html )
  26 # specifies more:
  27 # - DISCNUMBER - if part of a multi-disc album, put the disc number here
  28 # - VERSION - e.g. "live", "radio edit"
  29 # - PARTNUMBER - part number if a work is divided across tracks
  30 # - PART - part name e.g. "Oh sole mio"
  31 # https://picard-docs.musicbrainz.org/en/appendices/tag_mapping.html
  32 # - ALBUMARTIST - maps to ID3v2 TPE2
  33
  34 # Input is a directory containing:
  35 # - trackNN.cdda.wav - WAV  format files ripped from CD-DA audio tracks where NN is track number 01 - 99
  36 # - tags - described below
  37 # - cover.front.jpeg - optional JPEG format file containing the album front cover
  38
  39 # The tags file is composed of two blocks:
  40 # 1. album tags
  41 # 2. track tags
  42 # Album tags may be:
  43 # - ALBUM
  44 # - ARTIST
  45 # - DATE
  46 # - DISCNUMBER (optional)
  47
  48 # Track tags may be any of the rest of the tags listed above, suffixed with
  49 # [N] where N is the track number.  ARTIST, and only ARTIST, may also appear
  50 # in the track tags.  In this case, it overrides the album artist.  In order
  51 # to add artists, the album artist must be listed again.  For example, Reba
  52 # McEntire's "The Heart Won't Lie" on the album "It's Your Call" features
  53 # Vince Gill, and is specified as:
  54 # ARTIST=Reba McEntire
  55 # ALBUM=It's Your Call
  56 # TITLE[5]=The Heart Won't Lie
  57 # ARTIST[5]=Reba McEntire
  58 # ARTIST[5]=Vince Gill
  59
  60 use v5.12;
  61 use warnings;
  62
  63 use Exporter 'import';
  64
  65 our @EXPORT_OK = qw[
  66     read_tags
  67     read_tags_metaflac
  68     disc_tags
  69     track_tags
  70
  71     mangle_for_file_name
  72     quote
  73     two_digits
  74 ];
  75
  76 sub two_digits {
  77     my $n = shift;
  78     my  $s = sprintf('%02d', $n);
  79     if (length($s) != 2) {
  80         die("$n won't fit into two digits")
  81     }
  82     $s
  83 }
  84
  85 sub read_tags {
  86     my $fh = shift;
  87     my %album;
  88     my @tracks;
  89     my $tracknum = 0;
  90     my $name;
  91     while (<$fh>) {
  92         chomp;
  93         if (!s/^([^=[\]]+)(\[(\d+)])?=//) {
  94             if (defined($name) && $name eq 'DESCRIPTION') {
  95                 # Qobuz offers FLAC files like this.
  96                 warn("looks like DESCRIPTION had multiple lines; discarding and returning early: $_");
  97                 last
  98             }
  99             die("no field name in:  $_");
 100         }
 101         $name = $1;
 102         # TODO validate $name
 103         # TODO album tags should be illegal after track tags
 104         if (defined($3)) {
 105             if ($3 == $tracknum + 2) {
 106                 $tracknum++;
 107             } elsif ($3 != $tracknum + 1) {
 108                 $tracknum++;    # increment from 0 to 1 for error message
 109                 die("illegal track number jump from $tracknum to $3")
 110             }
 111             push(@{$tracks[$tracknum]->{$name}}, $_);
 112         } else {
 113             push(@{$album{$name}}, $_);
 114         }
 115     }
 116
 117     \%album, \@tracks
 118 }
 119
 120 sub read_tags_metaflac {
 121     my $fn = shift;
 122     open(my $fh, '-|', 'metaflac', '--no-utf8-convert', '--export-tags-to=-', $fn) || die("metaflac: $!");
 123     my @result = read_tags($fh);
 124     if (!close($fh)) {
 125         if ($! == 0) {
 126             die("metaflac exited $?")
 127         }
 128         die("close(metaflac): $!")
 129     }
 130     @result
 131 }
 132
 133 sub one_or_undef {
 134     my $name = shift;
 135     my $tags = shift;
 136     my $tag = $tags->{$name};
 137     if (defined($tag) && @$tag > 0) {
 138         return $tag->[0]
 139     }
 140     undef
 141 }
 142
 143 sub one {
 144     my $tag = one_or_undef(@_);
 145     if (!defined($tag)) {
 146         my $name = shift;
 147         die("exactly one $name tag required")
 148     }
 149     $tag
 150 }
 151
 152 =over
 153
 154 =item B<disc_tags>
 155
 156 Interpret the tags hash for a disc, returning:
 157
 158 =over
 159
 160 =item *
 161 Artist tag (exactly one required in the hash).
 162
 163 =item *
 164 Album tag (exactly one required).
 165
 166 =item *
 167 Date tag (zero or one required).
 168
 169 =item *
 170 Disc number (zero or one required) as a reference to an array of size 0 or 1.
 171
 172 =back
 173 =cut
 174 sub disc_tags {
 175     my %tags = @_;
 176
 177     if (!defined($tags{ALBUM}) || @{$tags{ALBUM}} != 1) {
 178         die('exactly one ALBUM tag required')
 179     }
 180     my $album_tag = $tags{ALBUM}->[0];
 181
 182     # TODO ALBUMARTIST
 183     if (!defined($tags{ARTIST}) || @{$tags{ARTIST}} != 1) {
 184         die('exactly one ARTIST tag required')
 185     }
 186     my $artist = $tags{ARTIST}->[0];
 187
 188     my $date;
 189     if (defined($tags{DATE})) {
 190         if (@{$tags{DATE}} != 1) {
 191             die('one or zero DATE tags required')
 192         }
 193         $date = $tags{DATE}->[0];
 194     }
 195
 196     my @discnumber = ();
 197     if (defined($tags{DISCNUMBER})) {
 198         if (@{$tags{DISCNUMBER}} != 1) {
 199             die('one or zero DISCNUMBER tags required')
 200         }
 201         my ($discnum) = @{$tags{DISCNUMBER}};
 202         @discnumber = ($discnum);
 203         # But check it against DISCTOTAL if present.
 204         my $total = $tags{DISCTOTAL};
 205         if (defined($total) && @$total > 0) {
 206             my ($total) = @$total;
 207             if ($total < $discnum) {
 208                 die("DISCNUMBER=$discnum > DISCTOTAL=$total")
 209             }
 210             if ($total == 1) {
 211                 # Qobuz offers FLAC files like this.
 212                 @discnumber = ();
 213             }
 214         }
 215     }
 216
 217     $artist, $album_tag, $date, \@discnumber
 218 }
 219
 220 # TODO dedup with flac2mp3
 221 sub track_tags {
 222     my $tags = shift;
 223     # TODO probably ought to return hash too.  then track_tags would augment
 224     my ($artist, $album, $date, $discnumber) = disc_tags(%$tags);
 225
 226         # TODO resurrect whole-disc FLAC?
 227         # Stupid hack: only a single-track file should have the
 228         # TRACKNUMBER tag, so use it if set for the first pass through
 229         # the loop.  At the end of the loop, we'll set $track for the
 230         # next run, so this continues to work for multi-track files.
 231                 # if track == None:
 232                 #     track = 1
 233                 # else:
 234                 #     track = int(track)
 235
 236     my $tracknumber = epg::flac::archive::tags::one(TRACKNUMBER => $tags);
 237     my $title = epg::flac::archive::tags::one(TITLE => $tags);
 238     # TODO restore PARTNUMBER and VERSION next time i need them
 239
 240     (
 241      artist => $artist,
 242      album => $album,
 243      date => $date,
 244      discnumber => $discnumber,
 245      tracknumber => $tracknumber,
 246      title => $title,
 247     )
 248 }
 249
 250 sub mangle_for_file_name {
 251     my $fn = shift;
 252     $fn =~ s/[!,.?]//g;          # discard these punctuation marks
 253     $fn =~ s/\s+/_/g;            # replace all whitespace with _
 254     $fn =~ s/[^A-Za-z0-9_]/-/g;  # everything else with -
 255     $fn =~ s/_[_-]/_/g;          # collapse repeated _ or - to _
 256     $fn =~ s/-[_-]/_/g;          # more
 257     $fn =~ s/^[_-]+//;           # discard any _ or - at beginning
 258     $fn =~ s/[_-]+$//;           # at end too
 259     $fn
 260 }
 261
 262 sub quote {
 263     my $s = shift;
 264     $s =~ s/'/'\\''/g;
 265     "'$s'"
 266 }
 267
 268 =back
 269
 270 =cut
 271
 272 1;