diplodocus.org Git - flac-archive/blob - fa-rip

   1 #! /usr/bin/env perl
   2
   3 # $Id$
   4 # $URL$
   5
   6 =head1 NAME
   7
   8 B<fa-rip> - rip a CD for B<fa-flacd>
   9
  10 =head1 SYNOPSIS
  11
  12 B<fa-rip> [B<-d> I<device>] [B<-p> I<post-processor> [B<-t> I<track-count>]
  13
  14 =cut
  15
  16 use strict;
  17 use warnings;
  18
  19 use Env qw(
  20            CDDEV
  21 );
  22
  23 use Fcntl qw(O_CREAT O_WRONLY);
  24 use File::Temp;
  25 use Getopt::Long qw(:config gnu_getopt no_ignore_case);
  26 use List::Util qw(min);
  27 use POSIX ':sys_wait_h';
  28 use Pod::Usage;
  29
  30 use MusicBrainz::Client;
  31 use MusicBrainz::Queries qw(
  32                             MBQ_GetCDTOC
  33                             MBE_TOCGetFirstTrack
  34                             MBE_TOCGetLastTrack
  35                             MBE_TOCGetTrackSectorOffset
  36 );
  37 use MusicBrainz::Client::Simple;
  38
  39 sub mkcue {
  40     my $device = shift;
  41     my $trackcount = shift;
  42
  43     my $mb = MusicBrainz::Client->new;
  44     defined($device) and $mb->set_device($device);
  45
  46     $mb->query(MBQ_GetCDTOC) or die($mb->get_query_error);
  47
  48     open(my $fh, '>cue') or die("open('>cue'): $!");
  49     print($fh "FILE \"dummy.wav\" WAVE\n");
  50     print($fh "  TRACK 01 AUDIO\n");
  51     print($fh "    INDEX 01 00:00:00\n");
  52
  53     my $first = $mb->get_result_data(MBE_TOCGetFirstTrack) + 1;
  54     $trackcount = min($trackcount, $mb->get_result_data(MBE_TOCGetLastTrack));
  55     # There is frequently (always?) an offset of 150 sectors, so
  56     # we'll subtract this offset from each track offset.
  57     my $something = $mb->get_result_data1(MBE_TOCGetTrackSectorOffset, 2);
  58
  59     for my $track ($first .. $trackcount) {
  60         my $off = $mb->get_result_data1(MBE_TOCGetTrackSectorOffset, $track+1);
  61         $off -= $something;
  62
  63         my ($minutes,$seconds)=(0,0);
  64         my $sectors = $off % 75;
  65         if ($off >= 75) {
  66             $seconds = $off / 75;
  67             if ($seconds >= 60) {
  68                 $minutes = $seconds / 60;
  69                 $seconds = $seconds % 60;
  70             }
  71         }
  72
  73         printf($fh "  TRACK %02d AUDIO\n", $track);
  74         printf($fh "    INDEX 01 %02d:%02d:%02d\n",
  75                $minutes, $seconds, $sectors);
  76     }
  77
  78     close($fh) or die("close(>cue): $!");
  79
  80     return $trackcount;
  81 }
  82
  83 sub tags_file {
  84     my $fn = shift;
  85     my $trackcount = shift;
  86     my $various = shift;
  87     my $artist = shift;
  88     my $album = shift;
  89     my $release_dates = shift;
  90     my $fh;
  91     my $i;
  92     my $track;
  93     my $name;
  94
  95     open($fh, '>', $fn) or die("open('>$fn'): $!");
  96     print($fh 'ARTIST=', (defined($artist) and $artist or ''), "\n");
  97     print($fh 'ALBUM=', (defined($album) and $album or ''), "\n");
  98
  99     if (defined($release_dates) and %$release_dates) {
 100         while (my ($country, $date) = each(%$release_dates)) {
 101             print($fh "DATE[$country]=$date\n");
 102         }
 103     } else {
 104         print($fh "DATE=\n");
 105     }
 106
 107     for $i (1 .. $trackcount) {
 108         $various and print($fh "ARTIST[$i]=\n");
 109         if ($track = shift(@_)) {
 110             $name = $track->get_name;
 111         } else {
 112             $name = '';
 113         }
 114         print($fh "TITLE[$i]=$name\n");
 115     }
 116
 117     close($fh) or die("close(>$fn): $!");
 118 }
 119
 120 sub tags {
 121     my $device = shift;
 122     my $trackcount = shift;
 123     my $mb;
 124     my @results;
 125     my $album;
 126     my $i;
 127     my $various;
 128     my $seen_various;
 129
 130     if (defined($device)) {
 131         $mb = new MusicBrainz::Client::Simple (device=>$device);
 132     } else {
 133         $mb = new MusicBrainz::Client::Simple;
 134     }
 135
 136     @results = $mb->lookup_cd;
 137     if (not $mb->success) {
 138         die($mb->get_error);
 139     }
 140
 141     tags_file('candidate-tags-0', $trackcount, 0);
 142
 143     for $album (@results) {
 144         $i++;
 145
 146         if ($various = $album->has_various_artists) {
 147             if (not $seen_various) {
 148                 $seen_various = 1;
 149                 tags_file('candidate-tags-0v', $trackcount, 1);
 150             }
 151         }
 152
 153         my %dates = $album->get_release_dates;
 154         tags_file("candidate-tags-$i", $trackcount, $various,
 155                   $album->get_artist->get_name, $album->get_name,
 156                   \%dates, $album->get_tracks);
 157     }
 158 }
 159
 160 sub rip {
 161     my $device = shift;
 162     my $trackcount = shift;
 163
 164     $device ||= '/dev/cdrom';
 165
 166     exec('cdparanoia', '-d', $device, "1-$trackcount", 'wav');
 167     # exec prints its own error message so just
 168     die;
 169 }
 170
 171 sub make_post_processor {
 172     my $command = shift;
 173
 174     defined($command) or return;
 175
 176     sysopen(F, 'post-processor', O_CREAT | O_WRONLY, 0555)
 177       or die("sysopen(post-processor, O_CREAT | O_WRONLY, 0555): $!");
 178     print(F $command, ' "$@"', "\n");
 179     close(F) or die("close(post-processor, O_CREAT | O_WRONLY, 0555): $!");
 180 }
 181
 182 MAIN: {
 183     my $post_processor;
 184     my $trackcount = 99;
 185     my $help;
 186     my $tempdir;
 187
 188     GetOptions(
 189                'device|d=s' => \$CDDEV,
 190                'post-processor|p=s', \$post_processor,
 191                'tracks|t=i' => \$trackcount,
 192                'help|h|?' => \$help,
 193               ) or pod2usage();
 194     $help and pod2usage(-exitstatus=>0, -verbose=>1);
 195
 196     # File::Temp::tempdir calls die on error.
 197     $tempdir = File::Temp::tempdir('flac-archive.XXXXXXXXXX');
 198     chdir($tempdir) or die("chdir($tempdir): $!");
 199
 200     make_post_processor($post_processor);
 201     $trackcount = mkcue($CDDEV, $trackcount);
 202     tags($CDDEV, $trackcount);
 203     rip($CDDEV, $trackcount);
 204 }
 205
 206 \f
 207 __END__
 208
 209 =head1 DESCRIPTION
 210
 211 B<fa-rip> creates a temporary directory for storage of its
 212 intermediate files, uses MusicBrainz to create the "cue" file and
 213 candidate tags files, and runs C<cdparanoia(1)> to rip the CD to the
 214 "wav" file.
 215
 216 In order for this CD to be processed by B<fa-flacd>, you must create a
 217 "tags" file.  This is usually done by renaming one of the
 218 candidate-tags files and deleting the others.  Don't forget to fill in
 219 the DATE tag in the selected candidate before renaming it.  If
 220 B<fa-rip> could not find any tag information from MusicBrainz, you'll
 221 have to fill out the candidate-tags-0 template.
 222
 223 =head1 OPTIONS
 224
 225 =over 4
 226
 227 =item B<-d> [B<--device>] I<device>
 228
 229 Use I<device> as the CD-ROM device, instead of the default
 230 "/dev/cdrom" or the environment variable CDDEV.
 231
 232 =item B<-p> [B<--post-processor>] I<post-processor>
 233
 234 Create a "post-processor" file in the temporary directory containing
 235 the line 'I<post-processor> "$@"'.  See B<fa-flacd>'s man page for
 236 information about this hook.
 237
 238 =item B<-t> [B<--tracks>] I<track-count>
 239
 240 Archive only the first I<track-count> tracks.  This is handy for
 241 ignoring data tracks.
 242
 243 =back
 244
 245 =head1 ENVIRONMENT
 246
 247 =over 4
 248
 249 =item CDDEV
 250
 251 B<fa-rip> uses this to rip audio and save the cuesheet for a CD.
 252 MusicBrainz::Client can usually figure this out automatically.
 253
 254 =back
 255
 256 =head1 AUTHORS
 257
 258 Written by Eric Gillespie <epg@pretzelnet.org>.
 259
 260 flac-archive is free software; you may redistribute it and/or modify
 261 it under the same terms as Perl itself.
 262
 263 =cut
 264
 265 # Local variables:
 266 # cperl-indent-level: 4
 267 # perl-indent-level: 4
 268 # indent-tabs-mode: nil
 269 # End:
 270
 271 # vi: set tabstop=4 expandtab: