diplodocus.org Git - flac-archive/blob - flac2mp3

   1 #! /usr/bin/env perl
   2
   3 # $Id$
   4
   5 =head1 NAME
   6
   7 B<flac2mp3> - transcode FLAC file to MP3 files
   8
   9 =head1 SYNOPSIS
  10
  11 B<flac2mp3> [B<--lame-options> I<lame-options>] [B<-q>] [B<-v>] I<file> [...]
  12
  13 =head1 DESCRIPTION
  14
  15 B<flac2mp3> transcodes the FLAC files I<file> to MP3 files.  I<file>
  16 may be the kind of FLAC file B<fa-flacd> generates.  That is, it
  17 contains a cue sheet, one TITLE tag per track listed therein, and
  18 ARTIST, ALBUM, and DATE tags.
  19
  20 =cut
  21
  22 use strict;
  23 use warnings;
  24
  25 use POSIX ':sys_wait_h';
  26 use Pod::Usage;
  27 use Getopt::Long qw(:config gnu_getopt no_ignore_case);
  28
  29 my $flac_options;
  30 my $lame_options;
  31 my $quiet;
  32 my $verbose;
  33
  34 sub run_or_die {
  35     my $command = shift;
  36     my $status;
  37
  38     $verbose and print(STDERR "$command\n");
  39     $status = system($command);
  40
  41     if (WIFEXITED($status)) {
  42         if (($status = WEXITSTATUS($status)) != 0) {
  43             die("$command exited with status $status");
  44         }
  45     } elsif (WIFSIGNALED($status)) {
  46         die("$command killed with signal ", WTERMSIG($status));
  47     } elsif (WIFSTOPPED($status)) {
  48         die("$command stopped with signal ", WSTOPSIG($status));
  49     } else {
  50         die("Major horkage on system($command): \$? = $? \$! = $!");
  51     }
  52 }
  53
  54 sub tformat {
  55     return sprintf('%02d:%02d.%02d', @_);
  56 }
  57
  58 sub get_decode_args {
  59     my $fn = shift;
  60     my @l;
  61
  62     open(F, '-|', 'metaflac', '--export-cuesheet-to=-', $fn);
  63     while (<F>) {
  64         /INDEX 01 (\d\d):(\d\d):(\d\d)$/ or next;
  65         push(@l, [$1, $2, $3]);
  66     }
  67
  68     my @args;
  69     for my $i (0..$#l) {
  70         my $arg = ["--skip=" . tformat(@{$l[$i]})];
  71         my $next = $l[$i+1];
  72         if (defined($next)) {
  73             if ($next->[2] == 0) {
  74                 if ($next->[1] == 0) {
  75                     push(@$arg, '--until=' . tformat($next->[0] - 1, 59, 74));
  76                 } else {
  77                     push(@$arg, '--until=' . tformat($next->[0], $next->[1] - 1,
  78                                                     74));
  79                 }
  80             } else {
  81                 push(@$arg, '--until=' . tformat($next->[0], $next->[1],
  82                                                 $next->[2] - 1));
  83             }
  84         }
  85         push(@args, $arg);
  86     }
  87
  88     # If no cue sheet, stick a dummy in here.
  89     if (@args == 0) {
  90         @args = ([]);
  91     }
  92
  93     return @args;
  94 }
  95
  96 # Return the ARTIST, ALBUM, and DATE tags followed by the TITLE tags
  97 # in the file FN.
  98 sub get_tags {
  99     my $fn = shift;
 100     my $artists = shift;
 101     my $titles = shift;
 102     my $tag;
 103     my $value;
 104     my $artist;
 105     my $album;
 106     my $date;
 107     my $track;
 108
 109     open(TAGS, '-|', 'metaflac', '--export-vc-to=-', $fn)
 110       or die("open(metaflac --export-vc-to=- $fn): $!");
 111     while (<TAGS>) {
 112         chomp;
 113
 114         ($tag, $value) = split(/=/, $_, 2);
 115
 116         if (/^ARTIST=/i) {
 117             $artist = $value;
 118         } elsif (/^ALBUM=/i) {
 119             $album = $value;
 120         } elsif (/^DATE=/i) {
 121             $date = $value;
 122         } elsif (/^ARTIST\[/i) {
 123             push(@$artists, $value);
 124         } elsif (/^TRACKNUMBER=/i) {
 125             $track = $value;
 126
 127         # Intentionally don't match the = on this one, to support the
 128         # TITLE[1] .. TITLE[n] tag style.
 129         } elsif (/^TITLE/i) {
 130             push(@$titles, $value);
 131         }
 132     }
 133     close(TAGS) or die("close(metaflac --export-vc-to=- $fn): $?");
 134
 135     return ($artist, $album, $date, $track);
 136 }
 137
 138 sub arg {
 139     my $arg = shift;
 140     my $var = shift;
 141
 142     if (defined($$var)) {
 143         $$var = "$arg '$$var'";
 144     } else {
 145         $$var = ''
 146     }
 147 }
 148
 149 sub flac2mp3 {
 150     my $fn = shift;
 151     my $title = shift;
 152     my $artist = shift;
 153     my $album = shift;
 154     my $date = shift;
 155     my $track = int(shift);
 156     my $skip_arg = shift;
 157     my $until_arg = shift;
 158     my @tmp;
 159     my $outfile;
 160
 161     if ($quiet) {
 162         $flac_options = '--silent';
 163     } else {
 164         $flac_options = '';
 165     }
 166
 167     if ($lame_options) {
 168         push(@tmp, $lame_options);
 169     } else {
 170         push(@tmp, '--preset standard');
 171     }
 172     $quiet and push(@tmp, '--quiet');
 173     $verbose and push(@tmp, '--verbose');
 174     $lame_options = join(' ', @tmp);
 175
 176     # We'll be putting these in single quotes, so we need to escape
 177     # any single quotes in the filename by closing the quote ('),
 178     # putting an escaped quote (\'), and then reopening the quote (').
 179     for ($fn, $title, $artist, $album, $date) {
 180         defined and s/'/'\\''/g;
 181     }
 182
 183     $outfile = sprintf("$artist ($album) \%02s $title.mp3", $track);
 184     $outfile =~ s/\//_/g;
 185
 186     arg('--tt', \$title);
 187     arg('--ta', \$artist);
 188     arg('--tl', \$album);
 189     arg('--ty', \$date);
 190     arg('--tn', \$track);
 191
 192     $skip_arg ||= '';
 193     $until_arg ||= '';
 194     run_or_die(join(' ', "flac $flac_options -cd $skip_arg $until_arg '$fn'",
 195                     " | lame $lame_options $title $artist $album $date $track",
 196                     " - '$outfile'"));
 197 }
 198
 199 MAIN: {
 200     my $help;
 201     GetOptions(
 202                'lame-options=s', \$lame_options,
 203                'quiet|q' => \$quiet,
 204                'verbose|v' => \$verbose,
 205                'help|h|?' => \$help,
 206               ) or pod2usage();
 207     $help and pod2usage(-exitstatus=>0, -verbose=>1);
 208
 209     @ARGV or pod2usage();
 210     for my $fn (@ARGV) {
 211         my @args = get_decode_args($fn);
 212         my (@artists, @titles);
 213         my ($artist, $album, $date, $track) = get_tags($fn, \@artists,
 214                                                        \@titles);
 215
 216         # Stupid hack: only a single-track file should have the
 217         # TRACKNUMBER tag, so use it if set for the first pass through
 218         # the loop.  At the end of the loop, we'll set $track for the
 219         # next run, so this continues to work for multi-track files.
 220         $track ||= 1;
 221
 222         for my $i (0..$#titles) {
 223             flac2mp3($fn, $titles[$i], ($artists[$i] or $artist), $album, $date,
 224                      $track, @{$args[$i]});
 225             $track = $i + 2;
 226         }
 227     }
 228 }
 229
 230 \f
 231 __END__
 232
 233 =head1 OPTIONS
 234
 235 =over 4
 236
 237 =item B<--lame-options> I<lame-options>
 238
 239 Pass I<lame-options> to B<lame>.  This ends up being passed to the
 240 shell, so feel free to take advantage of that.  You'll almost
 241 certainly have to put I<lame-options> in single quotes.
 242
 243 =item B<-q> [B<--quiet>]
 244
 245 Suppress status information.  This option is passed along to B<flac>
 246 and B<lame>.
 247
 248 =item B<-v> [B<--verbose>]
 249
 250 Print diagnostic information.  This option is passed along to B<flac>
 251 and B<lame>.
 252
 253 =back
 254
 255 =head1 AUTHORS
 256
 257 Written by Eric Gillespie <epg@pretzelnet.org>.
 258
 259 =cut
 260
 261 # Local variables:
 262 # cperl-indent-level: 4
 263 # perl-indent-level: 4
 264 # indent-tabs-mode: nil
 265 # End:
 266
 267 # vi: set tabstop=4 expandtab: