(get_tags): http://us.xiph.org/ogg/vorbis/doc/v-comment.html says the

[flac-archive] / flac2mp3

#! /usr/bin/env perl

# $Id$

=head1 NAME

B<flac2mp3> - transcode FLAC file to MP3 files

=head1 SYNOPSIS

B<flac2mp3> [B<--lame-options> I<lame-options>] [B<-q>] [B<-v>] I<file>

=head1 DESCRIPTION

B<flac2mp3> transcodes the FLAC file I<file> to MP3 files.  I<file> is
the kind of FLAC file B<fa-flacd> generates.  That is, it contains a
cue sheet, one TITLE tag per track listed therein, and ARTIST, ALBUM,
and DATE tags.

=cut

use strict;
use warnings;

use POSIX ':sys_wait_h';
use Pod::Usage;
use Getopt::Long qw(:config gnu_getopt no_ignore_case);

my $flac_options;
my $lame_options;
my $quiet;
my $verbose;

sub run_or_die {
    my $command = shift;
    my $status;

    $verbose and print(STDERR "$command\n");
    $status = system($command);

    if (WIFEXITED($status)) {
        if (($status = WEXITSTATUS($status)) != 0) {
            die("$command exited with status $status");
        }
    } elsif (WIFSIGNALED($status)) {
        die("$command killed with signal ", WTERMSIG($status));
    } elsif (WIFSTOPPED($status)) {
        die("$command stopped with signal ", WSTOPSIG($status));
    } else {
        die("Major horkage on system($command): \$? = $? \$! = $!");
    }
}

sub tformat {
    return sprintf('%02d:%02d.%02d', @_);
}

sub get_decode_args {
    my $fn = shift;
    my @l;

    open(F, '-|', 'metaflac', '--export-cuesheet-to=-', $fn);
    while (<F>) {
        /INDEX 01 (\d\d):(\d\d):(\d\d)$/ or next;
        push(@l, [$1, $2, $3]);
    }

    my @args;
    for my $i (0..$#l) {
        my $arg = ["--skip=" . tformat(@{$l[$i]})];
        my $next = $l[$i+1];
        if (defined($next)) {
            if ($next->[2] == 0) {
                if ($next->[1] == 0) {
                    push(@$arg, '--until=' . tformat($next->[0] - 1, 59, 74));
                } else {
                    push(@$arg, '--until=' . tformat($next->[0], $next->[1] - 1,
                                                    74));
                }
            } else {
                push(@$arg, '--until=' . tformat($next->[0], $next->[1],
                                                $next->[2] - 1));
            }
        }
        push(@args, $arg);
    }

    return @args;
}

# Return the ARTIST, ALBUM, and DATE tags followed by the TITLE tags
# in the file FN.
sub get_tags {
    my $fn = shift;
    my $artists = shift;
    my $titles = shift;
    my $tag;
    my $value;
    my $artist;
    my $album;
    my $date;

    open(TAGS, '-|', 'metaflac', '--export-vc-to=-', $fn)
      or die("open(metaflac --export-vc-to=- $fn): $!");
    while (<TAGS>) {
        chomp;

        ($tag, $value) = split(/=/, $_, 2);

        if (/^ARTIST=/i) {
            $artist = $value;
        } elsif (/^ALBUM=/i) {
            $album = $value;
        } elsif (/^DATE=/i) {
            $date = $value;
        } elsif (/^ARTIST\[/i) {
            push(@$artists, $value);

        # Intentionally don't match the = on this one, to support the
        # TITLE[1] .. TITLE[n] tag style.
        } elsif (/^TITLE/i) {
            push(@$titles, $value);
        }
    }
    close(TAGS) or die("close(metaflac --export-vc-to=- $fn): $?");

    return ($artist, $album, $date);
}

sub flac2mp3 {
    my $fn = shift;
    my $title = shift;
    my $artist = shift;
    my $album = shift;
    my $date = shift;
    my $track = shift;
    my $skip_arg = shift;
    my $until_arg = shift;
    my @tmp;
    my $outfile;

    if ($quiet) {
        $flac_options = '--silent';
    } else {
        $flac_options = '';
    }

    if ($lame_options) {
        push(@tmp, $lame_options);
    } else {
        push(@tmp, '--preset standard');
    }
    $quiet and push(@tmp, '--quiet');
    $verbose and push(@tmp, '--verbose');
    $lame_options = join(' ', @tmp);

    # We'll be putting these in single quotes, so we need to escape
    # any single quotes in the filename by closing the quote ('),
    # putting an escaped quote (\'), and then reopening the quote (').
    for ($fn, $title, $artist, $album, $date) {
        s/'/'\\''/g;
    }

    $outfile = sprintf("$artist ($album) \%02s $title.mp3", $track);
    $outfile =~ s/\//_/g;

    $until_arg ||= '';
    run_or_die(join(' ', "flac $flac_options -cd $skip_arg $until_arg '$fn'",
                    " | lame $lame_options --tt '$title' --ta '$artist'",
                    " --tl '$album' --ty '$date' --tn $track - '$outfile'"));
}

MAIN: {
    my $help;
    GetOptions(
               'lame-options=s', \$lame_options,
               'quiet|q' => \$quiet,
               'verbose|v' => \$verbose,
               'help|h|?' => \$help,
              ) or pod2usage();
    $help and pod2usage(-exitstatus=>0, -verbose=>1);

    my $fn = shift or pod2usage();
    my @args = get_decode_args($fn);
    my (@artists, @titles);
    my ($artist, $album, $date) = get_tags($fn, \@artists, \@titles);

    for my $i (0..$#titles) {
        flac2mp3($fn, $titles[$i], ($artists[$i] or $artist), $album, $date,
                 $i + 1, @{$args[$i]});
    }
}

\f
__END__

=head1 OPTIONS

=over 4

=item B<--lame-options> I<lame-options>

Pass I<lame-options> to B<lame>.  This ends up being passed to the
shell, so feel free to take advantage of that.  You'll almost
certainly have to put I<lame-options> in single quotes.

=item B<-q> [B<--quiet>]

Suppress status information.  This option is passed along to B<flac>
and B<lame>.

=item B<-v> [B<--verbose>]

Print diagnostic information.  This option is passed along to B<flac>
and B<lame>.

=back

=head1 AUTHORS

Written by Eric Gillespie <epg@pretzelnet.org>.

=cut

# Local variables:
# cperl-indent-level: 4
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:

# vi: set tabstop=4 expandtab: