diplodocus.org Git - flac-archive/blob - fa-rip

   1 #! /usr/bin/env perl
   2
   3 # $Id$
   4 # $URL$
   5
   6 =head1 NAME
   7
   8 B<fa-rip> - rip a CD for B<fa-flacd>
   9
  10 =head1 SYNOPSIS
  11
  12 B<fa-rip> [B<-d> I<device>] [B<-p> I<post-processor> [B<-t> I<track-count>]
  13
  14 =cut
  15
  16 use strict;
  17 use warnings;
  18
  19 use Env qw(
  20            CDDEV
  21 );
  22
  23 use Fcntl qw(O_CREAT O_WRONLY);
  24 use File::Temp;
  25 use Getopt::Long qw(:config gnu_getopt no_ignore_case);
  26 use List::Util qw(min);
  27 use POSIX ':sys_wait_h';
  28 use Pod::Usage;
  29
  30 use MusicBrainz::Client;
  31 use MusicBrainz::Queries qw(
  32                             MBQ_GetCDTOC
  33                             MBE_TOCGetFirstTrack
  34                             MBE_TOCGetLastTrack
  35                             MBE_TOCGetTrackSectorOffset
  36 );
  37 use MusicBrainz::Client::Simple;
  38
  39 sub mkcue {
  40     my $device = shift;
  41     my $trackcount = shift;
  42
  43     my $mb = MusicBrainz::Client->new;
  44     defined($device) and $mb->set_device($device);
  45
  46     $mb->query(MBQ_GetCDTOC) or die($mb->get_query_error);
  47
  48     open(my $fh, '>cue') or die("open('>cue'): $!");
  49     print($fh "FILE \"dummy.wav\" WAVE\n");
  50     print($fh "  TRACK 01 AUDIO\n");
  51     print($fh "    INDEX 01 00:00:00\n");
  52
  53     my $first = $mb->get_result_data(MBE_TOCGetFirstTrack) + 1;
  54     $trackcount = min($trackcount, $mb->get_result_data(MBE_TOCGetLastTrack));
  55     # There is frequently (always?) an offset of 150 sectors, so
  56     # we'll subtract this offset from each track offset.
  57     my $something = $mb->get_result_data1(MBE_TOCGetTrackSectorOffset, 2);
  58
  59     for my $track ($first .. $trackcount) {
  60         my $off = $mb->get_result_data1(MBE_TOCGetTrackSectorOffset, $track+1);
  61         $off -= $something;
  62
  63         my ($minutes,$seconds)=(0,0);
  64         my $sectors = $off % 75;
  65         if ($off >= 75) {
  66             $seconds = $off / 75;
  67             if ($seconds >= 60) {
  68                 $minutes = $seconds / 60;
  69                 $seconds = $seconds % 60;
  70             }
  71         }
  72
  73         printf($fh "  TRACK %02d AUDIO\n", $track);
  74         printf($fh "    INDEX 01 %02d:%02d:%02d\n",
  75                $minutes, $seconds, $sectors);
  76     }
  77
  78     close($fh) or die("close(>cue): $!");
  79
  80     return $trackcount;
  81 }
  82
  83 sub tags_file {
  84     my $fn = shift;
  85     my $trackcount = shift;
  86     my $various = shift;
  87     my $artist = shift;
  88     my $album = shift;
  89     my $release_dates = shift;
  90     my $fh;
  91     my $i;
  92     my $track;
  93     my $name;
  94
  95     open($fh, '>', $fn) or die("open('>$fn'): $!");
  96     print($fh 'ARTIST=', (defined($artist) and $artist or ''), "\n");
  97     print($fh 'ALBUM=', (defined($album) and $album or ''), "\n");
  98
  99     if (defined($release_dates) and %$release_dates) {
 100         while (my ($country, $date) = each(%$release_dates)) {
 101             print($fh "DATE[$country]=$date\n");
 102         }
 103     } else {
 104         print($fh "DATE=\n");
 105     }
 106
 107     for $i (1 .. $trackcount) {
 108         $various and print($fh "ARTIST[$i]=\n");
 109         if ($track = shift(@_)) {
 110             $name = $track->get_name;
 111         } else {
 112             $name = '';
 113         }
 114         print($fh "TITLE[$i]=$name\n");
 115     }
 116
 117     close($fh) or die("close(>$fn): $!");
 118 }
 119
 120 sub tags {
 121     my $device = shift;
 122     my $trackcount = shift;
 123     my $no_mb = shift;
 124     my $mb;
 125     my @results;
 126     my $album;
 127     my $i;
 128     my $various;
 129     my $seen_various;
 130
 131     tags_file('candidate-tags-0', $trackcount, 0);
 132
 133     defined($no_mb) and $no_mb and return;
 134
 135     if (defined($device)) {
 136         $mb = new MusicBrainz::Client::Simple (device=>$device);
 137     } else {
 138         $mb = new MusicBrainz::Client::Simple;
 139     }
 140
 141     @results = $mb->lookup_cd;
 142     if (not $mb->success) {
 143         die($mb->get_error);
 144     }
 145
 146     for $album (@results) {
 147         $i++;
 148
 149         if ($various = $album->has_various_artists) {
 150             if (not $seen_various) {
 151                 $seen_various = 1;
 152                 tags_file('candidate-tags-0v', $trackcount, 1);
 153             }
 154         }
 155
 156         my %dates = $album->get_release_dates;
 157         tags_file("candidate-tags-$i", $trackcount, $various,
 158                   $album->get_artist->get_name, $album->get_name,
 159                   \%dates, $album->get_tracks);
 160     }
 161 }
 162
 163 sub rip {
 164     my $device = shift;
 165     my $trackcount = shift;
 166
 167     $device ||= '/dev/cdrom';
 168
 169     exec('cdparanoia', '-d', $device, "1-$trackcount", 'wav');
 170     # exec prints its own error message so just
 171     die;
 172 }
 173
 174 sub make_post_processor {
 175     my $command = shift;
 176
 177     defined($command) or return;
 178
 179     sysopen(F, 'post-processor', O_CREAT | O_WRONLY, 0555)
 180       or die("sysopen(post-processor, O_CREAT | O_WRONLY, 0555): $!");
 181     print(F $command, ' "$@"', "\n");
 182     close(F) or die("close(post-processor, O_CREAT | O_WRONLY, 0555): $!");
 183 }
 184
 185 MAIN: {
 186     my $no_mb;
 187     my $post_processor;
 188     my $trackcount = 99;
 189     my $help;
 190     my $tempdir;
 191
 192     GetOptions(
 193                'device|d=s' => \$CDDEV,
 194                'no-musicbrainz|m' => \$no_mb,
 195                'post-processor|p=s', \$post_processor,
 196                'tracks|t=i' => \$trackcount,
 197                'help|h|?' => \$help,
 198               ) or pod2usage();
 199     $help and pod2usage(-exitstatus=>0, -verbose=>1);
 200
 201     # File::Temp::tempdir calls die on error.
 202     $tempdir = File::Temp::tempdir('flac-archive.XXXXXXXXXX');
 203     chdir($tempdir) or die("chdir($tempdir): $!");
 204
 205     make_post_processor($post_processor);
 206     $trackcount = mkcue($CDDEV, $trackcount);
 207     tags($CDDEV, $trackcount, $no_mb);
 208     rip($CDDEV, $trackcount);
 209 }
 210
 211 \f
 212 __END__
 213
 214 =head1 DESCRIPTION
 215
 216 B<fa-rip> creates a temporary directory for storage of its
 217 intermediate files, uses MusicBrainz to create the "cue" file and
 218 candidate tags files, and runs C<cdparanoia(1)> to rip the CD to the
 219 "wav" file.
 220
 221 In order for this CD to be processed by B<fa-flacd>, you must create a
 222 "tags" file.  This is usually done by renaming one of the
 223 candidate-tags files and deleting the others.  Don't forget to fill in
 224 the DATE tag in the selected candidate before renaming it.  If
 225 B<fa-rip> could not find any tag information from MusicBrainz, you'll
 226 have to fill out the candidate-tags-0 template.
 227
 228 =head1 OPTIONS
 229
 230 =over 4
 231
 232 =item B<-d> [B<--device>] I<device>
 233
 234 Use I<device> as the CD-ROM device, instead of the default
 235 "/dev/cdrom" or the environment variable CDDEV.
 236
 237 =item B<-p> [B<--post-processor>] I<post-processor>
 238
 239 Create a "post-processor" file in the temporary directory containing
 240 the line 'I<post-processor> "$@"'.  See B<fa-flacd>'s man page for
 241 information about this hook.
 242
 243 =item B<-t> [B<--tracks>] I<track-count>
 244
 245 Archive only the first I<track-count> tracks.  This is handy for
 246 ignoring data tracks.
 247
 248 =back
 249
 250 =head1 ENVIRONMENT
 251
 252 =over 4
 253
 254 =item CDDEV
 255
 256 B<fa-rip> uses this to rip audio and save the cuesheet for a CD.
 257 MusicBrainz::Client can usually figure this out automatically.
 258
 259 =back
 260
 261 =head1 AUTHORS
 262
 263 Written by Eric Gillespie <epg@pretzelnet.org>.
 264
 265 flac-archive is free software; you may redistribute it and/or modify
 266 it under the same terms as Perl itself.
 267
 268 =cut
 269
 270 # Local variables:
 271 # cperl-indent-level: 4
 272 # perl-indent-level: 4
 273 # indent-tabs-mode: nil
 274 # End:
 275
 276 # vi: set tabstop=4 expandtab: